Chuyên đề giải đáp các bài tập

[BNTT]

Thi chứng chỉ A

Kết quả là Rớt trong trường hợp sau:

• ĐTB < 5
• Điểm Windows < 5, hoặc Điểm (Word + PowerPoint)/5<5 hoặc Excel < 5
• Bỏ thi 1 môn (Môn thi ko có đỉểm)

Bạn phân tích theo từng cái một, rồi đưa vào trong một hàm OR:

1. ĐTB<5: quá dễ
   
   
2. Điểm Windows < 5, hoặc Điểm (Word + PowerPoint)/5<5 hoặc Excel < 5:
   
   Cái này, chắc bạn gõ sai, vì nếu (Word + PowerPoint)/5 thì lúc nào cũng nhỏ hơn 5, nghĩa là lúc nào cũng rớt! Chia cho 2 thôi, phải không bạn?
   OR(Windows<5, (Word+PowerPoint)/2<5, Excel<5)
   
   
3. Bỏ thi 1 môn (Môn thi ko có đỉểm):
   
   Bạn cho nó đếm hết các ô có chứa điểm thi mà lớn hơn 0, nếu tổng số ô có điểm thi nhỏ hơn số môn thi thì không tính.
   Hàm đếm theo điều kiện là COUNTIF, tổng số môn thi là 4:
   COUNTIF(C4:F4,">0")<4

Gom cả ba cái lại trong một hàm OR, rồi lồng vào trong một hàm IF, là xong:

=IF(OR(ĐTB<5, OR(Windows<5, (Word+PowerPoint)/2<5, Excel<5), COUNTIF(C4:F4,">0")<4), "Rớt", "Không rớt")

=IF(OR(G4<5, OR(C4<5, (D4+E4)/2<5, F4<5), COUNTIF(C4:F4,">0")<4), "Rớt", "Không rớt")​

OK ? Tại bạn không nói rằng nếu như không Rớt thì sao nên tôi để đại vào đó là "Không rớt", nếu không thích chữ đó thì bạn sửa lại chữ khác nghe.

Các công thức trên vẫn có thể làm cho ngắn hơn nữa, nhưng ở đây tôi chỉ dùng kiểu đơn giản nhất cho bạn dễ hiểu.

 

[0939594694]

ko phải mình gõ sai . mà đề bài cho sai . mình đánh chính xác theo đề đấy .( W + P )/5 đàng hoàng

 

[BNTT]

ko phải mình gõ sai . mà đề bài cho sai . mình đánh chính xác theo đề đấy .

Nếu đề cho sai thì cứ làm theo đề đi, rồi thầy giáo hỏi tại sao ai cũng rớt hết, thì nói thầy xem lại cái đề.
Dễ thôi mà: Sửa /2 thành /5 trong công thức cho nó giống cái đề.

 

[BNTT]

còn 2 bài kia nữa . bạn có thể giúp mình không ?

Nó đây. Bạn chịu khó làm tí đi, rồi có gì không hiểu thì hỏi, chứ làm hết dùm bạn như vầy thì đến bao giờ bạn mới biết tự làm ?

 

[member_vip]

nhờ giải hộ bài toán quản lý khách sạn

nhờ các cao thủ giải hộ em bài này với ạ

 

[BNTT]

nhờ các cao thủ giải hộ em bài này với ạ

Nhờ cao thủ thì chơi công thức kiểu cao thủ luôn nha.
Mời bạn xem file.

 

[ndu96081631]

Nhờ cao thủ thì chơi công thức kiểu cao thủ luôn nha.
Mời bạn xem file.

Công thức này:

=VLOOKUP(LEFT(C2),$C$13:$F$15,MATCH("tầng "&RIGHT(C2),$C$12:$F$12,0),0)

Có thể sửa lại:

=VLOOKUP(LEFT(C2),$C$13:$F$15,RIGHT(C2)+1,0)

Và công thức này:

=VLOOKUP(LEFT(C2),$C$13:$I$15,MATCH("tầng "&RIGHT(C2),$G$12:$I$12,0)+4,0)

Có thể sửa lại:

=VLOOKUP(LEFT(C2),$C$13:$I$15,RIGHT(C2)+4,0)

Mới gọn hơn chứ ---> Trừ phi bảng tra cứu được sắp xếp theo kiểu khác, lúc ấy ta hãy dùng MATCH vẫn chưa muộn
Còn công thức:

=SUMPRODUCT((LEFT(C2:C7)=C19)*$J$2:$J$7)

thì hình như quên $
Như thế này đúng hơn:

=SUMPRODUCT((LEFT($C$2:$C$7)=C19)*$J$2:$J$7)

Và mặc khác ta vẫn có thể dùng SUMIF... như vầy đây:

=SUMIF($C$2:$C$7,$C19&"*",$J$2:$J$7)

 

[08dqt02]

VlOOUP ???? Cùng học nhé . thank!

