Chuyên đề giải đáp các bài tập

[ptm0412]

Cò già ăn uống thiếu thốn kí rì mà để tưng tưng zậy?
Coi thử mấy cáicông thức cải tiến nè. Mắc chi mà offset tưng bừng hoa lá vậy kà? Câu số bốn đọc hoa mắt luôn zậy đó.
Còn cái câu số 9:
=SUMPRODUCT((WEEKDAY(B7:B16;2)>5)*(F7:F16))+SUMPRODUCT((WEEKDAY(B7:B16;2)>5)*(G7:G16))

- sao hông đặt thừa số chung? trở thành
=SUMPRODUCT((WEEKDAY(B7:B16;2)>5)*(F7:F16+G7:G16))

- sau đó cộng zô luôn thành
=SUMPRODUCT((WEEKDAY(B7:B16;2)>5)*(F7:G16))

Thích nhất là chọt cò già cho tức chơi!

 

[ptm0412]

Chọt sai mà không tức nhỉ?
Sai câu 3 và 4, khà khà

 

[winsdc]

A cho em hỏi vì sao trong các công thức lại có dấu " { " ở đầu và cuối dzậy

 

[ptm0412]

A cho em hỏi vì sao trong các công thức lại có dấu " { " ở đầu và cuối dzậy

Công thức mảng cần phải nhấn Ctrl Shift Enter mới ra kết quả. Nhấn 3 phím đó sẽ xuất hiện cặp dấu này.

 

[nguyetca007]

Bài tập rắc rối, nhờ ACE giúp đỡ....

Mình có một bài tập về tính tiền phòng cho khách sạn.
Yêu cầu: Tính thành tiền cho các loại khách thuê từ 1 tháng trở lên tính theo đơn giá tháng,
khách thuê từ 1 tuần trở lên tính theo đơn giá tuần, còn lại tính theo đơn giá ngày.
Chú ý tới những khách hàng được giảm giá.
Nhờ ACE trong GPE xem giúp. Cám ơn nhiều nhiều

 

[khoavu87]

Mình có một bài tập về tính tiền phòng cho khách sạn.
Yêu cầu: Tính thành tiền cho các loại khách thuê từ 1 tháng trở lên tính theo đơn giá tháng,
khách thuê từ 1 tuần trở lên tính theo đơn giá tuần, còn lại tính theo đơn giá ngày.
Chú ý tới những khách hàng được giảm giá.
Nhờ ACE trong GPE xem giúp. Cám ơn nhiều nhiều

trong lúc chưa có ng hướng dẫn bạn thử dùng hàm này:

=IF(G6=0,1,G6)*VLOOKUP(D6,$B$18:$E$21,IF(DATEDIF(E6,F6,"m")>=1,4,IF(DATEDIF(E6,F6,"d")>=7,3,2)))

Bạn xem lại xem? mình kiểm tra khách hàng thứ hai vẫn ổn mà. mình sửa lại hàm chút rùi đó.

 

[hoangminhtien]

Mình thì lại nghĩ theo hướng khác.tức là số tiền bằng số tiền tính theo tháng+số tiền tính theo tuần còn lẽ sau khi tính theo tháng+số tiền tính theo ngày còn lại sau khi tính tháng và tuần

=(1-G6)*(DATEDIF(E6,F6,"m")*VLOOKUP(D6,$B$17:$E$21,4,0)+INT(DATEDIF(E6,F6,"md")/7)*VLOOKUP(D6,$B$17:$E$21,3,0)+(DATEDIF(E6,F6,"md")-INT(DATEDIF(E6,F6,"md")/7)*7)*VLOOKUP(D6,$B$17:$E$21,2,0))

 

[nguyetca007]

Cám ơn khoavu87 và hoangminhtien cách giải của 2 bạn có vẻ tương đối đúng, nhưng với ô đầu tiên thôi, còn KH thu 2 thi ko ổn lắm. nhờ các bạn xem thêm giúp mình... Mình cũng lăn tăn như bạn khoavu87 ở khoảng tháng chênh lệch ngày, 28,30,31 ngày.

 

[hoangminhtien]

Nếu bạn lăn tăn ở khoảng tháng chênh lệch ngày, 28,30,31 ngày sao bạn không dùng DATEDIF(E6,F6,"m")>=1 nhỉ?

 

[7hsas]

Không hiểu ý nghĩa của câu hỏi.

Thầy mới cho em một bài tập về nhà. Các câu khác em đã làm xong rôi, riêng câu cuối cùng em chưa hiểu ý của đề bài (ý câu hỏi là gì!). Mong anh chị giải thích dùm em.
- Tính cột Thành Tiền: Số Tiêu thụ * Đơn giá 1KW. Nếu số tiêu thụ thứ 101 trở lên thì mỗi KWh tính giá gấp đôi.

 

[khoavu87]

