TÌM GIÁ TRỊ MIN, MAX NHIỀU ĐIỀU KIỆN

tuanpmac · 31/3/20

Em có file đính kèm cùng đề bên trong nhờ cả nhà hỗ trợ Em ạ.

leonguyenz · 31/3/20

Công thức mảng:

Mã:

=MAX(($C$6:$C$5028=F6)*(MONTH($B$6:$B$5028)=1)*$D$6:$D$5028)

Hoặc dùng AGGREGATE (Excel 2010 trở lên)

Mã:

=AGGREGATE(14,6,$D$6:$D$5028*($C$6:$C$5028=F6)*(MONTH($B$6:$B$5028)=1),1)

tuanpmac · 31/3/20

leonguyenz đã viết:
Công thức mảng:

Mã:

=MAX(($C$6:$C$5028=F6)*(MONTH($B$6:$B$5028)=1)*$D$6:$D$5028)

Hoặc dùng AGGREGATE (Excel 2010 trở lên)

Mã:

=AGGREGATE(14,6,$D$6:$D$5028*($C$6:$C$5028=F6)*(MONTH($B$6:$B$5028)=1),1)

Cảm ơn bạn đã giúp, mình cũng thử dùng rồi nhưng chưa ra kết quả mong muốn.
Vì một mã sp trong 1 ngày có thể phát sinh nhiều lần, À có thể do diễn giải trong đề của mình hơi khó hiểu.
Cái mình mong muốn là so sánh tổng số phát sinh trong các ngày của tháng 1 tương ứng với những mã sp đó.

HieuCD · 31/3/20

tuanpmac đã viết:
Em có file đính kèm cùng đề bên trong nhờ cả nhà hỗ trợ Em ạ.

Mã:

G6 =MAX(SUMIFS($D$6:$D$5028,$C$6:$C$5028,F6,$B$6:$B$5028,"*/"&TEXT(G$5,"00")&"/*",$B$6:$B$5028,TEXT(ROW($1:$31),"00")&"/*"))

Nhấn Ctrl+Shift+Enter

tuanpmac · 31/3/20

HieuCD đã viết:
Mã:

G6 =MAX(SUMIFS($D$6:$D$5028,$C$6:$C$5028,F6,$B$6:$B$5028,"*/"&TEXT(G$5,"00")&"/*",$B$6:$B$5028,TEXT(ROW($1:$31),"00")&"/*"))

Nhấn Ctrl+Shift+Enter

Dạ đúng cái em cần rồi, Em cảm ơn Anh ạ

tuanpmac · 31/3/20

HieuCD đã viết:
Mã:

G6 =MAX(SUMIFS($D$6:$D$5028,$C$6:$C$5028,F6,$B$6:$B$5028,"*/"&TEXT(G$5,"00")&"/*",$B$6:$B$5028,TEXT(ROW($1:$31),"00")&"/*"))

Nhấn Ctrl+Shift+Enter

Trường hợp tìm giá trị nhỏ nhất bỏ giá trị 0 thì làm ntn ạ.

HieuCD · 31/3/20

tuanpmac đã viết:
Trường hợp tìm giá trị nhỏ nhất bỏ giá trị 0 thì làm ntn ạ.

Lớn nhất

Mã:

=MAX(SUMIFS($D$6:$D$5028,$C$6:$C$5028,F6,$B$6:$B$5028,TEXT(ROW($1:$31),"00")&"/"&TEXT(G$5,"00")&"/*"))

Nhỏ nhất

Mã:

=MIN(IF(SUMIFS($D$6:$D$5028,$C$6:$C$5028,F6,$B$6:$B$5028,TEXT(ROW($1:$31),"00")&"/"&TEXT(G$5,"00")&"/*")>0,SUMIFS($D$6:$D$5028,$C$6:$C$5028,F6,$B$6:$B$5028,TEXT(ROW($1:$31),"00")&"/"&TEXT(G$5,"00")&"/*")))

Nhấn Ctrl+Shift+Ente

Phan Thế Hiệp · 2/4/20

HieuCD đã viết:
Lớn nhất

Mã:

=MAX(SUMIFS($D$6:$D$5028,$C$6:$C$5028,F6,$B$6:$B$5028,TEXT(ROW($1:$31),"00")&"/"&TEXT(G$5,"00")&"/*"))

Nhỏ nhất

Mã:

=MIN(IF(SUMIFS($D$6:$D$5028,$C$6:$C$5028,F6,$B$6:$B$5028,TEXT(ROW($1:$31),"00")&"/"&TEXT(G$5,"00")&"/*")>0,SUMIFS($D$6:$D$5028,$C$6:$C$5028,F6,$B$6:$B$5028,TEXT(ROW($1:$31),"00")&"/"&TEXT(G$5,"00")&"/*")))

Nhấn Ctrl+Shift+Ente