Các câu hỏi về hàm SUMIF (1 người xem)

[Hoàng Trọng Nghĩa]

Làm sao có thể SUM với 2 điều kiện trở lên?

Bài toán cho như sau:​

​

​

​

​

Tổng giá trị THANH LÝ của ngày 25/09/2008?​

​

​

(Xin gửi file đính kèm, mong các Anh Chị giúp đỡ mình vì mình mới chập chững bước vào Excel)
cám ơn rất nhiều!

 

[ndu96081631]

Bài toán cho như sau:​

Tổng giá trị THANH LÝ của ngày 25/09/2008?​

(Xin gửi file đính kèm, mong các Anh Chị giúp đỡ mình vì mình mới chập chững bước vào Excel)
cám ơn rất nhiều!

Dùng SUMPRODUCT bạn ơi

=SUMPRODUCT(($A$2:$A$16=DATE(2008,9,25))*($C$2:$C$16="thanh lý")*($B$2:$B$16))

 

[Kimminhanh]

Bài toán tính tổng có điều kiện

Mình thắc mắc về bài toán tính tổng có điều kiện, ở đây, tại một cột có các giá trị như A01, A02, A03, B01,B02,B03...giờ mình muốn tính tổng của tất cả các giá trị có chữ A đầu tiền thì thế nào

 

[BNTT]

Mình thắc mắc về bài toán tính tổng có điều kiện, ở đây, tại một cột có các giá trị như A01, A02, A03, B01,B02,B03...giờ mình muốn tính tổng của tất cả các giá trị có chữ A đầu tiền thì thế nào

Giả bộ cột đó là cột A, từ A1:A10; cột chứa mấy con số để tính tổng là B, từ B1:B10

1. Tại chỗ muốn lấy kết quả, gõ công thức: =SUM(IF(LEFT(A1:A10)="A",B1:B10))
   Nhấn Ctrl+Shift+Enter.
   
   
2. Tại chỗ muốn lấy kết quả, gõ công thức: =SUMPRODUCT((LEFT(A1:A10)="A")*B1:B10)
   Nhấn Enter.

 

[ndu96081631]

Giả bộ cột đó là cột A, từ A1:A10; cột chứa mấy con số để tính tổng là B, từ B1:B10

1. Tại chỗ muốn lấy kết quả, gõ công thức: =SUM(IF(LEFT(A1:A10)="A",B1:B10))
   Nhấn Ctrl+Shift+Enter.
2. Tại chỗ muốn lấy kết quả, gõ công thức: =SUMPRODUCT((LEFT(A1:A10)="A")*B1:B10)
   Nhấn Enter.

Cần gì công thức mãng, dùng SUMIF cũng được mà:

=SUMIF(A1:A10,"A*",B1:B10)

 

[duyag]

Hỏi về đếm số lượng thiết bị với 2 điều kiện?

Chào các bác, em là lính mới tò te của GPE, lại rất ẹ về excel, mong các bác chỉ giúp em công thức thỏa mãn như đề tài saudo attach file không được!)
THIẾT BỊ----------------LOẠI
Nokia -------------------200
Samsung ---------------200
Nokia ------------------100
Nokia ------------------300
Samsung ---------------300
Nokia ------------------200
Samsung ---------------100
Samsung ---------------200
........................

Tính số lượng:
Nokia100: ?
Nokia200: ?
Nokia300: ?
Samsung100: ?
Samsung200: ?
Samsung300: ?

 

[Po_Pikachu]

Dùng Sumproduct đó bạn!
Xem file nha!
Thân.

 

[phongba19]

Mình là dân không chuyên xin các bạn chỉ gúp:
Mình có một bảng sổ cái khi nhấp chuột vào ô công thức hiển thị như sau:{=SUM(IF(LEFT(TKNO_NK;3)="152";1;0)*IF(LEFT(TKCO_NK;3)=LEFT(A149;3);1;0)*SOTIEN_NO_NK)} nhưng khi nhấp đúp chuột vào để sửa công thức thị dấu { } tự nhiên biến mất và khi gõ Enter thì ô công thức đó hiện lỗi VALUE!
Các bạn cố giúp mình và nếu được có thể gửi qua mail: Phongba19@gmail.com mình xin cảm ơn nhiều

 

[Po_Pikachu]

Khi sửa xong bạn nhấn Ctrl + Shift + Enter. Vì dấu đó là công thức mảng nên phải nhấn thêm như vậy!
Thân.

 

[hong gam]

nhân tiện cho mình hỏi 1 chút. Mình cũng cần sum với 3 điều kiện bằng sumproduct. Tuy nhiên khi làm bảng dữ liệu và bảng thống kê kết quả trên 1 sheet thì ok, ngược lại làm dữ liệu 1 sheet, thống kê kết quả sang 1 sheet khác thì không được. kết quả là 0. không biết mình có sai chỗ nào không. nhờ các bác giúp đỡ.

 

[ThuNghi]

nhân tiện cho mình hỏi 1 chút. Mình cũng cần sum với 3 điều kiện bằng sumproduct. Tuy nhiên khi làm bảng dữ liệu và bảng thống kê kết quả trên 1 sheet thì ok, ngược lại làm dữ liệu 1 sheet, thống kê kết quả sang 1 sheet khác thì không được. kết quả là 0. không biết mình có sai chỗ nào không. nhờ các bác giúp đỡ.

em thêm -- vào thử nhé.
=SUMPRODUCT(--(HANG=C6),--(LOAI="N380"),SL)
Nâng cấp lên VBA đi.

 

[TKT]

nhân tiện cho mình hỏi 1 chút. Mình cũng cần sum với 3 điều kiện bằng sumproduct. Tuy nhiên khi làm bảng dữ liệu và bảng thống kê kết quả trên 1 sheet thì ok, ngược lại làm dữ liệu 1 sheet, thống kê kết quả sang 1 sheet khác thì không được. kết quả là 0. không biết mình có sai chỗ nào không. nhờ các bác giúp đỡ.

Bạn thay dấu "," thành dấu nhân "*".

 

[hong gam]

Em đã thử sử dụng * nhưng không được; sử dụng -- đằng trước cũng thế. Nhưng bây giờ thêm -- đằng trước lại được. Chẳng hiểu nổi.
Nhưng quan trọng ra kết quả là rất tốt.
Cám ơn các bác rất nhiều.

 

[nhathuy_hanh]

Dùng Sumif thế nào trong trường hợp này?

E mới là thành viên của diễn dàn, về Excel e chưa biết nhiều, e đang thiết lập hệ thống sổ sách kế toán công ty theo hình thức CTGS, tuy nhiên phần sổ tiền mặt và TGNHàng e chưa làm được, ý e là các số liệu vào ở các CTGS sẽ tự động nhảy vào 2 sổ TM và TGNG, tuy nhiên e áp dụng sumif không được, xin các pác chỉ giáo, e gửi kèm theo đây file e đang làm

 

