Hỏi về chữ Unicode trong Code (1 người xem)

[ncq2003]

Mình tìm được đoạn code này

Function Klg(rng As String)
Dim i As Integer
Dim strTemp As String
rng = Application.Trim(Right(rng, Len(rng) - InStr(rng, ":")))
rng = Replace(rng, "m2", "")
rng = Replace(rng, "m3", "")
For i = 1 To Len(rng)
    Select Case Asc(Mid(rng, i, 1))
    Case 40 To 57, 94
        strTemp = strTemp & Mid(rng, i, 1)
    End Select
Next i
strTemp = Replace(strTemp, ",", ".")
strTemp = Replace(strTemp, "/*", "*")
strTemp = Replace(strTemp, "/+", "+")
strTemp = Replace(strTemp, "/-", "-")
strTemp = Replace(strTemp, "//", "/")
If Right(strTemp, 1) = "/" Then strTemp = Left(strTemp, Len(strTemp) - 1)
Klg = Evaluate(strTemp)
End Function
Function DocSo(ByVal Number, Optional ByVal Font = 1) As String
Dim MyArray
Dim Str
Str = Format(Abs(Number), "000000000000000000")
Select Case Font
Case 1
MyArray = Array("không ", "m" & ChrW(7897) & "t ", "hai ", "ba ", "b" & ChrW(7889) & "n ", "n" & ChrW(259) & "m ", "sáu ", "b" & ChrW(7843) & "y ", "tám ", "chín ", "tri" & ChrW(7879) & "u, ", "ngàn, ", "t" & ChrW(7927) & ", ", "tri" & ChrW(7879) & "u, ", "ngàn, ", "", "tr" & ChrW(259) & "m ", "m" & ChrW(432) & ChrW(417) & "i ", "không " & "m" & ChrW(432) & ChrW(417) & "i" & " không ", "không " & "m" & ChrW(432) & ChrW(417) & "i", "l" & ChrW(7867), "m" & ChrW(432) & ChrW(417) & "i" & " không", "m" & ChrW(432) & ChrW(417) & "i", "m" & ChrW(432) & ChrW(417) & "i" & " n" & ChrW(259) & "m", "m" & ChrW(432) & ChrW(417) & "i" & " l" & ChrW(259) & "m", "m" & ChrW(7897) & "t " & "m" & ChrW(432) & ChrW(417) & "i", "m" & ChrW(432) & ChrW(7901) & "i", "m" & ChrW(432) & ChrW(417) & "i" & " m" & ChrW(7897) & "t", "m" & ChrW(432) & ChrW(417) & "i" & " m" & ChrW(7889) & "t", "Âm ")
Case 2
MyArray = Array("khoâng ", "moät ", "hai ", "ba ", "boán ", "naêm ", "saùu ", "baûy ", "taùm ", "chín ", "trieäu, ", "ngaøn, ", "tyû, ", "trieäu, ", "ngaøn, ", "", "traêm ", "möôi ", "khoâng möôi khoâng ", "khoâng möôi", "leû", "möôi khoâng", "möôi", "möôi naêm", "möôi laêm", "moät möôi", "möôøi", "möôi moät", "möôi moát", "AÂm ")
Case 3
MyArray = Array("kh«ng ", "mét ", "hai ", "ba ", "bèn ", "n¨m ", "s¸u ", "b¶y ", "t¸m ", "ch?n ", "triÖu, ", "ngµn, ", "tû, ", "triÖu, ", "ngµn, ", "", "tr¨m ", "m­¬i ", "kh«ng m­¬i kh«ng ", "kh«ng m­¬i", "lÎ", "m­¬i kh«ng", "m­¬i", "m­¬i n¨m", "m­¬i l¨m", "mét m­¬i", "m­êi", "m­¬i mét", "m­¬i mèt", "©m ")
End Select
If Str = "000000000000000000" Then
    DocSo = UCase(Left(MyArray(0), 1)) & Trim(Mid(MyArray(0), 2)) & "."
    Exit Function
End If
For i = 1 To Len(Str)
If Left(Str, i) <> 0 And Mid(Str, (Int((i + 2) / 3) - 1) * 3 + 1, 3) <> 0 Then
    DocSo = DocSo & MyArray(Mid(Str, i, 1)) & MyArray(-(9 + i / 3) * (i Mod 3 = 0) - (15 + i Mod 3) * (i Mod 3 <> 0))
ElseIf i = 9 And Mid(Str, 7, 3) = 0 And Left(Str, 6) <> 0 Then
    DocSo = DocSo & MyArray(12)
