tính giá điện dựa vào các chỉ tiêu của bảng đơn giá

[doichi9x]

cho số tiêu thụ điện trong tháng mình phải tính thành tiền dựa vào bảng đơn giá với các chỉ tiêu: 100 số đầu giá 550, 50 số tiếp giá 900, 50 số tiếp giá 1210, 100 số tiếp giá 1340, từ số 301 trở đi giá 1400

 

[nghiaphuc]

cho số tiêu thụ điện trong tháng mình phải tính thành tiền dựa vào bảng đơn giá với các chỉ tiêu: 100 số đầu giá 550, 50 số tiếp giá 900, 50 số tiếp giá 1210, 100 số tiếp giá 1340, từ số 301 trở đi giá 1400

Có lẽ đây là công thức tồi nhất cho trường hợp này: Giả sử A2=Số điện tiêu thụ, B2=Thành tiền. Khi đó:
B2=IF(A2<101,A2*550,IF(A2<151,55000+(A2-100)*900,IF(A2<201,100000+(A2-150)*1210,IF(A2<301,160500+(A2-200)*1340,249500+(A2-300)*1340))))

 

[nguyentinhhn]

Bạn nên dùng hàm Vlookup.
Xin lỗi công thức của mình chưa đúng

 

[linhngoc]

cho số tiêu thụ điện trong tháng mình phải tính thành tiền dựa vào bảng đơn giá với các chỉ tiêu: 100 số đầu giá 550, 50 số tiếp giá 900, 50 số tiếp giá 1210, 100 số tiếp giá 1340, từ số 301 trở đi giá 1400

------Mình thêm 1 cách tính nữa. Bạn tham khảo nhé!
VD: A2 là số điện tiêu thụ.
----B2==MIN(A2,100)*550+MIN(MAX(A2-100,0),50)*900+MIN(MAX(A2-150,0),50)*1210+MIN(MAX(A2-200,0),100)*1340+MAX(A2-300,0)*1400

 

[nghiaphuc]

Bạn nên dùng hàm Vlookup.

Trật rồi bạn ơi. Chẳng lẽ xài 301 Kwh cũng giống như xài 1000 Kwh sao? Giá 550, 900,... là giá tiền cho mỗi Kwh theo từng mức đó bạn.
VD: Tiêu thụ 110 Kwh thì
+ 100 Kwh đầu tính giá 550 --> 55000đ
+ 10 Kwh sau tính giá 900 --> 9000đ
--> Tổng cộng: 64000đ chứ không phải là 900đ đâu (tính như vầy thì nhà nước bù lỗ chết đó bạn).

 

[nguyentinhhn]

Xin lỗi công thức của mình chưa đúng, mình nhầm với việc tìm giá điện.

 

[nguyen duc man]

Bạn thử cách này xem

 

[tinpkk]

Dùng hàm vlookup và bảng phụ qui định đơn giá theo số điện năng tiêu thụ

 

[sealand]

Mình cũng tham gia khá nhiều bài về tính tiền điện bậc thang và đến giờ mình rút được 1 công thức tính không lồng hàm if nên không hạn chế về bậc. Chấp cả ông "điên nặng" chia thành 20 bậc. Nói chung khá đơn giản và dễ hiểu. Các bạn tham khảo nha (ô A2 là điện sử dụng)


=A2*550+IF(A2>100,A2-100,0)*350+IF(A2>150,A2-150,0)*310+IF(A2>200,A2-200,0)*130+IF(A2>300,A2-300,0)*60

 

[ptm0412]

Mình cũng tham gia khá nhiều bài về tính tiền điện bậc thang và đến giờ mình rút được 1 công thức tính không lồng hàm if nên không hạn chế về bậc. Chấp cả ông "điên nặng" chia thành 20 bậc. Nói chung khá đơn giản và dễ hiểu. Các bạn tham khảo nha (ô A2 là điện sử dụng)


=A2*550+IF(A2>100,A2-100,0)*350+IF(A2>150,A2-150,0)*310+IF(A2>200,A2-200,0)*130+IF(A2>300,A2-300,0)*60

Xét về phương pháp loại bỏ nhiều if lồng nhau thì công thức sealand giống giống với công thức của nhóc linhngoc: Cộng từng phần với nhau, mỗi phần chỉ 1 hoặc 2 If.

=MIN(A2,100)*550+MIN(MAX(A2-100,0),50)*900+MIN(MAX(A2-150,0),50)*1210+MIN(MAX(A2-200,0),100)*1340+MAX(A2-300,0)*1400

Mà công thức linhngoc có vận dụng min, max nên không có cái If nào. (chiêu của thầy nhóc). Nếu sealand cũng vận dụng max vào thì sẽ ngắn hơn:

=A2*550+MAX(A2-100,0)*350+MAX(A2-150,0)*310+MAX(A2-200,0)*130+MAX(A2-300,0)*60

Mà thực ra, các con số 350, 310, 130, 60 của sealand phải tính nhẩm nhẩm ra rồi điền vào. (nếu nhẩm không ra thì phải điền bài toán trừ vào đó).

 

[sealand]

Cám ơn anh Ptm 0412 đã có ý kiến cho công thức. Hàm Max gọn hơn nhưng thực chất của Max hay if thì cũng là chọn lấy điều kiện đúng. Cái mình muốn nêu để anh em tham khảo là thay đổi cách lập luận sẽ thay đổi công thức, cái này còn làm cho ta cơ sở khi viết hàm UDF sẽ ngắn gọn hơn. Trước đây, ta thường chia công suất sử dụng theo từng khoảng rồi nhân với từng đơn giá. Còn mình muốn tham gia là lấy tiền theo giá cơ sở cộng thêm các phần gia tăng giá. Cái mà anh nói là tính nhẩm ấy chính là mức gia tăng từng khoảng giá.
Đây cũng là nội dung những ai quan tâm tới thuế TNCN cũng có liên quan nên mình đề cập lại thôi, thú thật trước khi gửi bài mình cũng chưa đọc bài của ai cả nên không biết có trùng lặp hay không ? Lần sau mình sẽ cẩn thận hơn trong tham gia gửi bài.

 

[ptm0412]

Alo Alo, mình không nói là bài trùng lặp đâu sealand ơi. Chỉ nói các phương pháp loại bỏ nhiều If lồng nhau thôi.

Khi nghĩ ra 1 cách nào đó, có khi là mới toanh, cũng có khi là có sẵn của ai đó ở đâu đó, nhưng vẫn là của mình tự nghĩ ra mà, có sao đâu. Mình chỉ rút gọn công thức của sealand thôi, chứ ý tưởng vẫn của sealand.
Phương pháp của linhngoc lại khác nữa, chỉ giống 1 cái là loại bỏ được If lồng (nói theo sealand thì dù 2 chục mức giá cũng không sợ).

 

[nguyenvietviet]

Các bạn ơi có thể dùng marco không, chứ làm thế này nếu mà nhiều trường thì tính toán sẽ rất lâu.
Mong các bạn