[rollover79]

Bạn nên viết bài đầy đủ rõ ràng hơn, tránh viết tắt và sử dụng ngôn ngữ chát ở đây. Không phải ai cũng hiểu những từ ngữ viết tắt của bạn đâu, có hiểu thì đọc xong cũng đau hết cả đầu còn đầu óc đâu mà xem bài của bạn nữa.

 

[cadafi]

E mới là thành viên của diễn dàn, về Excel e chưa biết nhiều, e đang thiết lập hệ thống sổ sách kế toán công ty theo hình thức CTGS, tuy nhiên phần sổ tiền mặt và TGNHàng e chưa làm được, ý e là các số liệu vào ở các CTGS sẽ tự động nhảy vào 2 sổ TM và TGNG, tuy nhiên e áp dụng sumif không được, xin các pác chỉ giáo, e gửi kèm theo đây file e đang làm

Mình cũng không hiểu trong file của bạn phải làm sumIF chỗ nào cả! Bạn nên nói vấn đề của mình một cách rõ ràng hơn.

 

[duong78]

giúp cộng 2 điều kiện

giúp cách cộng hai hay nhiều điều kiện

 

[ndu96081631]

giúp cách cộng hai hay nhiều điều kiện

File này được tạo trên Excel2007, vậy thì dùng SUMIFS đi
cú pháp:

=SUMIFS(Vùng tính tổng, Vùng đ/k1, đ/k1, Vùng đ/k2, đ/k2... , Vùng đ/kn, đ/kn)

Với file của bạn thì:

=SUMIFS($C$3:$C$10,$A$3:$A$10,"aac",$B$3:$B$10,"b")

 

[ducnghia]

nếu vp mình còn đang sử dụng office 2003 thì có cách nào khác không vậy?

 

[hoangdanh282vn]

nếu vp mình còn đang sử dụng office 2003 thì có cách nào khác không vậy?

=SUMPRODUCT((A3:A10="aac")*(B3:B10="b"),C3:C10)

hay

{=SUM(((A3:A10&B3:B10)="aacb")*C3:C10)} bấm Ctrl+shit+enter

 

[BNTT]

giúp cách cộng hai hay nhiều điều kiện

Chủ đề này đã có quá nhiều trên diễn đàn. Bạn chịu khó tìm một chút đi, trước khi hỏi.
Tôi dời luôn bài của bạn vào đây, ở chung một chỗ với nhau cho vui.

 

[BNTT]

E mới là thành viên của diễn dàn, về Excel e chưa biết nhiều, e đang thiết lập hệ thống sổ sách kế toán công ty theo hình thức CTGS, tuy nhiên phần sổ tiền mặt và TGNHàng e chưa làm được, ý e là các số liệu vào ở các CTGS sẽ tự động nhảy vào 2 sổ TM và TGNG, tuy nhiên e áp dụng sumif không được, xin các pác chỉ giáo, e gửi kèm theo đây file e đang làm

Tạm thời, do bạn là thành viên mới, nên tôi không xóa hẳn đề tài này.
Nhưng tôi sẽ đóng nó lại, trong vòng 1 tuần, để bạn có thời gian xem lại nó.
Bạn nên gửi lại một bài khác, viết tiếng Việt đàng hoàng hơn, và diễn đạt yêu cầu của bạn cho rõ ràng hơn. Có như vậy, bạn mới có hy vọng được giúp đỡ.

 

[2410tn]

Xin các bạn giải giúp : loay hoay mãi mà ko ra... Xin cám ơn nhiều,

Giả thiết 2 cot 1 và 2 như sau :
1 2

A D
B E
C H
A E
B E
A D

Dùng cấu trúc hàm nào để đếm hàng có chứa B E . Ở ví dụ này là 2.

 

[hoangminhtien]

Xin các bạn giải giúp : loay hoay mãi mà ko ra... Xin cám ơn nhiều,

Giả thiết 2 cot 1 và 2 như sau :
1 2

A D
B E
C H
A E
B E
A D

Dùng cấu trúc hàm nào để đếm hàng có chứa B E . Ở ví dụ này là 2.

bạn dùng công thức
=SUMPRODUCT((A1:A6="B")*(B1:B6="E"))
với A1:A6, B1:B6 là dữ liệu cột 1 và cột 2

 

[Anhtuan732002]

Sum có nhiều điều kiện

Dùng hàm DSUM đi bao nhiêu điều kiện cũng được

 

[BNTT]

Dùng hàm DSUM đi bao nhiêu điều kiện cũng được

Bạn nói không sai. Nhưng DSUM() phải kèm theo một bảng điều kiện nữa, phức tạp hơn xài SUMPRODUCT() nhiều.

 

[npv]

. . .

 

[npv]

tại sao khi sai khi kết hợp if và sumif

tôi có ví dụ về kết hợp if và sumif nhưng không hiểu tại sao lại bị sai mong các bác chỉ giáo

 

[salam]

Bạn sửa lại ct:

=IF(B2<>"",E2*F2,SUMIF([B][COLOR=Red]A3[/COLOR][/B]:$A$21,A2,G3:$G$21))

 

[ptm0412]

Bạn xem file rồi tự tìm hiểu thử. Nếu vẫn không hiểu thì hỏi tiếp.

 

[npv]

Tiện thể mình xin hỏi, các dòng mà số liệu ở cột B trống muốn tô đậm hoặc tô mầu thì làm thế nào, hiện tại mình toàn làm bằng tay rất mất thời gian. Ví dụ các dòng 2, dòng 6, dòng 11,17.

 

[npv]

Cám ơn ptm0412, nhưng cách của bạn phải thêm dòng trống, nếu số liệu nhiều lại mất thơi gian, mình thấy theo cách của salam là nhanh và vẫn chính xác

 

[hoangminhtien]

Tiện thể mình xin hỏi, các dòng mà số liệu ở cột B trống muốn tô đậm hoặc tô mầu thì làm thế nào, hiện tại mình toàn làm bằng tay rất mất thời gian. Ví dụ các dòng 2, dòng 6, dòng 11,17.

bạn chọn toàn bộ vùng chứa dữ liệu (trong file của bạn là A1:G21), bạn vào Format/Conditional Formatting...
trong condition 1 bạn chọn Formula is, ô bên cạnh bạn nhập công thức =$B1="". bạn vào Format... chọn định dạng mà bạn muốn. nhấp OK.

 

[ptm0412]

Cám ơn ptm0412, nhưng cách của bạn phải thêm dòng trống, nếu số liệu nhiều lại mất thơi gian, mình thấy theo cách của salam là nhanh và vẫn chính xác

Vậy bạn đã biết tại sao sai chưa? Mục đích tôi insert dòng là để bạn thấy chỗ sai, và bạn tự sửa. Nếu bạn chỉ xem file của Salam, thấy hài lòng mà không biết vì sao, thì lần sau sẽ sai tiếp.

 

[npv]

