Thắc mắc hàm IF kết hợp với điều kiện chuỗi (khó)! (1 người xem)

[kjttj]

Mọi người cho mình hỏi
Thứ nhất, Ở cột ghi chú (bảng đinh kèm), mình sử dụng hàm như thế này không được: =IF(C4="HP Laser&*","khuyến mãi áo mưa"," "), mà phải dùng hàm như thế này mới được: =IF(LEFT(B4,6)="HP1100","khuyến mãi áo mưa"," ")_đề bài cho là nếu là mặt hàng HP Laser thì ghi chú là "khuyến mãi áo mưa".
Thứ hai là ở bảng Số lượng bán của các mặt hàng mình có dùng hàm thế này =SUMIFS($D$4:$D$11,$A$4:$A$11,MONTH(A4)=10,$B$4:$B$11,LEFT(B4,2)="HP") nhưng không được, không hiểu tại sao nữa. (dùng hàm sumifs hoặc dsum giúp mình nha!)
Mọi người ai biết giải thích giúp mình nha, mình xin cảm ơn trước.(nếu mọi người có hàm gì tổng quát và hay hơn thì chỉ cho mình luôn nha! mình xin cảm ơn trước)

 

[Hong.Van]

Mọi người cho mình hỏi, Ở cột ghi chú (bảng đinh kèm), mình sử dụng hàm như thế này không được: =IF(C4="HP Laser&*","khuyến mãi áo mưa"," "), mà phải dùng hàm như thế này mới được: =IF(LEFT(B4,6)="HP1100","khuyến mãi áo mưa"," ")_đề bài cho là nếu là mặt hàng HP Laser thì ghi chú là "khuyến mãi áo mưa".
Thứ hai là ở bảng Số lượn bán của các mặt hàng mình có dùng hàm thế này =SUMIF($A$4:$B$11,AND(VALUE(MID(A4,4,2)=10),LEFT(B4,2)="HP"),$D$4:$D$11) nhưng không được, không hiểu tại sao nữa.
Mọi người ai biết giải thích giúp mình nha, mình xin cảm ơn trước.(nếu mọi người có hàm gì tổng quát và hay hơn thì chỉ cho mình luôn nha! mình xin cảm ơn trước)

Trả lời câu 2 của bạn, cthức tại F19

=SUMPRODUCT((MONTH($A$4:$A$11)=$E19)*(LEFT($B$4:$B$11;2)=F$18)*1;$D$4:$D$11)

Kéo qua trái & xuống dưới

 

[kjttj]

Trả lời câu 2 của bạn, cthức tại F19

=SUMPRODUCT((MONTH($A$4:$A$11)=$E19)*(LEFT($B$4:$B$11;2)=F$18)*1;$D$4:$D$11)

Kéo qua trái & xuống dưới

Bạn ơi chỉ giúp mình các dùng hàm SUMIFS hoặc DSUM được không? Cảm ơn bạn nhiều

 

[quangdiepctmbk]

Mọi người cho mình hỏi
Thứ nhất, Ở cột ghi chú (bảng đinh kèm), mình sử dụng hàm như thế này không được: =IF(C4="HP Laser&*","khuyến mãi áo mưa"," "), mà phải dùng hàm như thế này mới được: =IF(LEFT(B4,6)="HP1100","khuyến mãi áo mưa"," ")_đề bài cho là nếu là mặt hàng HP Laser thì ghi chú là "khuyến mãi áo mưa".
Thứ hai là ở bảng Số lượng bán của các mặt hàng mình có dùng hàm thế này =SUMIFS($D$4:$D$11,$A$4:$A$11,MONTH(A4)=10,$B$4:$B$11,LEFT(B4,2)="HP") nhưng không được, không hiểu tại sao nữa. (dùng hàm sumifs hoặc dsum giúp mình nha!)
Mọi người ai biết giải thích giúp mình nha, mình xin cảm ơn trước.(nếu mọi người có hàm gì tổng quát và hay hơn thì chỉ cho mình luôn nha! mình xin cảm ơn trước)

