tìm giá trị nhỏ nhất trong hàng có điều kiện (1 người xem)

[sep_hatxel]

Mình có vấn đề này mong GPE giúp đỡ:
+ Hàng 1 là các mã
+ Giá trị của các mã từ B2:AL51
- Mình cần tìm các giá trị nhỏ nhất của các mã trong hàng và mã tương ứng với giá trị nhỏ nhất đó => kết quả dán vào các cột AM, AN, AO AP
- Mình có làm ví dụ cho 3 hàng đầu tiên theo file gửi.
- Xin cảm ơn các bạn!

 

[HieuCD]

AM2 =SMALL($B2:$AL2,COLUMN(A1))
AN2 =SMALL($B2:$AL2,COLUMN(B1))
AO2 =INDEX($B$1:$AL$1,,MATCH(AM2,$B2:$AL2,0))
Ap2 =INDEX(OFFSET($B$1,,MATCH(AO2,$B$1:$AL$1,0),,39),,MATCH(AN2,OFFSET($B2,,MATCH(AO2,$B$1:$AL$1,0),,39),0))

 

[ndu96081631]

Mình có vấn đề này mong GPE giúp đỡ:
+ Hàng 1 là các mã
+ Giá trị của các mã từ B2:AL51
- Mình cần tìm các giá trị nhỏ nhất của các mã trong hàng và mã tương ứng với giá trị nhỏ nhất đó => kết quả dán vào các cột AM, AN, AO AP
- Mình có làm ví dụ cho 3 hàng đầu tiên theo file gửi.
- Xin cảm ơn các bạn!

Công thức AM2

=SMALL($B2:$AL2,1)

Công thức AN2

=SMALL($B2:$AL2,2)

Công thức AO2

=LOOKUP(2,1/($B2:$AL2+COLUMN($B2:$AL2)/10^6=SMALL($B2:$AL2+COLUMN($B2:$AL2)/10^6,COLUMNS($A$1:A$1))),$B$1:$AL$1)

Kéo fill AO2 sang AP2
Quét chọn AM2:AP2 ---> Kéo fill xuống

 

[eke_rula]

Mình có vấn đề này mong GPE giúp đỡ:
+ Hàng 1 là các mã
+ Giá trị của các mã từ B2:AL51
- Mình cần tìm các giá trị nhỏ nhất của các mã trong hàng và mã tương ứng với giá trị nhỏ nhất đó => kết quả dán vào các cột AM, AN, AO AP
- Mình có làm ví dụ cho 3 hàng đầu tiên theo file gửi.
- Xin cảm ơn các bạn!

Cách khác dùng CT mảng tại AO2, AP2:

AO=INDEX($B$1:$AL$1,MATCH(1,($B2:$AL2=AM2)*($B$1:$AL$1<>AN2),))
Hoặc
AO=INDEX($B$1:$AL$1,SMALL(IF($B2:$AL2=AM2,COLUMN($A$1:$AK$1)),COUNTIF($AM2:AM2,AM2)))

Bấm Ctrl+Shift+Enter fill xuống, rồi fill sang cột AP!!!

 

[sep_hatxel]

Vâng, xin cảm ơn các bạn và GPE nhiều quá! Xin chân thành cảm ơn!