Bài toán tính tổng chi phí thỏa mãn chi phí cho mỗi phòng là thấp nhất (1 người xem)

[khuongvietphong]

Chào mọi người. Em có bài toán thực tế này cần được sự giúp đỡ của mọi người ạ.

Chi tiết em đã ghi trong File . Em muốn dùng CT nhé )

 

[lenongree]

Chào mọi người. Em có bài toán thực tế này cần được sự giúp đỡ của mọi người ạ.

Chi tiết em đã ghi trong File . Em muốn dùng CT nhé )

Được dùng cột phụ không bạn????

 

[khuongvietphong]

Được dùng cột phụ không bạn????

Mình cũng đang tính đến hướng dùng tới cột phụ. Bạn cứ thử làm xem sao. Cảm ơn bạn !

 

[lenongree]

Mình cũng đang tính đến hướng dùng tới cột phụ. Bạn cứ thử làm xem sao. Cảm ơn bạn !

Bạn nhận file xem thử!!!!
P/s: có cách nào khác cho mình mình xin luôn nhe bạn !!!
CT số 2 chỉ tính đúng khi tổng chi phí <10 tỷ thôi nhe bạn!!!

 

[anhtuan2012]

=SUM(DMIN($A$1:$C$17,$C$1,$B$20:$B21),DMIN($A$1:$C$17,$C$1,$B$22:$B$23),DMIN($A$1:$C$17,$C$1,$B$24:$B$25),DMIN($A$1:$C$17,$C$1,$B$26:$B$27),DMIN($A$1:$C$17,$C$1,$B$28:$B$29))
Xem file nhé

 

[HieuCD]

tạo cột phụ D và nhập công thức vào ô
D2 =IF(A2<>"",MIN(OFFSET(C2,,,MATCH("*",A3:$A$17,0))),0)
copy xuống và dùng hàm SUM để tính tổng cộng

 

[khuongvietphong]

tạo cột phụ D và nhập công thức vào ô
D2 =IF(A2<>"",MIN(OFFSET(C2,,,MATCH("*",A3:$A$17,0))),0)
copy xuống và dùng hàm SUM để tính tổng cộng

Công thức rất hay nhưng nếu như phòng Marketting mà có thêm nhóm nữa thì sẽ bị lỗi bạn à. Bạn sửa thêm giúp mình nhé

 

[khuongvietphong]

Bạn HieuCD:

Tại sao khi đề bài thay đổi như mình nói ở trên, mình sửa công thức của bạn thành thế :

=IF(A2<>"",MIN(OFFSET(C2,,,IFERROR(MATCH("*",A3:$A$18,0),COUNTA(B2:B$18))),0))

Lại không được nhỉ !

 

[HieuCD]

Công thức rất hay nhưng nếu như phòng Marketting mà có thêm nhóm nữa thì sẽ bị lỗi bạn à. Bạn sửa thêm giúp mình nhé

lổi thì thay thế bằng hàm Count
=IF(A2<>"",MIN(OFFSET(C2,,,IFERROR(MATCH("*",A3:$A$100,0),COUNT(C2:$C$100)))),0)

 

[lenongree]

tạo cột phụ D và nhập công thức vào ô
D2 =IF(A2<>"",MIN(OFFSET(C2,,,MATCH("*",A3:$A$17,0))),0)
copy xuống và dùng hàm SUM để tính tổng cộng

CT hay, bạn cho mình hỏi MATCH("*",A3:$A$17,0) ý nghĩa là sao vậy bạn!!!

 

[lenongree]

Chào mọi người. Em có bài toán thực tế này cần được sự giúp đỡ của mọi người ạ.

Chi tiết em đã ghi trong File . Em muốn dùng CT nhé )

Hi, không cần dùng Cột phụ luôn

=--RIGHT(SUM(SMALL(LOOKUP(ROW($1:$16),MATCH($A$2:$A$17,$A$2:$A$17,))*10^10+$C$2:$C$17,ROW($1:$16))*ISNUMBER(MATCH($A$2:$A$17,$A$2:$A$17,))),10)

