Excel's Math Functions - Các Hàm về Toán học (1 người xem)

[BNTT]

List of Excel's Math Functions


Danh mục các hàm toán học

ABS (number): Tính trị tuyệt đối của một số (giá trị tuyệt đối của một số là số luôn luôn dương).

CEILING (number, significance) : Làm tròn lên một số (cách xa khỏi số 0) đến bội số gần nhất của significance.

COMBIN (number, number_chosen) : Trả về số tổ hợp được chọn từ một số các phần tử. Thường dùng để xác định tổng số nhóm có được từ một số các phần tử.

EVEN (number) : Làm tròn một số đến số nguyên chẵn gần nhất

EXP (number) : Tính lũy thừa cơ số e của một số

FACT (number) : Tính giai thừa của một số

FACTDOUBLE (number) : Tính giai thừa cấp hai của một số

FLOOR (number, significance) : Làm tròn xuống một số đến bội số gần nhất

GCD (number1, number2, ...) : Tìm ước số chung lớn nhất của các số

INT (number) : Làm tròn một số xuống số nguyên gần nhất

LCM (number1, number2, ...) : Tìm bội số chung nhỏ nhất của các số

LN (number) : Tính logarit tự nhiên của một số

LOG (number) : Tính logarit của một số

LOG10 (number) : Tính logarit cơ số 10 của một số

MDETERM (array) : Tính định thức của một ma trận

MINVERSE (array) : Tìm ma trận nghịch đảo của một ma trận

MMULT (array1, array2) : Tính tích hai ma trận

MOD (number, divisor) : Lấy phần dư của một phép chia.

MROUND (number, multiple) : Làm tròn một số đến bội số của một số khác

MULTINOMIAL (number1, number2, ...) : Tính tỷ lệ giữa giai thừa tổng và tích giai thừa các số

ODD (number): Làm tròn một số đến số nguyên lẻ gần nhất

PI () : Trả về giá trị con số Pi

POWER (number, power) : Tính lũy thừa của một số

PRODUCT(number1, number2, ...) : Tính tích các số

QUOTIENT (numberator, denominator) : Lấy phần nguyên của một phép chia

RAND () : Trả về một số ngẫu nhiên giữa 0 và 1

RANDBETWEEN (bottom, top) : Trả về một số ngẫu nhiên giữa một khoảng tùy chọn

ROMAN (number, form) : Chuyển một số (Ả-rập) về dạng số La-mã theo định dạng tùy chọn

ROUND (number, num_digits) : Làm tròn một số theo sự chỉ định

ROUNDDOWN (number, num_digits) : Làm tròn xuống một số theo sự chỉ định

ROUNDUP (number, num_digits) : Làm tròn lên một số theo sự chỉ định

SERIESSUM (x, n, m, coefficients) : Tính tổng lũy thừa của một chuỗi số

SIGN (number) : Trả về dấu (đại số) của một số

SQRT (number) : Tính căn bậc hai của một số

SQRTPI (number) : Tính căn bậc hai của một số được nhân với Pi

SUBTOTAL (function_num, ref1, ref2, ...) : Tính toán cho một nhóm con trong một danh sách tùy theo phép tính được chỉ định

SUM (number1, number2, ...) : Tính tổng các số

SUMIF (range, criteria, sum_range) : Tính tổng các ô thỏa một điều kiện chỉ định

SUMIFS (sum_range, criteria_range1, criteria1, criteria_range2, criteria2, …) : Tính tổng các ô thỏa nhiều điều kiện chỉ định[/URL]


SUMPRODUCT (array1, array2, ...) : Tính tổng các tích của các phần tử trong các mảng dữ liệu

SUMSQ (number1, number2, ...) : Tính tổng bình phương của các số

SUMX2MY2 (array_x, array_y) : Tính tổng của hiệu bình phương của các phần tử trong hai mảng giá trị

SUMX2PY2 (array_x, array_y) : Tính tổng của tổng bình phương của các phần tử trong hai mảng giá trị

SUMXMY2 (array_x, array_y) : Tính tổng của bình phương của hiệu các phần tử trong hai mảng giá trị

TRUNC (number, num_digits) : Lấy phần nguyên của một số (mà không làm tròn)​

 

[BNTT]

Tìm hiểu về vấn đề làm tròn số trong Excel


Tìm hiểu về vấn đề làm tròn số trong Excel

Excel có nhiều hàm dùng để làm tròn số. Mỗi hàm có một chức năng riêng.
Bài này xin nêu ra những cái khác nhau và giống nhau giữa các hàm:
ROUND(), ROUNDUP(), ROUNDDOWN(), MROUND(), CEILING(), FLOOR(), EVEN(), ODD(), INT() và TRUNC()

• Bài tham khảo thêm: Bạn đã thử các hàm làm tròn số chưa? của chị HanDung107

Hàm ROUND()

Cú pháp: = ROUND(number, num_digits)

• number: Con số sẽ làm tròn
  
  
• num_digits: Là một số nguyên, chỉ cách mà bạn muốn làm tròn

num_digits > 0 : làm tròn đến số thập phân được chỉ định

num_digits = 0 : làm tròn đến số nguyên gần nhất

num_digits < 0 : làm tròn đến phần nguyên được chỉ định
​

Ví dụ: Với con số 1234.5678

ROUND(1234.5678, 3) = 1234.568
ROUND(1234.5678, 2) = 1234.57
ROUND(1234.5678, 1) = 1234.6
ROUND(1234.5678, 0) = 1235
ROUND(1234.5678, -1) = 1230
ROUND(1234.5678, -2) = 1200
ROUND(1234.5678, -3) = 1000
​

 

[BNTT]

Tìm hiểu về vấn đề làm tròn số trong Excel


Hàm MROUND()

Làm tròn đến bội số của một số khác

Cú pháp: = MROUND(number, multiple)

• number: Con số sẽ làm tròn
  
  
• multiple: Con số mà bạn cần làm tròn number đến bội số của nó

- Nếu number và multiple khác dấu, hàm sẽ báo lỗi #NUM!
- Nếu number và multiple bằng nhau, kết quả là chính số đó
- MROUND() sẽ làm tròn lên, nếu phần chia của phép chia number cho multiple lớn hơn hoặc bằng 1/2 multiple, và làm tròn xuống nếu phần chia của phép chia number cho multiple nhỏ hơn 1/2 multiple
​

Ví dụ:

MROUND(5, 2) = 6 (do 5/2 > 2/2, bội số của 2 gần nhất mà lớn hơn 5 là 6)
MROUND(11, 5) = 10 (do 11/5 < 5/2, bội số của 5 gần nhất mà nhỏ hơn 11 là 10)
MROUND(13, 5) = 15 (do 13/5 > 5/2, bội số của 5 gần nhất mà lớn hơn 13 là 15)
MROUND(5, 5) = 5 (number và multiple bằng nhau)
MROUND(7.31, 0.5) = 7.5 (do 7.31/0.5 > 0.5/2, bội số của 0.5 gần nhất mà lớn hơn 7.31 là 7.5)
MROUND(-11, -5) = -10 (do -11/-5 > -5/2, bội số của -5 gần nhất mà lớn hơn -11 là -10)
MROUND(-11, 5) = #NUM! (number và multiple khác dấu)​

 

