Công thức nhiều điều kiện (1 người xem)

[letienmai]

Kính gửi: anh/chị
Hiện tại mình đang xây dựng nhật ký kiểm tra chất lượng mình muốn gõ kết quả vào sẽ so sánh với tiêu chuẩn và kết luận là đạt hoặc không đạt. Tuy nhiên đang vướng là cột tiêu chuẩn có nhiều định dạng +/- . >=, <= vì vậy mình làm cách thủ công là tạo 02 cột phụ Min,Max và dùng hàm if,left,right,search...nhưng rất là loằng ngoằng.
Vì vậy rất mong mọi người giúp đỡ gợi ý công thức nào không cần dùng cột phụ để dung lượng file được nhẹ (Mình có đính kèm file và ảnh)
Xin cám ơn.

 

[xuongrongdat]

Kính gửi: anh/chị
Hiện tại mình đang xây dựng nhật ký kiểm tra chất lượng mình muốn gõ kết quả vào sẽ so sánh với tiêu chuẩn và kết luận là đạt hoặc không đạt. Tuy nhiên đang vướng là cột tiêu chuẩn có nhiều định dạng +/- . >=, <= vì vậy mình làm cách thủ công là tạo 02 cột phụ Min,Max và dùng hàm if,left,right,search...nhưng rất là loằng ngoằng.
Vì vậy rất mong mọi người giúp đỡ gợi ý công thức nào không cần dùng cột phụ để dung lượng file được nhẹ (Mình có đính kèm file và ảnh)
Xin cám ơn.

View attachment 262336

Bạn ví dụ minh họa thêm 20 Tiêu chuẩn nữa xem. Hay chỉ bao nhiêu tiêu chuẩn đó thôi bạn?

 

[befaint]

"Đầu bày" là đầu gì vậy bạn? @@


Cột Ghi chú để làm gì? Có liên quan gì đề bài?

Còn chưa thấy nêu yêu cầu làm gì? Mới thấy kêu cấm dùng cột phụ!

 

[letienmai]

"Đầu bày" là đầu gì vậy bạn? @@
View attachment 262338

Cột Ghi chú để làm gì? Có liên quan gì đề bài?

Còn chưa thấy nêu yêu cầu làm gì? Mới thấy kêu cấm dùng cột phụ!

Hi anh
1. Cột ghi chú em thay bằng Diễn giải.
2. Đầu bày em gõ nhầm đúng là Đầu bài
3. Yêu cầu: em có ghi rõ là dùng công thức ở các ô tô màu xanh lá cây.

Bài đã được tự động gộp: 13/7/21

Bạn ví dụ minh họa thêm 20 Tiêu chuẩn nữa xem. Hay chỉ bao nhiêu tiêu chuẩn đó thôi bạn?

Có mấy trường hợp như trên thôi bạn.

 

[xuongrongdat]

Có mấy trường hợp như trên thôi bạn.

Vậy dễ ẹc, haha. Bạn đợi mình xíu.

 

[befaint]

3. Yêu cầu: em có ghi rõ là dùng công thức ở các ô tô màu xanh lá cây.

Chời đất. Có ai hiểu làm cái gì để viết công thức vào ô xanh lá đâu?

 

[letienmai]

Vậy dễ ẹc, haha. Bạn đợi mình xíu.

Hi anh.
Ô xanh cụ thể là cột kết quả sẽ được gọi là Đạt khi cột kết quả thỏa mãn các điều kiện cột tiêu chuẩn ngược lại thì là Không đạt.

Bài đã được tự động gộp: 13/7/21

Vậy dễ ẹc, haha. Bạn đợi mình xíu.

Hi cám ơn bạn.

 

[concogia]

Chời đất. Có ai hiểu làm cái gì để viết công thức vào ô xanh lá đâu?