Hoặc

=SUM(IFERROR(10^(SMALL(LOOKUP(ROW($1:$16),MATCH($A$2:$A$17,$A$2:$A$17,))*100+LOG($C$2:$C$17),ROW($1:$16))-MATCH($A$2:$A$17,$A$2:$A$17,)*100),0))

Ctrl+Shift+Enter!!!!

 

[lenongree]

-----------------------

 

[anhtuan2012]

Là thay cho hàm countif đếm ngược từ lớn đến nhỏ số dòng mà tên phòng đè lên

 

[khuongvietphong]

Hi, không cần dùng Cột phụ luôn

=--RIGHT(SUM(SMALL(LOOKUP(ROW($1:$16),MATCH($A$2:$A$17,$A$2:$A$17,))*10^10+$C$2:$C$17,ROW($1:$16))*ISNUMBER(MATCH($A$2:$A$17,$A$2:$A$17,))),10)

Hoặc

=SUM(IFERROR(10^(SMALL(LOOKUP(ROW($1:$16),MATCH($A$2:$A$17,$A$2:$A$17,))*100+LOG($C$2:$C$17),ROW($1:$16))-MATCH($A$2:$A$17,$A$2:$A$17,)*100),0))

Ctrl+Shift+Enter!!!!

Công thức bá đạo quá Lenongree à, phải nghiền mãi mới hiểu được , cảm ơn Lenonggree nhiều nha

 

[HieuCD]

CT hay, bạn cho mình hỏi MATCH("*",A3:$A$17,0) ý nghĩa là sao vậy bạn!!!

MATCH("*",A3:$A$17,0) là tính số dòng của nhóm đang xét

 

[HieuCD]

Hi, không cần dùng Cột phụ luôn

=--RIGHT(SUM(SMALL(LOOKUP(ROW($1:$16),MATCH($A$2:$A$17,$A$2:$A$17,))*10^10+$C$2:$C$17,ROW($1:$16))*ISNUMBER(MATCH($A$2:$A$17,$A$2:$A$17,))),10)

Hoặc

=SUM(IFERROR(10^(SMALL(LOOKUP(ROW($1:$16),MATCH($A$2:$A$17,$A$2:$A$17,))*100+LOG($C$2:$C$17),ROW($1:$16))-MATCH($A$2:$A$17,$A$2:$A$17,)*100),0))

Ctrl+Shift+Enter!!!!

Tư duy quá tốt, nếu học lập trình chắc chắn thành công

 

[khuongvietphong]

Chân thành cảm ơn các bạn đã gửi bài tham gia trợ giúp cho vấn đề của mình.

Nhờ có sự giúp đỡ đó mà trong ngày hôm nay mình đã giải quyết được xong công việc.

Qua đây mình cũng học hỏi được rất nhiều điều hay từ công thức của mọi người.

Hi hi, tối nay về nghiền ngẫm lại mình cũng nghĩ ra được công thức củ chuối này.

Công thức của mình hơi dài nhưng mình cũng cứ gửi lên đây các bạn cùng xem thêm nha:

=SUM(SUBTOTAL(5,OFFSET(C1,MATCH(SUBTOTAL(3,OFFSET(A2,,,ROW(1:16),)),SUBTOTAL(3,OFFSET(A2,,,ROW(1:16),)),0),,SUBTOTAL(4,OFFSET(B1,MATCH(SUBTOTAL(3,OFFSET(A2,,,ROW(1:16),)),SUBTOTAL(3,OFFSET(A2,,,ROW(1:16),)),0),,MAX(B2:B17,)))))/SUBTOTAL(4,OFFSET(B1,MATCH(SUBTOTAL(3,OFFSET(A2,,,ROW(1:16),)),SUBTOTAL(3,OFFSET(A2,,,ROW(1:16),)),0),,MAX(B2:B17,))))

Một lần nữa cảm ơn các bạn !