hỏi về công thức tách kí tự từ chuỗi (1 người xem)
- Thread starter Momominh
- Ngày gửi
Người dùng đang xem chủ đề này
Duy Tùng 9x
Zalo 0987841557
- Tham gia
- 6/11/23
- Bài viết
- 220
- Được thích
- 231
- Giới tính
- Nam
2019 thì bạn có hàm CONCAT rồi. Thử với công thức sau xem sao nhé:
=CONCAT(UPPER(LEFT(TRIM(MID(SUBSTITUTE(" "&B2," ",REPT(" ",99)),ROW($1:$20)*99,99)))))
=CONCAT(UPPER(LEFT(FILTERXML("<x><s>"&SUBSTITUTE(B2," ","</s><s>")&"</s></x>","//s"))))
Hoặc 365 thì có thể :
=MAP(B2:B4,LAMBDA(s,CONCAT(UPPER(LEFT(TEXTSPLIT(s," "))))))
=REGEXREPLACE(PROPER(B2:B4),"\B\p{L}|\s",)
dungpham01
Thành viên chính thức
- Tham gia
- 22/7/25
- Bài viết
- 86
- Được thích
- 64
trao đổi về phương diện nghiên cứu thôi nhé. công thức đầu tiên của bạn có chút lợn cợn, nó chỉ giới hạn ở 20 từ thôi sao? tại sao không thay ROW($1:$20) bằng ROW(INDIRECT("1:"&LEN(B2))) cho được nhiều? với lại nếu 1 chữ nào đó trong câu có độ dài rất lớn, cỡ vài chục ký tự thì sao? biết rằng nó dùng được với 99,99% các trường hợp nhưng nó không hoàn hảo.
vì vậy tôi đưa ra 1 giải pháp khác, nó đúng với nhiều trường hợp hơn, nếu muốn hoàn hảo hơn nữa có thể thay B1 bằng TRIM(B1) nhưng công thức sẽ khó nhìn hơn
Mã:
=UPPER(LEFT(B1;1)&CONCAT(TRIM(IF(MID(B1;ROW(A1:INDEX(A:A;LEN(B1)));1)=" ";MID(B1;ROW(A1:INDEX(A:A;LEN(B1)))+1;1);" "))))
Phan Thế Hiệp
-⍟-
- Tham gia
- 10/10/17
- Bài viết
- 3,678
- Được thích
- 12,687
- Giới tính
- Nam
Vậy, chơi vầy có được không?
Mã:
=CONCAT(UPPER(IFERROR(MID(B1,FIND("|",SUBSTITUTE(" "&B1," ","|",ROW(INDIRECT("1:"&LEN(B1))))),1),"")))dungpham01
Thành viên chính thức
- Tham gia
- 22/7/25
- Bài viết
- 86
- Được thích
- 64
Vậy, chơi vầy có được không?
dạ được, do chat gpt bảo hàm indirect là hàm bay hơi nên đề xuất dùng index cho nhẹMã:=CONCAT(UPPER(IFERROR(MID(B1,FIND("|",SUBSTITUTE(" "&B1," ","|",ROW(INDIRECT("1:"&LEN(B1))))),1),"")))
dungpham01
Thành viên chính thức
- Tham gia
- 22/7/25
- Bài viết
- 86
- Được thích
- 64
Dạ không, thuật toán này là em tự nghĩ ra sau đó viết công thức. Rồi sau cùng mới đi hỏi chat gpt ,xem có cách tối ưu không thôi. Chứ AI cũng không nghĩ ra dc đâu, chịu khó nghĩ cho đầu óc nó tăng động lên bác ạ.
- Tham gia
- 8/6/06
- Bài viết
- 14,786
- Được thích
- 23,251
- Nghề nghiệp
- U80
[Copilot] (Khá đanh thép đó nha):
Nếu bạn muốn nâng cấp hơn nữa, có thể dùng **Power Query** hoặc **hàm `XLOOKUP`** (trong Excel 365 trở lên).
Nhưng với Excel 2019, `VLOOKUP` vẫn là lựa chọn vàng
Nếu bạn muốn nâng cấp hơn nữa, có thể dùng **Power Query** hoặc **hàm `XLOOKUP`** (trong Excel 365 trở lên).
Nhưng với Excel 2019, `VLOOKUP` vẫn là lựa chọn vàng
dungpham01
Thành viên chính thức
- Tham gia
- 22/7/25
- Bài viết
- 86
- Được thích
- 64
Vấn đề ở đây là muốn dùng công thức với excel 2019. Chứ công cụ thì làm mẫu 2 ví dụ rồi ctrl+E cũng ra, còn excel 365 thì có rất nhiều cách. Riêng hàm regex thôi cũng 2-3 cách rồi, chưa kể đến kết hợp giữa texsplit và filter...
Bài viết mới nhất
- Question
Đã cách dòng, nhưng có Mã trùng lặp thì báo trùng
(4 người xem)
HÀM EXCEL TÍNH CÔNG
(3 người xem)
- Đã giải quyết
- Question
- Question