[BNTT]

Tìm hiểu về vấn đề làm tròn số trong Excel


Hàm ROUNDDOWN() và Hàm ROUNDUP()

Hai hàm này, về cơ bản thì giống hàm ROUND(), chỉ khác là chúng chỉ làm tròn theo một chiều: ROUNDDONW() luôn luôn làm tròn một số về số 0, còn ROUNDUP() thì luôn luôn làm tròn một số ra xa số 0.

Cú pháp:

= ROUNDDOWN(number, num_digits)
= ROUNDUP(number, num_digits)

• number: Con số sẽ làm tròn
  
  
• num_digits: Là một số nguyên, chỉ cách mà bạn muốn làm tròn

num_digits > 0 : làm tròn đến số thập phân được chỉ định

num_digits = 0 : làm tròn đến số nguyên gần nhất

num_digits < 0 : làm tròn đến phần nguyên được chỉ định
​

Ví dụ: So sánh giữa ROUNDDOWN() và ROUNDUP()

​

 

[BNTT]

Tìm hiểu về vấn đề làm tròn số trong Excel


Hàm CEILING() và Hàm FLOOR()

Hai hàm này, hao hao giống hàm MROUND(), là làm tròn đến bội số gần nhất của một số được chỉ định, chỉ khác đôi chút về cách tính: CEILING() luôn luôn làm tròn một số ra xa số 0, còn FLOOR() làm tròn về số 0.

Cú pháp:

= CEILING(number, significance)
= FLOOR(number, significance)

• number: Con số sẽ làm tròn
  
  
• significance: Con số mà bạn cần làm tròn number đến bội số của nó

- Nếu number và significancekhác dấu, hàm sẽ báo lỗi #NUM!
- Nếu number là bội số của significance, kết quả là chính số đó
​

Ví dụ: So sánh giữa CEILING(), FLOOR() và MROUND() - ở ví dụ này, xem như significance là multiple của MROUND()

​

 

[BNTT]

Tìm hiểu về vấn đề làm tròn số trong Excel


Hàm EVEN() và Hàm ODD()

Hai hàm này làm tròn rất đơn giản. EVEN() làm tròn đến số nguyên chẵn gần nhất, còn ODD() làm tròn đến số nguyên lẻ gần nhất. Cả hai đều làm tròn theo kiểu chạy xa khỏi số 0.

Cú pháp: = EVEN(number) | = ODD(number)


Ví dụ:

EVEN(14.2) = 16
EVEN(-23) = 24
ODD(58.1) = 59
ODD(-6) = -7
​

 

[BNTT]

Tìm hiểu về vấn đề làm tròn số trong Excel


Hàm INT() và hàm TRUNC()

Hai hàm này gần như giống nhau nếu như bạn muốn làm tròn một số thành một số nguyên.

Cú pháp:

= INT(number)

= TRUNC(number [, num_digits])
​

• number: Số cần làm tròn

• num_digits: Là một số nguyên, chỉ cách mà bạn muốn cắt bớt số
  

num_digits > 0 : nếu number là một số thập phân, thì num_digits chỉ ra số con số thập phân mà bạn muốn giữ lại (sau dấu phẩy)

num_digits = 0 hoặc không nhập: cắt bỏ hết phần thập phân của number (nếu có)

num_digits < 0 : làm tròn number thành một số nguyên và làm tròn number sang trái thành một bội số của 10 (xem thêm ở ví dụ)
​

​

Hàm INT() làm tròn một số tới số nguyên gần nhất

Đối với số dương, hàm INT() và TRUNC() cho kết quả giống nhau (num_digits của TRUNC() = 0 hoặc không có), nhưng đối với số âm thì hai hàm này sẽ cho kết quả hoàn toàn khác nhau.

Ví dụ:

INT( 123.456) = 123 | TRUNC( 123.456) = 123

INT(-123.456) = -124 | TRUNC(-123.456) = -123
​

Khi num_digits khác 0, TRUNC() khác hẳn với ROUND() ở chỗ: ROUND() thì làm tròn, còn TRUNC() chỉ cắt bỏ bớt số chứ không làm tròn.

Một số ví dụ về hàm TRUNC()

​

 

[BNTT]

Tìm hiểu về vấn đề làm tròn số trong Excel


Dùng TRUNC() để sửa lỗi Excel

Excel có một số lỗi rất vô duyên mà chắc hẳn trong chúng ta ai cũng vài lần nhức đầu với nó. Nhất là khi làm việc với số thập phân.

Tôi xin nêu một ví dụ rất nhỏ: Đố bạn 2.02 trừ 2.01 bằng bao nhiêu ? Chắc các bạn sẽ cười. Con nít cũng biết:

2.02 - 2.01 = 0.01
​

Nhưng Excel thì không biết ! Các bạn thử nhập phép tính 2.02 - 2.01 vào một ô nào đó, rồi cho ô này có 16 số lẻ xem, các bạn sẽ thấy Excel làm toán:

2.02 - 2.01 = 0.0100000000000002
​

Sao đây? Nếu các bạn dùng kết quả của 2.02-2.01 làm một tham số của VLOOKUP(), các bạn có nhận được kết quả chính xác không ?

Để chắc ăn, tôi dùng cái này:

= TRUNC(2.02 - 2.01, 2) = 0.01
​

Bây giờ thì định dạng ô đó có đến 100 số lẻ cũng vẫn đúng.

​

 

[BNTT]

Tính tổng các giá trị


Hàm SUM()

Khi cộng các giá trị với nhau trong Excel, ta có thể dùng dấu cộng (+) hoặc dùng hàm SUM()

Cú pháp: = SUM(number1 [, number2...])

Trong Excel 2007, bạn có thể dùng SUM() để để tính tổng của 255 giá trị lại với nhau (trong những version trước, con số này chỉ là 30)

Ví dụ: = SUM(A2:A13, C2:C13, E2:E13)
​

 

[BNTT]

Hàm MOD()

Dùng để lấy số dư của một phép chia

Cú pháp: = MOD(number, divisor)

number: Số bị chia
divisor: Số chia
​

Ví dụ: MOD(24, 10) = 4 (24 chia 10 được 2, dư 4)
​

 

[BNTT]

Cộng các ô cách nhau một số hàng cố định

Có một bài toán như sau:

Trong một cột dữ liệu, người ta muốn tính tổng của cách ô cách nhau mỗi n hàng nào đó.
Ví dụ, trong dãy A1:A20, tính tổng của các ô cách nhau 5 ô, nghĩa là lấy A1 + A6 + A11 + A16

Nói tới hàng, ta nghĩ đến hàm ROW(): ROW(A1) = 1, ROW(A6) = 6, v.v...