Hàm IF không thể sử dụng các ký tự đại diện được nên bị báo lỗi. Sumproduct và Sumifs cách làm gần giống nhau mà. Bạn nhìn Sumproduct sẽ tự làm được Sumifs

 

[ndu96081631]

Sumproduct và Sumifs cách làm gần giống nhau mà. Bạn nhìn Sumproduct sẽ tự làm được Sumifs

Vậy bạn sửa SUMPRODUCT thành SUMIFS rồi gửi lên đây cho tôi học hỏi với

 

[kjttj]

Hàm IF không thể sử dụng các ký tự đại diện được nên bị báo lỗi. Sumproduct và Sumifs cách làm gần giống nhau mà. Bạn nhìn Sumproduct sẽ tự làm được Sumifs

Không lẽ hàm sumifs này mình sai chỗ nào sao bạn, mình làm hoài chả ra, nếu trích hai điều kiện theo luân lý thì đều TRUE hết mà, nhưng sao nó không SUM lại mình chẳng hiểu nữa

 

[ndu96081631]

Không lẽ hàm sumifs này mình sai chỗ nào sao bạn, mình làm hoài chả ra, nếu trích hai điều kiện theo luân lý thì đều TRUE hết mà, nhưng sao nó không SUM lại mình chẳng hiểu nữa

Đương nhiên là sai rồi
SUMIFS với điều kiện MONTH không thể làm kiểu đó được
Ít ra cũng phải vầy:

=SUMIFS($D$4:$D$11,$A$4:$A$11,">="&DATE(2010,$E19,1),$A$4:$A$11,"<="&DATE(2010,$E19+1,0),$B$4:$B$11,F$18&"*")

Hoặc kiểu khác:

=SUMIFS($D$4:$D$11,$A$4:$A$11,">="&DATE(2010,$E19,1),$B$4:$B$11,F$18&"*")-SUMIFS($D$4:$D$11,$A$4:$A$11,">"&DATE(2010,$E19+1,0),$B$4:$B$11,F$18&"*")

Bạn sẽ thấy SUMPRODUCT có cú pháp đơn giản và dễ hiểu hơn

=SUMPRODUCT((MONTH($A$4:$A$11)=$E19)*(LEFT($B$4:$B$11,2)=F$18)*($D$4:$D$11))

(đồng chí Hong.Van làm công thức này tự nhiên có vụ *1 vào làm chi không biết)
Còn DSUM thì bạn tự nghiên cứu đi

 

[kjttj]

Đương nhiên là sai rồi
SUMIFS với điều kiện MONTH không thể làm kiểu đó được
Ít ra cũng phải vầy:

=SUMIFS($D$4:$D$11,$A$4:$A$11,">="&DATE(2010,$E19,1),$A$4:$A$11,"<="&DATE(2010,$E19+1,0),$B$4:$B$11,F$18&"*")

Hoặc kiểu khác:

=SUMIFS($D$4:$D$11,$A$4:$A$11,">="&DATE(2010,$E19,1),$B$4:$B$11,F$18&"*")-SUMIFS($D$4:$D$11,$A$4:$A$11,">"&DATE(2010,$E19+1,0),$B$4:$B$11,F$18&"*")

Bạn sẽ thấy SUMPRODUCT có cú pháp đơn giản và dễ hiểu hơn

=SUMPRODUCT((MONTH($A$4:$A$11)=$E19)*(LEFT($B$4:$B$11,2)=F$18)*($D$4:$D$11))

(đồng chí Hong.Van làm công thức này tự nhiên có vụ *1 vào làm chi không biết)
Còn DSUM thì bạn tự nghiên cứu đi

Quoa bạn hay thiệt, cảm ơn bạn nhiều nhé!
Cảm phiền bạn có thể giải thích tại sao ở thắc mắc 1, và thắc mắc 2 mình lại sai không, nếu bạn thấy phiền thì thôi, dù sao mình rất cảm ơn!

 

[ndu96081631]

