Chuyên đề giải đáp các bài tập (3 người xem)

[BNTT]

nhờ mọi người xem hộ mình bài này với:

Công thức tính thưởng:

[F7]: =HLOOKUP(D7, $C$23:$E$26, IF(C7<10, 2, IF(C7<19, 3, 4)), 0)​

Công thức đếm số người theo A, B, C:

[H9]: =COUNTIF($D$7:$D$21, G9)​

Công thức tính tổng số tiền thưởng theo A, B, C:

[I9]: =SUMIF($D$7:$D$21, G9, $F$7)​

(copy xuống cho những ô còn lại)

 

[hittho]

Giúp mình bài tập xếp học lực này nhé.

Mình có một bài tập về xếp học lực nhưng làm đến câu cuối cùng thì bí mò mãi không ra.
Điều kiện xếp học lực dựa vào điểm trung bình và điểm tối thiểu của các môn. Mình giửi file lên nhờ các bạn lập cho mình một công thức mẩu là mình sẽ hiểu. Cảm ơn các bạn trước nhé. Đang tự mò excel nên không có thầy hỏi nhờ các bạn vậy.
File đính kèm ở đây: http://s18.galaxyz.net/data/4f7e7e777c767d7d/BaiTapExcel.rar.glx

 

[ptlong04x1]

Bạn xem file đính kèm.

Bạn xem lại xem đúng ý chưa nhé, trong này mình có dùng 1 số NAME để đơn giản bớt công thức, bạn bấm Ctrl F3 để xem nhé.

 

[BNTT]

Mình có một bài tập về xếp học lực nhưng làm đến câu cuối cùng thì bí mò mãi không ra.
Điều kiện xếp học lực dựa vào điểm trung bình và điểm tối thiểu của các môn. Mình giửi file lên nhờ các bạn lập cho mình một công thức mẩu là mình sẽ hiểu. Cảm ơn các bạn trước nhé. Đang tự mò excel nên không có thầy hỏi nhờ các bạn vậy.

Để dễ nói, tôi để luôn cái bảng tính của bạn ở đây nhé:

Để tách số điểm ở MÃ ĐIỂM LƯU thành 5 cột cho 5 môn, có thể làm như sau:
Chọn hết từ F5 cho đến J17 (tất cả những ô sẽ chứa điểm), nhập công thức sau:

=--MID($E5, COLUMN()-5, 1)​

Xong nhấn 2 phím Ctrl+Enter, số điểm sẽ được chia hết vào trong các ô.
Chúng ta sẽ sử dụng 1 công thức cho tất cả, không cần đến 5 công thức như bạn đã làm.

Cái dấu -- ở trước công thức là để chuyển luôn kết quả thành dạng số để tính trung bình.
Hàm COLUMN() lấy con số của cột chứa công thức (ví dụ, cột Toán (cột F) là cột thứ 6), rồi trừ bớt đi 5, ra số 1, dùng số 1 này làm tham số cho hàm MID...

Để tính trung bình, chỉ cần dùng hàm này: AVERAGE
Công thức ở K5:K17 (chọn hết các ô từ K5 đến K17, nhập công thức xong nhấn Ctrl+Enter):

=AVERAGE(F5:J5)​

Công thức để Xếp loại, dùng hàm MIN để xét con số nhỏ nhất trong dãy ô chứa điểm, buộc hàm MIN này phải lớn hơn hoặc bằng 1 con số, để cho "không có môn nào dưới...". Rồi kết hợp với hàm AND, rồi lồng vào trong nhiều hàm IF.

Theo đề bài (xét trường hợp đầu tiên, Nguyễn Trúc A):

• loại Giỏi: =AND(K5>=8, MIN(F5:J5)>=6.5)
• loại Khá: =AND(K5>=6.5, MIN(F5:J5)>=5)
• loại TB: =AND(K5>=5, MIN(F5:J5)>=3.5)
• còn lại là Yếu

Dùng hàm IF lồng những điều kiện trên đây lại (bạn cũng làm như trên tôi đã nói, chọn hết từ L5 đến L17, nhập công thức, rồi nhấn Ctrl+Enter):

=IF(AND(K5>=8,MIN(F5:J5)>=6.5), "Giỏi", IF(AND(K5>=6.5,MIN(F5:J5)>=5), "Khá", IF(AND(K5>=5,MIN(F5:J5)>=3), "Trung bình", "Yếu")))​

---------------------------------------

Bạn ptlong04x1 có kiểm tra lại kết quả không vậy?
Tôi chưa xem công thức của bạn, nhưng nhìn vào trường hợp 1 (Nguyễn Trúc A), anh chàng này có số điểm lần lượt là 1, 2, 3, 4, 5. Riêng con số 1 ở môn đầu tiên thôi, đủ để xếp anh ta loại Yếu, vậy mà bạn xếp anh ta loại TB?

 

[ptlong04x1]

Cảm ơn anh đã nhắc nhở, em kiểm tra lại rồi, em đặt 2 NAME là Tbinh và TB nên khi viết công thức thì bị nhầm 2 NAME này với nhau. Em đã đưa file lên lại bài trước rồi, nếu anh có thời gian xem qua giùm em 1 chút.

 

[thaibinh1212]

Câu hỏi như sau:
_Từ cột "Mã NV", Bảng 1, Bảng 2. Điền CVỤ (T-KD00==>TrPhòng Kinh Doanh)
Thanks

 

[salam]

Câu hỏi như sau:
_Từ cột "Mã NV", Bảng 1, Bảng 2. Điền CVỤ (T-KD00==>TrPhòng Kinh Doanh)
Thanks

Bạn dùng hàm vlookup và hlookup nhé.

=VLOOKUP(LEFT(A3,1),$A$19:$C$21,2,0)&" "&HLOOKUP(MID(A3,3,2),$D$18:$G$19,2,0)

 

[cop_kh]

Câu hỏi như sau:
_Từ cột "Mã NV", Bảng 1, Bảng 2. Điền CVỤ (T-KD00==>TrPhòng Kinh Doanh)
Thanks

Bạn dùng công thức sau nhé:

C3=VLOOKUP(LEFT(A3;1);$A$19:$B$21;2;0)&" "&HLOOKUP(MID(A3;3;2);$D$18:$G$19;2;0)

 

[hittho]

Cảm ơn 2 bạn rất nhiều..!. BNTT có cách hướng dẫn rất hay. Mình học hỏi được nhiều thứ nữa. Bây giờ thì mình hiểu tại sao ở cột trung bình minh không dùng hàm AVERAGE được rồi đơn giản vì các ô điểm Toán, Lý.....sinh không phải dạng dữ liệu số phải không bạn. Lại học được cách chuyễn về dữ liệu dạng số khi dùng hảm Mid.. hi hi.. (--)... Quy tắc lòng hàm ..!!!.
Mình thấy để học một hàm đơn lẽ thì rất dễ. Nhưng để kết hợp nhiều hàm trong một công thức thì hơi khó thông thường sách lại ích viết hoặc cho nhiều các ví dụ theo dạng này. Nếu các cao thủ excel ở diễn đàn ta mở một topic chia sẽ nhưng kinh nghiệm này thì tuyệt cú mèo.
pm ptlong04x1 cảm ơn bạn đã làm hộ mình. Cách của bạn cũng rất hay khi dùng Defile name để gán giá trị vùng. Nhưng cách này không biết đi thi lấy bằng giám khảo có chịu không nhỉ. Vì thông thường người ta cho đề bài dạng này thì yêu cầu chính là phải dùng hàm căn bản trực tiếp (trình độ A) mà... hì hì..! Cảm ơn bạn rất nhiều..!
Mong còn được các bạn giúp đở nhiều mổi khi "bí lù".. Thân mến!!!

 

