Chia sẻ: Công thức chuyển số thành chữ cho Excel 2007

huuthang_bd · 12/4/23

Như đã hứa, hôm nay tôi chia sẻ công thức chuyển số thành chữ sử dụng được trên Excel 2007 trở lên.
Tiếng Việt:

Mã:

=IF(ABS(A1)>=10^15;"###";IF(A1<0;"Âm ";MID("KMHBBNSBTC";LEFT(ROUND(A1;0))+1;1))&MID(TRIM(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(RIGHT(TEXT(A1;SUBSTITUTE("0\*0\=0\/0\*0;0\*0\=0\/0\*0";0;"0\-0\+0"));LEN(ROUND(ABS(A1);0))*2-1);"0-0+0*";"");"0-0+0/";"");"0-0+0";"");"0+0";"");"0+";" lẻ");"+0";"+");"+5";"+ lăm");"1+";" mười");"+1";"+ mốt");0;" không");1;" một");2;" hai");3;" ba");4;" bốn");5;" năm");6;" sáu");7;" bảy");8;" tám");9;" chín");"+";" mươi");"-";" trăm");"*";" ngàn,");"/";" triệu,");",=";"=");"=";" tỷ,")&"  ";",  ";""));2-(A1<0);999))

Tiếng Anh:

Mã:

=IF(ABS(A1)>=10^15;"###";IF(A1<0;"Negative ";MID("ZOTTFFSSENTETTFFSSEN";LEFT(ROUND(A1;0);IFERROR(IF(LEFT(ROUND(A1;0))*MOD(INT(LOG10(ROUND(ABS(A1);0)));3)=1;2;1);1))+1;1))&MID(TRIM(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(RIGHT(TEXT(A1;SUBSTITUTE("0\\0\=0\/0\*0;0\\0\=0\/0\*0";0;"0\-0\+0"));LEN(ROUND(ABS(A1);0))*2-1);"0-0+0=";"");"0-0+0/";"");"*0-";"* and");"0-0+0*";"");"0-";"");"0+";"");"1+0";" ten");"1+1";" eleven");"1+2";" twelve");"1+3";" thirteen");"1+4";"4teen");"1+5";" fifteen");"1+6";"6teen");"1+7";"7teen");"1+8";"8een");"1+9";"9teen");"2+";" twenty:");"3+";" thirty:");"4+";" forty:");"5+";" fifty:");"8+";"8y:");"+";"ty:");"y:0";"y");0;" zero");1;" one");2;" two");3;" three");4;" four");5;" five");6;" six");7;" seven");8;" eight");9;" nine");"-";" hundred and");"*";" thousand,");"/";" million,");"=";" billion,");"\";" trillion,");": ";"-");" and zero";"");", a";" a")&"  ";",  ";""));2-(A1<0);999))

Lưu ý: Các công thức trên chỉ chuyển được số trong phạm vi từ -10^15+1 đến 10^15-1, ngoài phạm vi này công thức sẽ trả về "###"
Bạn @cantl vào nhận hàng nhé.
--
Nhân tiện tôi chia sẻ luôn công thức chuyển số thành chữ tiếng Việt và tiếng Anh sử dụng trên Excel 365 và Goolge Sheet, không giới hạn độ lớn của số cần đọc (số lớn nhập vào dạng chuỗi).
Tiếng Việt:

Mã:

=LET(so;A1;d;SIGN(so)+2;n;"00"&IF(ISTEXT(so);MID(so;1+(d=1);99);TEXT(so;"0;0"));l;LEN(n);g;INT(l/3);r;SUBSTITUTE(TEXTJOIN(",";1;MAP(SEQUENCE(g;1;g;-1);LAMBDA(k;LET(s;LEFT(n;l-k*3+3);a;{"không";"một";"hai";"ba";"bốn";"năm";"sáu";"bảy";"tám";"chín"};b;MIN(k;MOD(k-2;3)+2);x;RIGHT(s;3)*1;y;MOD(x;100);z;MOD(y;10);IF(x>0;IF(LEN(s)>4;" "&INDEX(a;INT(x/100)+1)&" trăm"&IF(AND(y<10;z>0);" lẻ";"");"")&IF(y>=20;" "&INDEX(a;INT(y/10)+1)&" mươi";IF(y>=10;" mười";""))&IF(z>0;LET(t;(y>11)*((z=1)+(z=5)*2)+1;" "&CHOOSE(t;INDEX(a;z+1);"mốt";"lăm"));"")&CHOOSE(b;"";" ngàn";" triệu";" tỷ");IF(b=4;" tỷ";""))))));", tỷ";" tỷ");CHOOSE(d;"Âm"&r;"Không";UPPER(MID(r;2;1))&MID(r;3;999)))