End If
Next
DocSo = Trim(Replace(Replace(Replace(Replace(Replace(Replace(DocSo, MyArray(18), MyArray(15)), MyArray(19), MyArray(20)), MyArray(21), MyArray(22)), MyArray(23), MyArray(24)), MyArray(25), MyArray(26)), MyArray(27), MyArray(28)))
If Number < 0 Then
DocSo = MyArray(29) & DocSo
End If
DocSo = Replace(UCase(Left(DocSo, 1)) & Mid(DocSo, 2) & ".", ",.", " ")
End Function

Các bạn cho mình hỏi mình muốn thêm chữ đồng vào cuối Hàm thì thêm vào trong code thế nào
Ví dụ : Hàm docso(123) => Một trăm hai mươi ba
Mình muốn hàm trên thành Một trăm hai mươi ba đồng
P/S : mình muốn thêm luôn vào trong code.
Cám ơn các bạn đã đọc và giúp đỡ

 

[vu_tuan_manh_linh]

Các bạn cho mình hỏi mình muốn thêm chữ đồng vào cuối Hàm thì thêm vào trong code thế nào
Ví dụ : Hàm docso(123) => Một trăm hai mươi ba
Mình muốn hàm trên thành Một trăm hai mươi ba đồng
P/S : mình muốn thêm luôn vào trong code.
Cám ơn các bạn đã đọc và giúp đỡ

Sửa đoạn code gần cuối cùng như sau:

DocSo = Replace(UCase(Left(DocSo, 1)) & Mid(DocSo, 2) & " ", ",.", " ") & ChrW(273) & ChrW(7891) & "ng"

 

[ncq2003]

Sửa đoạn code gần cuối cùng như sau:

DocSo = Replace(UCase(Left(DocSo, 1)) & Mid(DocSo, 2) & " ", ",.", " ") & ChrW(273) & ChrW(7891) & "ng"

trước tiên cảm ơn Bạn
Cho mình hỏi tiếp Ví dụ mình có : docso(7600000) => Bảy triệu, bảy trăm ngàn, đồng.
Mình muốn bỏ dấu "," trước chữ "đồng" thì sửa code như thế nào
MÌnh đính kèm file nhờ bạn xem giùm

 

[vu_tuan_manh_linh]

trước tiên cảm ơn Bạn
Cho mình hỏi tiếp Ví dụ mình có : docso(7600000) => Bảy triệu, bảy trăm ngàn, đồng.
Mình muốn bỏ dấu "," trước chữ "đồng" thì sửa code như thế nào
MÌnh đính kèm file nhờ bạn xem giùm

Bạn thêm câu lệnh sau:

DocSo = Replace(DocSo, ", " & ChrW(273) & ChrW(7891) & "ng", " " & ChrW(273) & ChrW(7891) & "ng")

 

[ncq2003]

Bạn thêm câu lệnh sau:

DocSo = Replace(DocSo, ", " & ChrW(273) & ChrW(7891) & "ng", " " & ChrW(273) & ChrW(7891) & "ng")

Cám ơn bạn, Đã chạy
Còn tiếp vấn đề docso(7600000;2) => thì chữ đồng không hiện mà chữ như vầy
Bảy triệu, bảy trăm ngàn ồng.
(Ý mình là chọn font VNI đó mà)
Mong bạn giúp mình tiếp

 

[vu_tuan_manh_linh]

Cám ơn bạn, Đã chạy
Còn tiếp vấn đề docso(7600000;2) => thì chữ đồng không hiện mà chữ như vầy
Bảy triệu, bảy trăm ngànồng.
(Ý mình là chọn font VNI đó mà)
Mong bạn giúp mình tiếp

Thay cả cụm lệnh cuối luôn nhé!

If Font = 1 Then
    DocSo = Replace(UCase(Left(DocSo, 1)) & Mid(DocSo, 2) & " ", ",.", " ") & ChrW(273) & ChrW(7891) & "ng"
    DocSo = Replace(DocSo, ", " & ChrW(273) & ChrW(7891) & "ng", " " & ChrW(273) & ChrW(7891) & "ng")
Else
    If Font = 2 Then
        DocSo = Replace(UCase(Left(DocSo, 1)) & Mid(DocSo, 2) & " ", ",.", " ") & "ñoàng"
        DocSo = Replace(DocSo, ", ñoàng", " ñoàng")
    Else
        DocSo = Replace(UCase(Left(DocSo, 1)) & Mid(DocSo, 2) & " ", ",.", " ") & "®ång"
        DocSo = Replace(DocSo, ", ®ång", " ®ång")
    End If
End If

 

[ncq2003]

Cám ơn bạn, code này chạy tốt rồi