Và ở ví dụ vừa nêu trên đây, ta để ý các con số 1, 6, 11, 16 khi đem chia cho 5 đều dư 1, vậy ta nghĩ đến hàm MOD(), lấy số thứ tự của hàng chia cho 5: MOD(ROW(A1), 5) = 1, MOD(ROW(A6), 5) = 1, v.v...

Vậy ta sẽ lập công thức cho mảng A1:A20:
Xét trong khối A1:A20, ô nào có số thứ tự của hàng chia cho 5 mà dư 1, thì lấy các ô đó cộng lại:

{= SUM(IF(MOD(ROW(A1:A20), 5) = 1, A1:A20, 0))}
​

Hay cụ thể hơn, gọi dãy ô để tính tổng là range, và số hàng cách nhau giữa các ô là n, ta sẽ có công thức:

{= SUM(IF(MOD(ROW(range), n) = 1, range, 0))}
​

Con số 1 ở đây không phải là con số cố định, mà nó là số dư của phép chia của số thứ tự cho n. Do đó, tùy vào điều kiện của bài toán mà ta thay bằng con số thích hợp.
Chẳng hạn, cũng ví dụ trên đây, như ta muốn tính tổng của các ô A2, A7, A12, A17 thì công thức sẽ là:

{= SUM(IF(MOD(ROW(A1:A20), 5) = 2, A1:A20, 0))}
​

(2 là số dư của 2, 7, 12, 17 cho 5)

​

Cộng các ô có số thứ tự hàng là chẵn, hoặc có số thứ tự hàng là lẻ

Từ bài toán trên đây, ta có công thức để cộng các ô có số thứ tự hàng làm chẵn:

{= SUM(IF(MOD(ROW(Range), 2) = 0, Range, 0))}
​

Và công thức để cộng các ô có số thứ tự hàng làm lẻ:

{= SUM(IF(MOD(ROW(Range), 2) = 1, Range, 0))}
​

----------------------- Xem thêm: Hàm ROW()​

 

[BNTT]

Xem một năm có phải là năm nhuận hay không

Nếu bạn muốn có một công thức để xem thử một năm nào đó có phải là năm nhuận hay không, bạn có thể dùng hàm MOD().
Năm nhuận, là năm chia hết cho 4, hay phép dư của phép chia số năm cho 4 thì bẳng 0 ở công thức sau đây:

= MOD(year, 4)
​

Số năm phải là một con số có 4 chữ số.

Công thức trên chỉ đúng trong khoảng từ năm 1901 đến 2099 (có lẽ chúng ta cũng sống tối đa trong khoảng thời gian này thôi). Công thức này không đúng với năm 1900 và 2100, bởi vì điều kiện để tính năm nhuận còn có chuyện: Năm nhuận là năm chia hết cho 4, nếu năm này tận cùng bằng hai con số 0 thì nó phải chia hết cho 400 (ví dụ, năm 2000).

Vậy, để có một công thức đúng cho tất cả mọi năm, ta làm một công thức luận lý như sau:

= (MOD(year, 4) = 0) - (MOD(year, 100) = 0) + (MOD(year, 400) = 0)
​

Nếu công thức này cho đáp số là 1 (TRUE), thì đó là năm nhuận, còn nếu cho đáp số là 0 (FALSE), thì đó không phải là năm nhuận.
​

 

[BNTT]

Ứng dụng của hàm MOD() trong định dạng bảng tính

Chắc cũng có một lúc nào đó, bạn thích định dạng cho bảng tính của mình theo kiểu Ledger Shading. Ledger Shading là kiểu định dạng các hàng có màu xen kẽ nhau (ví dụ, xanh và trắng). Loại định dạng này thích hợp cho những danh sách dài, có nhiều cột, giúp ta phân biệt được hàng này với hàng kia cách dễ dàng, ít khi bị nhìn lầm dữ liệu giữa các hàng...

Hình sau đây là một ví dụ:
​

​

Dĩ nhiên là việc này rất dễ thực hiện, chúng ta chỉ cần chọn các hàng xen kẽ nhau và tô màu cho nó. Tuy nhiên, nếu làm thủ công bằng tay, thì sẽ có một số bất tiện sau:

- Rất lâu cho những bảng dữ liệu lớn.

- Mỗi khi chèn thêm một hàng hoặc xóa bớt một hàng, thì phải định dạng lại.
​

Để tránh những bất tiện đó, bạn có thể dùng một liên kết giữa hàm MOD() và chức năng Conditional Formatting (định dạng có điều kiện) của Excel.

Cách làm như sau:

1. Chọn vùng bạn muốn định dạng
   
   
2. Gọi hộp thoại Conditional Formatting, và chọn New Ruler để mở hộp thoại New Formatting Ruler
   
   
3. Chọn Use a Formula to Determine Which Cells to Format
   
   
4. Trong khung Format values where this formular is true, gõ công thức = MOD(ROW(), 2)
   
   

   
   ​
   
   
5. Nhấn nút Format... để mở hộp thoại Format Cells
   
   
6. Chọn tab Fills, chọn màu bạn thích tô cho các hàng xen kẽ với màu trắng, rồi nhấn OK để quay về hộp thoại New Formatting Ruler
   
   
7. Nhấn OK

Công thức = MOD(ROW(), 2) sẽ trả về 1 cho những hàng có số thứ tự lẻ và trả về 0 cho những hàng có số thứ tự chẵn. Bởi vì 1 thì tương đương với TRUE, nên Excel sẽ áp dụng màu tô mà bạn đã chọn cho tất cả những hàng có số thứ tự lẻ trong vùng bạn muốn định dạng, và bỏ qua những hàng có số thứ tự chẵn.


Tương tự,

• Nếu muốn định dạng các cột có màu xen kẽ, bạn chỉ cần thay công thức ở trên thành:
  = MOD(COLUMN(), 2)
  
  
• Nếu thích định dạng cho hàng có số thứ tự lẻ thì không tô màu, còn hàng có số thứ tự chẵn mới tô màu, bạn thay đổi công thức trên một tí:
  = MOD(ROW() + 1, 2)

----------------------- Xem thêm: Hàm ROW(), Hàm COLUMN()​

 

[BNTT]

Lấy một số ngẫu nhiên

Đôi khi, chúng ta cần có một dữ liệu mô phỏng để thử nghiệm một công việc, một kế hoạch gì đó, và cần điền một vài con số vào để có cái mà thử nghiệm. Trong nhiều trường hợp, chúng ta sẽ cần có những con số ngẫu nhiên, không biết trước. Excel cung cấp cho chúng ta hai hàm để lấy số ngẫu nhiên, đó là RAND() và RANDBETWEEN().

Hàm RAND()

Cú pháp: = RAND()

Hàm RAND() trả về một con số ngẫu nhiên lớn hơn hoặc bằng 0 và nhỏ hơn 1. Nếu dùng hàm để lấy một giá trị thời gian, thì RAND() là hàm thích hợp nhất.

Bên cạnh đó, cũng có những cách để ép RAND() cung cấp cho chúng ta những con số ngẫu nhiên nằm giữa hai giá trị nào đó.