Tiếng Anh:

Mã:

=LET(so;A1;d;SIGN(so)+2;n;"00"&IF(ISTEXT(so);MID(so;1+(d=1);99);TEXT(so;"0;0"));l;LEN(n);g;INT(l/3);r;SUBSTITUTE(TEXTJOIN(",";1;MAP(SEQUENCE(g;1;g;-1);LAMBDA(k;LET(s;LEFT(n;l-k*3+3);a;{"zero";"one";"two";"three";"four";"five";"six";"seven";"eight";"nine";"ten";"eleven";"twelve";"thirteen";"fourteen";"fifteen";"sixteen";"seventeen";"eighteen";"nineteen"};b;{"";"twenty";"thirty";"forty";"fifty";"sixty";"seventy";"eighty";"ninety"};x;RIGHT(s;3)*1;y;MOD(x;100);z;MOD(y;10);IF(x>0;IF(LEN(s)>4;IF(x<100;IF(k=1;" and";"");" "&INDEX(a;INT(x/100)+1)&" hundred"&IF(y>0;" and";""));"")&IF(y>=20;" "&INDEX(b;INT(y/10))&IF(z>0;"-"&INDEX(a;z+1);"");IF(y>0;" "&INDEX(a;y+1);""))&CHOOSE(k;"";" thousand"; " million"; " billion"; " trillion";" quadrillion";" quintillion";" sextillion";" septillion";" octillion");"")))));", and";" and");CHOOSE(d;"Negative"&r;"Zero";UPPER(MID(r;2;1))&MID(r;3;999)))

--
-460.101.895.031
Âm bốn trăm sáu mươi tỷ, một trăm lẻ một triệu, tám trăm chín mươi lăm ngàn, không trăm ba mươi mốt
Negative four hundred and sixty billion, one hundred and one million, eight hundred and ninety-five thousand and thirty-one

cantl · 12/4/23

huuthang_bd đã viết:

Như đã hứa, hôm nay tôi chia sẻ công thức chuyển số thành chữ sử dụng được trên Excel 2007 trở lên.

Mã:

=IF(ABS(A1)>=10^15;"###";IF(A1<0;"Âm ";MID("KMHBBNSBTC";LEFT(ABS(A1))+1;1))&MID(TRIM(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(RIGHT(TEXT(A1;SUBSTITUTE("0;0";0;"0\-0\+0\*0\-0\+0\=0\-0\+0\/0\-0\+0\*0\-0\+0"));LEN(ROUND(ABS(A1);0))*2-1);"0-0+0*";"");"0-0+0/";"");"0-0+0";"");"0+0";"");"0+";" lẻ");"+0";"+");"+5";"+ lăm");"1+";" mười");"+1";"+ mốt");"_=";"_");"0";" không");"1";" một");"2";" hai");"3";" ba");"4";" bốn");"5";" năm");"6";" sáu");"7";" bảy");"8";" tám");"9";" chín");"+";" mươi");"-";" trăm");"*";" ngàn,");"/";" triệu,");",=";"=");"=";" tỷ,")&"  ";",  ";""));2-(A1<0);999))

Lưu ý: Công thức trên chỉ chuyển được số trong phạm vi từ -10^15+1 đến 10^15-1, ngoài phạm vi này công thức sẽ trả về "###"
Bạn @cantl vào nhận hàng nhé.
--
Nhân tiện tôi chia sẻ luôn công thức chuyển số thành chữ tiếng Việt và tiếng Anh sử dụng trên Excel 365 và Goolge Sheet, không giới hạn độ lớn của số cần đọc (số lớn nhập vào dạng chuỗi).
Tiếng Việt:

Mã:

=LET(so;A1;d;SIGN(so)+2;n;"00"&IF(ISTEXT(so);MID(so;1+(d=1);99);TEXT(so;"0;0"));l;LEN(n);g;INT(l/3);r;SUBSTITUTE(TEXTJOIN(",";1;MAP(SEQUENCE(g;1;g;-1);LAMBDA(k;LET(s;LEFT(n;l-k*3+3);a;{"không";"một";"hai";"ba";"bốn";"năm";"sáu";"bảy";"tám";"chín"};b;MIN(k;MOD(k-2;3)+2);x;RIGHT(s;3)*1;y;MOD(x;100);z;MOD(y;10);IF(x>0;IF(LEN(s)>4;" "&INDEX(a;INT(x/100)+1)&" trăm"&IF(AND(y<10;z>0);" lẻ";"");"")&IF(y>=20;" "&INDEX(a;INT(y/10)+1)&" mươi";IF(y>=10;" mười";""))&IF(z>0;LET(t;(y>11)*((z=1)+(z=5)*2)+1;" "&CHOOSE(t;INDEX(a;z+1);"mốt";"lăm"));"")&CHOOSE(b;"";" ngàn";" triệu";" tỷ");IF(b=4;" tỷ";""))))));", tỷ";" tỷ");CHOOSE(d;"Âm"&r;"Không";UPPER(MID(r;2;1))&MID(r;3;999)))

Tiếng Anh:

Mã:

=LET(so;A1;d;SIGN(so)+2;n;"00"&IF(ISTEXT(so);MID(so;1+(d=1);99);TEXT(so;"0;0"));l;LEN(n);g;INT(l/3);r;SUBSTITUTE(TEXTJOIN(",";1;MAP(SEQUENCE(g;1;g;-1);LAMBDA(k;LET(s;LEFT(n;l-k*3+3);a;{"zero";"one";"two";"three";"four";"five";"six";"seven";"eight";"nine";"ten";"eleven";"twelve";"thirteen";"fourteen";"fifteen";"sixteen";"seventeen";"eighteen";"nineteen"};b;{"";"twenty";"thirty";"forty";"fifty";"sixty";"seventy";"eighty";"ninety"};x;RIGHT(s;3)*1;y;MOD(x;100);z;MOD(y;10);IF(x>0;IF(LEN(s)>4;IF(x<100;IF(k=1;" and";"");" "&INDEX(a;INT(x/100)+1)&" hundred"&IF(y>0;" and";""));"")&IF(y>=20;" "&INDEX(b;INT(y/10))&IF(z>0;"-"&INDEX(a;z+1);"");IF(y>0;" "&INDEX(a;y+1);""))&CHOOSE(k;"";" thousand"; " million"; " billion"; " trillion";" quadrillion";" quintillion";" sextillion";" septillion";" octillion");"")))));", and";" and");CHOOSE(d;"Negative"&r;"Zero";UPPER(MID(r;2;1))&MID(r;3;999)))

--
-460.000.101.895.031
Âm bốn trăm sáu mươi tỷ, một trăm lẻ một triệu, tám trăm chín mươi lăm ngàn, không trăm ba mươi mốt
Negative four hundred and sixty billion, one hundred and one million, eight hundred and ninety-five thousand and thirty-one

Vinh dự quá bác ạ!!!
Em đã đối chiếu với hàm VBA của bác, giống tuyệt đối.

tieutuvodanh192 · 12/4/23

Quá đỉnh luôn anh ạ, em chạy thử công thức dành cho Excel 2007 trở lên, dữ liệu hơn 1 triệu dòng chạy công thức của anh sổ xuống mất khoảng 5 giây, tốc độ quá tuyệt vời. :clap:

HeSanbi · 12/4/23

huuthang_bd đã viết:
-460.000.101.895.031
Âm bốn trăm sáu mươi tỷ, một trăm lẻ một triệu, tám trăm chín mươi lăm ngàn, không trăm ba mươi mốt

... .... nghìn (tỷ) .... .... .... "chạy trốn đâu rồi" bác ơi.

cantl · 12/4/23

HeSanbi đã viết:
... .... nghìn (tỷ) .... .... .... "chạy trốn đâu rồi" bác ơi.

Lỗi đánh máy thôi bác ạ, kết quả có đủ cả.

chim_zunzun · 12/4/23

Công thức đỉnh thiệt !!!

HeSanbi · 12/4/23

Có nhiều bạn sẽ hỏi sao em chép đúng biểu thức ở trên mà báo lỗi hoài.
Vì là công thức với dấu tách đối số có thể là dấu phẩy hoặc dấu chấm phẩy. Dấu tách mảng là dấu \ hoặc dấu ;. Mà Excel của bạn đang là dấu ngược lại thì chắc chắn lỗi.

Để sao chép công thức dài như công thức trong bài viết này một cách nhanh nhất các bạn có thể tham khảo Add-in dưới đây:
Ví dụ chỉ cần nhấn nút [sao chép] phần công thức ở trên và gõ vào ô Excel:

Dán công thức và chuẩn hóa:
=fx_paste()

Chuẩn hóa công thức cho Google Sheets:
=Fx_Copy_forGoolgeSheet()

Đơn giản vậy thôi.

FormulaBeautifyXL: Định dạng công thức dễ dàng chỉnh sửa

Nhấn để tải về FormulaBeautifyXL Hôm nay tôi chia sẻ cho các bạn Add-in Phân tích biểu thức thành dạng cây để dễ dàng chỉnh sửa. Và các hàm tự động chuẩn hóa công thức khi sao chép (ví dụ ngược dấu tách đối số ; và , hoặc mảng \ và ; ) Nhiều...

www.giaiphapexcel.com

Các bạn có thể tham khảo thêm hàm Đọc số trong chuỗi chứa số được viết bằng VBA.

Ví dụ với chuỗi : "Vào ngày 12/04/2023 tôi được tin báo trúng số Vietlott với giải thưởng chỉ có 44,037,000,000 VNĐ, nhưng may mắn họ báo nhầm người"
Có thể đọc số giữ chuỗi hoặc chỉ đọc số.

Hàm UDF Đọc số thành chữ, chuyển chữ thành số, kể cả số thập phân

*****CẬP NHẬT: 19/07/2024 ***** Hôm nay tôi mang đến cho các bạn một giải pháp đọc số thành chữ tối ưu, và đa dạng tùy chọn kiểu trả về kết quả để phù hợp với nhu cầu từng trường hợp cho văn bản hay biên bản, hàm mới này thay vì chỉ đọc duy nhất số thì hàm có thể đọc được số trong chuỗi chứa...

www.giaiphapexcel.com

Maika8008 · 12/4/23

Công thức ngon. Tuy nhiên muốn thay đổi ô tham chiếu thì chịu khó dùng Ctrl+H

cantl · 12/4/23

Maika8008 đã viết:
Công thức ngon. Tuy nhiên muốn thay đổi ô tham chiếu thì chịu khó dùng Ctrl+H

Cách của em hơi khác tí. Em sẽ:
- Dán công thức vào ô bất kỳ khác A1 trước.
- Ctrl+x ô A1 dán vào vị trí bản thân cho là hoàn hảo nào đấy.
- Nhập số vào ô hoàn hảo ấy.

huuthang_bd · 12/4/23

cantl đã viết:
Cách của em hơi khác tí. Em sẽ:
- Dán công thức vào ô bất kỳ khác A1 trước.
- Ctrl+x ô A1 dán vào vị trí bản thân cho là hoàn hảo nào đấy.
- Nhập số vào ô hoàn hảo ấy.

Cách của bạn chuẩn đấy. Nhưng không phải ai cũng biết.

LmoovoenX · 12/4/23

huuthang_bd đã viết:
Cách của bạn chuẩn đấy. Nhưng không phải ai cũng biết.

Nhờ bác góp ý hộ. Cơ bản công thức này chia số cần đọc theo hàng trăm, hàng chục và đơn vị, đọc từng bộ 3 số rồi kết hợp với "hàng" (ngàn, triệu, tỷ).

Mã:

=LET(so,SUBSTITUTE(IF(ISTEXT(A2),A2,TEXT(A2,"0")),"-",""),
    doc_so,TRIM(IF(LEFT(A2)="-","Âm ","")&TEXTJOIN(", ",,
        LET(l,SEQUENCE(ROUNDUP(LEN(so)/3,0),,1,3),m,MOD(2*LEN(so),3),
            tr,--MID(so,l-m,1),ch,--MID(so,l-m+1,1),dv,--MID(so,l-m+2,1),
            chuso,{"không ","một ","hai ","ba ","bốn ","năm ","sáu ","bảy ","tám ","chín "},
            doc_tr,IFERROR(IF(tr+ch+dv>0,INDEX(chuso,tr+1)&"trăm ",""),""),
            doc_ch,IFERROR(IF(ch+dv>0,IF(ch=0,"lẻ ",IF(ch=1,"mười ",INDEX(chuso,ch+1)&"mươi ")),""),""),
            doc_dv,IF(dv>0,IF(dv=1,IF(IFERROR(ch,0)>1,"mốt ","một "),IF(IFERROR(dv,0)=5,IF(IFERROR(ch,0)=0,"năm ","lăm "),INDEX(chuso,dv+1))),""),
            doc_hang,IF(IFERROR(tr,0)+IFERROR(ch,0)+dv>0,INDEX({"","ngàn","triệu"},MOD((MAX(l)-l)/3,3)+1),""),
            doc_ty,IF(MOD(MAX(l)-l,9)=0,IF(l=MAX(l),"","tỷ"),""),
        doc_tr&doc_ch&doc_dv&doc_hang&doc_ty))),
SUBSTITUTE(SUBSTITUTE(doc_so,LEFT(doc_so),UPPER(LEFT(doc_so)),1),", tỷ"," tỷ"))&" đồng."

