Tham chiếu theo chuỗi ký tự (1 người xem)

[winsoft001]

Mình cần lấy dữ liệu tại cột D, E, F, G cho từng loại công việc tương ứng với cột họ và tên
Nhờ ae giúp với (có file excel đính kèm)
Xin cảm ơn
PS: Mình dùng excel 2016

 

[Phuocam]

Mình cần lấy dữ liệu tại cột D, E, F, G cho từng loại công việc tương ứng với cột họ và tên
Nhờ ae giúp với (có file excel đính kèm)
Xin cảm ơn

Nếu excel của bạn có hàm FILTER, thì thử công thức này trong D3 và copy sang phải:

=FILTER($B$3:$B$8,ISNUMBER(SEARCH(D$2,$C$3:$C$8)),"")

 

[dungpham01]

mình dùng office 365 nên không rõ office 2016 trở xuống nếu muốn sửa công thức thì làm thế nào. có lẽ phải nhấn Ctrl+Shift+Enter
nếu dùng office 2019 trở lên thì vẫn dùng bình thường

=IF(ISNUMBER(SEARCH(D$2;$C$3:$C$8));$B$3:$B$8;"")

 

[Duy Tùng 9x]

quan trọng bạn muốn bảng theo từng dòng này. Hay bảng thống kê (là tương ứng vị trí thì tên nó là 1 cột liên tiếp luôn)

=DROP(REDUCE(0,D2:G2,LAMBDA(s,r,IFNA(HSTACK(s,FILTER(B3:B8,1-ISERR(SEARCH(r,C3:C8)))),""))),,1)

=REPT(B3:B8,1-ISNA(REGEXEXTRACT(C3:C8,D2:G2,,1)))

 

[winsoft001]

Nếu excel của bạn có hàm FILTER, thì thử công thức này trong D3 và copy sang phải:

=FILTER($B$3:$B$8,ISNUMBER(SEARCH(D$2,$C$3:$C$8)),"")

Excel của mình không có hàm Filter

View attachment 310310
quan trọng bạn muốn bảng theo từng dòng này. Hay bảng thống kê (là tương ứng vị trí thì tên nó là 1 cột liên tiếp luôn)

=DROP(REDUCE(0,D2:G2,LAMBDA(s,r,IFNA(HSTACK(s,FILTER(B3:B8,1-ISERR(SEARCH(r,C3:C8)))),""))),,1)

=REPT(B3:B8,1-ISNA(REGEXEXTRACT(C3:C8,D2:G2,,1)))

Cảm ơn bạn
Excel mình ko sử dụng đc hàm Drop và hàm regexextract

Bài đã được tự động gộp: 12/11/25

Cảm ơn các ace
Do mình dùng Excel phiên bản thấp nên nhiều hàm ở trên mình ko sử dụng đc cho nên chỉ dùng được theo cách của bạn @dungpham01 bên trên
=IF(ISNUMBER(SEARCH(D$2;$C$3:$C$8));$B$3:$B$8;"")

Bài đã được tự động gộp: 12/11/25

mình dùng office 365 nên không rõ office 2016 trở xuống nếu muốn sửa công thức thì làm thế nào. có lẽ phải nhấn Ctrl+Shift+Enter
nếu dùng office 2019 trở lên thì vẫn dùng bình thường

=IF(ISNUMBER(SEARCH(D$2;$C$3:$C$8));$B$3:$B$8;"")

Cảm ơn bạn
Mình đã làm đc theo cách của bạn

 

[CHAOQUAY]

Mình cần lấy dữ liệu tại cột D, E, F, G cho từng loại công việc tương ứng với cột họ và tên
Nhờ ae giúp với (có file excel đính kèm)
Xin cảm ơn
PS: Mình dùng excel 2016
View attachment 310304

Công thức có phân biệt hoa thường. Tại D3

=IF(ISERROR(FIND(", "&D$2&",",", "&$C3)),"",$B3)

 

[dungpham01]

xin lỗi hôm qua mình chưa đọc kỹ, nếu muốn filter cho dữ liệu liền mạch nữa thì dùng công thức này

=IFERROR(INDEX($B$1:$B$8;SMALL(IF(ISNUMBER(SEARCH(D$2;$C$3:$C$8));ROW($C$3:$C$8);"");ROW()-ROW(D$2)));"")

 

[winsoft001]

xin lỗi hôm qua mình chưa đọc kỹ, nếu muốn filter cho dữ liệu liền mạch nữa thì dùng công thức này

=IFERROR(INDEX($B$1:$B$8;SMALL(IF(ISNUMBER(SEARCH(D$2;$C$3:$C$8));ROW($C$3:$C$8);"");ROW()-ROW(D$2)));"")

Sao dữ liệu mình thêm dòng tại cột B, C (vd đến dòng 20) và thay đổi tại đây cho đến dòng cuối mà ko ra kết quả vậy bạn

 

[dungpham01]

Sao dữ liệu mình thêm dòng tại cột B, C (vd đến dòng 20) và thay đổi tại đây cho đến dòng cuối mà ko ra kết quả vậy bạn

tại vì mình đang để đến dòng thứ 8 thôi. bạn xem trên công thức chỗ nào có B8, C6 thì cho thành B1000, C1000 đi cho chắc. công thức sẽ bị mất dấu {}, lúc đó phải ấn Ctrl Alt Enter mới được