Đề bài ghi rất rõ:
90 ± 10 ==> trong khoảng 80- 100 ==> Kết quả 99 ==> Đạt, kết quả 105 ==> Không đạt
Các hàng khác tương tự
Thân

 

[befaint]

Đề bài ghi rất rõ:
90 ± 10 ==> trong khoảng 80- 100 ==> Kết quả 99 ==> Đạt, kết quả 105 ==> Không đạt

Đề bài giờ mới gọi là "ghi rất rõ". Còn trước đó: Đề bài không ghi gì cả.

Có biết 90 ± 10 là gì đâu.

=CHOOSE(MATCH(SUBSTITUTE(C6," ",""),{"90±10";"≥90";"≤90"},0),IF(AND(D6<=90+10,D6>=90-10),"Đạt","Không đạt"),IF(D6>=90,"Đạt","Không đạt"),IF(D6<=90,"Đạt","Không đạt"))

 

[xuongrongdat]

@letienmai :
Bạn tham khảo công thức tại ô E6 trong file mình đính kèm nhé.
Mình làm rừng thôi, thấy cũng dài. Nếu bạn muốn ngắn hơn thì chờ các bạn khác xem sao, híc.

=IF(LEN(C6)>=5;IF(AND(D6>=80;D6<=100);"Đạt";"Không đạt");IF(LEFT(C6;1)="≥";IF(D6>=90;"Đạt";"Không đạt");IF(D6<=90;"Đạt";"Không đạt")))

 

[letienmai]

Đề bài giờ mới gọi là "ghi rất rõ". Còn trước đó: Đề bài không ghi gì cả.

Có biết 90 ± 10 là gì đâu.

=CHOOSE(MATCH(SUBSTITUTE(C6," ",""),{"90±10";"≥90";"≤90"},0),IF(AND(D6<=90+10,D6>=90-10),"Đạt","Không đạt"),IF(D6>=90,"Đạt","Không đạt"),IF(D6<=90,"Đạt","Không đạt"))

Cám ơn anh đã quan tâm giúp đỡ.
Tuy nhiên em xin đính chính gõ hơn là số 90 ± 10 là em chỉ demo một số thôi trong thực tế thì không cố định là 90 mà cũng không cố định là 10 mà nó là số nguyên dương ví dụ có thể là: 85 ± 5 hoặc 4 ± 2 .v.v

 

[befaint]

chỉ demo một số thôi

Bạn nên đưa đề bài sao cho tổng quát.

 

[letienmai]

@letienmai :
Bạn tham khảo công thức tại ô E6 trong file mình đính kèm nhé.
Mình làm rừng thôi, thấy cũng dài. Nếu bạn muốn ngắn hơn thì chờ các bạn khác xem sao, híc.

=IF(LEN(C6)>=5;IF(AND(D6>=80;D6<=100);"Đạt";"Không đạt");IF(LEFT(C6;1)="≥";IF(D6>=90;"Đạt";"Không đạt");IF(D6<=90;"Đạt";"Không đạt")))

Cám ơn bạn đã quan tâm giúp đỡ.
Do #4 mình sai sót không nói rõ là chỉ có mấy trường hợp là +/-, >=,<= còn lại con số thì ngẫu nhiên như mình vừa viết ở bài #11

 

[Phuocam]

Kính gửi: anh/chị
Hiện tại mình đang xây dựng nhật ký kiểm tra chất lượng mình muốn gõ kết quả vào sẽ so sánh với tiêu chuẩn và kết luận là đạt hoặc không đạt. Tuy nhiên đang vướng là cột tiêu chuẩn có nhiều định dạng +/- . >=, <= vì vậy mình làm cách thủ công là tạo 02 cột phụ Min,Max và dùng hàm if,left,right,search...nhưng rất là loằng ngoằng.

Chỉ có 3 dạng này: ±, ≥, ≤ , hay còn nhiều dạng khác? Mỗi dạng có thể phải dủng 1 hàm IF+

.

 

[letienmai]