• Để lấy một số ngẫu nhiên lớn hơn hoặc bằng 0 và nhỏ hơn n, ta dùng cú pháp:

RAND() * n​

Ví dụ, công thức sau đây sẽ cung cấp cho chúng ta một con số ngẫu nhiên giữa 0 và 30:

= RAND() * 30
​

• Trường hợp khác, mở rộng hơn, chúng ta cần có một con số ngẫu nhiên lớn hơn hoặc bằng số m nào đó, và nhỏ hơn số n nào đó, ta dùng cú pháp:

RAND() * (n - m) + m​

Ví dụ, để lấy một số ngẫu nhiên lớn hơn hoặc bằng 100 và nhỏ hơn 200, ta dùng công thức:

= RAND() * (200 - 100) + 100
​

Lưu ý:

Do hàm RAND() là một hàm biến đổi (volatile function), tức là kết quả do RAND() cung cấp có thể thay đổi mỗi khi bạn cập nhật bảng tính hoặc mở lại bảng tính, ngay cả khi bạn thay đổi một ô nào đó trong bảng tính...

Để có một kết quả ngẫu nhiên nhưng không thay đổi, bạn dùng cách sau:
Sau khi nhập công thức = RAND() vào, bạn nhấn F9 và sau đó nhấn Enter. Động tác này sẽ lấy một con số ngẫu nhiên ngay tại thời điểm gõ công thức, nhưng sau đó thì luôn dùng con số này, vì trong ô nhập công thức sẽ không còn hàm RAND() nữa.

​

 

[BNTT]

Lấy một số ngẫu nhiên

Ở bài trên, tôi đã trình bày cách lấy một số ngẫu nhiên nằm trong một khoảng {n, m} nào đó:

= RAND() * (n - m) + m​

Có một hàm nữa trong Excel có chức năng tương tự công thức trên: Hàm RANDBETWEEN().
RANDBETWEEN() chỉ khác RAND() ở chỗ: RANDBETWEEN() cho kết quả là số nguyên, còn RAND() thì cho kết quả vừa là số nguyên vừa là số thập phân.


Hàm RANDBETWEEN()

Hàm RANDBETWEEN() trả về một số nguyên ngẫu nhiên nằm trong một khoảng cho trước.

Cú pháp: = RANDBETWEEN(bottom, top)

bottom: Số nhỏ nhất trong dãy tìm số ngẫu nhiên (kết quả sẽ lớn hơn hoặc bằng số này)

top: Số lớn nhất trong dãy tìm số ngẫu nhiên (kết quả sẽ nhỏ hơn hoặc bằng số này)
​

Ví dụ: = RANDBETWEEN(0, 59) sẽ cho kết quả là một số nguyên nằm trong khoảng 0 tới 59.
​

 

[BNTT]

Các hàm toán học khác


Hàm ABS()

Lấy trị tuyệt đối của một số

Cú pháp: = ABS(number)

number: Số muốn tính trị tuyệt đối
​

Ví dụ:

ABS(2) = 2

ABS(-5) = 5

ABS(A2) = 7 (A2 đang chứa công thức = 3.5 x -2)
​

 

[BNTT]

Các hàm toán học khác


Hàm COMBIN()

Trả về số tổ hợp của một số phần tử cho trước

Cú pháp: = COMBIN(number, number_chosen)

number: Tổng số phần tử

number_chosen: Số phần tử trong mỗi tổ hợp
​

Chú ý:

• Nếu các đối số là số thập phân, hàm chỉ lấy phần nguyên

• Nếu các đối số không phải là số, COMBIN sẽ báo lỗi #VALUE!

• Nếu number < 0, number_chosen < 0, hoặc number < number_chosen, COMBIN sẽ báo lỗi #NUM!

• Tổ hợp khác với hoán vị: Tổ hợp không quan tâm đến thứ tự của các phần tử trong mỗi tổ hợp; còn hoán vị thì thứ tự của mỗi phần tử đều có ý nghĩa.

• COMBIN được tính như công thức sau đây (với n = number, k = number_chosen)

Trong đó:

​

Ví dụ:

Với 4 phần tử Mai, Lan, Cúc, Trúc có thể xếp được bao nhiêu tổ hợp khác nhau, với mỗi tổ hợp gồm 2 phần tử ?

= COMBIN(4, 2) = 6
​

6 tổ hợp này là: Mai-Lan, Mai-Cúc, Mai-Trúc, Lan-Cúc, Lan-Trúc và Cúc-Trúc
​

 

[BNTT]

Các hàm toán học khác


Hàm EXP()

Tính lũy thừa của cơ số e (2.71828182845905...)

Cú pháp: = EXP(number)

number: số mũ của cơ số e​

Lưu ý:

- Để tính lũy thừa của cơ số khác, bạn có thể dùng toán tử ^ (dấu mũ), hoặc dùng hàm POWER()

- Hàm EXP() là nghịch đảo của hàm LN(): tính logarit tự nhiên của một số
​

Ví dụ:

EXP(1) = 2.718282 (là chính cơ số e)
EXP(2) = 7.389056 (bình phương của e)
​

 

[BNTT]

Các hàm toán học khác


Hàm FACT()

Tính giai thừa của một số.

Cú pháp: = FACT(number)

number: số cần tính giai thừa
​

Lưu ý:

- number phải là một số dương

- Nếu number là số thập phân, FACT() sẽ lấy phần nguyên của number để tính
​

Ví dụ:

FACT(5) = 120 (5! = 1 x 2 x 3 x 4 x 5 = 120)

FACT(2.9) = 2 (2! = 1 x 2 = 2)

FACT(0) = 1 (0! = 1)

FACT(-3) = #NUM!
​

 

[BNTT]

Các hàm toán học khác


Hàm FACTDOUBLE()

Tính giai thừa cấp hai của một số.

Giai thừa cấp hai (ký hiệu bằng hai dấu !!) được tính như sau:

- Với số chẵn: n!! = n x (n-2) x (n-4) x ... x 4 x 2

- Với số lẻ: n!! = n x (n-2) x (n-4) x ... x 3 x 1
​

​

Cú pháp: = FACTDOUBLE(number)

number: số cần tính giai thừa cấp hai
​

Lưu ý:

- number phải là một số dương

- Nếu number là số thập phân, FACTDOUBLE() sẽ lấy phần nguyên của number để tính
​

Ví dụ:

FACTDOUBLE(6) = 48 (6!! = 6 x 4 x 2 = 24)

FACTDOUBLE(7) = 105 (7!! = 7 x 5 x 3 x 1 = 105)
​

 

[BNTT]

Các hàm toán học khác


Hàm GCD()

GCD là viết tắt của chữ Greatest Common Divisor: Ước số chung lớn nhất.

Cú pháp: = GCD(number1, number2 [,number3...])

number1, number2...: những số mà bạn bạn cần tìm ước số chung lớn nhất