[hittho]

Mình có thêm một câu hỏi nữa trong bài tập số 17 nhờ các bạn giúp đở. Liên quan đến tính ngày tháng
Mình gửi kèm file các bạn trả lời giùm mình nhé!!!!

 

[BNTT]

Mình có thêm một câu hỏi nữa trong bài tập số 17 nhờ các bạn giúp đở. Liên quan đến tính ngày tháng
Mình gửi kèm file các bạn trả lời giùm mình nhé!!!!

Hì hì, ở trên bày bạn hàm MID, xong bạn đem áp dụng vào bài này, thấy vui quá.

Không ai dùng cái này: MID(B6,1,1) đâu, mà người ta dùng hàm LEFT (lấy ký tự đầu tiên bên trái), cụ thể, bạn có thể thay cái MID(B6,1,1) bằng LEFT(B6).

Công thức để dò ra tên vật tư đúng rồi, nhưng nên thay như sau cho nó ngắn hơn:

=VLOOKUP(LEFT(B6), $B$19:$C$21, 2, 0)​

Tương tự, ở đơn giá cũng vậy:

=VLOOKUP(LEFT(B6), $B$19:$D$21, 3, 0)​

Còn cái chuyện: Nếu thanh toán trước 15 ngày kể từ "Ngày nhận" hàng thì được giảm giá 10% so với "Đơn giá", bạn dùng hàm IF đi (tại có chữ Nếu đó), thanh toán trước 15 ngày kể từ ngày nhân hàng (lẽ ra phải dùng chữ thanh toán trong vòng 15 ngày thì hay hơn), nghĩa là lấy ngày trả tiền trừ đi ngày nhân hàng, mà nó nhỏ hơn 15 ngày, thì giảm cho nó 10%.

[H6]: =F6 * G6 * (1-IF(E6-D6<15, 10%, 0))​

Hoặc là vầy, ngắn hơn tí:

[H6]: =F6 * G6 * (1-((E6-D6)<15)*10%)​

Mà nói cho vui thôi, chớ cái bài toán của bạn, chả có ma nào thanh toán sau 15 ngày kể từ ngày nhận hàng hết trơn! Nghĩa là ai cũng được giảm 10% hết!

 

[hittho]

Hì hì, ở trên bày bạn hàm MID, xong bạn đem áp dụng vào bài này, thấy vui quá.

Không ai dùng cái này: MID(B6,1,1) đâu, mà người ta dùng hàm LEFT (lấy ký tự đầu tiên bên trái), cụ thể, bạn có thể thay cái MID(B6,1,1) bằng LEFT(B6).

Công thức để dò ra tên vật tư đúng rồi, nhưng nên thay như sau cho nó ngắn hơn:

=VLOOKUP(LEFT(B6), $B$19:$C$21, 2, 0)​

Tương tự, ở đơn giá cũng vậy:

=VLOOKUP(LEFT(B6), $B$19:$D$21, 3, 0)​

Còn cái chuyện: Nếu thanh toán trước 15 ngày kể từ "Ngày nhận" hàng thì được giảm giá 10% so với "Đơn giá", bạn dùng hàm IF đi (tại có chữ Nếu đó), thanh toán trước 15 ngày kể từ ngày nhân hàng (lẽ ra phải dùng chữ thanh toán trong vòng 15 ngày thì hay hơn), nghĩa là lấy ngày trả tiền trừ đi ngày nhân hàng, mà nó nhỏ hơn 15 ngày, thì giảm cho nó 10%.

[H6]: =F6 * G6 * (1-IF(E6-D6<15, 10%, 0))​

Hoặc là vầy, ngắn hơn tí:

[H6]: =F6 * G6 * (1-((E6-D6)<15)*10%)​

Mà nói cho vui thôi, chớ cái bài toán của bạn, chả có ma nào thanh toán sau 15 ngày kể từ ngày nhận hàng hết trơn! Nghĩa là ai cũng được giảm 10% hết!

Cảm ơn bạn rất nhiều.! Với những chĩ dẫn này thì mình hoàn toàn không lo không có sư phụ nữa..!! hi.hi. Bây giờ thì mình đã hiểu khi nào nên áp dụng hàm LEFT(trích biên trái), MID(trích khoãng giữa), RIGHT(trích biên phải). Có đúng thế không.?. À mà bạn cho mình một vài ví dụ khi nào sử dụng hàm DATE(yyyy,mm,dd) được không ?
pm: Hỏi nhiều quá ...hihi đang máu học cel mà.. ..! Còn phải thọ giáo dài dài ...Nhận học trò nhé..!!!

 

[cop_kh]

À mà bạn cho mình một vài ví dụ khi nào sử dụng hàm DATE(yyyy,mm,dd) được không ?

Mục đích của hàm DATE(yyyy,mm,dd) là dùng để lấy ngày tháng năm chuẩn cho Excel mà không cần quan tâm đến máy đang dùng sử dụng kiểu ngày tháng năm theo định dạng nào cả (mm/dd/yyyy; mm/dd/yyyy...).
VD như thế này cho dễ hiểu bạn nhé: ở ô A1 bạn có ô dữ liệu là 10042009, tức là người dùng có dữ liệu như vậy, cho kiểu ngày tháng năm là ngày 10 tháng 4 năm 2009.
Ở ô B1 có công thức: DATE(RIGHT(A1;4);MID(A1;3;2);LEFT(A1;2)), KQ sẽ là:

• 10/04/2009 nếu máy tính định dạng theo kiểu dd/mm/yyyy.
• 04/10/2009 nếu máy tính định dạng theo kiểu mm/dd/yyyy.
• 2009/04/10 nếu máy tính định dạng theo kiểu yyyy/mm/dd.

Sơ sơ như vậy được chưa bạn nhỉ?

 

[tonggiap]

Mình có 1 số khó khăn mong các bạn giúp đỡ mình đang pải trả bài sớm!
Mình gửi kèm File bài tập nhé
2,Tên hàng : Dựa vào 2 ký tự đầu của Mã hàng tra trong Bảng tên hàng và 1 ký tự cuối của Mã hàng tra trong Bảng loại hàng
3. Thôngs kế số liệu vào bảng Thống Kê
Cám ơn các bạn rất nhiều!!

 

[cop_kh]

Gởi lại đáp án cho bạn luôn nè:
C4=VLOOKUP(LEFT(B4;2);$A$20:$B$22;2;0)&" "&HLOOKUP(RIGHT(B4;1);$A$25:$C$26;2;0)
K20=SUMIF($B$4:$B$15;A20&"*";$K$4:$K$15)

Góp ý thêm bạn ở ô E4 có thể sửa lại như sau cho tốt hơn nhé:
E4==INDEX($F$20:$H$22;MATCH(RIGHT(B4;1);$E$20:$E$22;0);MATCH(LEFT(B4;2);$F$19:$H$19;0))

 

[tonggiap]

Gởi lại đáp án cho bạn luôn nè:
C4=VLOOKUP(LEFT(B4;2);$A$20:$B$22;2;0)&" "&HLOOKUP(RIGHT(B4;1);$A$25:$C$26;2;0)
K20=SUMIF($B$4:$B$15;A20&"*";$K$4:$K$15)

Góp ý thêm bạn ở ô E4 có thể sửa lại như sau cho tốt hơn nhé:
E4==INDEX($F$20:$H$22;MATCH(RIGHT(B4;1);$E$20:$E$22;0);MATCH(LEFT(B4;2);$F$19:$H$19;0))

