Hỏi về cách dò tìm cùng lúc 2 giá trị ở 2 cột để tìm giá trị tham chiếu cho bảng khác

[kiemchu74]

Mình có vấn đề với bảng tổng hợp này, mình muốn dò tìm giá trị mã xuất ở bảng 2 từ hai tham số mã thẻ và ngày tháng từ bảng thứ nhất, các bạn giúp mình nha.Thank nhiều lắm P/s:Bữa trước mình có được giúp về hàm sumproduct nhưng gửi phản hồi để thank không được ai giải thích giúp mình đuợc không

 

[chucuoi92]

Để dò tìm bảng của bạn thì có thể dùng hàm mảng, đặt name nhưng như thế phức tạp và khó hiểu hơn là dùng cột phụ.
Mình hướng dẫn dùng cột phụ cho bài của bạn:
Ở bảng 1 ghép hai cột B và D :ở cell A7 gõ CT=B7&D7, rồi fill đế A12.
Ở bảng 2 ghép hai cột F và G :ở cell E7 gõ CT=F7&G7, rồi fill đế E26.
Ở I7 chép CT này vào =INDEX($C$7:$C$12,MATCH(E7,$A$7:$A$12,0)) rồi fill cho hết cột trong bảng 2

 

[bebo021999]

Mình có vấn đề với bảng tổng hợp này, mình muốn dò tìm giá trị mã xuất ở bảng 2 từ hai tham số mã thẻ và ngày tháng từ bảng thứ nhất, các bạn giúp mình nha.Thank nhiều lắm P/s:Bữa trước mình có được giúp về hàm sumproduct nhưng gửi phản hồi để thank không được ai giải thích giúp mình đuợc không

Dùng công thức này tại H7:

=INDEX($B$7:$B$12,MATCH(2,IF($A$7:$A$12=E7,1,0)+IF($C$7:$C$12=F7,1,0),0))

Kết thúc bằng giữ Ctrl-Shift và nhấn Enter

 

[leonguyenz]

Cái này cũng là sản phẩm của anh bebo021999 nè: H7 =INDEX($B$7:$B$12,MATCH(1,($A$7:$A$12=$E7)*($C$7:$C$12=$F7),0)) và Ctrl+Shift+Enter.

 

[concogia]

Mình có vấn đề với bảng tổng hợp này, mình muốn dò tìm giá trị mã xuất ở bảng 2 từ hai tham số mã thẻ và ngày tháng từ bảng thứ nhất, các bạn giúp mình nha.Thank nhiều lắm P/s:Bữa trước mình có được giúp về hàm sumproduct nhưng gửi phản hồi để thank không được ai giải thích giúp mình đuợc không

Thêm một cách:

=INDEX($B$7:$B$12,MATCH(E7&F7,$A$7:$A$12&$C$7:$C$12,0))

Kết thúc bằng Ctrl + Shift + Enter
Thân

 

[ndu96081631]

Dùng cái này thì khỏi Ctrl + Shift + Enter gì ráo:

=LOOKUP(2,1/($A$7:$A$12=E7)/($C$7:$C$12=F7),$B$7:$B$12)

 

[kiemchu74]

Thank mấy bạn đã tham gia giúp mình nha, mình gặp thêm vấn đề này,mong các bạn giúp!

Không được rồi mấy bạn ơi, khi bảng 1 mình chèn thêm dữ liệu ở phía đầu bảng thì công thức không tìm được giá trị.mình gửi kèm file maxuat2.xls, các bạn xem lại giúp mình

 

[ndu96081631]

Không được rồi mấy bạn ơi, khi bảng 1 mình chèn thêm dữ liệu ở phía đầu bảng thì công thức không tìm được giá trị.mình gửi kèm file maxuat2.xls, các bạn xem lại giúp mình

Người ta căn dặn cẩn thận rằng: Gõ công thức xong phải bấm tổ hợp phím Ctrl + Shift + Enter mà bạn đâu có làm
Muốn Enter bình thường thì dùng cái này:

=LOOKUP(2,1/($H$4:$H$13=$B4)/($J$4:$J$13=C4),$I$4:$I$13)

 

[leonguyenz]

Bạn dùng cách của thầy ndu96081631:

Dùng cái này thì khỏi Ctrl + Shift + Enter gì ráo:

=LOOKUP(2,1/($A$7:$A$12=E7)/($C$7:$C$12=F7),$B$7:$B$12)

 

[phihndhsp]

Trong cách bố trí bài này ngày tháng khác nhau nên có thể dùng cái này tạm cũng được
=OFFSET($B$6,MATCH(F7,$C$7:$C$12,0),0)