Công thức ngày của tuần (1 người xem)

[trandungnd]

Em muốn hỏi công thức hiển thị ngày của số tuần.
Ví Dụ em có tuần thứ 5. Làm thế nào để nó hiển thị ra

Tuần thứ 5 của năm 2016 là từ ngày 25/01/2016 đến 31/1/2016.

Các bác giúp em với ạ.

 

[lenongree]

Em muốn hỏi công thức hiển thị ngày của số tuần.
Ví Dụ em có tuần thứ 5. Làm thế nào để nó hiển thị ra

Tuần thứ 5 của năm 2016 là từ ngày 25/01/2016 đến 31/1/2016.

Các bác giúp em với ạ.

Ví dụ A1 là số tuần của năm 2016, bạn nhập các CT ở B1,C1:

B1=IFERROR(INDEX(ROW($42370:$42735),SMALL(IF(WEEKDAY(ROW($42370:$42735),2)=7,ROW($1:$365)),A1-1))+1,--"01/01/2016")
C1=INDEX(ROW($42370:$42735),IFERROR(SMALL(IF(WEEKDAY(ROW($42370:$42735),2)=7,ROW($1:$366)),A1),366))

Cả CT đều bấm Ctrl+Shift+Enter!!!

 

[VMH0307]

Em muốn hỏi công thức hiển thị ngày của số tuần.
Ví Dụ em có tuần thứ 5. Làm thế nào để nó hiển thị ra

Tuần thứ 5 của năm 2016 là từ ngày 25/01/2016 đến 31/1/2016.

Các bác giúp em với ạ.

Bạn có thể sử dụng công thức sau:
Giả sử A1 là số tuần
A2 là ngày đầu tiên của năm cần tìm (ở đây là 01/01/2016)
Công thức ngày đầu tuần (lấy thứ 2 là ngày đầu tuần và CN là ngày cuối tuần)

B1=MIN(MAX((A1-1)*7+A2-WEEKDAY(A2,3),A2),DATE(YEAR(A2),12,31))

Công thức ngày cuối tuần:

=MIN(B1+6-WEEKDAY(A2,3)*(A1=1),DATE(YEAR(A2),12,31))

 

[befaint]

A3=2016
B3=5
C3="Tuần thứ "&B3& " của năm "&A3&" là từ ngày "&TEXT(DATE(A3,1,1) - WEEKDAY(DATE(A3,1,1),2) + (B3-1)*7 + 1,"dd/mm/yyyy")&" đến "&TEXT(DATE(A3,1,1)- WEEKDAY(DATE(A3,1,1),2) + B3*7,"dd/mm/yyyy")

 

[VMH0307]

A3=2016
B3=5
C3="Tuần thứ "&B3& " của năm "&A3&" là từ ngày "&TEXT(DATE(A3,1,1) - WEEKDAY(DATE(A3,1,1),2) + (B3-1)*7 + 1,"dd/mm/yyyy")&" đến "&TEXT(DATE(A3,1,1)- WEEKDAY(DATE(A3,1,1),2) + B3*7,"dd/mm/yyyy")

Tuần 1, kết quả sẽ không đúng bạn nhé.

 

[lenongree]

Bạn có thể sử dụng công thức sau:
Giả sử A1 là số tuần
A2 là ngày đầu tiên của năm cần tìm (ở đây là 01/01/2016)
Công thức ngày đầu tuần (lấy thứ 2 là ngày đầu tuần và CN là ngày cuối tuần)

=MAX((A1-1)*7+A2-WEEKDAY(A2,3),A2)

Công thức ngày cuối tuần:

=B1+6-WEEKDAY(A2,3)*(A1=1)

2016 chỉ có 53 tuần. CT gõ tuần 54,55 nó nhảy sang năm 2017 luôn rồi anh, ah, mà CT của em tuần 53 cũng chưa đúng nữa

 

[VMH0307]

2016 chỉ có 53 tuần. CT gõ tuần 54,55 nó nhảy sang năm 2017 luôn rồi anh, ah, mà CT của em tuần 53 cũng chưa đúng nữa

Mình quên giới hạn trên, mình đã sửa lại ở #3,

 

[trandungnd]

Không đúng với tuần cuối cùng của năm. (Tuần 53)

 

[lenongree]

Không đúng với tuần cuối cùng của năm. (Tuần 53)

Mình đã sửa lại ở trên rồi đó bạn, bài #2!!!!

 

[be_09]

Các bạn tính làm sao mà năm 2016 có 53 tuần hay quá, tôi tính mãi không ra mà chỉ ra kết quả 52 tuần và 1/4 ngày.

 

[quanluu]

Em muốn hỏi công thức hiển thị ngày của số tuần.
Ví Dụ em có tuần thứ 5. Làm thế nào để nó hiển thị ra

Tuần thứ 5 của năm 2016 là từ ngày 25/01/2016 đến 31/1/2016.

Các bác giúp em với ạ.

Nếu theo đúng lịch thì tuần thứ 5 là từ 1/2 tới 7/2/2016
Còn nếu ý của bạn như trên thù thử ct này xem
B1=DATE(2016,1,A1*7-10)
C1=DATE(2016,1,A1*7-4)

 

[khuongvietphong]

Các bạn tính làm sao mà năm 2016 có 53 tuần hay quá, tôi tính mãi không ra mà chỉ ra kết quả 52 tuần và 1/4 ngày.

Tuần đầu tiên của năm 2016 là bắt đầu từ: 1/1/2016 - 3/1/2016 (thứ 6 - CN) không đủ 7 ngày nhưng vẫn tính là 1 tuần.

Cứ luân phiên như vậy thì tuần thứ 53 sẽ bắt đầu từ: 26/12/2016 - 31/12/2016.

Theo con hiểu thì ý là như vậy đó bác

 

[lenongree]

Các bạn tính làm sao mà năm 2016 có 53 tuần hay quá, tôi tính mãi không ra mà chỉ ra kết quả 52 tuần và 1/4 ngày.

Chỗ này em dùng Weeknum để kiểm tra thầy, Weeknum(--"31/12/2016")=53

 

[lenongree]

Nếu theo đúng lịch thì tuần thứ 5 là từ 1/2 tới 7/2/2016
Còn nếu ý của bạn như trên thù thử ct này xem
B1=DATE(2016,1,A1*7-10)
C1=DATE(2016,1,A1*7-4)

CT này của bạn đơn giản thật , nhưng tuần đầu tiên thì bắt đầu từ 2015,tuần 53 thì nhảy sang 2017 luôn, bạn chỉnh lại ok luôn đi bạn!!!

 

[be_09]

Tuần đầu tiên của năm 2016 là bắt đầu từ: 1/1/2016 - 3/1/2016 (thứ 6 - CN) không đủ 7 ngày nhưng vẫn tính là 1 tuần.

Cứ luân phiên như vậy thì tuần thứ 53 sẽ bắt đầu từ: 26/12/2016 - 31/12/2016.

Theo con hiểu thì ý là như vậy đó bác

Đúng là có tính mới thấy được, chứ cứ nhớ theo quáng tính (mỗi năm có 52 tuần) có thể sai lầm.

Sau khi tôi kiểm tra lại thì ngày 01/1/2016 là thứ sáu và ngày 31/12/2016 là thứ bảy.

WEEKNUM ngày 31/12/2016 là 53