Làm tròn số trong excel

[dasdragon]

Chả là em đi làm siêu thịm tới hôm nay gặp phải vấn đề hóc búa đó là làm sao để làm tròn số
Ví dụ: mình tính file tiền ra được những con số này trong excel
+ 20.654
+ 23.900
+ 35.970
+ 57.000
Thì tính làm sao mà 3 số cuối nếu nó nhỏ hơn 900( VD 20.654) thì cho nó về 900 (thành 20.900), còn nếu bằn 900 (VD 23.900) thì giữ nguyên, nếu nó hơn 900 thì sẽ làm tròn số (VD 35.970 thành 36.000) Nếu là số chẵn (VD 57.000) thì giữ nguyên
Mong cả nhà giúp đỡ em với

 

[huuthang_bd]

Bạn làm vầy thử xem

=FLOOR(A1,1000)+CEILING(MOD(A1,1000),IF(MOD(A1,1000)>900,1000,900))

 

[VMH0307]

Bạn có thể dùng hàm sau:

=MAX(ROUNDDOWN(A1,-3)+900,ROUNDUP(A1,-2))

 

[huuthang_bd]

Bạn có thể dùng hàm sau:

=MAX(ROUNDDOWN(A1,-3)+900,ROUNDUP(A1,-2))

57.000 thì thành 57.900 à?

 

[mhung12005]

Bạn làm vầy thử xem

=FLOOR(A1,1000)+CEILING(MOD(A1,1000),IF(MOD(A1,1000)>900,1000,900))

Cái hàm CELLING này giờ em mới va vào lần đầu tiên hihi hay thật. Cảm ơn anh.

Nhưng với yêu cầu của chủ topic em nghĩ ct như này mới đạt yêu cầu chứ anh:

=FLOOR(A1,1)+CEILING(MOD(A1,1),IF(MOD(A1,1)>0.9,1,0.9))
hoặc=INT(A1)+CEILING(MOD(A1,1),IF(MOD(A1,1)>0.9,1,0.9))

 

[VMH0307]

57.000 thì thành 57.900 à?

Hehe, copy nhầm tí xíu:
như thế này mới đúng

=MAX(ROUNDDOWN(A1[COLOR=#ff0000]-1[/COLOR],-3)+900,ROUNDUP(A1,-2))

 

[huuthang_bd]

Hehe, copy nhầm tí xíu:
như thế này mới đúng

=MAX(ROUNDDOWN(A1[COLOR=#ff0000]-1[/COLOR],-3)+900,ROUNDUP(A1,-2))

0 làm tròn thành 900
1.000,5 làm tròn thành 1.100

Nhưng với yêu cầu của chủ topic em nghĩ ct như này mới đạt yêu cầu chứ anh:

Dấu chấm là dấu phân cách hàng ngàn chứ không phải dấu phân cách thập phân đâu bạn.

 

[VMH0307]

0 làm tròn thành 900
1.000,5 làm tròn thành 1.100

Nói chung là tùy vào nhu cầu của chủ topic, tùy thuộc dữ liệu của chủ topic (ví như: dữ liệu >0), công thức nào đơn giản, ngắn gọn mà thỏa mãn nhu cầu thì dùng thôi. Chứ bóc tách các trường hợp thì vô vàn (ví như công thức của bạn không áp dụng cho số âm chẳng hạn).
Còn vụng chèo khéo chống đối với công thức của tôi thì
với số 0 thì thêm if(A1=0,0,...)
với số thập phân thì thay -1 thành -0.000...1 gì đó là xong.

 

[0922825456]

Mình cũng chưa thử công thức này ở bảng tính Excel vì excel của mình đang bị lỗi. mình nghĩ rồi mình viết thôi bạn thử xem có được ko nha

=IF((RIGHT(A3,LEN(A3)-FIND(".",A3,FIND(".",A3))))>"900",ROUND(A3,0),IF((RIGHT(A3,LEN(A3)-FIND(".",A3,FIND(".",A3))))<"900",LEFT(A3,FIND(".",A3,FIND(".",A3)))&"900",A3))

 

[dasdragon]

Cám ơn cả nhà đã trả lời dùm mình,mình sẽ test thu
Thank cả nhà nhiều nhé

 

[thanh258]

Chả là em đi làm siêu thịm tới hôm nay gặp phải vấn đề hóc búa đó là làm sao để làm tròn số
Ví dụ: mình tính file tiền ra được những con số này trong excel
+ 20.654
+ 23.900
+ 35.970
+ 57.000
Thì tính làm sao mà 3 số cuối nếu nó nhỏ hơn 900( VD 20.654) thì cho nó về 900 (thành 20.900), còn nếu bằn 900 (VD 23.900) thì giữ nguyên, nếu nó hơn 900 thì sẽ làm tròn số (VD 35.970 thành 36.000) Nếu là số chẵn (VD 57.000) thì giữ nguyên
Mong cả nhà giúp đỡ em với

Mình cũng xin đóng góp 1 công thức cho bạn:
=IF(AND(RIGHT(A1,3)*1<=900,RIGHT(A1,3)*1<>0),LEFT(A1,LEN(A1)-3)*1000+900,ROUND(A1,-3))
Công thức của mình toàn hàm quen thuộc nên dễ hiểu ^^! Mình đã text thử và đúng với mọi trường hợp