Mọi người ơi giúp em phần Bangluong với ạ

Cherry1502 · 18/4/20

1.Tính Lương = 3.000.000 nếu là bậc lương 1, = 6.000.000 nếu là bậc lương 2, = 8.000.000 nếu là bậc lương 3, sau đó cứ một bậc thì được tăng thêm 1.500.000.
2. Tính Tạm ứng = Lương/3, làm tròn đến phần nghìn e. Tính Phụ cấp, biết nếu là GĐ hoặc PGĐ thì được 3.000.000, nếu là TP hoặc PP thì được 2.000.000, còn lại là 0.
3. Tính Ăn trưa = 500.000 nếu đi làm đủ 22 ngày, nếu đi làm trên 22 ngày thì mỗi ngày dư được cộng thêm 50.000 còn nếu đi làm dưới 22 ngày thì mỗi ngày thiếu bị trừ đi 50.000
4. Tính Thưởng cho NV và BV nếu đi làm trên 22 ngày thì được 700.000, còn lại không được thưởng.
5. Tính Thực lĩnh = (Lương+ Phụ Cấp+ Ăn trưa+Thưởng) -Tạm ứng i. Thực hiện tổng hợp lương theo từng phòng b

Hoàng Trọng Nghĩa · 18/4/20

Cherry1502 đã viết:
1.Tính Lương = 3.000.000 nếu là bậc lương 1, = 6.000.000 nếu là bậc lương 2, = 8.000.000 nếu là bậc lương 3, sau đó cứ một bậc thì được tăng thêm 1.500.000.
2. Tính Tạm ứng = Lương/3, làm tròn đến phần nghìn e. Tính Phụ cấp, biết nếu là GĐ hoặc PGĐ thì được 3.000.000, nếu là TP hoặc PP thì được 2.000.000, còn lại là 0.
3. Tính Ăn trưa = 500.000 nếu đi làm đủ 22 ngày, nếu đi làm trên 22 ngày thì mỗi ngày dư được cộng thêm 50.000 còn nếu đi làm dưới 22 ngày thì mỗi ngày thiếu bị trừ đi 50.000
4. Tính Thưởng cho NV và BV nếu đi làm trên 22 ngày thì được 700.000, còn lại không được thưởng.
5. Tính Thực lĩnh = (Lương+ Phụ Cấp+ Ăn trưa+Thưởng) -Tạm ứng i. Thực hiện tổng hợp lương theo từng phòng b

1.Tính Lương
=IF(H4=0,0,IF(H4=1,3000000,IF(H4=2,6000000,IF(H4=3,8000000,8000000+(H4-3)*1500000))))

2.1 Tính Tạm ứng
=ROUND(J4/3,-3)

2.2 Tính Phụ cấp
=IF(OR(E4="GĐ",E4="PGĐ"),3000000,IF(OR(E4="TP",E4="PP"),2000000,0))

3. Tính Ăn trưa
=500000+(I4-22)*50000

4. Tính Thưởng
=IF(AND(I4>22,OR(E4="NV",E4="BV")),700000,0)

5.1 Tính Thực lĩnh
=SUM(J4:N4)-K4*2

5.2 Tổng hợp
=SUMIF($F$4:$F$33,C36,$O$4:$O$33)

dazkangel · 18/4/20

Tính lương như vậy cho chất

=SUM(H4,TEXT(H4,"[<2]0;\2")/2)*"2e6"

huonglien1901 · 18/4/20

dazkangel đã viết:
Tính lương như vậy cho chất
=SUM(H4,TEXT(H4,"[<2]0;\2")/2)*"2e6"

Giải thích giúp em công thức này không Anh? Đọc thấy hay mà không hiểu.

Cherry1502 · 18/4/20

Hoàng Trọng Nghĩa đã viết:
1.Tính Lương
=IF(H4=0,0,IF(H4=1,3000000,IF(H4=2,6000000,IF(H4=3,8000000,8000000+(H4-3)*1500000))))

2.1 Tính Tạm ứng
=ROUND(J4/3,-3)

2.2 Tính Phụ cấp
=IF(OR(E4="GĐ",E4="PGĐ"),3000000,IF(OR(E4="TP",E4="PP"),2000000,0))

3. Tính Ăn trưa
=500000+(I4-22)*50000

4. Tính Thưởng
=IF(AND(I4>22,OR(E4="NV",E4="BV")),700000,0)

