Xin hàm chuyển số thành chuỗi ký tự

[BinhTam]

Chào các bạn,

Mình có cột A chứa các số nguyên, cột B=char(A1+64). Mình muốn cột B có giá trị giống cột trong bảng tính excel.

Tuy nhiên hàm này chỉ chuyển được 26 chữ cái.

Để chuyển số nguyên tiếp theo theo 27 thành AA, 28 thành AB,...

Rất mong nhận được công thức từ các bạn hoặc nếu đề tài này có rồi rất mong nhận được link tham khảo.

Thanks,
Tâm

 

[concogia]

Chào các bạn,

Mình có cột A chứa các số nguyên, cột B=char(A1+64). Mình muốn cột B có giá trị giống cột trong bảng tính excel.

Tuy nhiên hàm này chỉ chuyển được 26 chữ cái.

Để chuyển số nguyên tiếp theo theo 27 thành AA, 28 thành AB,...

Rất mong nhận được công thức từ các bạn hoặc nếu đề tài này có rồi rất mong nhận được link tham khảo.

Thanks,
Tâm

Công thức ở [B1]:

=SUBSTITUTE(ADDRESS(1,A1,2),"$1","")

kéo xuống
Thân

 

[ndu96081631]

Công thức ở [B1]:

=SUBSTITUTE(ADDRESS(1,A1,2),"$1","")

kéo xuống
Thân

Hoặc vầy cũng tương tự:

=SUBSTITUTE(ADDRESS(1,A1,4),1,"")

Ẹc... Ẹc...

 

[huuthang_bd]

Nếu bạn muốn số mã nhiều hơn thì thử công thức sau, tạo được đến mã XFD

=SUBSTITUTE(SUBSTITUTE(CELL("address",OFFSET($A$1,,ROW(A1)-1)),"$",""),1,"")

Nếu muốn số mã nhiều hơn thì bạn thử công thức sau cho ô A2 (A1 rỗng), số lượng mã không giới hạn

=IF(LEN(SUBSTITUTE(A1,"Z",""))=0,REPT("A",LEN(A1)+1),LEFT(REPLACE(A1,LEN(A1)-SUMPRODUCT(COUNTIF(A1,"*"&REPT("Z",ROW($1:$9)))),9,CHAR(CODE(MID(A1,LEN(A1)-SUMPRODUCT(COUNTIF(A1,"*"&REPT("Z",ROW($1:$9)))),1))+1)&REPT("A",9)),LEN(A1)))

 

[ndu96081631]

Nếu bạn muốn số mã nhiều hơn thì thử công thức sau, tạo được đến mã XFD

=SUBSTITUTE(SUBSTITUTE(CELL("address",OFFSET($A$1,,ROW(A1)-1)),"$",""),1,"")

Mình không hiểu lắm! Công thức bài 2 và 3 cũng chơi được đến XFD vậy
???

 

[huuthang_bd]

Mình không hiểu lắm! Công thức bài 2 và 3 cũng chơi được đến XFD vậy
???

À à, lúc nãy em nhầm.

 

[concogia]

Hoặc vầy cũng tương tự:

=SUBSTITUTE(ADDRESS(1,A1,4),1,"")

Ẹc... Ẹc...

Híc, đúng là "ẹct ẹct" thiệt

 

[BinhTam]

Thanks.

Mình đã tìm được công thức rồi chuyển số sang A-ZZ.
=IF(A1>26,CHAR(64+INT((A1-1)/26))&CHAR(65+MOD(A1-1,26)),CHAR(65+MOD(A1-1,26)))
Ý tưởng công thức này có thể chuyển sang code vba cho các ứng khác.

Have a nice working day!

 

[huuthang_bd]

Sao nhiều người cứ thích cái kiểu này nhỉ. Cần cái gì thì hỏi đúng như vậy có phải nhanh hơn không.

Function TaoMa(ByVal Num As Long) As String
Do While Num > 0
    TaoMa = ChrW(65 + ((Num - 1) Mod 26)) & TaoMa
    Num = (Num - 1) \ 26
Loop
End Function