GCD() có thể tìm ước số chung lớn nhất của một dãy có đến 255 giá trị (với Excel 2003 trở về trước thì con số này là 19)
​

Lưu ý:

Nếu có bất kỳ một number nào < 0, GCD() sẽ báo lỗi #NUM!

Nếu có bất kỳ một number nào không phải là một con số, GDC() sẽ báo lỗi #VALUE!

Nếu number là số thập phân, GCD() chỉ tính toán với phần nguyên của nó.

​

Ví dụ: GCD(5, 2) = 1 ; GCD(24, 36) = 12 ; GCD(5, 0) = 5​

 

[BNTT]

Các hàm toán học khác


Hàm LCM()

LCM là viết tắt của chữ Lowest common multiple: Bội số chung nhỏ nhất.

Cú pháp: = LCM(number1, number2 [,number3...])

number1, number2...: những số mà bạn bạn cần tìm bội số chung nhỏ nhất

LCM() có thể tìm bội số chung nhỏ nhất của một dãy có đến 255 giá trị (với Excel 2003 trở về trước thì con số này là 19)
​

Lưu ý:

Nếu có bất kỳ một number nào < 0, GDC() sẽ báo lỗi #NUM!

Nếu có bất kỳ một number nào không phải là một con số, GDC() sẽ báo lỗi #VALUE!

Nếu number là số thập phân, LCM() chỉ tính toán với phần nguyên của nó.

​

Ví dụ: LCM(5, 2) = 10 ; LCM(24, 36) = 72
​

 

[BNTT]

Các hàm toán học khác


Hàm LN()

Tính logarit tự nhiên của một số (logarit cơ số e = 2.71828182845905...)

Cú pháp: = LN(number)

number: số thực, dương mà ta muốn tính logarit tự nhiên (logarit cơ số e) của nó​

Lưu ý:

- Hàm LN() là nghịch đảo của hàm EXP(): tính lũy thừa của cơ số e
​

Ví dụ:

LN(86) = 4.454347 (logarit cơ số e của 86)
LN(2.7181818) = 1 (logarit cơ số e của e)
LN(EXP(3)) = 3 (logarit cơ số e của e lập phương)​

 

[BNTT]

Các hàm toán học khác


Hàm LOG()

Tính logarit của một số với cơ số được chỉ định

Cú pháp: = LOG(number [, base])

number: Số thực, dương mà ta muốn tính logarit tự nhiên (logarit cơ số e) của nó​

base: Cơ số để tính logarit (mặc định là 10) - Nếu bỏ trống, hàm LOG() tương đương với hàm LOG10()
​

Ví dụ:

LOG(10) = 1 (logarit cơ số 10 của 10)
LOG(8, 2) = 3 (logarit cơ số 2 của 8)
LOG(86, 2.7182818) = 4.454347 (logarit cơ số e của 86)


​

Hàm LOG10()

Tính logarit cơ số 10 của một số

Cú pháp: = LOG10(number)

number: số thực, dương mà ta muốn tính logarit tự nhiên (logarit cơ số e) của nó​

Ví dụ:

LOG10(10) = LOG(10) = 1 (logarit cơ số 10 của 10)
LOG10(86) = LOG(86) = 1.93449845 (logarit cơ số 10 của 86)
LOG10(1E5) = 5 (logarit cơ số 10 của 1E5)
LOG10(10^5) = 5 (logarit cơ số 10 của 10^5)
​

 

[BNTT]

Hàm về ma trận


Trước khi trình bày các hàm về ma trận, xin giải thích chút xíu về định nghĩa ma trận.


Định nghĩa Ma Trận

Ma trận là một bảng có m hàng và n cột

​

A còn được gọi là một ma trận cỡ m x n
Một phần tử ở hàng thứ i và cột thứ j sẽ được ký hiệu là

​

Một ma trận A có m = n gọi là ma trận vuông
​

Hàm MDETERM()

MDETERM viết tắt từ chữ Matrix Determinant: Định thức ma trận
Hàm này dùng để tính định thức của một ma trận vuông

Cú pháp: = MDETERM(array)

array: mảng giá trị chứa ma trận vuông (có số hàng và số cột bằng nhau)
​

Lưu ý:

- array có thể một dãy ô như A1:C3; hoặc một mảng như {1,2,3 ; 4,5,6 ; 7,8,9}; hoặc là một khối ô đã được đặt tên...

- Hàm MDETERM() sẽ báo lỗi #VALUE! khi:

• array không phải là ma trận vuông (số hàng khác số cột)
• Có bất kỳ 1 vị trí nào trong array là rỗng hoặc không phải là dữ liệu kiểu số

- Hàm MDETERM() có thể tính chính xác với ma trận 4 x 4 (có 16 ký số)

- Ví dụ về cách tính toán của hàm MDETERM() với ma trận 3 x 3 (A1:C3):

MDETERM(A1:C3) = A1*(B2*C3 - B3*C2) + A2*(B3*C1 - B1*C3) + A3*(B1*C2 - B2*C1)​

Ví dụ:

MDETERM(A14) = 88
​

MDETERM(A1:C4) = #VALUE! (A1:C4 không phải là ma trận vuông)

MDETERM({3,6,1 ; 1,1,0 ; 3,10,2}) = 1

MDETERM({3,6 ; 1,1}) = 1​

 

[BNTT]

Hàm về ma trận


Hàm MINVERSE()

MINVERSE viết tắt từ chữ Matrix Inverse: Ma trận nghịch đảo
Hàm này dùng để tính ma trận nghịch đảo của một ma trận vuông

Cú pháp: = MINVERSE(array)

array: mảng giá trị chứa ma trận vuông (có số hàng và số cột bằng nhau)
​

Lưu ý:

- array có thể một dãy ô như A1:C3; hoặc một mảng như {1,2,3 ; 4,5,6 ; 7,8,9}; hoặc là một khối ô đã được đặt tên...

- Giống hàm MDETERM, hàm MINVERSE() sẽ báo lỗi #VALUE! khi:

• array không phải là ma trận vuông (số hàng khác số cột)
  
  
• Có bất kỳ 1 vị trí nào trong array là rỗng hoặc không phải là dữ liệu kiểu số
  
  
• Ma trận không thể tính nghịch đảo (ví dụ ma trận có định thức = 0)
  

- Hàm MINVERSE() có thể tính chính xác với ma trận 4 x 4 (có 16 ký số)

​

Ví dụ về cách sử dụng hàm MINVERSE():

Ví dụ bạn có một ma trận A14, để tìm ma trận nghịch đảo của ma trận này, bạn quét chọn một khối ô tương ứng với A14, ví dụ A69 (cùng có 4 hàng và 4 cột), tại A6, gõ công thức = MINVERSE(A14) và sau đó nhấn Ctrl-Shift-Enter, bạn sẽ có kết quả tại A69 là một ma trận nghịch đảo của ma trận A14

​

 

[BNTT]

Hàm về ma trận


Hàm MMULT()

MMULT viết tắt từ chữ Matrix Multiple: Ma trận tích
Hàm này dùng để tính tích của hai ma trận

