Hàm giá trị tuyệt đối (1 người xem)

[trungletien]

Chào các bác,

Em có 1 file excel như đính kèm (có date và price). Hiện tại em đang muốn trả ra giá trị ở ô D8 là giá trị tuyệt đối lớn nhất của price trong tháng 1/2015 mà vẫn giữ nguyên dấu của giá trị đó. Em có giải thích cụ thể hơn ở trong file.

Em dùng hàm max(index(abs thì ra được giá trị tuyệt đối lớn nhất nhưng kết quả trả ra là giá trị tuyệt đối (mang dấu dương) trong khi em muốn giá trị phải được giữ nguyên dấu và chỉ trong 1 hàm ạ.

Em cảm ơn các bác nhiều.

 

[ppc0312]

theo trong file thì -1.32 nằm vào tháng 2 rui, vậy kết quả sao , cho riêng tháng hay là tất cả.

kết quả nằm ở cell nào, và công thức của bạn thử đâu rui?

 

[trungletien]

Thanks bác đã nhắc. Em gửi lại bác file ạ nhưng mà sao công thức em đặt ở file này nó lại không ra ấy ạ Bác xem giúp em ạ.

 

[ppc0312]

công thức sau là được
=INDEX(B2:B7,MATCH(MAX(INDEX(ABS(B2:B7)*(A2:A7>=A12)*(A2:A7<=B12),0)),INDEX(ABS(B2:B7)*(A2:A7>=A12)*(A2:A7<=B12),0),0))

 

[giaiphap]

Nếu tìm trong tháng 1 thì sử dụng thế này:
=INDEX(B2:B7;MATCH(MAX(ABS(B2:B7)*(MONTH(A2:A7)=1));ABS(B2:B7)*(MONTH(A2:A7)=1);0) )
Nhớ kết thúc bằng Ctrl + Shift + Enter

 

[trungletien]

Em cảm ơn bác giaiphap!

Bác cho em hỏi chút là công thức trên đúng với hàm "max" nhưng sao khi em thay "max" bằng "min" vào trong công thức thì nó lại không ra đúng ạ

 

[trungletien]

Bác xem hộ em ô D8 em dùng công thức của bác giaiphap thay min bằng max thì nó ra kết quả không đúng ạ

 

[dhn46]

Bạn tham khảo cái sau enter bình thường

=IF(COUNTIF($B$2:$B$7,MAX(INDEX(ABS(B2:B7)*(MONTH(A2:A7)=1),0))),MAX(INDEX(ABS(B2:B7)*(MONTH(A2:A7)=1),0)),-MAX(INDEX(ABS(B2:B7)*(MONTH(A2:A7)=1),0)))

 

[trungletien]

Em cam on bac dhn46!

Cong thức của bác vẫn ra giá trị max đúng như em muốn, nhưng nếu giờ em muốn, ngược lại, tìm giá trị mà absolute value của nó là min và trả ra giá trịi giữ nguyên dấu thì thay "max" bằng "min" trong công thức của bác thì lại ra 0.0000 ạ. (Em có gửi file đính kèm ạ).

Bác xem giúp em ạ.

Em cảm ơn bác ạ.

 

[ppc0312]

Em cam on bac dhn46!

Cong thức của bác vẫn ra giá trị max đúng như em muốn, nhưng nếu giờ em muốn, ngược lại, tìm giá trị mà absolute value của nó là min và trả ra giá trịi giữ nguyên dấu thì thay "max" bằng "min" trong công thức của bác thì lại ra 0.0000 ạ. (Em có gửi file đính kèm ạ).

Bác xem giúp em ạ.

Em cảm ơn bác ạ.

Hỏi max lại mong kết quả min là sao?, lần sau bạn cần xác định rõ xem mong kết quả gì hay các kết quả gì, thì mới có giúp đỡ chính xác được.

Công thức cho min đây (thay thành max cũng được)

=INDEX(B$2:B$7,MATCH(MIN(IF((A$2:A$7>=A12)*(A$2:A$7<=B12)=1,ABS(B$2:B$7),"")),IF((A$2:A$7>=A12)*(A$2:A$7<=B12)=1,ABS(B$2:B$7),""),0))

nhớ bấm Ctrl+Shift+Enter khi kết thúc nhập công thức

 

[trungletien]

Thanks bac ppc0312 ạ.

Thực ra công việc của em là tìm giá trị min, max và trung bình của giá trị tuyệt đối theo từng tháng ạ Em xin lỗi vì đã không hỏi rõ ngay từ đầu ạ

Bác có thể giúp em nốt công thức tính average của trị tuyệt đối của dãy B2:B7 trong tháng 1 được không ạ? (average của trị tuyệt đối chứ không phải là trị tuyệt đối của average ạ )

Em đội ơn bác ạ

 

[khuongvietphong]

Bạn dùng hàm này:

=SUMPRODUCT((MONTH(A2:A7)=1)*(ABS(B2:B7)))/SUMPRODUCT((MONTH(A2:A7)=1)*1)

 

[trungletien]

Em làm được rồi ạ! Em cảm ơn các bác nhiều ạ!!