Tính tổng có điều kiện theo 1 hàng

[chungtl9x]

Xin các bác giúp em xử lý dạng bài tập này ạ.
Em có đính kèm xin các bác chỉ giúp.
Em cảm ơn trước ạ.

 

[Phan Thế Hiệp]

Xin các bác giúp em xử lý dạng bài tập này ạ.
Em có đính kèm xin các bác chỉ giúp.
Em cảm ơn trước ạ.

Thử:

L3=IF(SUM(G3:K3),IF(OR(INDEX(ISERROR(MATCH(G3:K3,N(IF({1},$A$2:$A$7)),)),)),"Sai","Đúng"),"")

Chỉ Enter, rồi fill xuống.

Thân

 

[Phuocam]

Công thức này dùng 6 hàm, chỉ Enter.

=IF(COUNT(G3:K3),IF(OR(INDEX(COUNTIF($A$3:$A$7,G3:K3)+(G3:K3="")=0,0)),"Sai","Đúng"),"")

 

[Phan Thế Hiệp]

Xin các bác giúp em xử lý dạng bài tập này ạ.
Em có đính kèm xin các bác chỉ giúp.
Em cảm ơn trước ạ.

Hình như không phải chỉ tạo công thức tại cột "Ghi chú", mà bạn còn muốn tính tổng!?

Ví dụ ở đây là nó chỉ cộng đơn hàng 1, 2 và 4 thôi

E2=SUMPRODUCT(SUMIF(A3:A7,(L3:L21="Đúng")*G3:K21,C3:C7))

Enter.

Thân

 

[chungtl9x]

Cảm ơn bác Phan Thế Hiệp và bác Phuocam đã giúp đỡ. Nhưng chưa đúng ý em lắm ạ.
Em xin đính kèm lại để các bác rõ hơn điều em muốn nói ạ.

 

[Phan Thế Hiệp]

Cảm ơn bác Phan Thế Hiệp và bác Phuocam đã giúp đỡ. Nhưng chưa đúng ý em lắm ạ.
Em xin đính kèm lại để các bác rõ hơn điều em muốn nói ạ.View attachment 210703

Tôi dùng công thức của anh @phuocam, bổ sung thêm đoạn công thức theo yêu cầu mới của bạn:
Thử: (dùng cho excel từ 2010 trở lên)

L3=IF(COUNTIF(G3:K3,"<>"),IF(OR(INDEX(COUNTIF($B$3:$B$7,G3:K3)+(G3:K3="")=0,),AGGREGATE(14,6,COUNTIF(G3:K3,$B$3:$B$7),1)>1),"Sai","Đúng"),"")
Hoặc
L3=IF(COUNTIF(G3:K3,"<>"),IF(OR(INDEX(COUNTIF($B$3:$B$7,G3:K3)+(G3:K3="")=0,),INDEX(COUNTIF(G3:K3,$B$3:$B$7)>1,)),"Sai","Đúng"),"")

Enter fill xuống.
Hoặc:

L3=IF(COUNTIF(G3:K3,"<>"),IF(OR(COUNTIF($B$3:$B$7,G3:K3)+(G3:K3="")=0,COUNTIF(G3:K3,$B$3:$B$7)>1),"Sai","Đúng"),"")
C3=SUM(COUNTIF(B3,IF($L$3:$L$21="Đúng",$G$3:$K$21)))

Kết thúc bằng Ctrl+Shift+Enter, rồi fill xuống.

Thân