5.1 Tính Thực lĩnh
=SUM(J4:N4)-K4*2

5.2 Tổng hợp
=SUMIF($F$4:$F$33,C36,$O$4:$O$33)

EM CẢM ƠN ANH Ạ!

Bài đã được tự động gộp: 18/4/20

Hoàng Trọng Nghĩa đã viết:
1.Tính Lương
=IF(H4=0,0,IF(H4=1,3000000,IF(H4=2,6000000,IF(H4=3,8000000,8000000+(H4-3)*1500000))))

2.1 Tính Tạm ứng
=ROUND(J4/3,-3)

2.2 Tính Phụ cấp
=IF(OR(E4="GĐ",E4="PGĐ"),3000000,IF(OR(E4="TP",E4="PP"),2000000,0))

3. Tính Ăn trưa
=500000+(I4-22)*50000

4. Tính Thưởng
=IF(AND(I4>22,OR(E4="NV",E4="BV")),700000,0)

5.1 Tính Thực lĩnh
=SUM(J4:N4)-K4*2

5.2 Tổng hợp
=SUMIF($F$4:$F$33,C36,$O$4:$O$33)

dazkangel · 18/4/20

huonglien1901 đã viết:
Giải thích giúp em công thức này không Anh? Đọc thấy hay mà không hiểu.

Hàm text lấy số theo điều kiện:
[<2] tức nhỏ hơn 2 là số 1 thì lấy số 1, còn nếu lớn hơn thì chỉ lấy số 2 sau đó gom lại chia cho 2 ta được:
Nếu H4 = 0 thì ra SUM(0,0/2) * 2e6 tương đương 2.000.0000
H4 = 1 thì ra SUM(1,1/2)* 2e6 = SUM(1,0.5)*2.000.000 = 3.000.000
H4 = 2 thì ra SUM(2,2/2)* 2e6 = SUM(2,1)*2.000.000 = 6.000.000
H4 = 3 thì ra SUM(3,2/2)* 2e6 = SUM(3,1)*2.000.000 = 8.000.000

concogia · 18/4/20

dazkangel đã viết:
Tính lương như vậy cho chất
=SUM(H4,TEXT(H4,"[<2]0;\2")/2)*"2e6"

Công thức hay quá, nhìn chẳng hiểu mô tê gì, bạn sửa lại cho bậc từ 4 trở lên chỉ cộng 1,5 trệu thôi
Híc

Cherry1502 · 18/4/20

concogia đã viết:
Công thức hay quá, nhìn chẳng hiểu mô tê gì, bạn sửa lại cho bậc từ 4 trở lên chỉ cộng 1,5 trệu thôi
Híc

e nhìn cái đó e cũng không hiểu gì hihi

dazkangel · 18/4/20

concogia đã viết:
Công thức hay quá, nhìn chẳng hiểu mô tê gì, bạn sửa lại cho bậc từ 4 trở lên chỉ cộng 1,5 trệu thôi
Híc

Chết thật em nhìn nhầm, già rồi mắt mũi kèm nhèm

Để em mò lại.

Cherry1502 · 18/4/20

dazkangel đã viết:
Chết thật em nhìn nhầm, già rồi mắt mũi kèm nhèm
Để em mò lại.

dạ. em cảm ơn a nha

dazkangel · 18/4/20

Cherry1502 đã viết:
dạ. em cảm ơn a nha

Chắc chưa có cách nào khác, bạn thông cảm vậy

Phan Thế Hiệp · 18/4/20

dazkangel đã viết:
Chắc chưa có cách nào khác, bạn thông cảm vậy

Có chứ! mà tại em giấu.
J4=(MIN(H4,2)*3+(H4>2)*2+(H4>3)*(H4-3)*1.5)*10^6

Chúc em ngày vui.
/-*+/

HieuCD · 18/4/20

Cherry1502 đã viết:
dạ. em cảm ơn a nha

Góp vui
Thử dùng hàm Text
=SUM(H4*2,TEXT(H4,"[<2]0;\2"),-(0&TEXT(H4-3,"#;;"))/2)*10^6
Cách khác
=(H4*3-(H4>2)-(H4>3)*(H4-3)*3/2)*10^6

SA_DQ · 19/4/20

1.Tính Lương
=IF(H4=0,0,IF(H4=1,3000000,IF(H4=2,6000000,IF(H4=3,8000000,8000000+(H4-3)*1500000))))
. . . . . .