ban ah sao ở chỗ "; mình nhập dữ liệu vào lại báo lỗi nhỉ?
&" "& bạn có thể giải thích hộ mình các đó có tác dụng gì ko? mình hời nhiều chuyện nhưng mình muốn hiểu vì mình thấy hơi là!

 

[volga]

ban ah sao ở chỗ "; mình nhập dữ liệu vào lại báo lỗi nhỉ?
&" "& bạn có thể giải thích hộ mình các đó có tác dụng gì ko? mình hời nhiều chuyện nhưng mình muốn hiểu vì mình thấy hơi là!

Bạn nhìn lại công thức , chia ra làm 2 vế rỏ gàng đúng không? (vlookup & hlookup)
& Mang nghĩa là và thôi ,củng như ghép A và B
( A&B) = AB Đúng không ? công thức trên củng vậy .
&" " & .Có nghĩa nom na là . Kết quả của hàm vlookup + khoảng trắng + kết quả của hlookup .

Bạn thay dấu ; thành dấu , thử xem
Thân.

 

[lamphibang]

chỉ giúp tôi 1 công thức nữa

Tôi cần xử lý dữ liệu trên cột A, vd như ô A1 có dữ liệu là KS000003 , ô A2 trống, ô A3 trống, đến ô A4 thì dữ liệu là KS000006, cứ tiếp tục như thế, 1 ô có dữ liệu rồi vài ô kô có dữ liệu,....
tôi cần lập hàm cho cột B sao cho, nếu ô tương ứng bên A có dữ liệu rồi thì hiện dữ liệu ấy ra, nếu ô A tương ứng không có dữ liệu thì hiện dữ liệu của ô A phía trên của nó mà có chứ dữ liệu....
vd: lúc đầu A1 = KS0000003
A2 = blank
A3 = Blank
A4 = KS0000006
A5 = blank
bây giờ tôi muốn B1 = KS000003
B2 = KS000003 (giống B1=A1)
B3 = KS000003 ( tương tự)
B4 = KS000006 (=A4)
B5 = KS000006 (=B4=A4)
help

 

[cop_kh]

tôi cần xử lý dữ liệu trên cột a, vd như ô a1 có dữ liệu là ks000003 , ô a2 trống, ô a3 trống, đến ô a4 thì dữ liệu là ks000006, cứ tiếp tục như thế, 1 ô có dữ liệu rồi vài ô kô có dữ liệu,....
Tôi cần lập hàm cho cột b sao cho, nếu ô tương ứng bên a có dữ liệu rồi thì hiện dữ liệu ấy ra, nếu ô a tương ứng không có dữ liệu thì hiện dữ liệu của ô a phía trên của nó mà có chứ dữ liệu....
Vd: Lúc đầu a1 = ks0000003
a2 = blank
a3 = blank
a4 = ks0000006
a5 = blank
bây giờ tôi muốn b1 = ks000003
b2 = ks000003 (giống b1=a1)
b3 = ks000003 ( tương tự)
b4 = ks000006 (=a4)
b5 = ks000006 (=b4=a4)
help

bạn có thể dùng công thức đơn giản như sau:
ô b1=a1
ô b2=if(a2<>"";a2;b1)

 

[salam]

Tôi cần xử lý dữ liệu trên cột A, vd như ô A1 có dữ liệu là KS000003 , ô A2 trống, ô A3 trống, đến ô A4 thì dữ liệu là KS000006, cứ tiếp tục như thế, 1 ô có dữ liệu rồi vài ô kô có dữ liệu,....
tôi cần lập hàm cho cột B sao cho, nếu ô tương ứng bên A có dữ liệu rồi thì hiện dữ liệu ấy ra, nếu ô A tương ứng không có dữ liệu thì hiện dữ liệu của ô A phía trên của nó mà có chứ dữ liệu....
vd: lúc đầu A1 = KS0000003
A2 = blank
A3 = Blank
A4 = KS0000006
A5 = blank
bây giờ tôi muốn B1 = KS000003
B2 = KS000003 (giống B1=A1)
B3 = KS000003 ( tương tự)
B4 = KS000006 (=A4)
B5 = KS000006 (=B4=A4)
help

Bạn dùng ct dưới xem nhé.

=IF(A1="",LOOKUP(2,1/(1-ISBLANK($A$1:A1)),$A$1:A1),A1)

 

[lamphibang]

ths 2 bạn rất nhiều, tôi làm kiểm toán nên dùng excel là 1 điều kô tránh khỏi, ngày càng tôi càng thấy nó hay, tôi sẽ cố gắng học hỏi nhiều hơn nữa để bổ trợ cho côg việc của mình
ths 2 bạn 1 lần nữa

 

[anhdn]

Giúp hàm tính tổng

