Xin giúp đở về hàm thời gian (tiến độ)

Vongola104 · 26/4/23

Quy tắc làm việc là thời gian vào làm là từ 6h sáng đến 8h tối.
Đối với các công việc nếu khối lượng (giờ) vượt 8h tối thì sẽ bắt đầu thực hiện và cộng dồn vào 6h sáng hôm sau.
Mình đã viết công thức ở cột e nhưng đối với nhưng công việc có thời gian cộng dồn vượt quá 2 ngày thì công còn đúng nửa (các ô tô vàng)
Kính mong được các anh chị em diễn đàn giải đáp và giúp đở.

Phan Thế Hiệp · 27/4/23

Vongola104 đã viết:
Quy tắc làm việc là thời gian vào làm là từ 6h sáng đến 8h tối.
Đối với các công việc nếu khối lượng (giờ) vượt 8h tối thì sẽ bắt đầu thực hiện và cộng dồn vào 6h sáng hôm sau.
Mình đã viết công thức ở cột e nhưng đối với nhưng công việc có thời gian cộng dồn vượt quá 2 ngày thì công còn đúng nửa (các ô tô vàng)
Kính mong được các anh chị em diễn đàn giải đáp và giúp đở.

Thử công thức sau:

Mã:

E7=INT(C7)+CEILING((D7-(INT(C7)+5/6-C7)*24)/14,1)+1/4+(MOD(ROUND((D7-(INT(C7)+5/6-C7)*24)-1,2),14)+1)/24

Fill xuống.

Thân

Vongola104 · 27/4/23

Phan Thế Hiệp đã viết:
Thử công thức sau:

Mã:

E7=INT(C7)+CEILING((D7-(INT(C7)+5/6-C7)*24)/14,1)+1/4+(MOD((D7-(INT(C7)+5/6-C7)*24)-1,14)+1)/24

Fill xuống.

Thân

Rất cảm ơn anh đã giúp đở ạ. Công thức hoạt động đúng rồi ạ

Vongola104 · 28/4/23

Phan Thế Hiệp đã viết:
Thử công thức sau:

Mã:

E7=INT(C7)+CEILING((D7-(INT(C7)+5/6-C7)*24)/14,1)+1/4+(MOD(ROUND((D7-(INT(C7)+5/6-C7)*24)-1,2),14)+1)/24

Fill xuống.

Thân

Em mới gặp 1 sai sót của công thức này, nhờ các anh chị em hoàn thiện giúp em ạ

Thời gian bắt đầu	Khối lượng công việc (giờ)	Thời gian kết thúc
28/03 19:30	1	29/03 20:30
28/03 17:30	2.6	29/03 20:06

Khi thời gian công lại nằm trong khoảng lớn hơn 8h tối và bé hơn 9h tối thì kết quả bị sai (dư 1 ngày)
Mong được mọi người giúp đở

huutrang93 · 28/4/23

Vongola104 đã viết:
Em mới gặp 1 sai sót của công thức này, nhờ các anh chị em hoàn thiện giúp em ạ

Thời gian bắt đầu Khối lượng công việc
(giờ) Thời gian kết thúc
28/03 19:30 1 29/03 20:30
28/03 17:30 2.6 29/03 20:06

Khi thời gian công lại nằm trong khoảng lớn hơn 8h tối và bé hơn 9h tối thì kết quả bị sai (dư 1 ngày)
Mong được mọi người giúp đở

=IF((C8+D8/24)<=(INT(C8)+20/24);C8+D8/24;INT(C8)+6/24+ROUNDUP((((D8/24)-(INT(C8)+20/24-C8))/(14/24));0)+MOD(((D8/24)-(INT(C8)+20/24-C8));(14/24)))

Thử cái này xem

LmoovoenX · 28/4/23

Thử công thức sau xem sao bạn

Mã:

E7=C7+D7/24+MAX(0,INT((D7/24-20/24+C7-INT(C7))/14*24)+1)*10/24

Đang bị lỗi cái kết thúc lúc 20h thì kết quả là 6h sáng hôm sau. Bạn thử xem các trường hợp khác ổn không, để mình sửa.

Mã:

=C7+D7/24+max(0,ROUNDUP((D7/24-20/24+C7-int(C7))/14*24,0))*10/24

Phan Thế Hiệp · 28/4/23

Vongola104 đã viết:
Em mới gặp 1 sai sót của công thức này, nhờ các anh chị em hoàn thiện giúp em ạ

Thời gian bắt đầu Khối lượng công việc
(giờ) Thời gian kết thúc
28/03 19:30 1 29/03 20:30
28/03 17:30 2.6 29/03 20:06

Khi thời gian công lại nằm trong khoảng lớn hơn 8h tối và bé hơn 9h tối thì kết quả bị sai (dư 1 ngày)
Mong được mọi người giúp

Cảm ơn bạn đã kiểm tra lại, và phát hiện ra lỗi trong công thức.

Bạn chỉnh theo công thức sau:

Mã:

E7=INT(C7)+CEILING((D7-(INT(C7)+5/6-C7)*24)/14,1)+1/4+TEXT(MOD(ROUND((D7-(INT(C7)+5/6-C7)*24),2),14),"0.00;;\14")/24

Bạn xem lại xem sao nha!

Thân

cantl · 28/4/23

Hic, đầu óc em không thể có được tư duy chuẩn chỉnh như các bác nên em cứ suy nghĩ kiểu thật nông dân, nên hàm nó rất là luẩn quẩn như mớ bòng bong. Nhưng mà cái món thời gian này hay phết cơ.

Mã:

=IF(C7+D7/24<=INT(C7)+$D$2,C7+D7/24,SUM(INT(C7)+$D$1,ROUNDUP((C7+D7/24-(INT(C7)+$D$2))/(14/24),0),MOD((C7+D7/24-(INT(C7)+$D$2)),14/24)))

Bài đã được tự động gộp: 28/4/23

huutrang93 đã viết:
=IF((C8+D8/24)<=(INT(C8)+20/24);C8+D8/24;INT(C8)+6/24+ROUNDUP((((D8/24)-(INT(C8)+20/24-C8))/(14/24));0)+MOD(((D8/24)-(INT(C8)+20/24-C8));(14/24)))

Thử cái này xem

Suy nghĩ nông dân giống tớ.

cantl · 28/4/23

LmoovoenX đã viết:
C7+D7/24

Công thức ngắn gọn, nhưng nhìn vào đã thấy cái tổng này thì có vẻ hơi run run. Hiện thì các kết quả đều đúng nhưng vẫn có gì đó run run.

LmoovoenX · 28/4/23

cantl đã viết:
Công thức ngắn gọn, nhưng nhìn vào đã thấy cái tổng này thì có vẻ hơi run run. Hiện thì các kết quả đều đúng nhưng vẫn có gì đó run run.

Thì giờ trong excel nó cũng là số mà.
Cách mình làm theo nguyên lý sau:

Mỗi lần thời gian vượt quá 20h tối thì được tính cộng dồn và bắt đầu tính tiếp từ 6h ngày hôm sau, tức là được cộng thêm 10h (20h đến 6h).

Do đó, chỉ cần tính số lượng lần cộng thêm này, chính là hàm roundup sau đó.

Roundup nó làm tròn lên, nên có thể bỏ luôn hàm Max cũng được.

Mã:

=C7+D7/24+ROUNDUP((D7/24-20/24+C7-INT(C7))/14*24,0)*10/24

Cơ mà vẫn dính lỗi nếu giờ kết thúc đúng 20h, kết quả trả về 6h sáng hôm sau. Mình đang suy nghĩ giải quyết.

ptm0412 · 28/4/23

Như vầy mới gọi là nông dân:
Tính cho ngày đầu tiên trước. Nếu chưa vượt 20:00 thì là kết quả cuối,
Nếu vượt 20:00 thì chỉ tính đến 20:00, số còn dư:
- lấy số nguyên trong phép chia cho 14 giờ, đó là số ngày cộng thêm
- Lấy số dư trong phép chia cho 14 giờ, đó là số giờ cộng thêm, và cộng thêm 6 giờ (sáng).

cantl · 28/4/23

ptm0412 đã viết:
Như vầy mới gọi là nông dân:
Tính cho ngày đầu tiên trước. Nếu chưa vượt 20:00 thì là kết quả cuối,
Nếu vượt 20:00 thì chỉ tính đến 20:00, số còn dư:
- lấy số nguyên trong phép chia cho 14 giờ, đó là số ngày cộng thêm
- Lấy số dư trong phép chia cho 14 giờ, đó là số giờ cộng thêm, và cộng thêm 6 giờ (sáng).

Đúng cách tính em đấy bác.

Phan Thế Hiệp · 28/4/23

cantl đã viết:
Đúng cách tính em đấy bác.

Thử dữ liệu sau:
- Thời gian bắt đầu: 28/03 08:00
- KL Thời gian hoàn thành: 26 tiếng
==> Thời gian kết thúc là: 29/03 20:00

Xem file kèm.

Thân

ptm0412 · 29/4/23

Làm kiểu nông dân là phải làm từng bước sẽ ít sai:
Bước 1:
Tính cho ngày đầu tiên trước. Nếu chưa vượt 20:00 thì là kết quả cuối, nếu vượt 20:00 thì chỉ tính đến 20:00 (cột phụ)
H7 =MIN(INT(C7)+5/6,C7+D7/24)
Bước 2:
Số giờ còn lại
X = ROUND(D7/24 -(H7-C7),10)
(phải round để tránh sai số trên 10 số thập phân)

Nếu số giờ còn lại > 0

Số ngày cộng thêm:
= INT((X)/(14/24))+1 = INT((D7/24-(H7-C7))/(14/24))+1

Số giờ cộng thêm:
= MOD(X,14/24) = MOD(D7/24-(H7-C7),14/24)

Cộng thêm 6 giờ (sáng):
= INT(H7)+6/24

Công thức cuối:
I7 =IF(ROUND(D7/24 -(H7-C7),5)=0,H7,INT(H7)+6/24+MOD(D7/24-(H7-C7),14/24)+INT((D7/24-(H7-C7))/(14/24))+1)