cột chức vụ dò tìm chức vụ dựa vào kí tự đầu của MA NHÂN ViÊN và Bảng 1
Cột phụ cấp nếu ký tự thứ 3 từ trái sang phải của mả nv là"T" là phụ cấp = 0 , ngược lại dò tìm phụ cấp dựa vào kí tự đầu của MÃ NV và Bảng 1
Hệ Số Lương :nếu kí tự thứ 3 của mã nv là T thì hệ số lương là 0.75 ngược lại dò tìm trong bảng 2 với giá trị đó là 2 ký tự cuối của mã NV được hiểu là số năm công tác
Ai biết thì chỉ giúp mình , mình củng đang suy nghỉ mà ko ra ???? CHÂN THÀNH CẢM ƠN AE!!​

 

[BNTT]

Giải ở đây luôn nha:

cột chức vụ dò tìm chức vụ dựa vào kí tự đầu của MA NHÂN ViÊN và Bảng 1

= VLOOKUP(LEFT(A3), $A$16:$B$20, 2, 0)​

Cột phụ cấp nếu ký tự thứ 3 từ trái sang phải của mả nv là"T" là phụ cấp = 0 , ngược lại dò tìm phụ cấp dựa vào kí tự đầu của MÃ NV và Bảng 1

= (MID($A3, 3, 1) > "T") * VLOOKUP(LEFT($A3), $A$17:$C$21, 3, 0)

Nhưng Bảng 1 trong file bạn gửi lên hổng có phụ cấp bằng bi nhiêu hết trơn...​

Hệ Số Lương :nếu kí tự thứ 3 của mã nv là T thì hệ số lương là 0.75 ngược lại dò tìm trong bảng 2 với giá trị đó là 2 ký tự cuối của mã NV được hiểu là số năm công tác

= IF(MID(A3, 3, 1) = "T", 0.75, HLOOKUP(RIGHT(A3, 2) * 1, $F$15:$I$16, 2))​

Ai biết thì chỉ giúp mình , mình củng đang suy nghỉ mà ko ra ???? CHÂN THÀNH CẢM ƠN AE!!​

Tôi có xóa môt hàng (hàng 12) tại vì trong ô A12 bạn nhập sai, tên nhân viên là "ÉT".

 

[cadafi]

cột chức vụ dò tìm chức vụ dựa vào kí tự đầu của MA NHÂN ViÊN và Bảng 1
Cột phụ cấp nếu ký tự thứ 3 từ trái sang phải của mả nv là"T" là phụ cấp = 0 , ngược lại dò tìm phụ cấp dựa vào kí tự đầu của MÃ NV và Bảng 1
Hệ Số Lương :nếu kí tự thứ 3 của mã nv là T thì hệ số lương là 0.75 ngược lại dò tìm trong bảng 2 với giá trị đó là 2 ký tự cuối của mã NV được hiểu là số năm công tác
Ai biết thì chỉ giúp mình , mình củng đang suy nghỉ mà ko ra ???? CHÂN THÀNH CẢM ƠN AE!!​

Bạn nên sửa lại tiêu đề cho rõ ràng! Đây là câu hỏi bạn nhờ người khác trả lời! Và vấn đề này không phải là mới nếu bạn chịu khó search trên diễn đàn!

Cột [chức vụ]:

E3 = VLOOKUP(LEFT($A3),$A$17:$B$21,2,0)

Sau đó bạn fill công thức xuống

Cột [phụ cấp]:

F3 = (MID($A3,3,1)<>"T")*VLOOKUP(LEFT($A3),$A$17:$C$21,3,0)

Sau đó bạn fill công thức xuống

Cột [hệ số lương]:
Do bạn không nói rõ các mốc điều kiện như thế nào, cho nên tôi mặc định như sau

Số năm công tác|>=1|>=4|>=8|>=12
HS lương|1|1.15|1.3|1.5

G3 = CHOOSE((MID($A3,3,1)<>"T")--1,0.75,HLOOKUP(--RIGHT($A3,2),$F$16:$I$17,2,1))

Sau đó bạn fill công thức xuống

Ngoài ra, tôi đoán là ký tự thí hai trong mã quy định giới tính, do đó cột [Phái]:

C3 = CHOOSE(MID($A3,2,1)--1,"Nam","Nữ")

Sau đó bạn fill công thức xuống

Bạn xem thêm file đính kèm!

 

[ndu96081631]

cột chức vụ dò tìm chức vụ dựa vào kí tự đầu của MA NHÂN ViÊN và Bảng 1
Cột phụ cấp nếu ký tự thứ 3 từ trái sang phải của mả nv là"T" là phụ cấp = 0 , ngược lại dò tìm phụ cấp dựa vào kí tự đầu của MÃ NV và Bảng 1
Hệ Số Lương :nếu kí tự thứ 3 của mã nv là T thì hệ số lương là 0.75 ngược lại dò tìm trong bảng 2 với giá trị đó là 2 ký tự cuối của mã NV được hiểu là số năm công tác
Ai biết thì chỉ giúp mình , mình củng đang suy nghỉ mà ko ra ???? CHÂN THÀNH CẢM ƠN AE!!​