cám ơn ptm0412, xin lỗi vì không hiểu hết ý của bạn.

 

[shinichiqn]

Cho hỏi về Hàm SUMIF

Vấn đề là .. thế này ...
Có thể dùng hàm sumif trong trường hợp này ko mấy anh chị
Nếu không được thì sử lý làm sao nhỉ ... giúp em

Tính các cột L1 , L2 của bảng TỔNG SỐ SỐ LƯỢNG cho từng TÊN HÀNG.

 

[ThuNghi]

Vấn đề là .. thế này ...
Có thể dùng hàm sumif trong trường hợp này ko mấy anh chị
Nếu không được thì sử lý làm sao nhỉ ... giúp em
View attachment 17744

Bài này phải dùng sumproduct(...) vì hơn 2 biến. Nếu Excel 2007 thì sumifs OK
J23=SUMPRODUCT(($D$6:$D$17=$I23)*((RIGHT($C$6:$C$17,2)=J$22)*($E$6:$E$17)))
Copy qua phải và copy xuống.

 

[shinichiqn]

anh có thể .. chỉ dẫn rõ hơn được ko ạ ... em ko biết sử dụng sao cả

 

[cop_kh]

Xem bài gởi em nhé, chúc thành công.

 

[BNTT]

@shinichiqn:

Trước hết, xin gợi ý cho bạn vài công thức khác. Công thức của bạn không sai, nhưng có thể làm cho nó ngắn hơn. Bạn xem, và tự rút kinh nghiệm nha:

Tôi sẽ để công thức của bạn có màu xanh, còn công thức rút ngắn hơn màu nâu:

• Ô D6:
  
  =VLOOKUP(LEFT(C6, 1), $B$23:$F$26, 2, 0)
  =VLOOKUP(LEFT(C6), $B$23:$F$26, 2, 0)​
• Ô E6:
  
  =VALUE(MID(C6, 2, LEN(C6)-3))
  =MID(C6, 2, LEN(C6)-3)*1​
• Ô F6:
  
  =INDEX($C$22:$E$26, MATCH(D6, $C$22:$C$26, 0), MATCH(RIGHT(C6, 2), $C$22:$E$22, 0))
  =VLOOKUP(D6, $C$23:$E$26, RIGHT(C6)+1, 0)​

----------------------------------------------

Viết chung cho tất cả những ai chưa hiểu về SUMPRODUCT:

Giải thích công thức ở ô J23 (và sẽ được copy ra cho cả dãy J23:K26):

=SUMPRODUCT(($D$6:$D$17=$I23) * (RIGHT($C$6:$C$17,2)=J$22) * $E$6:$E$17)​

Hàm SUMPRODUCT ở trên tạo ra 3 mảng (trong bộ nhớ máy tính):

• $D$6:$D$17=$I23: Dò trong dãy $D$6:$D$17, nếu ô nào bằng với $I23 (GẠO) thì cho nó = 1 (nghĩa là TRUE), còn không bằng thì cho nó = 0 (FALSE)
  
  
• RIGHT($C$6:$C$17,2)=J$22: Dò trong dãy $C$6:$C$17, nếu ô nào có 2 ký tự cuối cùng bằng J$22 (L1) thì cho nó = 1 (nghĩa là TRUE), còn không bằng thì cho nó = 0 (FALSE)
  
  
• $E$6:$E$17: Mảng này chính là các giá trị trong dãy $E$6:$E$17

Sau khi đã có 3 mảng, SUMPRODUCT sẽ nhân theo hàng ngang từng phần tử tương ứng trong mỗi mảng với nhau. Ví dụ:

• Với các phần tử thứ 1 trong 3 mảng (tương ứng với D6, C6 và E6):
  - D6 = BẮP, nên nó = 0 (sai)
  - C6 có hai ký tự cuối là L1, nên nó bằng 1 (đúng)
  - E6 = 1230
  Nhân 3 cái này lại, ra kết quả là 0 (= 0 x 1 x 1230)
  
  
• Với các phần tử thứ 2 trong 3 mảng (tương ứng với D7, C7 và E7):
  - D7 = GẠO, nên nó = 1 (đúng)
  - C7 có hai ký tự cuối là L2, nên nó bằng 0 (sai)
  - E6 = 350
  Nhân 3 cái này lại, ra kết quả là 0 (= 1 x 0 x 350)
  ...
  
  
• Với các phần tử thứ 5 trong 3 mảng (tương ứng với D10, C10 và E10):
  - D10 = GẠO, nên nó = 1 (đúng)
  - C10 có hai ký tự cuối là L1, nên nó bằng 1 (đúng)
  - E10 = 5730
  Nhân 3 cái này lại, ra kết quả là 5730 (= 1 x 1 x 5730)
  ...

Sau khi đã đủ kết quả của các phép nhân này, SUMPRODUCT sẽ cộng tất cả các kết quả lại. Và ra con số là tổng của tất cả GẠO loại 1 (L1).

Giải thích như vậy, bạn hiểu chứ?

Để sử dụng hàm này, bạn cứ đặt hết các điều kiện trong một cặp dấu ngoặc đơn, rồi ghép chúng lại với nhau bẳng những dấu nhân (*). Riêng cái cuối cùng, là dãy dùng để lấy số liệu (là Số lượng, trong bài này), thì không có điều kiện, và do đó cũng không cần bỏ chúng vào trong dấu đơn. Nhớ rằng, ở 2 đầu, có một cặp dấu ngoặc đơn nữa, cặp này là của hàm SUMPRODUCT(). Nhắc vậy cũng không thừa, vì có nhiều bạn quên chuyện này. Xem lại công thức một tí đi, bạn sẽ thấy tôi đã làm đúng như tôi nói.

Có thể định nghĩa SUMPRODUCT như sau:

SUMPRODUCT là SUM của PRODUCT, hay nó là Tổng của các Tích số.​

​

 

[nhattan1311]

Mình lại gặp vấn đề với hàm Sumif

Mình muốn show tổng cộng Invoiced Total tính theo từng tháng, dữ liệu được lấy từ sheet Filled_Jobs là cột Invoiced total và Month Invoiced Raise.Kết quả thể hiện ở sheet Observation

 

[salam]

Bạn sửa lại công thức:

=SUMIF(Filled_Jobs!$[B][COLOR=Red]A[/COLOR][/B]$4:$D$314,A12,Filled_Jobs!$C$4:$C$314)

=SUMIF(Filled_Jobs!$D$4:$D$314,A12,Filled_Jobs!$C$4:$C$314)

 

[BNTT]

Mình muốn show tổng cộng Invoiced Total tính theo từng tháng, dữ liệu được lấy từ sheet Filled_Jobs là cột Invoiced total và Month Invoiced Raise.Kết quả thể hiện ở sheet Observation

Công thức của bạn sai ở đây:

=SUMIF(Filled_Jobs!$A$4:$D$314, A12, Filled_Jobs!$C$4:$C$314)​