befaint · 12/4/23

Ế ẩm quá phải vào thớt hót của người khác rao =)))
Người ta úp file lên rồi thì cứ thế chép lấy công thức trong file mà dùng, dấu phân cách là gì thì mặc kệ nhà máy tính, nhà phần mềm nó tự biết mà làm.
Chép công thức ra bài là để dành người có khả năng đọc được nó.

huuthang_bd · 12/4/23

LmoovoenX đã viết:
Nhờ bác góp ý hộ.

Trước mắt tôi thấy công thức của bạn không hoạt động được trên Google Sheet. Những hàm bạn dùng Google Sheet đều có mà công thức không sử dụng được trên Google Sheet là một điểm trừ rồi.

Bài đã được tự động gộp: 12/4/23

befaint đã viết:
Ế ẩm quá phải vào thớt hót của người khác rao =)))
Người ta úp file lên rồi thì cứ thế chép lấy công thức trong file mà dùng, dấu phân cách là gì thì mặc kệ nhà máy tính, nhà phần mềm nó tự biết mà làm.
Chép công thức ra bài là để dành người có khả năng đọc được nó.

Cùng suy nghĩ luôn.
Nhưng khách đến nhà không lẽ...

lehuong1409 · 12/4/23

Công thức quá đỉnh ạ. Cảm ơn sự kỳ công và chia sẻ tuyệt vời của bác ạ. Lại có thêm một hàm bỏ túi cho những file cần "di chuyển" nhiều rồi ạ.

LmoovoenX · 12/4/23

huuthang_bd đã viết:
Trước mắt tôi thấy công thức của bạn không hoạt động được trên Google Sheet. Những hàm bạn dùng Google Sheet đều có mà công thức không sử dụng được trên Google Sheet là một điểm trừ

Cảm ơn bác. Em không xài Google Sheet nên không biết viết sao cho nó hoạt động trên đó. Để từ từ nghiên cứu sau.
Em viết công thức trên để tự học là chính. Bữa có đọc trên trang chủ về mấy hàm kết hợp với LET mà nó viết nhức đầu quá nên thôi. Bởi vậy nên hàm Map và Lambda em đâu có xài được.

huuthang_bd · 12/4/23

LmoovoenX đã viết:
Cảm ơn bác. Em không xài Google Sheet nên không biết viết sao cho nó hoạt động trên đó. Để từ từ nghiên cứu sau.
Em viết công thức trên để tự học là chính. Bữa có đọc trên trang chủ về mấy hàm kết hợp với LET mà nó viết nhức đầu quá nên thôi. Bởi vậy nên hàm Map và Lambda em đâu có xài được.

Thì trước giờ tôi cũng có biết LET với LAMBDA là gì đâu, tôi dùng Excel 2007 từ xưa đến giờ. Tại thấy cái bạn giỏi excel kia hô to quá nên tôi mới dùng excel online làm thử xem thế nào thôi.

LmoovoenX · 12/4/23

huuthang_bd đã viết:
Thì trước giờ tôi cũng có biết LET với LAMBDA là gì đâu, tôi dùng Excel 2007 từ xưa đến giờ. Tại thấy cái bạn giỏi excel kia hô to quá nên tôi mới dùng excel online làm thử xem thế nào thôi.

Cái máy cùi bắp ở nhà, bấm vào step in coi từng bước của công thức như thế nào thì đến chỗ hàm MAP đơ máy tự thoát Excel luôn.

huuthang_bd · 13/4/23

LmoovoenX đã viết:
Cái máy cùi bắp ở nhà, bấm vào step in coi từng bước của công thức như thế nào thì đến chỗ hàm MAP đơ máy tự thoát Excel luôn.

