Nhờ các thày giúp cho vài ví dụ về truyền tham số cho thủ tục Sub (hoặc hàm Function)

Liên hệ QC
D

Dauthivan

Thành viên tiêu biểu
Tham gia
15/8/08
Bài viết
565
Được thích
327
Em đang nghiên cứu về truyền tham số bằng giá trị (byVal tức Byvalue), em có tìm đọc trên diễn đàn thì hầu hết nói rất nhanh vấn đề này, chính vì vậy em nhờ mọi người giúp em:

- Tại sao lại phải cần thiết truyền tham số.

- Giúp em một vài ví dụ để em hiểu về "cách truyền" của nó

Xin đa tạ các thày
 
Sắp xếp theo thời gian sắp xếp theo bầu chọn
Em làm theo For...Next mà không được, xin sửa lại đúng giúp em với ah.

PHP: 
Sub Filter(ByVal sArray As Range)
    Dim SubArr, Arr, i As Long, j As Long, kk As Long
    SubArr = sArray
    Set Dic = CreateObject("Scripting.Dictionary")
    ReDim Arr(1 To UBound(SubArr, 1) * UBound(SubArr, 2), 1 To 1)
    For j = 1 To UBound(SubArr, 1)
        For j = 1 To UBound(Arr, 2)
            If SubArr(i, j) <> "" Then
                Tmp = SubArr(i, j)
                If Not Dic.Exists(Tmp) Then
                    kk = kk + 1
                    Dic.Add Tmp, kk
                    Arr(kk, 1) = Tmp
                End If
            End If
        Next j
    Next i
    Sheets("sheet2").[A1].Resize(kk).Value = Arr
End Sub

PHP: 
Sub Main()
    Dim sArray As String
    sArray = Range("A1:B1000")
    Filter sArray
End Sub
 
Upvote 0
Dauthivan đã viết:
Em làm theo For...Next mà không được, xin sửa lại đúng giúp em với ah.

PHP: 
Sub Filter(ByVal sArray As Range)
    Dim SubArr, Arr, i As Long, j As Long, kk As Long
    SubArr = sArray
    Set Dic = CreateObject("Scripting.Dictionary")
    ReDim Arr(1 To UBound(SubArr, 1) * UBound(SubArr, 2), 1 To 1)
    For j = 1 To UBound(SubArr, 1)
        For j = 1 To UBound(Arr, 2)
            If SubArr(i, j) <> "" Then
                Tmp = SubArr(i, j)
                If Not Dic.Exists(Tmp) Then
                    kk = kk + 1
                    Dic.Add Tmp, kk
                    Arr(kk, 1) = Tmp
                End If
            End If
        Next j
    Next i
    Sheets("sheet2").[A1].Resize(kk).Value = Arr
End Sub

PHP: 
Sub Main()
    Dim sArray As String
    sArray = Range("A1:B1000")
    Filter sArray
End Sub
Nhấp chuột vào đây để mở rộng...
Sai mấy chổ:
For j = 1 To UBound(SubArr, 1) --> Lý ra phải là For i = 1 To UBound(SubArr, 1)
For j = 1 To UBound(Arr, 2) ---> Lý ra phải là For j = 1 To UBound(SubArr, 2)
Dim sArray As String ---> Ở trên khai báo sArray As Range sao ở dưới lại là String?
Ngoài ra, Sub Filter là sub viết ở mức tổng quát, vậy không nên có dòng Sheets("sheet2").[A1].Resize(kk).Value = Arr ---> Sao bạn biết chắc sẽ trích lọc kết quả vào sheet2, cell A1?
Vậy, sửa lại toàn bộ sẽ như vầy:
PHP: 
Sub Filter(ByVal SrcRng As Range, ByVal Target As Range)
  Dim tmpArr, Arr(), lR As Long, lC As Long, kk As Long, Dic As Object, tmp
  On Error Resume Next
  tmpArr = SrcRng.Value
  Set Dic = CreateObject("Scripting.Dictionary")
  ReDim Arr(1 To UBound(tmpArr, 1) * UBound(tmpArr, 2), 1 To 1)
  For lR = 1 To UBound(tmpArr, 1)
    For lC = 1 To UBound(tmpArr, 2)
      If tmpArr(lR, lC) <> "" Then
        tmp = tmpArr(lR, lC)
        If Not Dic.Exists(tmp) Then
          kk = kk + 1
          Dic.Add tmp, kk
          Arr(kk, 1) = tmp
        End If
      End If
    Next
  Next
  If kk Then Target.Resize(kk).Value = Arr