Thầy mới cho em một bài tập về nhà. Các câu khác em đã làm xong rôi, riêng câu cuối cùng em chưa hiểu ý của đề bài (ý câu hỏi là gì!). Mong anh chị giải thích dùm em.
- Tính cột Thành Tiền: Số Tiêu thụ * Đơn giá 1KW. Nếu số tiêu thụ thứ 101 trở lên thì mỗi KWh tính giá gấp đôi.

Ở đây bạn hiểu sai vấn đề rùi.
Bạn nghĩ là nếu số tiêu thụ >101 trở lên thì lúc đó đơn giá của cả số điện tiêu thụ nhân lên gấp đôi, như vậy không đúng với yêu cầu đề bài.
đề bài nói như trên có nghĩa là :
- nếu Số tiêu thụ >=101 thì những số vượt đó với nhân đơn giá và nhân thêm với hai.
Ví dụ thế này :
- Số tiêu thụ A =105 số, có đơn giá 1KW =700 thì tính tiền như sau:
tiền = [(105-101)*2+101]*700

 

[7hsas]

Vậy cho em đáp án luôn được không ạ.

 

[khoavu87]

Vậy cho em đáp án luôn được không ạ.

Bạn làm thử xem xem thế nào.

=IF(F2>=101,((F2-100)*2+100)*HLOOKUP(RIGHT(B2,1),$B$9:$D$10,2,0),HLOOKUP(RIGHT(B2,1),$B$9:$D$10,2,0)*F2)

 

[dat_butmuc]

Bạn làm thử xem xem thế nào.

=IF(F2>=101,((F2-100)*2+100)*HLOOKUP(RIGHT(B2,1),$B$9:$D$10,2,0),HLOOKUP(RIGHT(B2,1),$B$9:$D$10,2,0)*F2)

Nếu như công thức của Khoavu đúng rồi thì sao không dùng "thừa số chung" cho nó gọn,
Thế này:

=IF(F2<101,F2,F2*2-100)*HLOOKUP(RIGHT(B2),$B$9:$D$10,2,0))

 

[BNTT]

Bạn làm thử xem xem thế nào.

=IF(F2>=101,((F2-100)*2+100)*HLOOKUP(RIGHT(B2,1),$B$9:$D$10,2,0),HL OOKUP(RIGHT(B2,1),$B$9:$D$10,2,0)*F2)

Cái này ngắn hơn tẹo:

=HLOOKUP(RIGHT(B2),$B$9:$D$10,2,0)*(F2*2-100+(F2<=100))

 

[7hsas]

Giờ thì hiểu rồi. Em cảm ơn tất cả.
Có 1 cách khác ngắn hơn nữa:

=IF(F2<101,F2,(F2*2-100)*G2

Vì ô G2 đã làm trước rồi nên lấy ô G2 cho nhanh

 

[BNTT]

Giờ thì hiểu rồi. Em cảm ơn tất cả.
Có 1 cách khác ngắn hơn nữa: Vì ô G2 đã làm trước rồi nên lấy ô G2 cho nhanh

=IF(F2<101,F2,(F2*2-100)*G2

Muốn ngắn hơn nữa không?

=(F2*2-100+(F2<101))*G2

 

[timkiem_abc]

Dò tìm,tham chiếu

Bài này Anh(Chị) nào chỉ giúp với.

 

[7hsas]

Muốn ngắn hơn nữa không?

=(F2*2-100+(F2<101))*G2

Cho em hỏi cái công thức mà em tô đỏ, em không hiểu sao phải để như vậy ạ.

 

[BNTT]

Cho em hỏi cái công thức mà em tô đỏ, em không hiểu sao phải để như vậy ạ.

Cái đó không phải là công thức, mà là biểu thức, sẽ trả về TRUE nếu đúng, trả về FALSE nếu sai.
Và thường (thường thôi, không phải lúc nào cũng thế) thì Excel xem TRUE = 1, FALSE = 0
Do đó, trong những trường hợp chỉ dùng IF để xét một điều kiện đúng hay sai, tôi thường dùng dạng biểu thức như thế này, mà không dùng IF.

Ví dụ, giả sử như có bài toán: Nếu A1 lớn hơn 1 thì bằng B1, còn nếu A1 nhỏ hơn hoặc bằng 1 thì bằng 0
Thay vì làm như thế này: =IF(A1>1,B1,0)
Có thể thay bằng: =B1*(A1>1)
Khi A1>1, biểu thức (A1>1) sẽ đúng, và bằng TRUE, hay là bằng 1, do đó kết quả sẽ là = 1*B1 = B1 (đúng với yêu cầu đề ra)
Còn khi A1<=1, biểu thức (A1>1) sẽ sai, và bằng FALSE, hay là bằng 0, do đó kết quả sẽ là = 0*B1 = 0 (đúng với yêu cầu đề ra)

Bài toán của bạn, tôi cũng làm theo kiểu suy luận đó. Bạn hiểu chứ?