Tôi thấy Microsoft mô tả rất dễ hiểu mà. Nếu muốn hiểu nguyên lý thì bạn nên thử với công thức đơn giản.
MAP({1;2;3};LAMBDA(x;x*x)) = {1;4;9}
MAP({1;2;3};LAMBDA(x;x*2)) = {2;4;6}
MAP({1;2;3};LAMBDA(x;f(x))) = {f(1);f(2);f(3)}

minhtienttyt · 13/4/23

huuthang_bd đã viết:
Như đã hứa, hôm nay mình chia sẻ công thức chuyển số thành chữ sử dụng được trên Excel 2007 trở lên.
_=";"_");"0";" không phải");"1";" một");"2";" hai");"3";" ba");"4";" bốn");"5";" năm");"6";" sáu");"7";" bảy");"8";" tám");"9";" chín");"+";" tút");"-";" Xe điện");"*";" ngàn,");"/";" triệu,");",=";"=");"=";" Tỷ,")&" ";", ";""));2-(A1<0);999))[/CODE]
Lưu ý: Công thức chuyển đổi chỉ được đánh số trong phạm vi từ -10^15+1 đến 10^15-1, ngoài phạm vi công thức này sẽ trả về "###"
Bạn @cantl vào nhận hàng nhé.
--
Nhân tiện ích tôi chia sẻ luôn công thức chuyển số thành chữ tiếng Việt và tiếng Anh sử dụng trên Excel 365 và Goolge Sheet, không giới hạn độ lớn của số cần đọc (số lớn nhập vào định dạng chuỗi).
Tiếng Việt:
")&CHOOSE(b;"";" điểm";" triệu";" tỷ");IF(b=4;" tỷ";""))))));", tỷ";" Tỷ");CHOOSE(d;"Âm"&r;"Không";UPPER(MID(r;2;1))&MID(r;3;999)))[/CODE]
Tiếng Anh:
Và";"");" "&INDEX(a;INT(x/100)+1)&" Trăm"&IF(y>0;" và";""));"")&IF(y>=20;" "&INDEX(b;INT (y/10))&IF(z>0;"-"&INDEX(a;z+1);"");IF(y>0;" "&INDEX(a;y+1);""))&CHOOSE (k;"";"nghìn"; "triệu"; "tỷ"; "nghìn Tỷ";"nghì Tỷ";"nghìn Tỷ";"sextillion";"septillion";"octillion");"")) ))) ;", Và";" and");CHOOSE(d;"Negative"&r;"Zero";UPPER(MID(r;2;1))&MID(r;3;999)))[/CODE] tỉ lệ";" Nghìn Tỷ Tỷ ";" Nghìn tỷ tỷ";" octillion");""))))); ", và";" and");CHOOSE(d;"Negative"&r;"Zero";UPPER(MID(r;2;1))&MID(r;3;999)))[/CODE] tỉ lệ ";" Nghìn tỷ tỷ";" Nghìn tỷ tỷ";" octillion");"")))));", và";" and");CHOOSE(d;"Negative"&r;"Zero";UPPER(MID(r;2;1))&MID(r;3;999)))[/CODE]
--
-460.000.101.895.031
Âm ba trăm sáu mươi tỷ, một trăm lẻ một triệu, tám trăm chín mươi vạn, không trăm ba mươi mốt
Âm bốn trăm sáu mươi tỷ một trăm lẻ một triệu tám trăm chín tàn ác ma quỷ

thêm chữ đồng đằng sau thì làm thế nào vậy bác

tieutuvodanh192 · 13/4/23

minhtienttyt đã viết:
thêm chữ đồng đằng sau thì làm thế nào vậy bác

Thêm chữ đồng vào sau công thức thôi mà bạn: &" đồng"

Chia sẻ: Công thức chuyển số thành chữ cho Excel 2007

Chuyên gia GPE

File đính kèm

!!! Giải thoát !!!

File đính kèm

Thành viên thường trực

Nam Nhân✨Hiếu Lễ Nghĩa Trí Tín✨

!!! Giải thoát !!!

File đính kèm

Thành viên mới

Nam Nhân✨Hiếu Lễ Nghĩa Trí Tín✨

Thành viên gạo cội

!!! Giải thoát !!!

Chuyên gia GPE

Thành viên tiêu biểu

|||||||||||||

Chuyên gia GPE

RILY

Thành viên tiêu biểu

Chuyên gia GPE

Thành viên tiêu biểu

Chuyên gia GPE

Thành viên mới

Thành viên thường trực

Đếm ngược thời gian