Hỏi nhanh - đáp nhanh

[dat_butmuc]

các anh chị cho em hỏi bài trong file đính kèm nha
mục điểm ưu tiên , cho em biết em sai chỗ nào mà nó báo #N/A
hàm là =VLOOKUP(RIGHT(C6,1),$G$12:$H$15,2,0)

Bảng tham chiếu (cột dùng tham chiếu - mã ưu tiên) của bạn đang là number, giá trị tham chiếu là Text => lỗi.
Vì vậy nên dùng:

=VLOOKUP(--RIGHT(C6),$G$12:$H$15,2,0)

Hoặc:

=VLOOKUP(1*RIGHT(C6),$G$12:$H$15,2,0)

Hoặc:

=VLOOKUP(value(RIGHT(C6)),$G$12:$H$15,2,0)

 

[dangqtkd]

ai chỉ em 1 chút về bài tập này nha

em đang bí câu 6 file đính kèm , ai xem giùm em dùng hàm countif có đúng không ạ .

 

[BNTT]

em đang bí câu 6 file đính kèm , ai xem giùm em dùng hàm countif có đúng không ạ .

COUNTIF thì phải có một vùng để nó đếm chứ bạn, sao bạn chỉ dùng =COUNTIF(D1,LEFT(A6,2)), cái vùng để đếm chỉ có mỗi 1 ô, vậy đếm làm gì?

Nhưng có lẽ nếu để thống kê số lượng đã bán, bạn dùng SUMIF có lý hơn, SUM = tổng những sản phẩm đã bán ra.

Bạn dùng công thức này cho ô G18 (rồi copy xuống đến G22) nhé:

=SUMIF($A$6:$A$13, F18&"*", $D$6)

 

[Lê Duy Thương]

em đang bí câu 6 file đính kèm , ai xem giùm em dùng hàm countif có đúng không ạ .

đặt công thức này cho
F18=SUM(IF(LEFT($A$6:$A$13,2)=$F18,$D$6:$D$13))

 

[dangqtkd]

COUNTIF thì phải có một vùng để nó đếm chứ bạn, sao bạn chỉ dùng =COUNTIF(D1,LEFT(A6,2)), cái vùng để đếm chỉ có mỗi 1 ô, vậy đếm làm gì?

Nhưng có lẽ nếu để thống kê số lượng đã bán, bạn dùng SUMIF có lý hơn, SUM = tổng những sản phẩm đã bán ra.

Bạn dùng công thức này cho ô G18 (rồi copy xuống đến G22) nhé:

=SUMIF($A$6:$A$13, F18&"*", $D$6) hàm của bạn rất đúng mihf hơi khó hiểu
bạn có thể giải thích rõ cho mình tại sao ra như vậy đc không ?
chỗ mà F18&"*",$D$6

 

[BNTT]

=SUMIF($A$6:$A$13, F18&"*", $D$6) hàm của bạn rất đúng mihf hơi khó hiểu
bạn có thể giải thích rõ cho mình tại sao ra như vậy đc không ?
chỗ mà F18&"*",$D$6

Dấu * đại diện cho bất kỳ thứ gì đứng sau lưng cái đang có ở F18.

Ví dụ, F18 là HD, thì SUMIF sẽ đi tìm hết trong $A$6:$A$13, lôi cổ hết mấy em HD1, HD2, HD3..... ra mà tính tổng của nó ở bên cột D.

 

[BNTT]

đặt công thức này cho
F18=SUM(IF(LEFT($A$6:$A$13,2)=$F18,$D$6:$D$13))

Nếu đặt như thế này, phải nhấn Ctrl+Shift+Enter thì nó mới chạy, vì đó là công thức mảng.

Nhưng có cần phải dùng đến công thức mảng không? Nếu thích dùng dạng như thế, thì dùng SUMPRODUCT để chỉ cần nhấn Enter thôi:

=SUMPRODUCT((LEFT($A$6:$A$13,2)=F18)*$D$6:$D$13)

 

[dangqtkd]

anh chị ai giúp em câu 10 và câu 12 trong file đc k ạ , em chẳng hiểu gì hết .

 

[MinhCong]

anh chị ai giúp em câu 10 và câu 12 trong file đc k ạ , em chẳng hiểu gì hết .