End Sub
PHP: 
Sub Main()
  Dim SrcRng As Range, Target As Range
  Set SrcRng = Sheet1.Range("A1:B1000")
  On Error Resume Next
  Set Target = Sheet2.Range("A1")
  Filter SrcRng, Target
End Sub
Lưu ý: Nếu viết như vầy thì chỉ hoạt động với nguồn dữ liệu là Range thôi nha
 
Upvote 0
Lưu ý: Nếu viết như vầy thì chỉ hoạt động với nguồn dữ liệu là Range thôi nha
Nhấp chuột vào đây để mở rộng...

Em vẫn chưa hiểu hết ý thày ở trên, rất mong thày giúp em bẫy các lỗi, để nó được áp dụng trong trường hợp tổng quát.
 
Upvote 0
Dauthivan đã viết:
Em vẫn chưa hiểu hết ý thày ở trên, rất mong thày giúp em bẫy các lỗi, để nó được áp dụng trong trường hợp tổng quát.
Nhấp chuột vào đây để mở rộng...

Thì do khai báo SrcRng as Range, đương nhiên dữ liệu đầu vào sẽ là Range thôi
Muốn tổng quát cho Range và Array, khai báo lại biến này... Nhưng nói trước là không dễ ăn, vì đã là Array thì bạn đâu biết trước nó 1 chiều hay 2 chiều... Vậy bằng cách nào để ReDim Arr cho đúng kích thước? (ít nhất là không bị thiếu)
 
Upvote 0
Dauthivan đã viết:
Em vẫn chưa hiểu hết ý thày ở trên, rất mong thày giúp em bẫy các lỗi, để nó được áp dụng trong trường hợp tổng quát.
Nhấp chuột vào đây để mở rộng...
Thôi, làm cho bạn luôn đây!
1> Đầu tiên phải viết 1 hàm hổ trợ để tính số phần tử trong Array
PHP: 
Function Elements(ByVal sArray) As Long
  Dim lEs As Long, lDim As Long, tmpArr
  On Error Resume Next
  tmpArr = sArray
  lEs = 1
  If IsArray(tmpArr) Then
    Do While Err.Number = 0
      lDim = lDim + 1
      lEs = lEs * (UBound(tmpArr, lDim) - LBound(tmpArr, lDim) + 1)
    Loop
    Elements = lEs
  End If
End Function
2> Sub Filter sửa lại:
PHP: 
Sub Filter(ByVal sArray, ByVal Target As Range)
  Dim tmpArr, Arr(), lEs As Long, Item, lR As Long, Dic As Object, tmp
  On Error Resume Next
  tmpArr = sArray
  If TypeName(tmpArr) <> "Variant()" Then
    Target(1, 1).Value = tmpArr
  Else
    lEs = Elements(tmpArr)
    Set Dic = CreateObject("Scripting.Dictionary")
    ReDim Arr(1 To lEs, 1 To 1)
    For Each Item In tmpArr
      If CStr(Item) <> "" Then
        tmp = CStr(Item)
        If Not Dic.Exists(tmp) Then
          lR = lR + 1
          Dic.Add tmp, lR
          Arr(lR, 1) = Item
        End If
      End If
    Next
    If lR Then Target.Resize(lR).Value = Arr
  End If
End Sub
3> Code chính:
PHP: 
Sub Main()
  Dim sArray, Target As Range
  sArray = Sheet1.Range("A1:B1000").Value
  On Error Resume Next
  Set Target = Sheet2.Range("A1")
  Filter sArray, Target