Chỉ có 3 dạng này: ±, ≥, ≤ , hay còn nhiều dạng khác? Mỗi dạng có thể phải dủng 1 hàm IF+

.

Chỉ có 3 dạng trên thôi ạ.

 

[Phuocam]

Chỉ có 3 dạng trên thôi ạ.

Dùng 3 hàm IF cho 3 trường hợp đó rồi nối lại.
.

 

[Phuocam]

Chỉ có 3 dạng trên thôi ạ.

Xem công thức trong file đính kèm.

.

 

[letienmai]

Xem công thức trong file đính kèm.

.

Em xin cám ơn nhé. Để em xem và nghiên cứu học hỏi thêm

 

[VetMini]

...Vì vậy rất mong mọi người giúp đỡ gợi ý công thức nào không cần dùng cột phụ để dung lượng file được nhẹ (Mình có đính kèm file và ảnh)
...

Ở đâu có chuyện "không dùng cột phụ thì nhẹ file" vậy?

 

[cadafi]

Chào bạn,
Bạn có thể tham khảo thêm công thức bên dưới:

=IF(CHOOSE(MATCH(1,--(SUBSTITUTE(C6," ","")={"90±10","≥90","≤90"}),0),(D6>=80)*(D6<=100),D6>=90,D6<=90),"Đạt","Không Đạt")

Hoặc Choose 2 lần thì không cần IF:

=CHOOSE(CHOOSE(MATCH(1,--(SUBSTITUTE(C6," ","")={"90±10","≥90","≤90"}),0),(D6>=80)*(D6<=100),D6>=90,D6<=90)+1,"Không Đạt","Đạt")

 

[xuongrongdat]

Chào bạn,
Bạn có thể tham khảo thêm công thức bên dưới:


Hoặc Choose 2 lần thì không cần IF:

Oái, anh đọc bài #11 của thớt chưa?

 

[VetMini]

Bài này phải diễn thành bảng tra. Dùng công thức tạo bảng tra cũng được. Hoặc dùng INDEX để tạo bảng tra bên trong công thức (theo yêu cầu khong cột phụ, khó hiểu, khó trông hơn thì mặc xác).

Tuy nhiên các điều kiện của thớt có chỗ chồng nhau mà không hề cho biết thằng nào trước mẹ nào cho nên chưa thể làm được gì.

 

[letienmai]

Chào bạn,
Bạn có thể tham khảo thêm công thức bên dưới:


Hoặc Choose 2 lần thì không cần IF:

Hi anh
Cám ơn anh đã quan tâm và giúp đỡ ạ. Tuy nhiên do thiếu xót nên phần đầu bài em nêu chưa cụ thể rõ ràng em có bổ sung thêm ở bài #11 ạ.

 

[cadafi]

Hi anh
Cám ơn anh đã quan tâm và giúp đỡ ạ. Tuy nhiên do thiếu xót nên phần đầu bài em nêu chưa cụ thể rõ ràng em có bổ sung thêm ở bài #11 ạ.

À, vậy thì mình thêm tham số so sánh với Kết quả ở cột D vào, công thức hơi dài chút nhé.

=IF(CHOOSE(MATCH(1,--(IFERROR(SEARCH({"±","≥","≤"},SUBSTITUTE(C6," ",""),1),0)>0),0),(D6>=LEFT(C6,FIND("±",C6,1)-1)-RIGHT(C6,LEN(C6)-FIND("±",C6,1)))*(D6<=LEFT(C6,FIND("±",C6,1)-1)+RIGHT(C6,LEN(C6)-FIND("±",C6,1))),--(D6>=--RIGHT(C6,LEN(C6)-FIND("≥",C6,1))),--(D6<=--RIGHT(C6,LEN(C6)-FIND("≤",C6,1)))),"Đạt","Không đạt")

Hàm LET trong Office 365 cũng chẳng ngắn hơn được!