Câu 1:

=VLOOKUP(LEFT($A3),$A$16:$B$21,2,0)

Câu 2: không hiểu

dò tìm phụ cấp dựa vào kí tự đầu của MÃ NV và Bảng 1

Bảng 1 có gì đâu mà dò (chỉ có Chức vụ thôi)
Câu 3:

=IF(MID($A3,3,1)="T",0.75,HLOOKUP(RIGHT($A3,2)*1,$D$16:$I$17,2))

Với bài toán trên, ca_dafi dùng CHOOSE xem ra dài hơn IF đấy

 

[congaikhiyeu]

giúp mình làm bài tập này với nha

cám ơn bạn ... giúp mình nhan







View attachment Bai tap.xlsx

 

[ndu96081631]

cám ơn bạn ... giúp mình nhan

Bài này chỉ dùng VLOOKUP và SUMIF thôi mà
Giãi cho bạn đây!

 

[BNTT]

cám ơn bạn ... giúp mình nhan
View attachment 20683

Bạn xem thử có đúng ý bạn không?

 

[BNTT]

Bài này chỉ dùng VLOOKUP và SUMIF thôi mà
Giãi cho bạn đây!

Hic hic... Anh Ndu ơi, có 2 điều:

1. Ở bảng tham chiếu, nó xếp giá loại B trước loại A, nên công thức tìm đơn giá của anh bị "sập bẫy" rồi!

2. Số tiền giảm, anh còn thiếu điều kiện: trước ngày 10/2/2001 thì không giảm!

 

[ndu96081631]

Hic hic... Anh Ndu ơi, có 2 điều:

1. Ở bảng tham chiếu, nó xếp giá loại B trước loại A, nên công thức tìm đơn giá của anh bị "sập bẫy" rồi!

2. Số tiền giảm, anh còn thiếu điều kiện: trước ngày 10/2/2001 thì không giảm!

Uh... hồi nãy xem file mà quên kéo xuống dưới xem câu hỏi (tưởng không có câu hỏi chứ)
Thì sửa lại như BNTT vậy!

 

[nhoccon_4mat]

tính tổng

Nhờ các anh (chị) giúp dùm em cái này nha. Em ko bít làm sao tính tổng giá tiền cho từng loại hàng. Em có gửi theo file đính kèm anh (chị) xem giúp em nha. Thanks

 

[viendo]

Nhờ các anh (chị) giúp dùm em cái này nha. Em ko bít làm sao tính tổng giá tiền cho từng loại hàng. Em có gửi theo file đính kèm anh (chị) xem giúp em nha. Thanks

Tại C21 bạn dùng cộng thức sau và fill xuống nhé :

C21=SUMIF($B$5:$B$14,$B21&"*",$J$5:$J$14)

 

[ZaceGL]

Nhờ các anh (chị) giúp dùm em cái này nha. Em ko bít làm sao tính tổng giá tiền cho từng loại hàng. Em có gửi theo file đính kèm anh (chị) xem giúp em nha. Thanks

Trên bảng dữ liệu chính bạn thêm cột Khu vực, dữ liệu cột này tính bằng LEFT(số điện kế)

Sau đó tính tổng tiền bên dưới bằng hàng SumIF là được mà.

 

[BNTT]

Nhờ các anh (chị) giúp dùm em cái này nha. Em ko bít làm sao tính tổng giá tiền cho từng loại hàng. Em có gửi theo file đính kèm anh (chị) xem giúp em nha. Thanks

Chỗ tính Tổng số tiền, bạn dùng SUMIF:

[A21] =SUMIF($B$5:$B$14, B21&"*", $J$5)​

Sẵn góp ý với bạn vài công thức. Bạn so sánh nhé:

Tính đơn giá:

Công thức của bạn:

=IF(RIGHT(B5,1)="1", HLOOKUP(LEFT(B5,1), Sheet1!$B$4:$F$6, 2, 0), HLOOKUP(LEFT(B5,1), Sheet1!$B$4:$F$6, 3, 0))
​

Công thức đề nghị:

=HLOOKUP(LEFT(B5), Sheet1!$B$4:$F$6, RIGHT(B5)+1, 0)​

Tính tiền trong định mức:

Công thức của bạn:

=IF((F5-E5)<D5, F5-E5, D5)*G5​

Công thức đề nghị:

=MIN(D5, F5-E5)*L5​

Tính góp ý cho bạn cái công thức tính tiền vượt định mức nữa, cái của bạn dài quá, nhưng không biết bạn muốn tính kiểu gì:

Khi nào thì bằng đơn giá * 1.5, khi nào thì bằng đơn giá * 2 ?​