Quoa bạn hay thiệt, cảm ơn bạn nhiều nhé!
Cảm phiền bạn có thể giải thích tại sao ở thắc mắc 1, và thắc mắc 2 mình lại sai không, nếu bạn thấy phiền thì thôi, dù sao mình rất cảm ơn!

Sẵn làm luôn câu 1:

=IF(COUNTIF(C4,"HP Laser*"),"khuyến mãi áo mưa"," ")

Điều kiện hàm IF không thể chơi ký tự đại diện như "*", "?" được nhưng còn COUNTIF thì OK
----------------
Còn hàm SUMIFS: tham số điều kiện phải là 1 chuổi so sánh chứ không thể là dạng công thức trả về TRUE, FALSE được
Ví dụ điều kiện ">0" hoặc ">=0" thì OK... nhưng viết theo kiểu A1 = A2 hay gì gì đó thì bác Bill cóc hiểu quái gì

 

[kjttj]

Sẵn làm luôn câu 1:

=IF(COUNTIF(C4,"HP Laser*"),"khuyến mãi áo mưa"," ")

Điều kiện hàm IF không thể chơi ký tự đại diện như "*", "?" được nhưng còn COUNTIF thì OK
----------------
Còn hàm SUMIFS: tham số điều kiện phải là 1 chuổi so sánh chứ không thể là dạng công thức trả về TRUE, FALSE được
Ví dụ điều kiện ">0" hoặc ">=0" thì OK... nhưng viết theo kiểu A1 = A2 hay gì gì đó thì bác Bill cóc hiểu quái gì

Hihi,cảm ơn bạn nhiều nhé, tại mấy cái nguyên tắc này trước giờ mỉnh chưa nhuyễn lắm!

 

[tungtung92]

Bạn ơi chỉ giúp mình các dùng hàm SUMIFS hoặc DSUM được không? Cảm ơn bạn nhiều

b gửi đề- cột số lượng lấy ở đâu vậy???

 

[kanila64]

Giúp em lập công thức cho bảng này với (file đính kem).
Sheet kho chính, cột nhập - xuất tháng 10, em muốn tạo một công thức khác mà nó tự cộng số lượng nhập-xuất trong từng tháng riêng biệt mà em không cần phải cách dòng trong phần nhập liệu như bảng em đã làm này. nghĩa là phải dùng kèm hàm sumifs và month hoặc hàm sumproduct, nhưng em làm đi làm lại nó đều ra 1 kết quả không đúng.

 

[lenongree]

Bạn ơi cột ngày của bạn định dạng tùm lum hết, bạn dùng text column rồi chỉnh lại ngày cho đúng nhe bạn, xoá hết phần #N/A luôn nhe bạn, bạn chỉnh xong bạn đưa lại mình gắn công thức vào cho bạn!!!

 

[kanila64]

Em chỉnh rồi ạ.
Cám ơn anh đã góp ý.

 

[lenongree]

Bạn nhận lại file nhe bạn!!!

Cái sheet "nhập liệu" minh đã chỉnh lại cột ngày CT và cột số CT, công thức mình để ở cột J,K, trong cái cột ngày CT mình thấy có tháng 1,3,6,9..., bạn xem lại đúng không hay là tháng 10 do đinh dạng bi sai, nếu sai bạn chinh lại nhe, Công thức bên kho chính mình đã để sẵn rồi, bạn fill xuống và fill qua phải nhe, rồi kiểm tra xem kết quả đúng ý bạn chưa!!!

 

[kanila64]

Công thức thì ok rồi, cảm ơn bạn nhiều.
Nhưng mà mình thắc mắc, phần mình tô đỏ ở trong công thức là ở đâu nhỉ? Vì file chính để ở công ty rồi, mình cần biết nó ở đâu ra để khi sao chép qua không bị sai.
=SUMPRODUCT((MONTH('Nhập liệu'!$A$3:$A$78)=INT(COLUMN(T:T)/2))*(LEFT('Nhập liệu'!$B$3:$B$78)=LEFT('kho chinh'!I$5))*('Nhập liệu'!$E$3:$E$78='kho chinh'!$B7)*'Nhập liệu'!$H$3:$I$78)

 