End Sub
Code trên chạy được với dữ liệu nguồn là Range, mảng 1 chiều hoặc nhiều chiều
Tự bạn nghiên cứu code trên nhé! Chỉ lưu ý điểm này:
- Tôi đặt tmp = CStr(Item) ---> Xét tmp theo dạng chuổi
- Add tmp vào Dic bằng code Dic.Add tmp, lR
- Nhưng tôi không nạp tmp mà lại nạp Item vào Arr (Arr(lR, 1) = Item)
Lý do vì có trường hợp thế này:
- Cell A1 ta có số 1 định dạng Text
- Cell A2 ta có số 1 định dạng Number
Trường hợp này thì code trên sẽ xem 2 "thằng" này là 1 và sẽ Add vào Dic 1 cái thôi
---------------
Còn vụ If TypeName(tmpArr) <> "Variant()" Then hình như có lần tôi đã nói rồi
 
Upvote 0
Dauthivan đã viết:
Em chưa hiểu tại sao lại phải tính số phần tử Array hả thày?
Nhấp chuột vào đây để mở rộng...

PHP: 
lEs = Elements(tmpArr)
....
ReDim Arr(1 To lEs, 1 To 1)
Mục đích khi tính số phần tử Array là để Redim cho chính xác, nhất là tránh trường hợp Redim thiếu
 
Upvote 0
Trình độ em còn CÒI quá, chưa biết nhiều thứ, xin thày cho em hỏi

PHP: 
If TypeName(tmpArr) <> "Variant()" Then
    Target(1, 1).Value = tmpArr
nó có ý nghĩa gì?

-----------------
Em thắc mắc là sArray = Sheet1.Range("A1:B1000").Value có nghĩa sArray nó là mảng rồi thì cần gì phải làm động tác thêm biến tmpArr (= sArray) làm gì ah.

Hay là đoạn bôi đỏ theo cách hiểu của em như vầy là sai?
 
Lần chỉnh sửa cuối:
Upvote 0
Dauthivan đã viết:
Trình độ em còn CÒI quá, chưa biết nhiều thứ, xin thày cho em hỏi

PHP: 
If TypeName(tmpArr) <> "Variant()" Then
    Target(1, 1).Value = tmpArr
nó có ý nghĩa gì?

-----------------
Em thắc mắc là sArray = Sheet1.Range("A1:B1000").Value có nghĩa sArray nó là mảng rồi thì cần gì phải làm động tác thêm biến tmpArr (= sArray) làm gì ah.

Hay là đoạn bôi đỏ theo cách hiểu của em như vầy là sai?
Nhấp chuột vào đây để mở rộng...
- Câu 1: Lở sArray chỉ là 1 cell thì sao? Dẫn đến tmpArr không phải là Array (mà là 1 giá trị đơn)
- Câu 2: Lở như khi áp dụng người ta ghi Set sArray = Sheet1.Range("A1:B1000") thì sao? Tức người ta truyền Range vào chứ không phải Array ----> Phòng ngừa: Nếu người ta truyền vào là 1 Array thì động tác tmpArr = sArray là dư nhưng nếu người ta truyền vào 1 Range, thì động tác tmpArr = sArray nhằm mục đích chuyển sArray sang Array thật sự
-----------------------
Cái này tôi đã nói mấy lần rồi nhưng hình như bạn không để ý
 
Upvote 0
Vì bận quá, không chịu tìm trên diễn đàn nên không biết là thày đã nói về vấn đề trên rồi.

Em vẫn chưa hiểu kỹ sự khác nhau giữa cách dùng Funtion và Sub trong bài này, cụ thể: Hai Code trên dùng Function nó có ưu điểm gì so với dùng Sub ah?
 
Upvote 0
Dauthivan đã viết:
Vì bận quá, không chịu tìm trên diễn đàn nên không biết là thày đã nói về vấn đề trên rồi.