Sao bạn muốn dò theo cột Month Invoiced Raised (cột D), hay là mà lại lấy cả từ A4314 ? Chỉ dò trong D4314 thôi chứ?
Công thức cho bạn đây:

=SUMIF(Filled_Jobs!$D$4:$D$314, A12, Filled_Jobs!$C$4:$C$314)​

Với bài của bạn, vì hai cột D (Month Invoiced Raised) và C (Invoice Total) có số lượng ô là tương đương nhau, nên bạn chỉ cần chỉ ra ô đầu tiên của cột C (ô C4):

=SUMIF(Filled_Jobs!$D$4:$D$314, A12, Filled_Jobs!$C$4)​

 

[Baton1123]

Dùng hàm sumif như thế có được không?

Tôi phải làm nhiều báo cáo nhập xuất tồn. Các báo cáo yêu cầu tôi phải kiểm soát được tôi đã xuất cho ai và xuất cho bộ phận nào.Tôi lấy đơn cử bảng nhập xuất giày đồng phục.
Tôi có bảng tổng hợp nhập xuất tồn về giày đồng phục. Công ty tôi có rất nhiều các bộ phận và hơn 300 nhân viên. Khi xuất giày cho nhân viên, tôi muốn nhân viên của phòng nào sẽ tự động chạy về phòng đó. Tôi đã có một bảng tổng hợp rất chi tiết. Khi tôi nhập,xuất hàng, bảng tổng hợp tổng hợp hết số giày xuất và nhập. Nhưng tôi không biết làm cách nào để tôi có thể tổng hợp số giày xuất về các bộ phận một cách tự động như tôi đang làm như bảng đính kèm.
Anh chị xem và chỉ giúp tôi với nhé.
Cảm ơn nhiều.

 

[boyxin]

Tôi phải làm nhiều báo cáo nhập xuất tồn. Các báo cáo yêu cầu tôi phải kiểm soát được tôi đã xuất cho ai và xuất cho bộ phận nào.Tôi lấy đơn cử bảng nhập xuất giày đồng phục.
Tôi có bảng tổng hợp nhập xuất tồn về giày đồng phục. Công ty tôi có rất nhiều các bộ phận và hơn 300 nhân viên. Khi xuất giày cho nhân viên, tôi muốn nhân viên của phòng nào sẽ tự động chạy về phòng đó. Tôi đã có một bảng tổng hợp rất chi tiết. Khi tôi nhập,xuất hàng, bảng tổng hợp tổng hợp hết số giày xuất và nhập. Nhưng tôi không biết làm cách nào để tôi có thể tổng hợp số giày xuất về các bộ phận một cách tự động như tôi đang làm như bảng đính kèm.
Anh chị xem và chỉ giúp tôi với nhé.
Cảm ơn nhiều.

Cả 2 sheet XUẤT KHO và NHẬP KHO đều không có chỗ nào ghi bộ phận thì tổng hợp về các bộ phận kiểu gì đây

 

[Cao Mạnh Sơn]

Cả 2 sheet XUẤT KHO và NHẬP KHO đều không có chỗ nào ghi bộ phận thì tổng hợp về các bộ phận kiểu gì đây

Tại bạn không xem kỹ đấy thôi.
To:Baton1123
bạn dùng Sumproduct nhé.

 

[robopingpong]

Câu hỏi về hàm SUMIF()

Em muốn dùng SUMIF với điều kiện >= giá trị của 1 cell và <=giá trị 1 cell thì làm thế nào các bác nhỉ

VD:
=SUMIF($B$4:$B$12;">= giá trị cell k1 và <= cell k2";$C$4:$C$12)

 

[cop_kh]

Bạn gởi File lên thì giúp bạn được cụ thể hơn nhé. Nếu có 2 điều kiện như vậy thì phải dùng Sumproduct thôi.

 

[salam]

Em muốn dùng SUMIF với điều kiện >= giá trị của 1 cell và <=giá trị 1 cell thì làm thế nào các bác nhỉ

VD:
=SUMIF($B$4:$B$12;">= giá trị cell k1 và <= cell k2";$C$4:$C$12)

Bạn thử công thức dưới xem.

{=sum(if($B$4:$B$12;>= giá trị cell k1,if($B$4:$B$12<= cell k2;$C$4:$C$12)))}

 

[robopingpong]

=sum(if($B$4:$B$12;>=k1,if($B$4:$B$12<= k2;$C$4:$C$12)))
Không chạy Bác ạ, Bác xem hộ tí

 

[TKT]

=sum(if($B$4:$B$12;>=k1,if($B$4:$B$12<= k2;$C$4:$C$12)))
Không chạy Bác ạ, Bác xem hộ tí

Nhập công thức xong bạn nhấn Ctrl + Shift + Enter, thay cho Enter. Vì là công thức mảng.

 

[robopingpong]

Cám ơn bạn Salam ,TKT đã gợi ý
Chạy tốt rồi
Thanks
Code chuẩn để bạn khác dùng nè
=SUM(IF($B$4:$B$12>=K1;IF($B$4:$B$12<= K2;$C$4:$C$12)))

 

[khieukienag]

Trong khi chờ "cao kiến" bạn cứ lấy sumIF>=k1 trừ cho sumIF>k2 là xong

 

[thanhvien1802]

Công thức sau nếu dùng Công thức Mảng.

=SUM(IF($B$4:$B$12>=100,IF($B$4:$B$12<= 200,$C$4:$C$12)))

CÒn Công thức : Bạn khieukienag là : nếu dùng CT bình thường:

=SUMIF(B4:B12,">=100",C4:C12)-SUMIF(B4:B12,">200",C4:C12)

"Chú ý: Thay tạm k1=100 và k2=200"

 

[Cao Mạnh Sơn]

Em muốn dùng SUMIF với điều kiện >= giá trị của 1 cell và <=giá trị 1 cell thì làm thế nào các bác nhỉ

VD:
=SUMIF($B$4:$B$12;"> giá trị cell k1 và <= cell k2";$C$4:$C$12)

