Làm sao để qui đổi thời gian sang các khung giờ (1 người xem)

[thanhhong.hr]

Em có bảng như đính kèm, có giờ bắt đầu-kết thúc, tổng A phút. Các bác chỉ giúp em dùng hàm gì để phân số phút đó sang từng khung giờ khác nhau như trong bảng với ạ, em xin chân thành cảm ơn ạ!!!

 

[bactu]

If kết hợp and

 

[bebo021999]

Tại D3, dùng cái này gọn hơn:

=ROUND((C3-B3)*1440,0)

E3

=ROUND((MIN(--$C3,"06:00:00")-$B3)*1440,0)*(MIN(--$C3,"06:00:00")-$B3>0)

F3

=ROUND((MIN(--$C3,"08:00:00")-MAX(--$B3,"06:00:00"))*1440,0)*(MIN(--$C3,"08:00:00")-MAX(--$B3,"06:00:00")>0)

G3

=ROUND((MIN(--$C3,"21:00:00")-MAX(--$B3,"08:00:00"))*1440,0)*(MIN(--$C3,"21:00:00")-MAX(--$B3,"08:00:00")>0)

H3

=ROUND(($C3-MAX(--$B3,"21:00:00"))*1440,0)*($C3-MAX(--$B3,"21:00:00")>0)

 

[thanhhong.hr]