Gửi các bác, các bác giúp em vụ này nhanh với ạ.
Em đang có 1 bảng như thế này( bảng rất dài :
Bảng 1:
Chủng hàng Doanh thu Số lượng bán Đơn giá bán Điện thoại Hittech 500,000.00 10.00 50,000.00 Điện thoại Hittech 600,000.00 5.00 120,000.00 Điện thoại LG 1,000,000.00 2.00 500,000.00 Điện thoại LG 700,000.00 3.00 233,333.33 Điện thoại Motorola 500,000.00 7.00 71,428.57
Mục đích của em, tính tổng số lượng, doanh số chủng hàng : Điện thoại Hittech với từng điều kiện:
- Đơn giá bán <60.000, điều kiện 2, đơn giá bán >=60.000 và <=100000
Các bác giúp em với.
Em cảm ơn

 

[BNTT]

Gửi các bác, các bác giúp em vụ này nhanh với ạ.
Em đang có 1 bảng như thế này( bảng rất dài :
Bảng 1:
Chủng hàng Doanh thu Số lượng bán Đơn giá bán Điện thoại Hittech 500,000.00 10.00 50,000.00 Điện thoại Hittech 600,000.00 5.00 120,000.00 Điện thoại LG 1,000,000.00 2.00 500,000.00 Điện thoại LG 700,000.00 3.00 233,333.33 Điện thoại Motorola 500,000.00 7.00 71,428.57
Mục đích của em, tính tổng số lượng, doanh số chủng hàng : Điện thoại Hittech với từng điều kiện:
- Đơn giá bán <60.000, điều kiện 2, đơn giá bán >=60.000 và <=100000
Các bác giúp em với.
Em cảm ơn

Có phải bảng tính của bạn nó như thế này:

|

A​

​

|

B​

​

|

C​

​

|

D​

​

|

1​

​

|

Chủng loại hàng​

​

|

Doanh thu​

​

|

Số lượng bán​

​

|

Đơn giá bán​

​

|

2​

​

|Điện thoại Hittech|

500,000​

|

10​

|

50,000​

|

3​

​

|Điện thoại Hittech|

600,000​

|

5​

|

120,000​

|

4​

​

|Điện thoại LG|

1,000,000​

|

2​

|

500,000​

|

5​

​

|Điện thoại LG|

700,000​

|

3​

|

233,333​

|

6​

​

|Điện thoại Motorola|

500,000​

|

7​

|

71,428.57​

|

Cộng nhiều điều kiện như thế này, bạn có thể dùng SUMPRODUCT. Ví dụ:

• Số lượng hàng "Điện thoại Hittech" có giá bán < 60,000 đã bán được:
  
  =SUMPRODUCT(($A$2:$A$6="Điện thoại Hittech") * ($D$2:$D$6<60000) * $C$2:$C$6)​
  
  
• Doanh số của "Điện thoại Hittech" có giá bán < 60,000:
  
  =SUMPRODUCT(($A$2:$A$6="Điện thoại Hittech") * ($D$2:$D$6<60000) * $B$2:$B$6)​
  
  
• Số lượng hàng "Điện thoại Hittech" có giá bán >= 60,000 và <100,000 đã bán được:
  
  =SUMPRODUCT(($A$2:$A$6="Điện thoại Hittech") * AND($D$2:$D$6>=60000, $D$2:$D$6<100000) * $C$2:$C$6)​
  
  
• Doanh số của "Điện thoại Hittech" có giá bán >= 60,000 và <100,000:
  
  =SUMPRODUCT(($A$2:$A$6="Điện thoại Hittech") * AND($D$2:$D$6>=60000, $D$2:$D$6<100000) * $B$2:$B$6)​

Còn nhiều cách khác nữa, ví dụ dùng Advanced Filter, v.v... Nhưng nói một lần nhiều quá sợ bạn đọc không nổi.

 

[tonggiap]

Minh có 1 bài tập tính đơn giá mong các bạn giúp
Mã số Đơn giá
AK001S ?
Bẳng 1:
Mã hàng Tên Hàng Đơn giá loại 1 ĐƠn giá loại 2
AK Áo kiẻu 95000 105000

Tính đơn giá : dựa vào 2 ký tự đầu của mảhhnnggtta trong bảng 1( tùy vào loại hàng)
với : 2 ký tự đầu là tên hàng
Ký tự thứ 5 của Mã số là loại hàng
Mong các bạn giúp đỡ mình ! cám ơn nhiều!
Minh lam Cthức này ko biet sai o dau?!!
=INDEX($C$16:$D$19,MATCH(LEFT(B5,2),$A$16:$A$19,0),MATCH(MID(B5,5,1),$C$15:$D$15,0))

 

[tonggiap]

giúp mình tính đơn giá

Mình có bài tập cần các bạn giúp đỡ!định gửi file nhưng ko hiêu san ko gửi được!

Mã sô ----Đơn giá
AK001S -----------?

BẢng 1 :
Mã hàng --Tên hàng --Đơn giá Loại 1 ---Đơn giá loại 2
AK ----------Áo kiểu ----95000 ---------105000

- 2 ký tự đầu mã hàng
- ký tự thứ 5 loại hàng

Tính đơn giá : dựa vaòp 2 ký tự đầu của Mã số hàng tra trong bảng 1 (tùy theo loại hàng)
Mình tính ntn mà ko được ?các bạn chỉ cho mình chỗ sai nhé! thanks
INDEX($C$16:$D$19,MATCH(LEFT(B5,2),$A$16:$A$19,0),MATCH(MID(B5,5,1),$C$15:$D$15,0))

 

[cadafi]

Bạn có thể dùng công thức sau:

=VLOOKUP(LEFT($B5,2),$A$16:$D$19,2+MID($B5,5,1),0)

Sau đó kéo công thức xuống dưới.

Công thức của bạn dài quá và không tổng quát! Nếu có khoản 100 danh mục hàng khác nhau mà bạn cứ IF như thế thì không được đâu!

 

[tonggiap]

Cám ơn 2 bạn đã giúp đỡ mình!
các bạn có thể giải thích hộ mình "MID($B5,5,1)+2" là gì ko mình ko hiều ? mình mới học nên ko biêt? làm phiền các bạn nhiều!

 

[tonggiap]

Bài của bạn đã được trả lời tại đây!

uh cám ơn đã nhiệt tình giúp mình! bạn có thể cho mình hỏi nếu dùng hàm INDEX kết hợp hàm Match thì làm thế nào?

 

[ndu96081631]

Cám ơn 2 bạn đã giúp đỡ mình!
các bạn có thể giải thích hộ mình "MID($B5,5,1)+2" là gì ko mình ko hiều ? mình mới học nên ko biêt? làm phiền các bạn nhiều!

MID($B5,5,1) nghĩa là lấy ký tự thứ 5 trong B5 và lấy 1 ký tự ---> Chỉ vậy thôi
Dựa vào ký tự thứ 5 này, nếu:
Nó =1, ta cộng thêm 2 thì nó = 3 <===> Dùng hàm VLOOKUP với cột dò là 3...
Nó =2, ta cộng thêm 2 thì nó = 4 <===> Dùng hàm VLOOKUP với cột dò là 4...

 

[ndu96081631]

uh cám ơn đã nhiệt tình giúp mình! bạn có thể cho mình hỏi nếu dùng hàm INDEX kết hợp hàm Match thì làm thế nào?

INDEX và MATCH thì vầy:
=INDEX($A$15:$D$19,MATCH(LEFT($B5,2),$A$15:$A$19,0),MID($B5,5,1)+2)

 

[jeajinqv]

Nhờ anh chị giúp đỡ em bài excel này ạ . Có cả câu hỏi trong bài luôn đó
http://dc110.4shared.com/download/89055485/5703750a/Book1.xls?tsid=20090223-061351-f16ef466

 

[cop_kh]

Nhờ anh chị giúp đỡ em bài excel này ạ . Có cả câu hỏi trong bài luôn đó
http://dc110.4shared.com/download/89055485/5703750a/Book1.xls?tsid=20090223-061351-f16ef466

Gở lại bạn bài giải, còn một số câu về trích lọc, vẽ đồ thị tương đối đơn giản, bạn tự làm đi nhé.

 

[jeajinqv]

http://dc131.4shared.com/download/89220501/5143dc05/nb_online.xls?tsid=20090224-051936-1f0694c2
Mấy câu lập bảng báo cáo lọc ra đó .Lọc được rồi ,nhưng lại có mấy cái chữ Value kỳ kỳ quá ,ai biết cách chỉnh sửa thì chỉnh giùm em được ko? .Chỉnh sao chỉ hiện tên thôi ,còn cái nào không thỏa ĐK thì không hiện lên

 

[hoangdanh282vn]

http://dc131.4shared.com/download/89220501/5143dc05/nb_online.xls?tsid=20090224-051936-1f0694c2
Mấy câu lập bảng báo cáo lọc ra đó .Lọc được rồi ,nhưng lại có mấy cái chữ Value kỳ kỳ quá ,ai biết cách chỉnh sửa thì chỉnh giùm em được ko? .Chỉnh sao chỉ hiện tên thôi ,còn cái nào không thỏa ĐK thì không hiện lên

Nếu làm đúng như yêu cầu của bạn, chỉ cần bỏ mấy cái ô có #value thi bạn chỉ cần dùng hàm If cho đơn giản.

 

[swat403]

chả hiểu sao không post được bài mới.em mới là thành viên nên admin không cho thì phải...huhu.em có bài nì khoai quá!có ai giúp em được thì em thanks nhìu nhìu.
yêu cầu đề ra là:
1 -Tính số ngày thuê = Ngày trả - Ngày thuê (cái này ai mà chả làm đc)
2- Tính Loai là ký tự cuối cùng của Mã hàng và chuyển qua giá trị số (em không bít chuyển như thế nào???)
3- Lập công thức điền dữ liệu cho cột Tên hàng,dựa theo Mã hàng và Bảng giá (cái này em chịu rồi)
4- Điền dữ liệu (ok rồi)
5-Tiền thuê = Số lượng x Giá x Số ngày thuê;nhưng nếu số lượng lơn hơn 20 thì sẽ giảm 10% tiền thuế (vế đằng sau em chịu)
6-Tính Tổng cộng cột Số ngày thuê và Tiền thuê (ok rồi)
đóa!cả cái bài tập của em là như vậy.ai rảnh + pro thì giúp em với nha.em thanks kiu !!!!

http://www.fileden.com/files/2007/2/13/768858/BT5.xls <== Link đây ạ.nó nhẹ lắm.chỉ 15 KB thôi ah.mong mọi người giúp em.THANKS!!!!

 

[cadafi]

@swat403: Bạn xem file đính kèm nha

 

[Po_Pikachu]

Bạn xem file nha!
Thân.

 

[cadafi]

thanks kiu!2 bài này sao lại có 2 đáp khác nhau???hic.nhưng dù sao em chỉ cần công thức thôi.mong lần sau anh chị giúp đỡ em nữa nha.

Khác nhau ở số ngày thuê!
Nếu ngày thuê và ngày trả cùng trong 1 ngày thì bạn tính là mấy ngày!? Cứ thế mà suy ra công thức!

 

[nhatquang619]

Giúp giải bài tập Excel

Mình đang chuẩn bị thi học phần môn Tin học (căn bản) rất gấp (thi vào sáng thứ sáu 06/03/2009). Tuy nhiên có một bài tập qua tham khảo có quá nhiều đáp số cho bài tập này. Mình đang rất rối. Mong các bạn giúp với.
Các bạn có thể giúp qua diễn đàn hoặc có thể gửi qua địa chỉ:
phamnhatquang619@yahoo.com.vn
(File bài tập đính kèm)

 

[cop_kh]

Mình đang chuẩn bị thi học phần môn Tin học (căn bản) rất gấp (thi vào sáng thứ sáu 06/03/2009). Tuy nhiên có một bài tập qua tham khảo có quá nhiều đáp số cho bài tập này. Mình đang rất rối. Mong các bạn giúp với.
Các bạn có thể giúp qua diễn đàn hoặc có thể gửi qua địa chỉ:
phamnhatquang619@yahoo.com.vn
(File bài tập đính kèm)

Bạn xem lại các yêu cầu của bài không rõ ràng. VD mã phòng A11 thì làm sao biết phòng đơn, phòng đôi, số người ở là bao nhiêu...
Đề bài khá dễ, bạn bổ sung các câu hỏi trên, mình gởi lại đáp án cho.

 

[nhatquang619]

Mình đã ghi trong phần lưu ý: ví dụ A11 thì: Ký tự đầu A là loại phòng A, ký tự cuối là 1 (tầng 1) , ký tự giữa là 1 (giường đơn). Bạn gửi đáp án cho mình nhé. Cám ơn bạn một lần nữa.

 

[volga]

Ở đây làm sao biết phòng đó mấy người đơn, đôi thì có rồi ?
Giải được hai câu ,bạn xem nhe !
Thân

 

[nhatquang619]

Minh xin lỗi, số người trọ mình đã xóa mất, làm phiền bạn xem lại mình gửi lại đề bài.

 

[salam]

Mình đã ghi trong phần lưu ý: ví dụ A11 thì: Ký tự đầu A là loại phòng A, ký tự cuối là 1 (tầng 1) , ký tự giữa là 1 (giường đơn). Bạn gửi đáp án cho mình nhé. Cám ơn bạn một lần nữa.

d/-Tính doanh thu (dựa vào đơn giá, phụ thu * số người vượt, số ngày ở).

Làm sao để biết được số người vượt
1. Thuê phòng đơn.
2. Thuê phòng đôi.

 

[nhatquang619]

File bài tập 4 đính kèm. Giúp mình với

 

[cop_kh]

File bài tập 4 đính kèm. Giúp mình với

Trời ơi giúp bạn mà bạn cứ làm khó anh em, làm sao để biết được phòng đơn, phòng đôi đây?

 

[salam]

File bài tập 4 đính kèm. Giúp mình với

Bạn xem trong file kèm nhé.

 

[nhatquang619]

Mình đã ghi rõ trong phần lưu ý rồi mà: Ký tự giữa là giường đơn hay đôi. Cố giúp mình với. (file đính kèm gửi cuối cùng mình đã xem rồi, chính xác theo đề của thầy)

 

[cop_kh]

mình đã ghi rõ trong phần lưu ý rồi mà: Ký tự giữa là giường đơn hay đôi. Cố giúp mình với. (file đính kèm gửi cuối cùng mình đã xem rồi, chính xác theo đề của thầy)

1. f5=e5-d5+1
2. h5=hlookup(left(b5;1);$d$20:$f$22;mid(b5;2;1)+1;0)
3. i5=if(g5>2;hlookup(left(b5;1);$d$20:$f$23;3;0);0)
4. j5=(h5+(g5-2))*f5
5. i21=sumif($b$5:$b$16;h21&"*";$j$5:$j$16)

 

[thaibinh1212]

Hình như mấy bạn giải không chính xác thì phải.................!!!!!!!!

 

[TongDe]

bài giải

Bài gởi có vài lỗi:
Định dạng ngày tháng không đúng ( đã sửa lại cho vài dòng )
Tính ngày ở có đúng ý bạn chưa?
Cột bao nhiêu khách phải có số liệu chứ !
Hẹn gặp lại.

 

[volga]

Bạn có thể xem thêm cái này !
Mình không biết tính doanh thu ?không hiểu
Liệt kê doanh thu của từng loại phòng ,bạn dùng sumif đi .
Lọc ra phụ thu dùng Auto Filer lọc ra nhe
Thân

 

[nhatquang619]

Như mình nói, một bài tập có quá nhiều đáp số làm cho mình càng thêm rối, chắc do bài của thầy ra câu hỏi không rõ ràng, mình chỉ tiếc không thấy được đáp án của thầy. Đây là bài làm của mình. Mong các bạn chia sẽ và cho mình một lời khuyên. Xin cám ơn các bạn.

 

[cop_kh]

Như mình nói, một bài tập có quá nhiều đáp số làm cho mình càng thêm rối, chắc do bài của thầy ra câu hỏi không rõ ràng, mình chỉ tiếc không thấy được đáp án của thầy. Đây là bài làm của mình. Mong các bạn chia sẽ và cho mình một lời khuyên. Xin cám ơn các bạn.

Theo mình thì bạn có thể sửa lại một số công thức sau để đơn giản hơn:
F14=E14-D14
Phần phụ thu I14 không liên quan gì đến Mã phòng vì trong yêu cầu không đề cập đến, chỉ có số người trong phòng mà thôi, nên:
I14=IF(G14>2;HLOOKUP(C14;$C$29:$F$32;4;0)*(G14-2);0)

 

[BNTT]

Như mình nói, một bài tập có quá nhiều đáp số làm cho mình càng thêm rối, chắc do bài của thầy ra câu hỏi không rõ ràng, mình chỉ tiếc không thấy được đáp án của thầy. Đây là bài làm của mình. Mong các bạn chia sẽ và cho mình một lời khuyên. Xin cám ơn các bạn.

Vài góp ý nhỏ:

1. Loại phòng:

Công thức này đúng, nhưng có thể rút gọn hơn một tí xíu xiu (không cần số 1):

[C14] =LEFT(B14)​

2. Tính số ngày ở:

Tại sao bạn không lấy ngày đi trừ ngày ở cho lẹ? Mà làm cái công thức dài như thế?

Và thêm điều này, tôi dám cá rằng thầy của bạn sẽ nói rằng đáp án của bạn sai. Vì khi tính số NGÀY Ở, bao giờ người ta cũng sẽ lấy NGÀY ĐI trừ NGÀY ĐẾN rồi CỘNG THÊM 1. Bạn thiếu cái CỘNG THÊM 1 này. Chắc chắn đáp án của Thầy bạn sẽ có chuyện cộng thêm 1.

Thôi để tôi cho bạn một ví dụ nhỏ. Bạn đến nhà tôi chơi ngày hôm qua (04/3/2009), bạn ở đến hôm nay (05/3/2009). Vậy bạn đã ở chơi với tôi mấy ngày? Hai ngày phải không? Nếu lấy 05/3 trừ 04/3 thì nó ra có 1 à. Bạn hiểu chuyện cộng thêm 1 rồi chứ. Hoặc bạn có thể tham khảo thêm bài này: http://www.giaiphapexcel.com/forum/showthread.php?p=141547#post141547

Công thức đề nghị:

[F14] =E14-D14+1​

3. Tính phụ thu:

Nếu dựa vào nguyên văn cái này:

c/- Tính đơn giá phòng và Phụ thu (nếu số người ở nhiều hơn 2 người/phòng) dựa vào Mã phòng và bảng đơn giá phòng.

Thì công thức của bạn sai!

Người ta chỉ nói là nếu số người ở nhiều hơn 2 người/ phòng, chứ người ta không có nói rằng phòng đơn thì chỉ được ở 1 người. Và người ta cũng không nói rằng dư bao nhiêu người thì tính phụ thu bấy nhiêu người.

Theo đúng nguyên xi đề bài, thì chúng ta chỉ xét những trường hợp nào mà số người ở nhiều hơn 2 người mà thôi, không quan tâm đến chuyện đó là phòng đơn hay phòng đôi, và cũng không quan tâm rằng dư mấy người.

Do đó, chỉ cần lấy số người ở (cột G) so sánh với 2 (để xem có dư người không), rồi nhân với đơn giá của phụ thu là xong. Công thức đề nghị:

[I14] =IF(G14>2, HLOOKUP(C14, $C$29:$F$32, 4, 0), 0)​

Hay cũng có thể dùng cái này, ngắn hơn 1 tí xíu:

[I14] =(G14>2) * HLOOKUP(C14, $C$29:$F$32, 4, 0)​

Cả hai công thức đều là: Nếu G14>2 thì phụ thụ = giá trị mà HLOOKUP tìm ra, còn không (G14 không lớn hơn 2) thì phụ thu = 0.
​

4. Tính doanh thu:

Công thức của bạn (xin lỗi trước nha) tức cười quá.

Doanh thu là bằng: (Số ngày ở) x (đơn giá + phụ thu)

Số ngày ở là cột F, đơn giá là cột H, và phụ thu là cột I, cứ như thế mà ghi vào công thức:

[J14] =F14*(H14+I14)​

Kết luận: Bài của bạn, nếu tôi chấm, thì e rằng dưới trung bình... Bạn đừng buồn. Bởi vì tính số ngày ở sai thì tất cả đều sai hết. Bạn chỉ đúng được chuyện trích ra loại phòng (A, B, C), tính ra đơn giá của mỗi loại.

Nói thêm một tí. Đề bài này không có gì là không rõ ràng hết. Đề cho như thế nào, ta cứ hiểu như thế ấy, và làm y như đề yêu cầu, là đạt. Đặc biệt trường hợp câu tính phụ thu, xin góp ý với bạn: Khi làm bài, bạn nên bám sát vào đề bài, thậm chí nếu đề bài sai thì làm theo cái sai luôn (kinh nghiệm xương máu của tôi đó), chứ đừng tự tiện suy luận theo ý riêng của mình.

 

[swat403]

em cần làm gấp bài này,ai giúp em với

đây là link file.rất nhẹ.mong các bác giúp đỡ.thanks!!!
http://www.fileden.com/files/2007/2/13/768858/BT9.xls

 

[volga]

đây là link file.rất nhẹ.mong các bác giúp đỡ.thanks!!!
http://www.fileden.com/files/2007/2/13/768858/BT9.xls

Mình làm chỉ được thế này thôi bạn xem có đúng không nhe !

 

[cop_kh]

đây là link file.rất nhẹ.mong các bác giúp đỡ.thanks!!!
http://www.fileden.com/files/2007/2/13/768858/BT9.xls

Bài tập của bạn có thể làm đơn giản như sau (có thể bạn gõ sai ô mã hàng B14):

1. F12=VLOOKUP(C12;$B$3:$D$6;D12+1;0)*E12
2. G12=IF(VLOOKUP(C12;$B$3:$E$6;4;0)="X";0;VLOOKUP(VALUE(MID(B12;2;1));$J$3:$K$6;2;0)*F12)

 

[swat403]

Bài tập của bạn có thể làm đơn giản như sau (có thể bạn gõ sai ô mã hàng B14):

1. F12=VLOOKUP(C12;$B$3:$D$6;D12+1;0)*E12
2. G12=IF(VLOOKUP(C12;$B$3:$E$6;4;0)="X";0;VLOOKUP(VALUE(MID(B12;2;1));$J$3:$K$6;2;0)*F12)

thanks kiu vinamilk.k phải mình viết sai đâu.đấy là do bài tập đề ra như vậy để thấy rõ sự khác biệt của công thức đó(tui đoán là vậy vì tui nhìn đi nhìn lại sách rùi- 0dưới 50 lần)
thanks nhìu nhưng chưa hiểu lắm.ai cho tui cái Yh có gì k bít tui còn hỏi nhỉ
tui mới học môn nè mà!!!

 

[volga]

công thức của pác này dài wá!huhu.dù sao cũng cảm ơn nhìu nha!!!

Bạn thử xem trong loạt mã hàng của bạn xem !
Có một mã không có (S) Nên mình đã bẫy lỗi luôn cho bạn .nên nó dài như thế hi hi!
Thanks

 

[vanbongtiensinh]

ban xem thử
C:\Documents and Settings\hien hien\Desktop\vanbong.xls
Cột giảm giá =if(and(month(F3)=1,day(F3)<16),left(G3,4)*90%&"đ",G3)
cột thành tiền=D3*left(H3,4)&"đ"

 

[quockhang]

mấy anh ơi giúp em vấn đề này
View attachment no hoc phi.rar

 

[cop_kh]

mấy anh ơi giúp em vấn đề này
View attachment 24383

Bạn yêu cầu mơ hồ quá, không biết đâu mà lần?

 

[quockhang]

ý em là dựa vào 2 bảng dò để tính số nợ của học sinh. vd học phí hk1 là 900000 mà chỉ đóng có 800000 thì nợ 100000 còn ko có tên trong danh sách đóng tiền tức là nợ nguyên 900000. em hỏi thêm có cách nào khi danh sách đóng tiền dài thêm thì phần nợ học phí cũng tự động cập nhật

 

[ndu96081631]

Cái này mà ghi rõ hàm nào SD cho mục đích j thì hay bít mí

Tại bạn không chịu tìm thôi... Ở đây có đủ:
http://www.giaiphapexcel.com/forum/showthread.php?t=10810

 

[motdai]

Giúp em tính tuổi ( 365 ngày 1 tuổi, không tính năm nhuận)
http://www.mediafire.com/?sharekey=1c1f9318e55dc8578c9e7c56ba37815ff13c3ab86c537612

 

[BNTT]

Giúp em tính tuổi ( 365 ngày 1 tuổi, không tính năm nhuận)
http://www.mediafire.com/?sharekey=1c1f9318e55dc8578c9e7c56ba37815ff13c3ab86c537612

Tôi không download được file của bạn. Nhưng nếu bạn chỉ cần tính 365 ngày thì lên một tuổi và không tính năm nhuận, bạn có thể dùng công thức này:

=INT((NOW()-A1)/365)​

Với A1 là ô chứa ngày tháng năm sinh của người cần tính tuổi.

 

[phat1987]

giúp mình bài này phần tính đơn giá và bảng thông kê, mình làm hoài k ra , thx
http://www.mediafire.com/download.php?xdncjtv0zln
forum up flie len k dc , các bạn vào đây down thử xem dc k

 

[volga]

giúp mình bài này phần tính đơn giá và bảng thông kê, mình làm hoài k ra , thx
http://www.mediafire.com/download.php?xdncjtv0zln
forum up flie len k dc , các bạn vào đây down thử xem dc k

Bạn tham khảo bài giải này nhe !chưa thật gọn gàng cho mấy
Thân

 

[huuthang_bd]

Bạn tham khảo bài giải này nhe !chưa thật gọn gàng cho mấy
Thân

Xin ké 1 công thức dò đơn giá gọn hơn

=VLOOKUP(B5,$B$18:$D$20,2+(D5="lẻ"),)

 

[Hà Huy Duy]

Các bạn giải giúp tôi bài toán này với

Tính tổng nhiều điều kiện, tôi gửi bài trong file đính kèm

 

[cop_kh]

Tính tổng nhiều điều kiện, tôi gửi bài trong file đính kèm

Đáp án bài 1:
=SUMPRODUCT((C15:C277<>"VN")*((I15:I277="B12")+(I15:I277="HG")+(I15:I277="CL"))*((F15:F277<>"KHACH")*(F15:F277<>"OIL")*(F15:F277<>"CONTAINER")*(F15:F277<>"DTV")*(F15:F277<>"HOA CHAT"))*(G15:G277="XK")*(H15:H277))

 

[cop_kh]

Đáp án bài 2:
=SUMPRODUCT((D15:E277<>"")*(C15:C277="VN")*((G15:G277="XK")+(G15:G277="NK")))

 

[rosy84]

Giúp em làm bài này với

Em không biêt dùng công thức nào cả. Yêu cầu em đã dể ở trong bài rôi. thanks!!

 

[huuthang_bd]

Em không biêt dùng công thức nào cả. Yêu cầu em đã dể ở trong bài rôi. thanks!!

Mời bạn xem file đính kèm.

 

[cop_kh]

Như vậy bạn làm như sau nhé:

1. Chọn chức năng AutoFilter cho hàng tiêu đề (Hàng 2 trong bảng tính của bạn).
2. Copy công thức tại hàng 4 (C4:H4).
3. Tại nút Filter của d1 (hay d2) chọn Blank.
4. Tô đen vùng cần dán công thức, Enter. Xong

Bạn thử đúng ý mình chưa.

 

[huuthang_bd]

Không phải đâu anh huuthang_bd a, ý em không phải như thế, em có nhiều bản ghi lắm, không làm từng cột một được.

Tôi đâu có làm từng cột đâu. Tôi dùng AutoFilter sau đó paste công thức mà. Nếu bạn không thích cách đó thì làm ra một bảng khác. Xem file đính kèm.
Nhập công thức vào ô J3 rồi FillRight, FillDown.

 

[Hà Huy Duy]

Hỏi bạn cop-kh: Tôi có cơ sở dữ liệu ở một sheet, lập công thức ở sheet khác có được không? Vì có trường hợp tôi lập công thức giồng như bạn hướng dẫn ở hai sheet link với nhau nhưng không được?

 

[rosy84]

Không cần lấy lớn >0 đâu anh ơi, anh có thể lấy cả giá trị âm giúp em được không?

Em nghĩ làm thế không ổn , em đã làmmột macro rồi chạy tốt nhưng có tới 24000 dòng lên em muốn dùng công thức cho nhanh thôi

 

[suvival198]

minh muốn hỏi bài tập này chút,minh biết cách dùng làm Vlookup và Hlookup nhưng ko biết cách kết hợp vs hàm IF để kết hợp các đk , bạn nào chỉ dùm minh vs >"<

 

[salam]

minh muốn hỏi bài tập này chút,minh biết cách dùng làm Vlookup và Hlookup nhưng ko biết cách kết hợp vs hàm IF để kết hợp các đk , bạn nào chỉ dùm minh vs >"<

Bạn xem CT dưới nhé.

=VLOOKUP(HLOOKUP(LEFT(A3,1),$I$9:$K$10,2,0),$H$16:$K$18,IF(RIGHT(A3,2)*1=10,2,IF(RIGHT(A3,2)*1=11,3,4)),0)

 

[BNTT]

minh muốn hỏi bài tập này chút,minh biết cách dùng làm Vlookup và Hlookup nhưng ko biết cách kết hợp vs hàm IF để kết hợp các đk , bạn nào chỉ dùm minh vs >"<

Bạn tận dụng kết quả của cột B (tên hãng) và cột C (phân khối) vào công thức cho cột D (tên xe), là thấy nó dễ liền. Ví dụ:

Cột B [ô B3]: =HLOOKUP(LEFT(A3), $I$9:$K$10, 2, 0)

Cột C [ô C3]: =VLOOKUP(RIGHT(A3,2)*1, $H$3:$I$5, 2, 0)​

Bây giờ vận dụng kết quả ở B3 và C3 vào trong D3:

Cột D [ô D3]: =VLOOKUP(B3, $H$16:$K$18, IF(C3=100, 2, IF(C3=110, 3, 4)), 0)
​

Hoặc nếu thích xài HLOOKUP thì đổi ngược lại, nhưng sẽ dài hơn:

Cột D [ô D3]: =HLOOKUP(C3, $I$15:$K$18, IF(B3="Honda", 2, IF(B3="Suzuki", 3, 4)), 0)
​

 

[suvival198]

thank bạn, cho mình hỏi thêm chút nữa là nếu với ô mã sản phầm chỉ có 2 thành phần thi mình dùng hàm Vlookup dể tìm cho phần dầu, và Hlookup dể tìm cho phần sau, vậy vs 1 ô mã có 3 thành phần thì muốn tìm đc giá trị ở giữa mình làm thế nào :|, cụ thể là ví dụ này , mình ko biết cách lấy gia trị cho ô số ngày thuê

 

[BNTT]

thank bạn, cho mình hỏi thêm chút nữa là nếu với ô mã sản phầm chỉ có 2 thành phần thi mình dùng hàm Vlookup dể tìm cho phần dầu, và Hlookup dể tìm cho phần sau, vậy vs 1 ô mã có 3 thành phần thì muốn tìm đc giá trị ở giữa mình làm thế nào :|, cụ thể là ví dụ này , mình ko biết cách lấy gia trị cho ô số ngày thuê

Số ngày thuê = Ngày thuê - Ngày trả + 1
Vậy thôi, có giá trị ở giữa gì đâu bạn ?

 

[suvival198]

ko phải, ý mình là mã khách là C2D, thì cái sô 2 này là số lượng đĩa thuê, vậy mìhh làm thế nào dể lấy đc giá trị này ra :|

 

[BNTT]

ko phải, ý mình là mã khách là C2D, thì cái sô 2 này là số lượng đĩa thuê, vậy mìhh làm thế nào dể lấy đc giá trị này ra :|

Ủa, vậy sao bài trên bạn lại hỏi số ngày thuê ?
Muốn lấy con số 2 từ C2D thì dùng hàm MID:
Cú pháp: =MID(chuỗi, bắt đầu từ vị trí thứ mấy, lấy bao nhiêu chữ)
Để lấy con số 2 (1 con số) từ C2D (nằm ở vị trí thứ 2): =MID(ô chứa C2D, 2, 1)*1
Phải nhân thêm với 1 để con số 2 đó trở thành số (vì hàm MID trả về giá trị text)

------------------------------------------------
Làm luôn cho bạn đây:

[F3]: =E3-D3+1

[G3]: =VLOOKUP(LEFT(C3), $A$11:$B$13, 2, 0)

[H3]: =IF(RIGHT(C3)="D", "DVD", "VCD")

[I3]: =MID(C3, 2, 1)*1

[J3]: =INDEX($C$11:$D$13, MATCH(G3, $B$11:$B$13, 0), MATCH(H3, $C$10:$D$10, 0))
hoặc =VLOOKUP(G3, $B$11:$D$13, IF(H3="DVD", 2, 3))

[K3]: =I3*J3​

 

[thuanduc08]

bài tập này thì dùng hàm nào?

Đây là một bài toán tính thể lực học sinh cấp I nhưng tôi làm mãi mà không được, các bạn giúp tôi với nhé.

Bài này tôi gửi từ tháng 4 nhưng mãi không thấy hồi âm, nay tôi gửi lại xin các bạn trên DĐ cùng giúp. Xin cảm ơn.

 

[khieukienag]

Thể lực

Đây là một bài toán tính thể lực học sinh cấp I nhưng tôi làm mãi mà không được, các bạn giúp tôi với nhé.


Còn hàm tính tổng có điều kiện này nữa sao tôi làm cứ bị báo lỗi #value!
=SUM(IF($F$8:$F$55="Nữ",1,0)) thế là thế nào vậy các bạn, trước đó tớ vẫn làm được mà. Xin cảm ơn nhiều

Tôi thường làm:
=SUMIF($F$8:$F$55="Nữ",$K$8:$K$55)

 

[kmcuong]

cho hỏi đôi chút về hàm sumif

mình mù tịt về exel, gặp chỗ này mắc hỏi các bạn đôi câu mong anh em giúp đỡ.
Cho một danh sách khoảng 20 người có độ tuổi từ 10-50 tuổi, tính tổng số người trong độ tuổi >15 và nhỏ hơn 45.
Mong anh em giúp đỡ

 

[hoangminhtien]

mình mù tịt về exel, gặp chỗ này mắc hỏi các bạn đôi câu mong anh em giúp đỡ.
Cho một danh sách khoảng 20 người có độ tuổi từ 10-50 tuổi, tính tổng số người trong độ tuổi >15 và nhỏ hơn 45.
Mong anh em giúp đỡ

Giả sử vùng B1:B20 là vùng chứa tuổi. để tính tổng số người trong độ tuổi >15 và nhỏ hơn 45 thì bạn dùng công thức

=SUMPRODUCT((B1:B20>15)*(B1:B20<45))

 

[salam]

mình mù tịt về exel, gặp chỗ này mắc hỏi các bạn đôi câu mong anh em giúp đỡ.
Cho một danh sách khoảng 20 người có độ tuổi từ 10-50 tuổi, tính tổng số người trong độ tuổi >15 và nhỏ hơn 45.
Mong anh em giúp đỡ

Bạn dùng thử ct dưới xem"
Với DS là danh sách.

=COUNTIF(DS,">15")-COUNTIF(DS,">44")

 

[anhvu24]

Giúp mình làm bài tập về hàm if với

ai giúp mình làm bài tập này với:



6.chính hãng sam sung bảo hành 24 tháng, Chính hãng nokia bảo hành 12 tháng .ngược lại bảo hành 6 tháng. Ở đây dùng hàm if thế nào đây
7.Lọc các mặt hàng chính hãng Nokia
8.Sắp xếp bảng tính tăng dần theo ngày bán nếu trùnhgg giảm dần theo sô lượng

 

[huuthang_bd]

ai giúp mình làm bài tập này với:



6.chính hãng sam sung bảo hành 24 tháng, Chính hãng nokia bảo hành 12 tháng .ngược lại bảo hành 6 tháng. Ở đây dùng hàm if thế nào đây
7.Lọc các mặt hàng chính hãng Nokia
8.Sắp xếp bảng tính tăng dần theo ngày bán nếu trùnhgg giảm dần theo sô lượng

6. Công thức phổ thông:

=IF(AND(E4="Sam sung",G4="Chính hãng"),24,IF(AND(E4="Nokia",G4="Chính hãng"),12,6))

Công thức rút gọn:

=IF(G4<>"Chính Hãng",6,IF(E4="Sam sung",24,12))

7. Sử dụng AutoFilter, Nhãn hiệu = Nokia, Loại hàng = Chính hãng
8. Sắp sếp lần lượt các cột theo thứ tự: Số lượng (giảm dần), Ngày bán (tăng dần).

 

[anhvu24]

6. Công thức phổ thông:

=IF(AND(E4="Sam sung",G4="Chính hãng"),24,IF(AND(E4="Nokia",G4="Chính hãng"),12,6))

Công thức rút gọn:

=IF(G4<>"Chính Hãng",6,IF(E4="Sam sung",24,12))

7. Sử dụng AutoFilter, Nhãn hiệu = Nokia, Loại hàng = Chính hãng
8. Sắp sếp lần lượt các cột theo thứ tự: Số lượng (giảm dần), Ngày bán (tăng dần).

Cả 2 công thức bạn đưa ra đều không được.Excel nó báo lỗi. .Công thức IF(E4="Sam sung",24,12) và IF(AND(E4="Nokia",G4="Chính hãng"),12,6) là sai bạn ạ chỗ đó phải là 1 value chứ không phải là 1 biểu thức logic.

 

[huuthang_bd]

Cả 2 công thức bạn đưa ra đều không được.Excel nó báo lỗi. .Công thức IF(E4="Sam sung",24,12) và IF(AND(E4="Nokia",G4="Chính hãng"),12,6) là sai bạn ạ chỗ đó phải là 1 value chứ không phải là 1 biểu thức logic.

Không biết nói gì hơn. Công thức có sẵn bạn nhập không đúng thì đừng có đi bắt lỗi người khác.

 

[logica]

Anh huuthang_bd làm đúng rồi mà!
Công thức hàm if theo mình nghĩ có thể như vầy dễ hỉu nhưng dỏm hơn:
=IF($G4=$G$18;IF($E4=$F$19;12;IF($E4=$F$20;24));6)
ko bit có phải như vậy ko?

 

[anhvu24]

Không biết nói gì hơn. Công thức có sẵn bạn nhập không đúng thì đừng có đi bắt lỗi người khác.

à biết chỗ sai rồi.Công thức bạn đưa cho mình không phải là ; mà là , nên Êxcl báo lỗi. Sửa lại thành ; thì hết.

=IF(AND(E4="Sam sung",G4="Chính hãng"),24,IF(AND(E4="Nokia",G4="Chính hãng"),12,6)) -->
=IF(AND(E4="Sam sung",G4="Chính hãng");24;IF(AND(E4="Nokia",G4="Chính hãng"),12,6))

 

[ptlong04x1]

; cũng được mà , cũng được, bài của huuthang_bd là hoàn toàn đúng, bạn xem thêm ở đây để hiểu rõ hơn.
http://www.giaiphapexcel.com/forum/showpost.php?p=149092&postcount=12

 

[cuongnavn]

Nhờ giúp đỡ Bài Tập Này

Nhờ mọi người giúp đỡ bài tập này? Làm sao để hiển thị được "Mã bị sai". Làm thế nào cũng không được, kết hợp với hàm if so sánh thì nó ra toàn mã bị sai hết.

 

[hoangdanh282vn]

Nếu để kiểm tra lỗi khi bóc dữ liệu thì bạn dùng hàm kiểm tra lỗi như ISNA, ISERROR..

Công thức tại ô C3 :

=IF(ISNA(VLOOKUP(B3,Sheet1!$B$14:$C$25,2,0)),"Mã Bị Sai",VLOOKUP(B3,Sheet1!$B$14:$C$25,2,0))