Cú pháp: = MMULT(array1, array2)

array1, array 2: mảng giá trị chứa ma trận
​

Lưu ý:

- array1, array2 có thể một dãy ô như A1:C3; hoặc một mảng như {1,2,3 ; 4,5,6 ; 7,8,9}; hoặc là một khối ô đã được đặt tên...

- Số cột của array1 phải bằng số dòng của array2
- Công thức tính tích hai ma trận (A = B x C) có dạng như sau:

Trong đó: i là số hàng của array1 (B), j là số cột của array2 (C); n là số cột của array1 (= số dòng của array2)
​

- Nếu có bất kỳ một phần tử nào trong hai ma trận là rỗng hoặc không phải là dữ liệu kiểu số, MMULT() sẽ báo lỗi #VALUE!

- Để có kết quả chính xác ở ma trận kết quả, phải dùng công thức mãng

​

Ví dụ:

Mời bạn xem hình sau:

​

Để tính tích của hai ma trận B và C, quét chọn khối C78
gõ công thức = MMULT(A2:C3,E2:F4) rồi nhấn Ctrl-Shift-Enter
sẽ có kết quả là ma trận A như trên hình.
​

 

[BNTT]

Các hàm toán học khác


Hàm MULTINOMIAL()

Dùng để tính tỷ lệ giữa giai thừa tổng và tích giai thừa của các số

Xin ví dụ cho dễ hiểu: Giả sử ta có 3 số a, b và c

Cú pháp: = MULTINOMIAL(number1, number2, ...)

number1, number2,... : là những con số mà ta muốn tính tỷ lệ giữa giai thừa tổng và tích giai thừa của chúng
​

Ghi chú:

• number1, number2, ... có thể lên đến 255 con số (với Excel 2003 trở về trước, con số này chỉ là 30)
  
  
• Nếu có bất kỳ một number nào không phải là dữ liệu kiểu số, MULTINOMIAL() sẽ báo lỗi #VALUE!
  
  
• Nếu có bất kỳ một number nào < 0, MULTINOMIAL() sẽ báo lỗi #NUM!

Ví dụ: MULTINOMIAL(2, 3, 4) = 1,260
​

 

[BNTT]

Các hàm toán học khác


Hàm PI()

Trả về giá trị của số Pi = 3.14159265358979, lấy chính xác đến 15 chữ số.

Cú pháp: = PI()

Hàm này không có tham số
​

Ví dụ:

PI() = 3.14159265358979
PI()/2 = 1.570796327
PI()*(3^2) = 28.27433388
​

 

[BNTT]

Các hàm toán học khác


Hàm POWER()

Tính lũy thừa của một số.
Có thể dùng toán tử ^ thay cho hàm này. Ví dụ: POWER(2, 10) = 2^10

Cú pháp: = POWER(number, power)

number: Số cần tính lũy thừa

power: Số mũ

​

Ví dụ:

POWER(5, 2) = 25
POWER(98.6, 3.2) = 2,401,077
POWER(4, 5/4) = 5.656854
​

 

[BNTT]

Các hàm toán học khác


Hàm PRODUCT()

Dùng để tính tích của các số

Cú pháp: = PRODUCT(number1, number2, ...)

number1, number2,... : là những con số mà ta muốn tính tỷ lệ giữa giai thừa tổng và tích giai thừa của chúng
​

Ghi chú:

• number1, number2, ... có thể lên đến 255 con số (với Excel 2003 trở về trước, con số này chỉ là 30)
  
  
• Nếu các number nằm trong một mảng dữ liệu, thì chỉ có những giá trị kiểu số trong mảng đó mới được tính; những giá trị không phải là kiểu số sẽ được bỏ qua.
  

Ví dụ: PRODUCT(2, 3, 4) = 24
​

 

[BNTT]

Các hàm toán học khác


Hàm QUOTIENT()

Lấy phần nguyên của phép chia.

Cú pháp: = QUOTIENT(numberator, denominator)

numberator: Số bị chia

denominator: Số chia
​

Ghi chú:

• Nếu các thông số không phải là dữ liệu kiểu số, hàm sẽ báo lỗi #VALUE!
  
  
• Hàm này tương đương với hàm INT(): QUOTIENT(a, b) = INT(a/b)

Ví dụ:

QUOTIENT(5, 2) = 2
QUOTIENT(4.5, 3.1) = 1
QUOTIENT(-10, 3) = -3​

 

[BNTT]

Các hàm toán học khác


Hàm ROMAN()

Dùng để chuyển đổi một số dạng Ả-rập sang dạng số La-mã

Cú pháp: = ROMAN(number, form)

number: Số cần chuyển đổi

form: dạng chuyển đổi

0 (hoặc TRUE, hoặc không nhập): Dạng cổ điển

1 cho đến 3: Dạng cổ điển nhưng được rút gọn, số càng lớn rút gọn càng nhiều (xem thêm ở ví dụ)

4 (hoặc FALSE): Dạng hiện đại

​

Chú ý:

• number phải là số dương, nếu number < 0 hàm sẽ báo lỗi #VALUE!
  
  
• Nếu number là số thập phân, ROMAN() chỉ chuyển đổi phần nguyên của nó
  
  
• Hàm ROMAN() chỉ xử lý được tới số lớn nhất là 3999, nếu number > 3999 hàm sẽ báo lỗi #VALUE!
  
  
• Sau khi đã chuyển đổi, kết quả sẽ là một dữ liệu dạng text, và không thể tính toán với nó được nữa
  
  

Ví dụ:
​

ROMAN(499, 0) = CDXCIX = ROMAN(499) = ROMAN(499, TRUE)

ROMAN(499, 1) = LDVLIV

ROMAN(499, 2) = XDIX

ROMAN(499, 3) = VDIV

ROMAN(499, 4) = ID = ROMAN(499, FALSE)

ROMAN(2008) = MMVIII​

 

[BNTT]

Các hàm toán học khác


Hàm SERIESSUM()

Dùng để tính tổng lũy thừa của một chuỗi số, theo công thức sau đây:

​

Cú pháp: = SERIESSUM(x, n, m, coefficients)

x : giá trị nhập vào cho chuỗi lũy thừa

n : lũy thừa khởi tạo để tăng tới x

m : bước tăng cho mỗi phần tử trong chuỗi

coefficients : tập hợp hệ số sẽ được nhân với mỗi lũy thừa của x

Các thông số này phải là các dữ liệu kiểu số, nếu không, hàm sẽ báo lỗi #VALUE!
​

Ví dụ:

SERIESSUM(5, 0, 2, {1, 2, 3, 4}) = 64,426

Diễn giải chi tiết: (x = 5, n = 0, m = 2, coefficients = 1, 2, 3, 4)

​

 

[BNTT]

Các hàm toán học khác


Hàm SIGN()

Trả về dấu của số: 1 nếu là số dương, 0 (zero) nếu là số 0 và -1 nếu là số âm.

Cú pháp: = SIGN(number)

Ví dụ:

SIGN(10) = 1
SIGN(4-4) = 0
SIGN(-0.057) = -1​

 

[BNTT]

Các hàm toán học khác


Hàm SQRT()

Dùng để tính căn bậc hai của một số

Cú pháp: = SQRT(number)

number: Số thực, dương (nếu number < 0 hàm sẽ báo lỗi #NUM!)

​

Ví dụ: Giả sử ở ô A2, có con số -16

SQRT(16) = 4
SQRT(A2) = #NUM!
SQRT(ABS(A2)) = 4
​

Hàm SQRTPI()

Dùng để tính căn bậc hai của một số nhân với Pi (= 3.14159265358979)

Cú pháp: = SQRTPI(number)

number: Số thực, dương nhân với Pi (nếu number < 0 hàm sẽ báo lỗi #NUM!)

​

Ví dụ: Giả sử ở ô A2, có con số -16

SQRT(1) = 1.772454 (căn bậc hai của Pi)
SQRT(2) = 2.506628 (căn bậc hai của 2*Pi)
​

 

[BNTT]

Các hàm toán học khác


Hàm SUBTOTAL()

(có tham khảo bài viết của Ttphong2007)
​

Hàm SUBTOTAL là một hàm rất linh hoạt nhưng cũng là một trong các hàm hơi khó sử dụng của Excel. Điều khó hiểu thứ nhất chính là cái tên của nó, vì nó thực sự làm được nhiều thứ hơn ý nghĩa của tên hàm. Đối số thứ nhất của hàm bắt buộc bạn phải nhớ con số đại diện cho phép tính cần thực hiện trên tập số liệu (trong Excel 2007 có tính năng AutoComplete giúp chúng ta khỏi nhớ các con số này). Hàm SUBTOTAL được Microsoft nâng cấp kể từ phiên bản Excel 2003 với sự gia tăng các tuỳ chọn cho đối số thứ nhất của hàm, tuy nhiên điều này dẫn đến sự không tương thích với các phiên bản cũ nếu chúng ta sử dụng các tính năng mới bổ sung này.

Đối số đầu tiên của của hàm SUBTOTAL xác định hàm thực sự nào sẽ được sử dụng khi tính toán (xem trong danh sách bên dưới). Ví dụ nếu đối số là 1 thì hàm SUBTOTAL hoạt động giống nhưng hàm AVERAGE, nếu đối số thứ nhất là 9 thì hàm hàm SUBTOTAL hoạt động giống nhưng hàm SUM.

SUBTOTAL là hàm tính toán cho một nhóm con trong một danh sách hoặc bảng dữ liệu tuỳ theo phép tính mà bạn chọn lựa trong đối số thứ nhất.

Cú pháp: = SUBTOTAL(function_num, ref1, ref2,...)

Function_num: Các con số từ 1 đến 11 (hay 101 đến 111) qui định hàm nào sẽ được dùng để tính toán trong SUBTOTAL

Ref1, ref2: Các vùng địa chỉ tham chiếu mà bạn muốn thực hiện phép tính trên đó.
Trong Excel 2007, bạn có thể dùng đến 254 ref (với Excel 2003 trở vế trước thì con số này chỉ là 29)​

Ghi chú:

• Nếu có hàm SUBTOTAL khác đặt lồng trong các đối số ref1, ref2,… thì các hàm lồng này sẽ bị bỏ qua không được tính, nhằm tránh trường hợp tính toán 2 lần.

• Đối số function_num nếu từ 1 đến 11 thì hàm SUBTOTAL tính toán bao gồm cả các giá trị ẩn trong tập số liệu (hàng ẩn). Đối số function_num nếu từ 101 đến 111 thì hàm SUBTOTAL chỉ tính toán cho các giá trị không ẩn trong tập số liệu (bỏ qua các giá trị ẩn).

• Hàm SUBTOTAL sẽ bỏ qua không tính toán tất cả các hàng bị ẩn bởi lệnh Filter (Auto Filter) mà không phụ thuộc vào đối số function_num được dùng (1 giống 101...).

• Hàm SUBTOTAL được thiết kế để tính toán cho các cột số liệu theo chiều dọc, nó không được thiết kế để tính theo chiều ngang.

• Hàm này chỉ tính toán cho dữ liệu 2-D, do vậy nếu dữ liệu tham chiếu dạng 3-D (Ví dụ về tham chiếu 3-D: =SUM(Sheet2:Sheet13!B5) thì hàm SUBTOTAL báo lỗi #VALUE!

Ví dụ:

SUBTOTAL(9, {120, 10, 150, 23}) = 303 = 120 + 10 + 150 + 23
SUBTOTAL(1, {120, 10, 150, 23}) = 75.75 = (120 + 10 + 150 + 23) / 4​

​

 

[BNTT]

Các hàm toán học khác


Hàm SUMPRODUCT()

Sum = Tổng / Product = Tích
SUMPRODUCT = Tổng của tích (các mảng dữ liệu)

Cú pháp: = SUMPRODUCT(array1, array2, ...)

array1, array2, ... : Có thể dùng từ 2 tới 255 mảng (với Excel 2003 trở về trước thì con số này chỉ là 30) và các mảng này phải cùng kích thước với nhau
​

Lưu ý:

• Nếu các mảng không cùng kích thước, SUMPRODUCT sẽ báo lỗi #VALUE!
  
• Bất kỳ một phần tử nào trong mảng không phải là dữ liệu kiểu số, sẽ được SUMPRODUCT coi như bằng 0 (zero)

Ví dụ:

SUMPRODUCT(A1:B3, C13) = 156

Cách tính: 156 = (3*2)+(4*7)+(8*6)+(6*7)+(1*5)+(9*3)
​

Nếu dùng SUM() với công thức mảng, sẽ cho kết quả tương đương:

{SUM(A1:B3 * C1:D3)} = SUMPRODUCT(A1:B3, C1:D3) = 156
​

Mời bạn đọc thêm: SUMPRODUCT và Công thức mảng

 

[BNTT]

Các hàm toán học khác


Hàm SUMSQ()

Dùng để tính tổng các bình phương của các số

Cú pháp: = SUMSQ(number1, number2, ...)

number1, number2, ... : Có thể dùng đến 255 tham số (với Excel 2003 trở về trước, con số này chỉ là 30)
Các tham số (number) có thể là một số, là một mảng, một tên, hay là một tham chiếu đến một ô chứa số, v.v...
​

Ví dụ: SUMSQ(3, 4) = (3^2) + (4^2) = 9 + 16 = 25​

 

[BNTT]

Các hàm toán học khác

Ba hàm sau đây có cách dùng và cú pháp tương tự nhau:

Hàm SUMX2MY2(), Hàm SUMXPY2() và Hàm SUMXMY2()

Để dễ nhớ tên của ba hàm này, bạn đọc chúng từ trái sang phải với các quy ước sau:

SUM = Tổng, M (Minus) = Trừ (hiệu số), P (Plus) = Cộng (tổng số), 2 = Bình phương, X và Y là hai mảng gì đó, có chứa nhiều phần tử x và y​

Vậy, định nghĩa và cách tính toán của 3 hàm này là:

• SUMX2MY2: Tổng của hiệu hai bình phương của các phần tử tương ứng trong 2 mảng dữ liệu

​

• SUMX2PY2: Tổng của tổng hai bình phương của các phần tử tương ứng trong 2 mảng dữ liệu

​

• SUMXMY2: Tổng của bình phương của hiệu các phần tử tương ứng trong 2 mảng dữ liệu

​

Cú pháp:

= SUMX2MY2(array_x, array_y)

= SUMX2PY2(array_x, array_y)

= SUMXMY2(array_x, array_y)
​

array_x và array_y là các dãy ô hoặc giá trị kiểu mảng
​

Lưu ý:

• array_x và array_y bắt buộc phải có cùng kích thước, nếu không, hàm sẽ báo lỗi #NA!
  
  
• Nếu trong array_x hoặc array_y có những giá trị kiểu text, kiểu logic hoặc rỗng, thì sẽ được bỏ qua (không tính), tuy nhiên các giá trị = 0 vẫn được tính.

Ví dụ:

Với hai mảng X = {1, 2, 3, 4} và Y = {5, 6, 7, 8}

SUMX2MY2({1, 2, 3, 4}, {5, 6, 7, 8}) = -144

= (1^2 - 5^2) + (2^2 - 6^2) + (3^2 - 7^2) + (4^2 - 8^2) = -144
​

SUMX2PY2({1, 2, 3, 4}, {5, 6, 7, 8}) = 204

= (1^2 + 5^2) + (2^2 + 6^2) + (3^2 + 7^2) + (4^2 + 8^2) = -204​

SUMXMY2({1, 2, 3, 4}, {5, 6, 7, 8}) = 64

= (1 - 5)^2 + (2 - 6)^2 + (3 - 7)^2 + (4 - 8)^2 = 64

​

 

[BNTT]

Hàm SUMIF()

Tính tổng các ô trong một vùng thỏa một điều kiện cho trước.

Cú pháp: = SUMIF(range, criteria, sum_range)

Range : Dãy các ô để tính tổng, có thể là ô chứa số, tên, mảng, hay tham chiếu đến các ô chứa số. Ô rỗng và ô chứa giá trị text sẽ được bỏ qua.

Criteria : Điều kiện để tính tổng. Có thể ở dạng số, biểu thức, hoặc text. Ví dụ, criteria có thể là 32, "32", "> 32", hoặc "apple", v.v...

Sum_range : Là vùng thực sự để tính tổng. Nếu bỏ qua, Excel sẽ coi như sum_range = range.​

Lưu ý:

• Sum_range không nhất thiết phải cùng kích thước với range. Vùng thực sự để tính tổng được xác định bằng ô đầu tiên phía trên bên trái của sum_range, và bao gồm thêm những ô tương ứng với kích thước của range. Ví dụ:
  
  - Nếu Range là A1:A5, Sum_range là B1:B5, thì vùng thực sự để tính tổng là B1:B5
  - Nếu Range là A1:A5, Sum_range là B1:B3, thì vùng thực sự để tính tổng là B1:B5
  - Nếu Range là A1:B4, Sum_range là C14, thì vùng thực sự để tính tổng là C14
  - Nếu Range là A1:B4, Sum_range là C12, thì vùng thực sự để tính tổng là C14​

• Có thể dùng các ký tự đại diện trong điều kiện: dấu ? đại diện cho một ký tự, dấu * đại diện cho nhiều ký tự (nếu như điều kiện là tìm những dấu ? hoặc *, thì gõ thêm dấu ~ ở trước dấu ? hay *).

• Khi điều kiện để tính tổng là những ký tự, SUMIF() không phân biệt chữ thường hay chữ hoa.

Ví dụ: Có bảng tính như sau

Tính tổng của những huê hồng mà có doanh thu > 160,000 ?

= SUMIF(A2:A5, ">160000", B2:B5) = 63,000​

Tính tổng của những doanh thu > 160,000 ?

= SUMIF(A2:A5, ">160000") = 900,000​

Tính tổng của những huê hồng mà có doanh thu = 300,000 ?

= SUMIF(A2:A5, "=300000", B2:B3) = 21,000​

 

[BNTT]

Hàm SUMIFS()

Tính tổng các ô trong một vùng thỏa nhiều điều kiện cho trước.

Cú pháp: = SUMIFS(sum_range, criteria_range1, criteria1, criteria_range2, criteria2, ...)

Sum_range : Dãy các ô để tính tổng, có thể là ô chứa số, tên, mảng, hay tham chiếu đến các ô chứa số. Ô rỗng và ô chứa giá trị text sẽ được bỏ qua.

Criteria_range1, criteria_range2... : Có thể có từ 1 đến 127 vùng dùng để liên kết với các điều kiện cho vùng.

Criteria1, criteria2... : Có thể có từ 1 đến 127 điều kiện để tính tổng. Chúng có thể ở dạng số, biểu thức, hoặc text. Ví dụ, criteria có thể là 32, "32", "> 32", hoặc "apple", v.v...​

Lưu ý:

• Mỗi ô trong sum_range chỉ được tính tổng nếu tất cả các điều kiên tương ứng với ô đó đều đúng. Nếu thỏa các điều kiện, nó sẽ bằng 1, còn không, thì nó bằng 0.

• Không giống như những đối số range và criteria của hàm SUMIF, trong hàm SUMIFS, mỗi vùng criteria_range phải có cùng kích thước và hình dạng giống như sum_range.

• Có thể dùng các ký tự đại diện trong các điều kiện: dấu ? đại diện cho một ký tự, dấu * đại diện cho nhiều ký tự (nếu như điều kiện là tìm những dấu ? hoặc *, thì gõ thêm dấu ~ ở trước dấu ? hay *)

• Khi điều kiện để đếm là những ký tự, SUMIFS() không phân biệt chữ thường hay chữ hoa.

Ví dụ 1: Có bảng tính như sau

Tính tổng số tiền của các tài khoản có lãi suất năm 2000 > 3% và lãi suất năm 2001 ≥ 2% ?

SUMIFS(B2:E2, B3:E3, ">3%", B4:E4, ">=2%") = $500​

Tính tổng số tiền của các tài khoản có lãi suất năm 2002 là từ 1% đến 3% và lãi suất năm 2001 > 1% ?

SUMIFS(B2:E2, B5:E5, ">= 1%", B5:E5, "<= 3%", B4:E4, "> 1%") = $8,711​

Ví dụ 2: Có bảng tính như sau

Hãy tính tổng lượng mưa của những ngày có nhiệt độ trung bình > 40 (độ) và tốc độ gió trung bình < 10 (miles/giờ) ?

SUMIFS(B2:E3, B4:E5, ">= 40", B6:E7, "< 10") = 3.5 (inches)​

------- HẾT PHẦN EXCEL'S MATH FUNCTIONS -------
​