Anh bebo021999 ơi cho em hỏi chút ạ, sao D3 lại nhân với 1440, và trong hàm Min max anh làm (--$ là mục đích gì ạ? Em cám ơn ạ

 

[huuthang_bd]

Em có bảng như đính kèm, có giờ bắt đầu-kết thúc, tổng A phút. Các bác chỉ giúp em dùng hàm gì để phân số phút đó sang từng khung giờ khác nhau như trong bảng với ạ, em xin chân thành cảm ơn ạ!!!

Cách khác

E3=IFERROR(ROWS(INDIRECT(ROUND($B3*1440,0)&":"&ROUND($C3*1440,0)) $1:$360),0)

Giải thích chỗ màu đỏ:
1 = 0 * 60 + 1
360 = 6 * 60

 

[Phan Thế Hiệp]

Em có bảng như đính kèm, có giờ bắt đầu-kết thúc, tổng A phút. Các bác chỉ giúp em dùng hàm gì để phân số phút đó sang từng khung giờ khác nhau như trong bảng với ạ, em xin chân thành cảm ơn ạ!!!

Góp thêm cách khác:

E3=ROUND((MEDIAN(0,6,$C3*24)-MEDIAN(0,6,$B3*24))*60,)
F3=ROUND((MEDIAN(6,8,$C3*24)-MEDIAN(6,8,$B3*24))*60,)
G3=ROUND((MEDIAN(8,21,$C3*24)-MEDIAN(8,21,$B3*24))*60,)
H3=ROUND((MEDIAN(21,24,$C3*24)-MEDIAN(21,24,$B3*24))*60,)

Enter fill xuống.
Thân.

 

[nilt02]

Anh bebo021999 ơi cho em hỏi chút ạ, sao D3 lại nhân với 1440, và trong hàm Min max anh làm (--$ là mục đích gì ạ? Em cám ơn ạ

1440=60*24
-- là 2 dấu trừ, vd: --1 thì =+1
$ địa chỉ tuyệt đối (cơ bản của excel)

 

[thanhhong.hr]

em cám ơn mọi người đã giúp đỡ em ạ, nhưng em thấy cái tổng số phút với cái mình dùng công thức phân ra kết quả lệch nhau +1,-1, có cách nào làm cho nó khớp ko ạ? thanks all!!!

 

[huuthang_bd]

em cám ơn mọi người đã giúp đỡ em ạ, nhưng em thấy cái tổng số phút với cái mình dùng công thức phân ra kết quả lệch nhau +1,-1, có cách nào làm cho nó khớp ko ạ? Cảm ơn all!!!

Bạn phải nói rõ quy tắc làm tròn thì mọi người mới giúp được.

 

[Phan Thế Hiệp]

em cám ơn mọi người đã giúp đỡ em ạ, nhưng em thấy cái tổng số phút với cái mình dùng công thức phân ra kết quả lệch nhau +1,-1, có cách nào làm cho nó khớp ko ạ? Cảm ơn all!!!

Do chênh lệch làm tròn ±1 phút giữa 2 cách tính: Số tổng và Số phân ra theo từng đoạn thời gian.
Bạn thử điều chỉnh công thức cột D như sau:

D3=IF(ROUNDUP((C3-B3)*1440,)>SUM(F3:I3),ROUNDDOWN((C3-B3)*1440,),ROUNDUP((C3-B3)*1440,))

Enter, fill xuống.
Xem file kèm.
Thân.

 

[thanhhong.hr]

Do chênh lệch làm tròn ±1 phút giữa 2 cách tính: Số tổng và Số phân ra theo từng đoạn thời gian.
Bạn thử điều chỉnh công thức cột D như sau:

D3=IF(ROUNDUP((C3-B3)*1440,)>SUM(F3:I3),ROUNDDOWN((C3-B3)*1440,),ROUNDUP((C3-B3)*1440,))

Enter, fill xuống.
Xem file kèm.
Thân.

CÁM ƠN BẠN NHIỀU NHÉ

 

[excel_lv1.5]

Em có bảng như đính kèm, có giờ bắt đầu-kết thúc, tổng A phút. Các bác chỉ giúp em dùng hàm gì để phân số phút đó sang từng khung giờ khác nhau như trong bảng với ạ, em xin chân thành cảm ơn ạ!!!

Cách khác, bạn chọn vùng E3:H3, rồi nhập công thức mảng này:

E3:H3=TRANSPOSE(FREQUENCY(ROUND($B3*1440,)+ROW(INDIRECT("1:"&ROUND((C3-B3)*1440,))),{6,8,21}*60))

Yêu cầu bấm Ctrl+Shift+Enter rồi copy xuống!!!

 

[batman1]

Em có bảng như đính kèm, có giờ bắt đầu-kết thúc, tổng A phút. Các bác chỉ giúp em dùng hàm gì để phân số phút đó sang từng khung giờ khác nhau như trong bảng với ạ, em xin chân thành cảm ơn ạ!!!

Bạn đọc bài #31 xong thì bạn phải tự làm được
https://www.giaiphapexcel.com/diend...c-tính-thời-gian-theo-buổi.129222/post-813153

 

[thanhhong.hr]

Bạn đọc bài #31 xong thì bạn phải tự làm được
https://www.giaiphapexcel.com/diendan/threads/giúp-code-hoặc-công-thức-tính-thời-gian-theo-buổi.129222/post-813153

E đọc mà vẫn chưa hiểu lắm, em có file đính kèm, muốn phân ra ca ngày-ca đêm(giờ vào ca từ ngày này sang tận sáng hôm sau và cũng có thể qua 2 ngày do lái xe đi đường xa vẫn tính tăng ca cho họ). Em xin chân thành cám ơn ạ

 

[Phan Thế Hiệp]

E đọc mà vẫn chưa hiểu lắm, em có file đính kèm, muốn phân ra ca ngày-ca đêm(giờ vào ca từ ngày này sang tận sáng hôm sau và cũng có thể qua 2 ngày do lái xe đi đường xa vẫn tính tăng ca cho họ). Em xin chân thành cám ơn ạ

Dùng thử công thức mảng để phân ra 2 ca và tính cho nhiều ngày:
Ca ngày:

C3=DATEDIF(A3-1,B3,"d")*16-ROUND(SUM(CHOOSE(MATCH(MOD(A3:B3,1)*24,{0,6,22}),{0,16},MOD(A3:B3,1)*24*{1,-1}+{-6,22},{16,0})),2)

Kết thúc bằng Ctrl+Shift+Enter.
Ca đêm:

D3=E3-C3
E3=ROUND((B3-A3)*24,2)

Chỉ Enter.
Xem file kèm.
Thân.

 

[thanhhong.hr]

Dùng thử công thức mảng để phân ra 2 ca và tính cho nhiều ngày:
Ca ngày:

C3=DATEDIF(A3-1,B3,"d")*16-ROUND(SUM(CHOOSE(MATCH(MOD(A3:B3,1)*24,{0,6,22}),{0,16},MOD(A3:B3,1)*24*{1,-1}+{-6,22},{16,0})),2)

Kết thúc bằng Ctrl+Shift+Enter.
Ca đêm:

D3=E3-C3
E3=ROUND((B3-A3)*24,2)

Chỉ Enter.
Xem file kèm.
Thân.

EM CÁM ƠN NHIỀU Ạ!!!