=LET(mR,SUBSTITUTE(C6," ",""),xR,FIND("±",mR,1),yR,FIND("≥",mR,1),zR,FIND("≤",mR,1),iNbr1,LEFT(mR,xR-1),jNbr1,RIGHT(mR,LEN(mR)-xR),iNbr2,
--RIGHT(mR,LEN(mR)-yR),iNbr3,--RIGHT(mR,LEN(mR)-zR),iAr,MATCH(1,--(IFERROR(SEARCH({"±","≥","≤"},mR,1),0)>0),0), IF(CHOOSE(iAr,(D6>=iNbr1-jNbr1)*(D6<=iNbr1+jNbr1),D6>=iNbr2,D6<=iNbr3),"Đạt","Không Đạt"))

 

[letienmai]

À, vậy thì mình thêm tham số so sánh với Kết quả ở cột D vào, công thức hơi dài chút nhé.




Hàm LET trong Office 365 cũng chẳng ngắn hơn được!



View attachment 262364

Thêm một cách rất hay. Cám ơn anh đã nhiệt tình giúp đỡ ạ.

 

[Phan Thế Hiệp]

Cám ơn anh đã quan tâm giúp đỡ.
Tuy nhiên em xin đính chính gõ hơn là số 90 ± 10 là em chỉ demo một số thôi trong thực tế thì không cố định là 90 mà cũng không cố định là 10 mà nó là số nguyên dương ví dụ có thể là: 85 ± 5 hoặc 4 ± 2 .v.v

Góp thêm cho bạn một cách khác, chỉ áp dụng cho cột "kết quả" là số nguyên dương từ 1 đến 1000 (có thể hơn chút )

E6=IF(MEDIAN(D6,IFERROR(LEFT(C6,FIND("±",C6)-1)+MID(C6,FIND("±",C6)+1,5)*{-1,1},MID(C6,2,5)*IF(LEFT(C6)="≤",{0,1},{1,1000})))=D6,"Đạt","Không đạt")

Enter, fill xuống.

Thân

 

[letienmai]

Góp thêm cho bạn một cách khác, chỉ áp dụng cho cột "kết quả" là số nguyên dương từ 1 đến 1000 (có thể hơn chút )

E6=IF(MEDIAN(D6,IFERROR(LEFT(C6,FIND("±",C6)-1)+MID(C6,FIND("±",C6)+1,5)*{-1,1},MID(C6,2,5)*IF(LEFT(C6)="≤",{0,1},{1,1000})))=D6,"Đạt","Không đạt")

Enter, fill xuống.

Thân

Hi anh.
- Cám ơn anh đã giúp đỡ. Quả thật lần đầu tiên em biết đến hàm MEDIAN qua google thì em biết thêm là hàm Trung bình vị.
- Thật sự rất ngưỡng mộ kiến thức rộng lớn của các anh/chị trong diễn đàn.

 

[Phan Thế Hiệp]

Quả thật lần đầu tiên em biết đến hàm MEDIAN qua google thì em biết thêm là hàm Trung bình vị.

Median() tìm số "Trung vị" không phải là số "Trung bình vị".
Ví dụ:

• Nếu dãy các số đếm lẻ: như 3 (5, 7, 9.... ) thì nó sẽ lấy số nằm ở khoảng giữa của 2 (4, 6, 8...) số còn lại. Vd: dãy 5 (số lẻ) số sau: 2, 8, 37, 15, 6 thì 8 là số trung vị vì nó nằm ở khoảng giữa so với 4 số còn lại là 2, 6, 15, 37.
• Nếu dãy các số đếm chẵn: thì nó là số "trung bình" của 2 số nằm ở khoảng giữa các số còn lại. Vd: dãy 4 (số chẵn) số: 7, 15, 51, 1 thì nó lấy trung bình của 2 số: 7 và 15 (2 số này nằm khoảng giữa của 1, 51), bằng 11 là số trung vị.

Thân