Câu 10: Là câu trích lọc dùng Advanced Filter để lọc.
Câu 12: Vẽ biểu đồ dựa trên số liệu thống kê của câu 11.
Bạn xem file nhé! Có hướng dẫn cách làm.

 

[Quang Tinh]

bài này đề câu 10 hình như là nhầm vì tất cả các thí sinh dự thi này đều thi khối A ( Toán ,lý, hoá) nếu trích lọc ra thí sinh dự thi có mã ngành là A thì hợp lý hơn

 

[dangqtkd]

Câu 10: Là câu trích lọc dùng Advanced Filter để lọc.
Câu 12: Vẽ biểu đồ dựa trên số liệu thống kê của câu 11.
Bạn xem file nhé! Có hướng dẫn cách làm.

bạn ơi sao mình làm bảng advanced theo chỉ dẫn của bạn mà nó quét rồi copy lại y hệt tất cả các khối ABC luôn

 

[MinhCong]

bạn ơi sao mình làm bảng advanced theo chỉ dẫn của bạn mà nó quét rồi copy lại y hệt tất cả các khối ABC luôn

Bạn xem lại cái điều kiện của nó có đúng không nhé! phải có dấu * phía sau chữ A (A*)

 

[mrphandinh]

Đặt điều kiện để ra kết quả tại 1 cell

Lời đề nghị giúp đỡ em viết trong file đính kèm. Các bác rảnh vào giúp em. Em cảm ơn nhiều

 

[Hai Lúa Miền Tây]

Lời đề nghị giúp đỡ em viết trong file đính kèm. Các bác rảnh vào giúp em. Em cảm ơn nhiều

Bạn dùng sumif nhé
E3=SUMIF($B$4:$B$15,"<"&D1,$C$4:$C$15)

 

[minabe]

Cho mình hỏi muốn khóa 1 vùng dữ liệu ( một vài cell) trong 1 sheet thì làm ntn ?
Thanks

 

[MinhCong]

Cho mình hỏi muốn khóa 1 vùng dữ liệu ( một vài cell) trong 1 sheet thì làm ntn ?
Thanks

Bấm Ctrl+A -> Phải chuột chọn Format cell -> Trong thẻ Protections bỏ dấu tick ở ô Locked -> OK
Chọn những ô muốn khóa -> Phải chuột chọn Format cell -> Trong thẻ Protections chọn dấu tick ở ô Locked -> OK
-> Vào Tool -> Đặt pass cho nó

 

[fdcode281]

chào mọi người, cho mình hỏi về sự khác nhau giữa 2 câu lệnh này:
1/ HLOOKUP(0+MID(B4,2,2),$A$27:$F$29,2,TRUE)
2/ HLOOKUP(MID(B4,2,2),$A$27:$F$29,2,TRUE)

Vì lúc đầu khi mình viết giống cái thứ 2 thì nó báo N/A, nhưng khi viết giống cái thứ 1 thì nó lại báo tìm đc Cái này có phải do lỗi của excel k hả mọi người??

 

[hoangdanh282vn]

chào mọi người, cho mình hỏi về sự khác nhau giữa 2 câu lệnh này:
1/ HLOOKUP(0+MID(B4,2,2),$A$27:$F$29,2,TRUE)
2/ HLOOKUP(MID(B4,2,2),$A$27:$F$29,2,TRUE)

Vì lúc đầu khi mình viết giống cái thứ 2 thì nó báo N/A, nhưng khi viết giống cái thứ 1 thì nó lại báo tìm đc Cái này có phải do lỗi của excel k hả mọi người??

khác nhau ở chỗ :

0+MID(B4,2,2) : là một số
MID(B4,2,2) : là một chuỗi.

chuỗi và số nhìn thì giống nhau nhưng khi dùng để tính toán hay tìm kiếm thì lại khác nhau. nếu dữ liệu của bạn có dạng số thì phải dùng công thức 1 mới tìm thấy.

 

[nonut]

làm sao để khi vlookup nó không trả kết quả là #N/A mà là 0 (Zero) khi không tìm thấy dữ liệu?

 

[BNTT]

làm sao để khi vlookup nó không trả kết quả là #N/A mà là 0 (Zero) khi không tìm thấy dữ liệu?

Bạn lồng thêm hàm IF và ISNA vào hàm VLOOKUP:

=IF(ISNA(VLOOKUP(hàm của bạn)), 0, VLOOKUP(hàm của bạn))​