Không cần dùng đến công thức mảng,bạn dùng sumif bình thường mà
=SUMIF($B$4:$B$12;">="& giá trị cell k1 và"<="&cell k2";$C$4:$C$12)
tham khảo File đính kèm

 

[ndu96081631]

Trong khi chờ "cao kiến" bạn cứ lấy sumIF>=k1 trừ cho sumIF>k2 là xong

Công thức này tưởng rằng "củ chuối" nhưng thật ra theo tôi nó là hay nhất (xét về mặt tốc độ)
Các bạn cứ thử trên file vài chục ngàn dòng công thức sẽ thấy sự khác biệt

 

[Cao Mạnh Sơn]

Trong khi chờ "cao kiến" bạn cứ lấy sumIF>=k1 trừ cho sumIF>k2 là xong

ừ mình xem kỹ lại yêu cầu thì không phải như mình nghĩ và đưa ra ý kiến.

 

[thanhvien1802]

Theo bạn trong trường hợp này. dùng cách nào hợp lý hơn.
Mình cũng có Text thử 42.000 dòng. Mình thấy kết quả cũng gần như tức thời.
"Mọi kiến thức để trao đổi, để thảo luận, để học hỏi ... để đưa đến 1 giải pháp thích hợp hơn."

 

[quanghai69]

Cần giúp đỡ với hàm sumif

Mình cần cộng có 2 dk, suy nghi mãi mà không biết lam sao.


----------------------
OverAC: Bạn cần chú ý vị trí post bài.

 

[salam]

Bạn dùng ct dưới nhé.

{=SUM(IF($B$2:$B$46=E2,IF(A2:A46>=DATE(2008,10,1),IF(A2:A46<=DATE(2008,10,30),$C$2:$C$46))))}

 

[cadafi]

Mình cần cộng có 2 dk, suy nghi mãi mà không biết lam sao.

Bạn có rất nhiều cách để làm:
1. Dùng SUM:

{=SUM(($B$2:$B$46=1)*(MONTH($A$2:$A$46)=10)*($C$2:$C$46))}

Gõ công thức xong thì ấn Ctrl+Shift+Enter nhé!

2. Dùng Sumproduct:

=SUMPRODUCT(--($B$2:$B$46=1),--(MONTH($A$2:$A$46)=10),($C$2:$C$46))

3. Dùng SUM(IF()):

{=SUM(IF(($B$2:$B$46=1)*(MONTH($A$2:$A$46)=10),$C$2:$C$46,0))}

Gõ công thức xong thì ấn Ctrl+Shift+Enter nhé!

 

[salam]

Ca_dafi ơi bạn ấy muốn tính từ 01-30 tháng 10 thôi mà.

Dùng công thức gì để cộng từ ngày 1/10 đến ngày 30/10 của line 1

 

[cadafi]

Bạn dùng ct dưới nhé.

{=SUM(IF($B$2:$B$46=E2,IF(A2:A46>=DATE(2008,10,1),IF(A2:A46<=DATE(2008,10,30),$C$2:$C$46))))}

Anh salam ơi! Mình không cần hai IF cho hai Điều kiện ngày như vậy cũng được mà anh!

{=SUM(IF(($B$2:$B$46=E2)*($A$2:$A$46>=DATE(2008,10,1))*($A$2:$A$46<=DATE(2008,10,30)),$C$2:$C$46,0))}

 

[cadafi]

Ca_dafi ơi bạn ấy muốn tính từ 01-30 tháng 10 thôi mà.

Dạ, nhưng em lại nghĩ bạn ấy muốn tính trong tháng 10.

Trong trường hợp muốn tính từ ngày đến ngày cụ thể thì công thức sẽ dài hơn chút xíu và tuân theo nguyên tắc giống như công thức của anh Salam.

 

[coc1984]

Mình có bài này chưa tìm được lời giải, ở bài này mình chỉ muốn dùng Sum, hoặc Sumif, hoặc if mà thui, ai co cách giải thì giải dùm mình với

Mình chỉ cần dùng 1 trong các hàm là: Sum, If, Sumif. Liệu có cách làm hay ko?

 

[thanhvien1802]

Dùng hàm Sumif

=SUMIF($A$2:$A$9,">=05/06/1999",$B$2:$B$9)-SUMIF($A$2:$A$9,">12/06/1999",$B$2:$B$9)

 

[coc1984]

Dùng hàm Sumif

=SUMIF($A$2:$A$9,">=05/06/1999",$B$2:$B$9)-SUMIF($A$2:$A$9,">12/06/1999",$B$2:$B$9)

Vậy còn bài đầu tiên (123.xls) thì làm sao vậy bạn?

 

[boyxin]

Mình có bài này chưa tìm được lời giải, ở bài này mình chỉ muốn dùng Sum, hoặc Sumif, hoặc if mà thui, ai co cách giải thì giải dùm mình với

Mình chỉ cần dùng 1 trong các hàm là: Sum, If, Sumif. Liệu có cách làm hay ko?

Bạn kiểm tra lại kết quả nhé

các công thức đều kết thúc bởi: Ctrl+Shift+Enter​

 

[ndu96081631]

Bạn kiểm tra lại kết quả nhé

các công thức đều kết thúc bởi: Ctrl+Shift+Enter​

Bài toán trong file 123.xls không dể nhai đâu nha!
Tại dòng 8:
- Ngày đến = 20/1/2008
- Ngày đi = 14/2/2008
===> Tổng cộng số ngày ở là 26 ngày nhưng trong đó có 12 ngày thuộc tháng 1 và 14 ngày thuộc tháng 2
Những trường hợp ở xuyên qua các tháng, bạn tính sao đây
???
Ẹc... Ẹc...

 

[boyxin]

Bài toán trong file 123.xls không dể nhai đâu nha!
Tại dòng 8:
- Ngày đến = 20/1/2008
- Ngày đi = 14/2/2008
===> Tổng cộng số ngày ở là 26 ngày nhưng trong đó có 12 ngày thuộc tháng 1 và 14 ngày thuộc tháng 2
Những trường hợp ở xuyên qua các tháng, bạn tính sao đây
???
Ẹc... Ẹc...

hic, thế mới phải thêm vào: THÁNG ĐI <=> SỐ LIỆU ĐÚNG NẾU TÍNH THEO NGÀY THU TIỀN (THÁNG ĐI)

 

[anhtuan1066]

hic, thế mới phải thêm vào: THÁNG ĐI <=> SỐ LIỆU ĐÚNG NẾU TÍNH THEO NGÀY THU TIỀN (THÁNG ĐI)

Vậy trường hợp vừa nêu trên Boyxin tính nó là tháng 2 à?
Kỳ lạ nhỉ?
Tôi thì cho rằng tính 12 ngày thuộc tháng 1 và 14 ngày thuộc tháng 2 chứ
(Hy vọng đây là BÀI TẬP, không "chơi ép" và phức tạp đến thế)

 

[boyxin]

Vậy trường hợp tôi vừa nêu trên Boyxin tính nó là tháng 2 à?
Kỳ lạ nhỉ?
Tôi thì cho rằng tính 12 ngày thuộc tháng 1 và 14 ngày thuộc tháng 2 chứ
(Hy vọng đây là BÀI TẬP, không "chơi ép" như tôi đã nghĩ)

1. Đây là bảng thống kê tiền phải trả
2. Vậy boyxin nghĩ: ngày đi là ngày trả tiền cũng là lẽ thường, đâu phải ép
3. Có chi tiết thì chi tiết trong bảng tính tiền phải trả ở trên (ô I8), nếu ô I8 đã tính đúng thì boyxin nghĩ như vậy là ổn

Không biết có cao kiến gì khác hợp lý hơn không ?
-------------------------------------
Xem ký lại cách tính số tiền phải trả (cột I) cũng không thấy chỗ nào quan trọng lắm khi ngày đó là ở tháng nào, mà chỉ quan tâm đến số ngày thôi

 

[ararechan]

Lồng hàm countif, sumif trong hàm if mà không ra kết quả

Chào các anh chị trong diễn đàn,
tôi thiết tha mong anh chị bỏ chút thời gian giúp tôi vấn đề này với.
tôi muốn lồng các hàm trên để lập thành bảng tính tự động sản lượng may
nội dung cụ thể tôi đã ghi chú trong file đính kèm.
Xin cám ơn trước

 

[salam]

Dây chuyền 1 bạn dùng ct dưới. Dây chuyền 2 bạn làm tương tự.

=IF(COUNTIF($D$5:$D$38,M4)>0,SUMIF($D$5:$D$38,M4,'bang ke'!$E$5:$E$38),0)

 

[hoangminhtien]

Công thức IF của bạn

=IF(D3>0,"SUMIF('bang ke'!D538,020(209),'bang ke'!E5:E38)",0)

bạn bỏ đi dấu """, và sửa thành

=IF(D3>0,SUMIF('bang ke'!D538,"020 (209)",'bang ke'!E5:E38),0)

Bạn muốn phần điều kiện countif và sumif tự động nhận nội dung của ô thì chỉ việc thay điều kiện nhập bằng tay bằng việc tham chiếu tới ô đó ví dụ

=SUMIF('bang ke'!D538,'danh muc ma va he so'!A3,'bang ke'!E5:E38)

tương tự cho countif

 

[solomon2211]

Bạn xem file đính kèm có đúng như bạn yêu cầu không nhé.

 

[ararechan]

Bạn xem file đính kèm có đúng như bạn yêu cầu không nhé.

mình đã đi đường vòng!!!
cám ơn các bạn rất nhiều!!!

 

[Elvis2705]

Thắc mắc về hàm Sumif và DSum

Mình có một bài tập này mong mọi người giúp đỡ. Mong là sẽ nhận được nhiều cách làm để mình tham khảo. Cảm ơn mọi người nhiều.

 

[volga]

Mình có một bài tập này mong mọi người giúp đỡ. Mong là sẽ nhận được nhiều cách làm để mình tham khảo. Cảm ơn mọi người nhiều.

Mình không hiểu câu hỏi của bạn ,nên chỉ trả lời được thế thôi.

 

[kchixinhdep]

Tại sao dùng sumif tính bị sai ?

Em co 1 file nay, can moi nguoi chi giup.

Trong Sheet " Jan" , em da dung ham Sumif de tinh. Vi du: những món hàng có line Abey, thi sẽ tinh tổng từ sheet "hand bag", nhưng không hiểu sao, tính ra lại bị sai.

Vi dụ: Sheet hand bag, nhìn 3 dòng cuối cung, nhìn vào cột A, line Gucci By Gucci, thang jan ban duoc 6, nhung sumif trang "Jan" lai chi tính ra la 0.

Em không hiểu em đã sai chỗ nào, mọi người giúp em với...

 

[hoangdanh282vn]

Em co 1 file nay, can moi nguoi chi giup.

Trong Sheet " Jan" , em da dung ham Sumif de tinh. Vi du: những món hàng có line Abey, thi sẽ tinh tổng từ sheet "hand bag", nhưng không hiểu sao, tính ra lại bị sai.

Vi dụ: Sheet hand bag, nhìn 3 dòng cuối cung, nhìn vào cột A, line Gucci By Gucci, thang jan ban duoc 6, nhung sumif trang "Jan" lai chi tính ra la 0.

Em không hiểu em đã sai chỗ nào, mọi người giúp em với...

Trong công thức Sumif, Vùng dò tìm và vùng tính tổng phải có độ lớn bằng nhau.
bạn sửa lại công thức như sau:

=SUMIF(HANDBAG!$A$5:$A$137, JAN!A27,HANDBAG!$AH$5:$AH$137)

 

[hoangvuluan]

Cũng chưa giải thích được 1 cách chặt chẽ cho lắm. Nhưng nếu bạn thay vùng tính:
HANDBAG!$AH$5:$AH$137
thành
HANDBAG!$AH$1:$AH$137
thì sẽ không bị lỗi do tính tổng bị thiếu!

 

[BNTT]

Em co 1 file nay, can moi nguoi chi giup.

Trong Sheet " Jan" , em da dung ham Sumif de tinh. Vi du: những món hàng có line Abey, thi sẽ tinh tổng từ sheet "hand bag", nhưng không hiểu sao, tính ra lại bị sai.

Vi dụ: Sheet hand bag, nhìn 3 dòng cuối cung, nhìn vào cột A, line Gucci By Gucci, thang jan ban duoc 6, nhung sumif trang "Jan" lai chi tính ra la 0.

Em không hiểu em đã sai chỗ nào, mọi người giúp em với...

Bạn nên xem lại hàm SUMIF ở đây: Hàm SUMIF()
Đọc kỹ phần Lưu ý nha:

Vùng thực sự để tính tổng được xác định bằng ô đầu tiên phía trên bên trái của sum_range, và bao gồm thêm những ô tương ứng với kích thước của range.

Do trong công thức của bạn:

=SUMIF(HANDBAG!A:A, JAN!A6, HANDBAG!$AH$5:$AH$137)​

Vùng range là A:A, do đó bạn phải chọn vùng sum_range sao cho tương đương với A:A, và nó chính là AH:AH

Bạn sửa lại công thức như sau:

=SUMIF(HANDBAG!A:A, JAN!A6, HANDBAG!$AH:$AH)​

hoặc chỉ cần là như vầy:

=SUMIF(HANDBAG!A:A, JAN!A6, HANDBAG!$AH$1)​

(vùng tính tổng bắt đầu từ AH1, còn xuống tới bao nhiêu thì cứ theo A:A mà làm!)

------------------------------------
@Hoangvuluan: Bạn xem công thức thứ 2 của tôi ở trên đây. Không cần phải chỉ rõ ra $AH$1:$AH$137 đâu, chỉ cần xác định cho SUMIF biết ô đầu tiên thôi: $AH$1, là đủ rồi. Excel nó sẽ tự hiểu phải làm tới đâu.

Mà nếu bạn có chỉ rõ ra là $AH$1:$AH$137 thì Excel cũng không theo ý bạn đâu, nó sẽ theo A:A cơ, và chính xác là nó chạy từ $AH$1:$AH$65536 (= $AH:$AH)

Nếu bạn không tin, bạn có thể nhập vùng sum_range là $AH$1:$AH$2 (chỉ có 2 ô), nhưng công thức vẫn chạy chính xác! Excel chẳng thèm đếm xỉa đến chuyện bạn quy định sum_range là 2 ô, mà nó nhất quyết vẫn theo vùng range: A:A (nguyên cột)

 

[jack_sparrow]

Cho mình hỏi các hàm sumif, countif, counta

Mình tự mò excel, nhưng cuốn ebook của mình ko có các hàm sumif, countif, counta
các bạn làm ơn cho mình hỏi các hàm sumif, countif, counta có tác dụng gj` và cú pháp như thế nào. Thanks các bạn!

 

[hoangdanh282vn]

Mình tự mò excel, nhưng cuốn ebook của mình ko có các hàm sumif, countif, counta
các bạn làm ơn cho mình hỏi các hàm sumif, countif, counta có tác dụng gj` và cú pháp như thế nào. Thanks các bạn!

Đây là sách do chính GPE phát hành, rất hay và đầy đủ. Bạn vào tham khảo nha :
http://www.giaiphapexcel.com/forum/showthread.php?t=11627

Sumif : Công các giá trị trong vùng khi thỏa mãn điều kiện nào đó.
Countif : Đếm số lượng các giá trị trong vùng khi thỏa mãn điều kiện nào đó.
Counta : Đếm số lượng các ô khác rỗng trong vùng nào đó.

 

[jack_sparrow]

ah, bây giờ thì em đã hiểu

 

[tieuthubuongbinh]

SUMIF có cho phép dò tìm 2 giá trị và Sum 2 Column hoặc nhiều hơn không?

|SP| FY07| FY08|
Megabrand| Sp A| 1500| 1800|
Megabrand| Sp B| 1200| 1350|
Megabrand| Sp C| 950| 1080|
Grower| Sp A| 500| 750|
Grower| Sp D| 800| 970|
Grower| Sp E| 130| 310|
Cashcow| Sp B| 100| 110|
New products| Sp F| 50| 75

Theo mình biết thì sumif chỉ dùng để sum 1 column cho 1 giá trị
Vd: =SUMIF($A$2:$A$12,$A14,$C$2:$C$12) khi mình muốn biết tổng Megabrand (dò 1 giá trị và sum các row trong 1 column)
Bây giờ, mình muốn dùng sumif cho bảng dưới đây thì được không?

|Sp A |Sp B| Sp C| Sp D |Sp E |Sp F|
Megabrand| 3300| 2550| 2030| | ||
Grower |1250 | | |1770| 440 |||
Cashcow | |210 | | | |||
New products | | | | | |125

 

[Po_Pikachu]

Hàm SumIF thì bạn có thể tham khảo ở đây.
http://www.giaiphapexcel.com/forum/showpost.php?p=58877&postcount=38
=SUMIF(A2:A12,"Megabrand",C2:C12)
Hoặc
=SUMPRODUCT(($A$2:$A$12="Megabrand")*(C2:C12))
Thân.

 

[tieuthubuongbinh]

|SP| FY07| FY08|
Megabrand| Sp A| 1500| 1800|
Megabrand| Sp B| 1200| 1350|
Megabrand| Sp C| 950| 1080|
Grower| Sp A| 500| 750|
Grower| Sp D| 800| 970|
Grower| Sp E| 130| 310|
Cashcow| Sp B| 100| 110|
New products| Sp F| 50| 75

Theo mình biết thì sumif chỉ dùng để sum 1 column cho 1 giá trị
Vd: =SUMIF($A$2:$A$12,$A14,$C$2:$C$12) khi mình muốn biết tổng Megabrand (dò 1 giá trị và sum các row trong 1 column)
Bây giờ, mình muốn dùng sumif cho bảng dưới đây thì được không?

|Sp A |Sp B| Sp C| Sp D |Sp E |Sp F|
Megabrand| 3300| 2550| 2030| | ||
Grower |1250 | | |1770| 440 |||
Cashcow | |210 | | | |||
New products | | | | | |125

* Mình đang muốn mở rộng hiểu biết về sumif (có cho phép dò 2 giá trị và sum 2 column không)

 

[Po_Pikachu]

Bạn có thể gửi file lên được không?
Cứ làm theo bạn kiểu này hoài oải quá!
Bạn phải tham khảo thêm nhiều hàm nữa. Rồi kết hợp chúng lại với nhau. Vậy bạn sẽ làm được tất cả mọi việc thôi.
http://www.giaiphapexcel.com/forum/showthread.php?p=58877#post58877
http://www.giaiphapexcel.com/forum/showthread.php?t=7971
Bạn xem file nha!
Thân.

 

[cadafi]

|SP| FY07| FY08|
Megabrand| Sp A| 1500| 1800|
Megabrand| Sp B| 1200| 1350|
Megabrand| Sp C| 950| 1080|
Grower| Sp A| 500| 750|
Grower| Sp D| 800| 970|
Grower| Sp E| 130| 310|
Cashcow| Sp B| 100| 110|
New products| Sp F| 50| 75

|Sp A |Sp B| Sp C| Sp D |Sp E |Sp F|
Megabrand| 3300| 2550| 2030| | ||
Grower |1250 | | |1770| 440 |||
Cashcow | |210 | | | |||
New products | | | | | |125

Theo mình biết thì sumif chỉ dùng để sum 1 column cho 1 giá trị
Vd: =SUMIF($A$2:$A$12,$A14,$C$2:$C$12) khi mình muốn biết tổng Megabrand (dò 1 giá trị và sum các row trong 1 column)
Bây giờ, mình muốn dùng sumif cho bảng dưới đây thì được không?

Cái này không cần dùng SUMIF[/B, mình dùng SUM cũng ra mà! Bạn xem file đính kèm. Góp thêm cho bạn hai cách luôn.
1. Cách 1: Dùng SUM
2. Cách 2: Không dùng công thức mà dùng Pivottable

 

[tieuthubuongbinh]

Bạn có thể gửi file lên được không?
Cứ làm theo bạn kiểu này hoài oải quá!
Bạn phải tham khảo thêm nhiều hàm nữa. Rồi kết hợp chúng lại với nhau. Vậy bạn sẽ làm được tất cả mọi việc thôi.
http://www.giaiphapexcel.com/forum/showthread.php?p=58877#post58877
http://www.giaiphapexcel.com/forum/showthread.php?t=7971
Bạn xem file nha!
Thân.

pikachu hiểu sai ý mình rồi, table 2 là cái mình muốn tạo ra bằng sumif thì có được không. chứ không phải làm sumif như bình thường cho table 2 (huhuhu.... như mình đã note bên dưới của bài #27 là mình muốn hiểu thêm về hàm sumif là có cho phép dò 2 giá trị (vừa phải là megabrand vừa phải là sp A thì mới sum) và sum 2 column (vừa năm 07 và 08) không mà)
Huhuhuhuhuhu..... mình cũng đã save toàn bộ hàm của BNTT nhưng có nhiều hàm đọc không hiểu (mình là dân a-ma-tơ về excel), làm theo ví dụ thì ra như theo cách mình hiẻu thì không ra cho nên mới phải post bài hỏi thêm
còn về file vì mình thấy làm table cũng đủ hiểu nên tiết kiệm dung lượng mừ hihi2

Cái này không cần dùng SUMIF[/B, mình dùng SUM cũng ra mà! Bạn xem file đính kèm. Góp thêm cho bạn hai cách luôn.
1. Cách 1: Dùng SUM => mình sẽ tập dùng cách này
2. Cách 2: Không dùng công thức mà dùng Pivottable

=> mình biết dùng pivot (thực tế đã dùng pivot cho việc này)
Nhưng ý chính mình hỏi vẫn là :

SUMIF CÓ CHO PHÉP DÒ TÌM 2 GIÁ TRỊ VÀ SUM 2 COLUMN hoặc nhiều hơn) KHÔNG? vì SUMIF mình đang sử dụng thông thường chỉ dò tìm 1 giá trị và trong 1 column thôi. Nhưng khi mình thử làm công thức này (cho table 2) thì lại ra giá trị 0 mà không báo lỗi, nên mình nghĩ công thưc không sai, chỉ là mình chưa hiểu nó work thế nào mà ra là 0, xin được phân tích giúp
=SUMIF($A$2:$B$9,AND(A2,B2),$C$2:$D$9)

 

[ndu96081631]

pikachu hiểu sai ý mình rồi, table 2 là cái mình muốn tạo ra bằng sumif thì có được không. chứ không phải làm sumif như bình thường cho table 2 (huhuhu.... như mình đã note bên dưới của bài #27 là mình muốn hiểu thêm về hàm sumif là có cho phép dò 2 giá trị (vừa phải là megabrand vừa phải là sp A thì mới sum) và sum 2 column (vừa năm 07 và 08) không mà)
Huhuhuhuhuhu..... mình cũng đã save toàn bộ hàm của BNTT nhưng có nhiều hàm đọc không hiểu (mình là dân a-ma-tơ về excel), làm theo ví dụ thì ra như theo cách mình hiẻu thì không ra cho nên mới phải post bài hỏi thêm
còn về file vì mình thấy làm table cũng đủ hiểu nên tiết kiệm dung lượng mừ hihi2


=> mình biết dùng pivot (thực tế đã dùng pivot cho việc này)
Nhưng ý chính mình hỏi vẫn là :

SUMIF CÓ CHO PHÉP DÒ TÌM 2 GIÁ TRỊ VÀ SUM 2 COLUMN hoặc nhiều hơn) KHÔNG? vì SUMIF mình đang sử dụng thông thường chỉ dò tìm 1 giá trị và trong 1 column thôi. Nhưng khi mình thử làm công thức này (cho table 2) thì lại ra giá trị 0 mà không báo lỗi, nên mình nghĩ công thưc không sai, chỉ là mình chưa hiểu nó work thế nào mà ra là 0, xin được phân tích giúp
=SUMIF($A$2:$B$9,AND(A2,B2),$C$2:$D$9)

Thế sao bạn không đưa file thực tế của mình lên đây ---> Đễ nguyên những công thức bạn đang làm ---> Giờ cứ giãi thích lòng vòng, khó đoán quá (có thể tôi đã đoán được ý bạn, nhưng không có file đính kèm, tôi thấy làm biếng quá)

 

[tieuthubuongbinh]

Câu hỏi ở cả sheet data và report, nhờ ndu giúp nhé
http://www.giaiphapexcel.com/forum/showthread.php?t=3369&page=3

 

[ndu96081631]

Câu hỏi ở cả sheet data và report, nhờ ndu giúp nhé

Ah... thì ra là vậy... cái này thì không SUMIF được rồi (trừ phi bạn thêm cột phụ)
Vậy thì ăn chắc là dùng công thức mãng...
Có 2 cách:
- Cách 1: dùng công thức giống trong sheet Report ---> Và sở dĩ nó có dấu {} là vì đây là công thức mãng ---> Sau khi gõ xong công thức người ta bấm Ctrl + Shift + Enter (chứ không phải Enter)
- Cách 2: Dùng SUMPRODUCT ---> Cú pháp gần như y chang công thức mãng ở cách 1 ---> Thay SUM thành SUMPRODUCT và khỏi cần phải Ctrl + Shift + Enter
Tuy nhiên công thức trên vẫn còn dài ---> Rút ngắn lại sẽ như vầy:

=SUMPRODUCT((Data!$A$2:$A$9=$A2)*(Data!$B$2:$B$9=B$1)*(Data!$C$2:$D$9))

 

[cadafi]

Nếu vẫn muốn dùng SUMIF với nhiều điều kiện, như anh ndu nói ta phải có cột phụ để nối tất cả các cột cần lấy điều kiện lại với nhau và dùng SUMIF theo cột phụ này! Bạn xem file nhé, sheet [Report3]!

 

[volga]

Các anh giúp em . Cho em hiểu cái dấu + trong công thức
Có một số trường hợp có bài dùng dấu + lòng vào công thức Như công thức này hoặc còn một số trường hợp khác nữa nhất là trong Name
SUMPRODUCT(($B$4:$H$4>1)*($B$4:$H$4<=2)*5000+($B$4:$H$4>2)*10000)

Dấu -- phía trước công thức thì đã có nói rỏ ràng dưới phần chử ký của anh Ca_Dafi rồi

Thanks!!!!!!!!!!!!

 

[cadafi]

Các anh giúp em . Cho em hiểu cái dấu + trong công thức
Có một số trường hợp có bài dùng dấu + lòng vào công thức Như công thức này hoặc còn một số trường hợp khác nữa nhất là trong Name
SUMPRODUCT(($B$4:$H$4>1)*($B$4:$H$4<=2)*5000+($B$4:$H$4>2)*10000)

Dấu -- phía trước công thức thì đã có nói rỏ ràng dưới phần chử ký của anh Ca_Dafi rồi

Thanks!!!!!!!!!!!!

Dấu + đó gần giống với OR vậy bạn à! Công thức đó có thể phát biểu như thế này

Nếu B4:H4 >1 và <2 thì lấy B4:H4 nhân với 5000, hoặc nếu B4:H4>2 thì lấy B4:H4 nhân với 1000. Sau đó SUMPRODUCT tất cả lại.

 

[volga]

Lúc trước khi em mới tập tành làm quen với Excel ( Khi đó chưa biết giaiphapexcel )
Hỏi các anh bạn trong công ty thì được giải thích với những câu thực tế thế này như của anh ca_dafi
Trích :
Nếu B4:H4 >1 và <2 thì lấy B4:H4 nhân với 5000, hoặc nếu B4:H4>2 thì lấy B4:H4 nhân với 1000. Sau đó SUMPRODUCT tất cả lại.

Rất dể hiểu ,cám ơn anh Ca_dafi Nhiều !!!!!!!!!!!!!!

 

[huongchi]

hàm sumif

Xin chào các anh, các chị
Em là thành viên mới, cũng mới tự học excel, rất mong sự giúp đỡ của mọi người.
Anh chị chỉ giúp em hàm sumif với ạ.
Em cảm ơn nhiều.