SA_DQ · 29/4/23

Hình như cơ quan của chủ bài đăng đang áp dụng thời gian làm việc sai so với Bộ Luật lao động thì phải, nếu đang đứng chưn trên lãnh thổ VN?
& Nếu như vậy thì ai xưng là nông dân có thể được châm chước; Còn lại thì cần học lại Bộ luật này thêm 2 tiếng trong mỗi tuần làm việc!

Phan Thế Hiệp · 29/4/23

ptm0412 đã viết:
Làm kiểu nông dân là phải làm từng bước sẽ ít sai:
Bước 1:
Tính cho ngày đầu tiên trước. Nếu chưa vượt 20:00 thì là kết quả cuối, nếu vượt 20:00 thì chỉ tính đến 20:00 (cột phụ)
H7 =MIN(INT(C7)+5/6,C7+D7/24)
Bước 2:
Số giờ còn lại
X = ROUND(D7/24 -(H7-C7),10)
(phải round để tránh sai số trên 10 số thập phân)

Nếu số giờ còn lại > 0

Số ngày cộng thêm:
= INT((X)/(14/24))+1 = INT((D7/24-(H7-C7))/(14/24))+1

Số giờ cộng thêm:
= MOD(X,14/24) = MOD(D7/24-(H7-C7),14/24)

Cộng thêm 6 giờ (sáng):
= INT(H7)+6/24

Công thức cuối:
I7 =IF(ROUND(D7/24 -(H7-C7),5)=0,H7,INT(H7)+6/24+MOD(D7/24-(H7-C7),14/24)+INT((D7/24-(H7-C7))/(14/24))+1)

Hình như còn chút xíu ở đâu đó, nên nếu thử dữ liệu cũng như bài #13 đề cập, thì nó chưa thay đổi.

Thân

Bài đã được tự động gộp: 29/4/23

SA_DQ đã viết:
nếu đang đứng chưn trên lãnh thổ VN?

Dạ! Tình trạng của em "không đứng chưn" chắc phải học gấp hai lần bộ luật này, anh ơi!

Chúc anh ngày vui.
/-*+/

LmoovoenX · 29/4/23

SA_DQ đã viết:
Hình như cơ quan của chủ bài đăng đang áp dụng thời gian làm việc sai so với Bộ Luật lao động thì phải, nếu đang đứng chưn trên lãnh thổ VN?
& Nếu như vậy thì ai xưng là nông dân có thể được châm chước; Còn lại thì cần học lại Bộ luật này thêm 2 tiếng trong mỗi tuần làm việc!

Em còn không được áp dụng Bộ Luật lao động đây nè bác.

cantl · 29/4/23

Phan Thế Hiệp đã viết:
Thử dữ liệu sau:
- Thời gian bắt đầu: 28/03 08:00
- KL Thời gian hoàn thành: 26 tiếng
==> Thời gian kết thúc là: 29/03 20:00

Xem file kèm.

Thân

Em thấy nó bị lỗi do làm tròn excel không giống như người bình thường. Khả năng thế này sẽ không làm chủ được thời gian rồi bác ạ.
Em đang ngâm cứu hàm khác để làm tròn, luẩn quẩn mãi chưa ngon được nữa. :wallbash:

LmoovoenX · 29/4/23

cantl đã viết:
Em thấy nó bị lỗi do làm tròn excel không giống như người bình thường. Khả năng thế này sẽ không làm chủ được thời gian rồi bác ạ.
Em đang ngâm cứu hàm khác để làm tròn, luẩn quẩn mãi chưa ngon được nữa.

Muốn làm tròn giờ hình như chỉ cần đưa vô hàm text là được.

Vongola104 · 3/5/23

SA_DQ đã viết:
Hình như cơ quan của chủ bài đăng đang áp dụng thời gian làm việc sai so với Bộ Luật lao động thì phải, nếu đang đứng chưn trên lãnh thổ VN?
& Nếu như vậy thì ai xưng là nông dân có thể được châm chước; Còn lại thì cần học lại Bộ luật này thêm 2 tiếng trong mỗi tuần làm việc!

Dạ bên em đang làm ở ngoài công trường nên nhiều khi thời gian nó hơi khác ạ

Bài đã được tự động gộp: 3/5/23

Cám ơn các anh chị em đã giúp đỡ nhiệt tình ạ

Xin giúp đở về hàm thời gian (tiến độ)

Thành viên mới

File đính kèm

-⍟-

File đính kèm

Thành viên mới

Thành viên mới

File đính kèm

Thành viên mới

Thành viên tiêu biểu

-⍟-

File đính kèm

!!! Giải thoát !!!

!!! Giải thoát !!!

Thành viên tiêu biểu

Bad Excel Member

!!! Giải thoát !!!

-⍟-

File đính kèm

Bad Excel Member

/(hông là gì!

-⍟-

File đính kèm

Thành viên tiêu biểu

!!! Giải thoát !!!

Thành viên tiêu biểu

Thành viên mới