Công thức này bị lạm dụng các con số 0 quá nhiều, khà, khà,. . . . ( }}}}}

& trốn thôi!)

HieuCD · 19/4/20

Chỉnh lại công thức theo hàm Text

Mã:

=SUM(--(0&TEXT((H4-{0,2,3}),"#;;"))*{3,-1,-0.5})*10^6

Phan Thế Hiệp · 19/4/20

Góp thêm 1 cái ngắn nữa:

Mã:

=IF(H4<3,H4*3,8+(H4-3)*1.5)*10^6

Enter

Chúc anh em ngày vui.
/-*+/

HieuCD · 19/4/20

Phan Thế Hiệp đã viết:
Góp thêm 1 cái ngắn nữa:

Mã:

=IF(H4<3,H4*3,8+(H4-3)*1.5)*10^6

Enter

Chúc anh em ngày vui.

Ngắn hơn Bikini rồi. Khà khà /-*+/

Chúc bạn buổi tối an lành

Hoàng Trọng Nghĩa · 19/4/20

Cherry1502 đã viết:
EM CẢM ƠN ANH Ạ!

Bài đã được tự động gộp: 18/4/20

a ơi cái tổng hợp cuối cùng ý ạ. e bấm hàm xong n đều ra kqua như này " - " là lms vậy a

Tốt nhất bạn xem công thức trong file vậy

Bài đã được tự động gộp: 19/4/20

SA_DQ đã viết:
Công thức này bị lạm dụng các con số 0 quá nhiều, khà, khà,. . . . ( & trốn thôi!)

Trước đây có một bài hình như là tính %, đại loại mình ghi là 70%, hình như là NDU chỉnh lại ghi 0.7, ảnh nói cứ ghi hẳn số đã được tính toán ra, để cho máy bớt tính đi và nếu một CSDL lớn nó đỡ chạy chậm hơn. Nên giờ, cũng là giá trị như thế và để làm cho ngắn hơn thì mình cũng không thêm công thức (ngoại trừ bất đắc dĩ).

excel_lv1.5 · 19/4/20

Cherry1502 đã viết:
1.Tính Lương = 3.000.000 nếu là bậc lương 1, = 6.000.000 nếu là bậc lương 2, = 8.000.000 nếu là bậc lương 3, sau đó cứ một bậc thì được tăng thêm 1.500.000.
2. Tính Tạm ứng = Lương/3, làm tròn đến phần nghìn e. Tính Phụ cấp, biết nếu là GĐ hoặc PGĐ thì được 3.000.000, nếu là TP hoặc PP thì được 2.000.000, còn lại là 0.
3. Tính Ăn trưa = 500.000 nếu đi làm đủ 22 ngày, nếu đi làm trên 22 ngày thì mỗi ngày dư được cộng thêm 50.000 còn nếu đi làm dưới 22 ngày thì mỗi ngày thiếu bị trừ đi 50.000
4. Tính Thưởng cho NV và BV nếu đi làm trên 22 ngày thì được 700.000, còn lại không được thưởng.
5. Tính Thực lĩnh = (Lương+ Phụ Cấp+ Ăn trưa+Thưởng) -Tạm ứng i. Thực hiện tổng hợp lương theo từng phòng b

Bài này giống như tìm quy luật của dãy số nhỉ, góp thêm 1 vui với với mọi người

Mã:

=(15*H4+MIN(15*H4,35))*10^5

HieuCD · 19/4/20

excel_lv1.5 đã viết:
Bài này giống như tìm quy luật của dãy số nhỉ, góp thêm 1 vui với với mọi người

Mã:

=(15*H4+MIN(15*H4,35))*10^5

Quá táo bạo, phá vỡ giới hạn của công thức rồi /-*+/

Mọi người ơi giúp em phần Bangluong với ạ

Thành viên mới

File đính kèm

Chuyên gia GPE

<New Horizons>

GPE là ngôi nhà thứ 2 của tôi!!!

Thành viên mới

<New Horizons>

Gội rồi mới Cạo

Thành viên mới

<New Horizons>

Thành viên mới

<New Horizons>

-⍟-

Chuyên gia GPE

/(hông là gì!

Chuyên gia GPE

-⍟-

Chuyên gia GPE

Chuyên gia GPE

File đính kèm

Thành viên tích cực

Chuyên gia GPE

Đếm ngược thời gian