Em vẫn chưa hiểu kỹ sự khác nhau giữa cách dùng Funtion và Sub trong bài này, cụ thể: Hai Code trên dùng Function nó có ưu điểm gì so với dùng Sub ah?
Nhấp chuột vào đây để mở rộng...
- Sub dùng để thực thi công việc nào đó (ví dụ tô màu, kẻ khung, gán 1 giá trị vào 1 vùng...) ---> Ví thế Sub có tham số sẽ có dạng
Mã: 
Sub TENSUB(Đối số)
'' Thực thi công việc
End Sub
- Function sẽ trả về 1 kết quả sau quá trình tính toán ---> Ví thế bạn sẽ luôn thấy Function có dạng thế này
Mã: 
Function TENHAM(Đối số) [COLOR=#ff0000]As Kiểu dữ liệu[/COLOR]
'' Tính toán gì đó
[COLOR=#ff0000]TENHAM = Kết quả tính toán[/COLOR]
End Function
Chổ tô đỏ là cái khác nhau giữa Sub và Function đấy
Ngoài ra, với 1 Function thì bạn có thể áp dụng trực tiếp trên bảng tính bằng cách gõ vào 1 cell nào đó (như hàm có sẵn của Excel) còn Sub thì không thể dùng cách này
------------------------------
Không thể nói cái nào có ưu điêm hơn, tùy theo yêu cầu mà chọn lựa hợp lý thôi
 
Lần chỉnh sửa cuối:
Upvote 0
Chán quá, thực hành lại từ bài đơn giản trước, bắt chước giống thày Ndu kiểm tra lại từng dòng rồi mà không hiểu sao Code chạy lại chẳng ra cái gì

PHP: 
Sub Filter(SrcRng As Range)
    Dim Arr(), TmpArr, lR As Long, lC As Long, kk As Long, Dic As Object
    TmpArr = SrcRng
    ReDim Arr(1 To UBound(TmpArr, 1) * UBound(TmpArr, 2), 1 To 1)
    Set Dic = CreateObject("Scripting.Dictionary")
    For lC = 1 To UBound(TmpArr, 2)
        For lR = 1 To UBound(TmpArr, 1)
            If TmpArr(lR, lC) <> "" Then
                Tmp = TmpArr(lR, lC)
                If Not Dic.Exists(Tmp) Then
                    kk = kk + 1
                    Dic.Add Tmp, kk
                    Arr(kk, 1) = Tmp
                End If
            End If
        Next lR
    Next lC
End Sub

PHP: 
Sub Main()
    Dim SrcRng As Range
    Set SrcRng = Sheet1.Range("A1:B1000")
    Filter SrcRng
    If kk Then Sheet2.[A1].Resize(kk).Value = Arr
End Sub
 
Upvote 0
Dauthivan đã viết:
Chán quá, thực hành lại từ bài đơn giản trước, bắt chước giống thày Ndu kiểm tra lại từng dòng rồi mà không hiểu sao Code chạy lại chẳng ra cái gì

PHP: 
Sub Filter(SrcRng As Range)
    Dim Arr(), TmpArr, lR As Long, lC As Long, kk As Long, Dic As Object
    TmpArr = SrcRng
    ReDim Arr(1 To UBound(TmpArr, 1) * UBound(TmpArr, 2), 1 To 1)
    Set Dic = CreateObject("Scripting.Dictionary")
    For lC = 1 To UBound(TmpArr, 2)
        For lR = 1 To UBound(TmpArr, 1)
            If TmpArr(lR, lC) <> "" Then
                Tmp = TmpArr(lR, lC)
                If Not Dic.Exists(Tmp) Then
                    kk = kk + 1
                    Dic.Add Tmp, kk
                    Arr(kk, 1) = Tmp
                End If
            End If
        Next lR
    Next lC
End Sub

PHP: 
Sub Main()
    Dim SrcRng As Range
    Set SrcRng = Sheet1.Range("A1:B1000")
    Filter SrcRng
    If kk Then Sheet2.[A1].Resize(kk).Value = Arr
End Sub
Nhấp chuột vào đây để mở rộng...
Như đã nói: Sub là để thực thi công việc nào đó... Vậy bạn nhìn lại Sub Filter của bạn xem, nó có thực thi 1 hành động cụ thể nào đâu? Sau khi Add Dic, nạp Arrary.. vân vân... thì chẳng làm cái gì cả ---> Lý ra, cuối cùng phải gán mảng kết quả vào sheet chứ
Còn Sub Main lại có câu If kk Then Sheet2.[A1].Resize(kk).Value = Arr ---> Chẳng có ý nghĩa gì cả! kk là cái gì? Arr là cái gì?
--------------
Mà bài này tôi đã viết rất rõ rồi còn gì:
PHP: 
Sub Filter(ByVal SrcRng As Range, ByVal Target As Range)
  Dim Arr(), tmpArr, lR As Long, lC As Long, kk As Long, Dic As Object, tmp
  tmpArr = SrcRng
  ReDim Arr(1 To UBound(tmpArr, 1) * UBound(tmpArr, 2), 1 To 1)
  Set Dic = CreateObject("Scripting.Dictionary")
  For lC = 1 To UBound(tmpArr, 2)
    For lR = 1 To UBound(tmpArr, 1)
      If tmpArr(lR, lC) <> "" Then
        tmp = tmpArr(lR, lC)
        If Not Dic.Exists(tmp) Then
          kk = kk + 1
          Dic.Add tmp, kk
          Arr(kk, 1) = tmp
        End If
       End If
     Next lR
  Next lC
  If kk Then Target.Resize(kk).Value = Arr
End Sub
PHP: 
Sub Main()
  Dim SrcRng As Range, Target As Range
  Set SrcRng = Sheet1.Range("A1:B1000")
  Set Target = Sheet2.Range("A1")
  Filter SrcRng, Target
End Sub
----------------
Hoặc nếu giữ nguyên code của bạn thì phải cho biến Arr() và kk lên thành Public
PHP: 
Public Arr(), kk As Long
Sub Filter(SrcRng As Range)
  Dim TmpArr, lR As Long, lC As Long, Dic As Object, tmp
  TmpArr = SrcRng
  kk = 0
  ReDim Arr(1 To UBound(TmpArr, 1) * UBound(TmpArr, 2), 1 To 1)
  Set Dic = CreateObject("Scripting.Dictionary")
  For lC = 1 To UBound(TmpArr, 2)
    For lR = 1 To UBound(TmpArr, 1)
      If TmpArr(lR, lC) <> "" Then
        tmp = TmpArr(lR, lC)
        If Not Dic.Exists(tmp) Then
          kk = kk + 1
          Dic.Add tmp, kk
          Arr(kk, 1) = tmp
        End If
      End If
    Next lR
  Next lC
End Sub
PHP: 
Sub Main()
  Dim SrcRng As Range
  Set SrcRng = Sheet1.Range("A1:B1000")
  Filter SrcRng
  If kk Then Sheet2.[A1].Resize(kk).Value = Arr
End Sub
 
Lần chỉnh sửa cuối:
Upvote 0
Em tưởng câu này
PHP: 
Arr(kk, 1) = tmp
cũng là thực thi hành động nào đó rồi?


PHP: 
Filter SrcRng
Bởi em nghĩ sau khi có câu lệnh trên, 2 Sub liên kết với nhau rồi thì thì Sub Main nó tự biết kk là cái gì từ Sub trên chứ ah?
PHP: 
    If kk Then Sheet2.[A1].Resize(kk).Value = Arr
 
Upvote 0
Dauthivan đã viết:
Em tưởng câu này
PHP: 
Arr(kk, 1) = tmp
cũng là thực thi hành động nào đó rồi?


PHP: 
Filter SrcRng
Bởi em nghĩ sau khi có câu lệnh trên, 2 Sub liên kết với nhau rồi thì thì Sub Main nó tự biết kk là cái gì từ Sub trên chứ ah?
PHP: 
    If kk Then Sheet2.[A1].Resize(kk).Value = Arr
Nhấp chuột vào đây để mở rộng...
Cấu lệnh Arr(kk, 1) = tmp gì gì đó chỉ có thể xem là "thực thi trên giấy"... Muốn kết quả cụ thể phải có hành động cụ thể (bằng động tác gán xuống sheet chẳng hạn)
Sub của bạn phải làm được 1 trong 2 việc sau đây:
- Thực thi 1 hành động cụ thể nào đó (đoạn code thứ nhất của tôi là gán xuống sheet bằng lệnh Target.Resize(kk).Value = Arr)
- Sinh ra 1 sản phẩm nào đó (đoạn code thứ 2 của tôi, sản phẩm sinh ra chính là biến Arr được khai báo dạng Public)
Nói thêm:
- Khi bạn để biến Arr bên trong Sub Filter thì sẽ không thể dùng biến này trong 1 sub khác được, tức nó sẽ chẳng biết Arr, kk là cái giống gì cả...
- Muốn lấy kết quả từ biến Arr, phải khai báo nó dạng Public (để sau khi chạy code, biến này còn lưu giữ được giá trị cuối cùng)
 
Upvote 0
Vâng, nhận thức của em ngây thơ quá, tưởng Sub trên làm công việc đến đâu thì làm, phần công việc còn lại Sub dưới "làm nốt". Tức là tựa như quyển sách vậy, 2 Sub trên như là 2 chương còn việc phân chia nội dung cho vào Chương nào cũng được, miễn sao tổng không đổi.

Nghe thày nói em đã hình dung ra được 1 chút, em xin hỏi tác dụng của Public là gì thế (em chỉ biết nghĩa Tiếng Việt của nó là công khai thôi)?
 
Upvote 0
Dauthivan đã viết:
Nghe thày nói em đã hình dung ra được 1 chút, em xin hỏi tác dụng của Public là gì thế (em chỉ biết nghĩa Tiếng Việt của nó là công khai thôi)?
Nhấp chuột vào đây để mở rộng...

Nguyên văn bởi ndu:
Muốn lấy kết quả từ biến Arr, phải khai báo nó dạng Public (để sau khi chạy code, biến này còn lưu giữ được giá trị cuối cùng)

Ngược lại:
Nếu không khai báo dạng Public, ...
 
Upvote 0
Dauthivan đã viết:
Vâng, nhận thức của em ngây thơ quá, tưởng Sub trên làm công việc đến đâu thì làm, phần công việc còn lại Sub dưới "làm nốt". Tức là tựa như quyển sách vậy, 2 Sub trên như là 2 chương còn việc phân chia nội dung cho vào Chương nào cũng được, miễn sao tổng không đổi.

Nghe thày nói em đã hình dung ra được 1 chút, em xin hỏi tác dụng của Public là gì thế (em chỉ biết nghĩa Tiếng Việt của nó là công khai thôi)?
Nhấp chuột vào đây để mở rộng...
Nhớ có lần tôi đã hình dung thế này:
- Public = công cộng ---> Vậy thì ai xài cũng được (tức "đứng" từ sub khác hoặc 1 module khác cũng có thể dùng được cái Public do thằng ở sub này hoặc module xây dựng nên)
- Private = riêng tư ---> Mạnh ai nấy xài
Vậy thôi
---------
Cũng giống như:
- Arr là cái kho gạo công cộng (Public), thằng Sub Filter sau khi chạy xong, sẽ "đổ gạo" vào kho công cộng này nên thằng Sub Main sẽ đến lấy được gạo về nấu
- Nếu Arr là biến nằm trong sub Filter, tức là gạo của riêng nó ---> Thằng Sub Main đến lấy, nó đánh bỏ xừ...
Ẹc... Ẹc...
 
Lần chỉnh sửa cuối:
Upvote 0
ndu96081631 đã viết:
Nhớ có lần tôi đã hình dung thế này:
- Public = công cộng ---> Vậy thì ai xài cũng được (tức "đứng" từ sub khác cũng có thể dùng được cái Public do thằng khác xây dựng nên)
- Private = riêng tư ---> Của ai nấy xài
Vậy thôi
Nhấp chuột vào đây để mở rộng...

Nếu nhớ lại nguyên văn thì lúc đó ndu dùng thí dụ cái toilet cơ.
Hic, spam cái. Công nhận vài hôm nay ndu quá kiên nhẫn.
Chứ có một câu ngắn như vậy, 1 là không đọc, 2 là đọc không hiểu, lão chết tiệt chịu, bó tay.
 
Upvote 0
Bạn phải đăng nhập hoặc đăng ký để trả lời bài viết tại đây.
Web KT

Bài viết mới nhất

SA_DQ
  • Question Question
[Bài tập VBA cho người rỗi rảnh] Hãy viết 1 macro tìm ra 3 số nguyên tố liên tiếp
2
Trả lời
24
Đọc
442
SA_DQ
SA_DQ
Xoainon3005
Xin file mẫu kế hoạch sản xuất theo tháng ngành động cơ
Trả lời
0
Đọc
31
Xoainon3005
Xoainon3005
A
Tạo vé Loto bằng Excel
Trả lời
19
Đọc
23K
vinhquang14292
vinhquang14292
ongke0711
  • Question Question
Tải hóa đơn điện tử (https://hoadondientu.gdt.gov.vn/) Excel Vba
    • Thích
    • Yêu thích
    • Cảm ơn
14 15 16
Trả lời
308
Đọc
22K
CheezeTube
CheezeTube
Akingee
Món quà tuyệt vời thứ 2 của Cloudflare dành cho nhân loại - WARP
Trả lời
0
Đọc
66
Akingee
Akingee
HeSanbi
  • Đã giải quyết
LocalizeXL v1.73 - Làm nổi bật ô đang chọn và cuộn trang tự động
    • Thích
    • Yêu thích
2 3 4
Trả lời
74
Đọc
10K
vn72259
V
H
Vì sao trong khi cộng và khi sum lại hiển thị sai
Trả lời
15
Đọc
57K
hieung99
hieung99
L
  • Question Question
[Hlep] Xóa ảnh theo tên và kích thước
Trả lời
3
Đọc
124
HUONGHCKT
H
Thanh271188
Tìm giá trị xuất hiện bất kì (không phải giá trị đầu, cuối) trong excel
    • Cười
Trả lời
3
Đọc
130
VetMini
V
T
Nhờ hỗ trợ hàm SUMIF không phân biệt được các ký tự "0" trước một số trong chuỗi
Trả lời
3
Đọc
182
tan10ckn
T
huuthang_bd
Add-in DeleteVirusMacro - Xóa và ngăn chặn virus macro
    • Thích
    • Yêu thích
    • Chấp nhận
2 3
Trả lời
46
Đọc
14K
tuantran203
T
ongke0711
  • Question Question
Trộn dữ liệu từ Excel sang Word mở rộng (phiên bản ongke0711)
    • Thích
    • Yêu thích
    • Cảm ơn
12 13 14
Trả lời
260
Đọc
27K
hoangtuan.net
hoangtuan.net
HeSanbi
  • Đã giải quyết
WeatherXL - Ứng dụng lấy dữ liệu Thời tiết siêu nhanh (*15/01/2024)
    • Thích
    • Yêu thích
3 4 5
Trả lời
88
Đọc
18K
vc_đi chơi
vc_đi chơi
L
[Help] tự động lấy dữ liệu cổ phiếu từ vietstock về file excel
    • Thích
Trả lời
3
Đọc
840
ketoan113
K
N
Tách chuỗi và tìm kiếm theo dữ liệu gần đúng trong chuỗi ký tự
Trả lời
8
Đọc
202
Ngocminh19
N
Mr.hieudoanxd
  • Question Question
[Cần hướng dẫn] Về lập trình Viết Function với Settimer và Killtimer
    • Thích
Trả lời
8
Đọc
341
nguyendang95
N
P
Các Bác cho e hỏi làm thế nào để ẩn công thức trên GOOGLE SHEET với ạ?
2
Trả lời
21
Đọc
18K
học excel googlesheet
học excel googlesheet
Emyeuexcel
  • Question Question
Code VBA mở nhiều file, value các sheet, lưu và đóng file
Trả lời
3
Đọc
142
Emyeuexcel
Emyeuexcel
V
Cho 2 biến - kết quả trả về giá trị của hàng đầu tiên
    • Chấp nhận
Trả lời
5
Đọc
173
Duy Tùng 9x
Duy Tùng 9x
D
Giúp đỡ thống kê dữ liệu theo điều kiện
Trả lời
8
Đọc
248
HieuCD
H
Xem thêm…

Thành viên có số lượng bài viết cao nhất tháng

  • Không tìm thấy.

Thành viên có điểm tương tác cao nhất tháng

  • Không tìm thấy.

Đếm ngược thời gian

000
Ngày
00
Giờ
00
phút
00
giây
Chúc mừng năm mới Ất Tỵ 2025
Back
Top Bottom