[lenongree]

INT(COLUMN(T:T)/2 mình tính tháng thôi bạn khi fill qua phải nó sẽ ra kết quả là:
10 10 11 11 12 12
vì tháng bạn có 2 phần: nhâp xuất, nếu bạn có 3 phần thì 3, 4 phần thì chia 4!!
P/S: Cái file của bạn chắc tập hợp từ nhiều nguồn, nên có nhiều định dạng khác nhau, bạn cố gắng chỉnh cái ngày CT cho đúng, thì kết quả mới đúng được!!!

 

[kanila64]

INT(COLUMN(T:T)/2 mình tính tháng thôi bạn khi fill qua phải nó sẽ ra kết quả là:
10 10 11 11 12 12
vì tháng bạn có 2 phần: nhâp xuất, nếu bạn có 3 phần thì 3, 4 phần thì chia 4!!
P/S: Cái file của bạn chắc tập hợp từ nhiều nguồn, nên có nhiều định dạng khác nhau, bạn cố gắng chỉnh cái ngày CT cho đúng, thì kết quả mới đúng được!!!

[Bạn giúp mình lập công thức lại cho file này với, chia ra từng kho nhập-xuất theo từng tháng luôn (file đính kèm), hôm qua quên nói chia từng kho]

 

[lenongree]

INT(COLUMN(T:T)/2 mình tính tháng thôi bạn khi fill qua phải nó sẽ ra kết quả là:
10 10 11 11 12 12
vì tháng bạn có 2 phần: nhâp xuất, nếu bạn có 3 phần thì 3, 4 phần thì chia 4!!
P/S: Cái file của bạn chắc tập hợp từ nhiều nguồn, nên có nhiều định dạng khác nhau, bạn cố gắng chỉnh cái ngày CT cho đúng, thì kết quả mới đúng được!!!

[Bạn giúp mình lập công thức lại cho file này với, chia ra từng kho nhập-xuất theo từng tháng luôn (file đính kèm), hôm qua quên nói chia từng kho]

Thử nhe bạn: (thay đổi chỗ chữ đỏ)
=SUMPRODUCT((MONTH('Nhập liệu'!$A$3:$A$78)=INT(COLUMN(H:H)/2))*(LEFT('Nhập liệu'!$B$3:$B$78)=LEFT('kho chinh'!I$5))*('Nhập liệu'!$E$3:$E$78='kho chinh'!$B7)*('Nhập liệu'!$D$3:$D$78='kho chinh'!$Q$3)*'Nhập liệu'!$H$3:$I$78)

P/s: Bạn để tiêu đề là quý 1/2016, mà ở dưới là tháng 4,5,6, nếu là quý 1 thì bạn chỉnh là : INT(COLUMN(B:B)/2) nhe bạn!!!

 

[kanila64]

Thử nhe bạn: (thay đổi chỗ chữ đỏ)
=SUMPRODUCT((MONTH('Nhập liệu'!$A$3:$A$78)=INT(COLUMN(H:H)/2))*(LEFT('Nhập liệu'!$B$3:$B$78)=LEFT('kho chinh'!I$5))*('Nhập liệu'!$E$3:$E$78='kho chinh'!$B7)*('Nhập liệu'!$D$3:$D$78='kho chinh'!$Q$3)*'Nhập liệu'!$H$3:$I$78)

P/s: Bạn để tiêu đề là quý 1/2016, mà ở dưới là tháng 4,5,6, nếu là quý 1 thì bạn chỉnh là : INT(COLUMN(B:B)/2) nhe bạn!!!

Mình đã làm theo ý bạn nhưng sao không nhảy ra kết quả nhỉ, bạn xem file đính kèm rồi chỉnh dùm mình với.
Thanks bạn nhiều.

 

[lenongree]

Mình đã làm theo ý bạn nhưng sao không nhảy ra kết quả nhỉ, bạn xem file đính kèm rồi chỉnh dùm mình với.
Thanks bạn nhiều.

Mình chỉnh lai CT rồi, bạn nhận lại file!!!