Hỏi nhanh - đáp nhanh về công thức (phần 1) (4 người xem)

bebo021999 · 16/8/11

hoanghienminh đã viết:
Tôi có bảng tính mong anh chị em giúp đỡ. Tôi xin được mô tả như sau:
Tại ô C3 tôi cần có kết quả thoả mãn điều kiện (nếu C1 và C2 cùng trống thì C3 trống; nếu C2 trống mà C1 không trống thì C3 có giá trị bằng C1; các trường hợp còn lại sẽ trả về giá trị là 1). Điểm quan trọng nhất tôi cần là nếu C1 và C2 cùng không có dữ liệu thì C3 cũng không có dữ liệu; nếuC1 có dữ liệu còn C2 không có dữ liệu thì C3 sẽ lấy dữ liệu từ C1.
Kính mong các anh chị bớt chút thời gian viết giúp tôi hàm trong trường hợp này.
Chân thành cảm ơn!

Thử công thức này tại C3:

Mã:

=IF(AND(C1="",C2=""),"",IF(C2="",C1,1))

phihndhsp đã viết:
=IF($C$1&$C$2="","",IF(AND($C$1<>"",$C$2=""),$C$1,1))
bạn xem công thức này được hơn không

Như của phihndhsp sửa 1 chút cho ngắn hơn cũng được:

Mã:

=IF(C$1&C$2="","",IF(C$2="",C$1,1))

yinghong · 16/8/11

Hỏi về các hàm và công thức Excel

Cảm ơn các bạn!Mình thực sự là không hiểu rõ về mấy cái NNLT, nên mình cũng không biết nó có gọi là NNLT không. Vì mình chỉ muốn biết sử dụng Excel để có thể áp dụng vô công việc của mình. Ví dụ như quản lý bán hàng và hóa đơn bán lẻ (theo mình hiểu thì nó cũng gần như là lập trình) mình tạo cho nó rùi và sau đó mình chỉ cần gõ 1 lệnh hay 1 mã nào đó (đã được đặt trước) là nó ra những thông tin mình cần mà không phải mất thời gian để nhập tất cả các thông tin đó như tên hàng, đơn giá, tên khách hàng, địa chỉ, điện thoại...và các công việc khác của mình như làm lương và công.Ý mình là mình có thể sử dụng các hàm của Excel cho công việc của mình.Mong các bạn chỉ giùm.Many thanks

kimhang1980 · 16/8/11

nói quá dai dòng đã tạo rồi làm dc rồi còn hỏi cái gì không hiểu luôn.nói cái bạn càn là gì?

hoanghienminh · 16/8/11

Cảm ơn các anh chị đã giúp đỡ. Tôi làm được rồi (các hàm đều rất tuyệt vời).
Xin chân thành cảm ơn!

hockhiem · 17/8/11

TRUE,MID(N14,11,1) nghĩa là sao? mình không hiểu lắm

vukien · 17/8/11

Các bậc Tiền bối giúp em về hàm đếm nhiều điệu kiện

E đang vướng phải hàm đếm nhiều điều kiện chưa khắc phục được mong các tiền bối giúp đỡ:
E muốn tổng hợp các NV bán hàng, các bậc tiền bối xem file e gửi đính kèm nhé.
Rất mong các bác hồi âm sớm
nic: vukien_unilever
Mail: vu.kien.unilever@gmail.com

Cảm ơn các bác

dhn46 · 17/8/11

bạn tìm kiếm trên diễn đàn về hàm SUMPRODUCT nha. Đó là chìa khoá đó -=09=

phihndhsp · 18/8/11

vukien đã viết:
E đang vướng phải hàm đếm nhiều điều kiện chưa khắc phục được mong các tiền bối giúp đỡ:
E muốn tổng hợp các NV bán hàng, các bậc tiền bối xem file e gửi đính kèm nhé.
Rất mong các bác hồi âm sớm
nic: vukien_unilever
Mail: vu.kien.unilever@gmail.com

Cảm ơn các bác

có thể sử dụng các hàm D
nếu sử dụng 2007 có thêm hàm Countifs

yinghong · 19/8/11

Hỏi về các hàm và công thức Excel

kimhang1980 đã viết:
nói quá dai dòng đã tạo rồi làm dc rồi còn hỏi cái gì không hiểu luôn.nói cái bạn càn là gì?

cái này mình chỉ biết dùng hàm Vlookup thui còn những hàm khác mình k biết dùng mình muốn hỏi các bạn cấu trúc và các dùng các hàm khác

motorolavn · 20/8/11

Mình đang bí không biết thống kê dữ liệu, mình có 1 sheet chứa dữ liệu tên là "Nhập", mình muốn thống kê theo từng Tuần để báo cáo trong sheet "Thống kê" (khi B2 thay đổi)
nhờ các bạn giúp mình với. **~**

phihndhsp · 20/8/11

Bạn thử cách cùi mía này xem sao
C6=INDEX(OFFSET(IF($B$2=1,Nhập!$B$4,IF($B$2=2,Nhập!$B$15,Nhập!$B$26)),1,1,8,4),MATCH($B6,Nhập!$B$5:$B$12,0),MATCH('Thống kê'!C$5,Nhập!$C$4:$F$4,0))

Lê Duy Thương · 20/8/11

motorolavn đã viết:
Mình đang bí không biết thống kê dữ liệu, mình có 1 sheet chứa dữ liệu tên là "Nhập", mình muốn thống kê theo từng Tuần để báo cáo trong sheet "Thống kê" (khi B2 thay đổi)
nhờ các bạn giúp mình với.

DÙNG CÔNG THỨC NÀY CHO SHEET THỐNG KÊ B6 BẠN NHÉ
CÒN NHIỀU CÁCH NỮA

PHP:

=OFFSET(Nhập!$A$1,MATCH($B$2,Nhập!$A:$A,0)+ROWS($1:1)-2,COLUMN()-1,,)

motorolavn · 20/8/11

phihndhsp đã viết:
Bạn thử cách cùi mía này xem sao
C6=INDEX(OFFSET(IF($B$2=1,Nhập!$B$4,IF($B$2=2,Nhập!$B$15,Nhập!$B$26)),1,1,8,4),MATCH($B6,Nhập!$B$5:$B$12,0),MATCH('Thống kê'!C$5,Nhập!$C$4:$F$4,0))

Thank bạn nhiều, nhưng cần phải sửa lại 1 chút ở B2 thì chạy ngon, vì B2 là Validation mà.

Lê Duy Thương đã viết:
DÙNG CÔNG THỨC NÀY CHO SHEET THỐNG KÊ B6 BẠN NHÉ
CÒN NHIỀU CÁCH NỮA

PHP:

=OFFSET(Nhập!$A$1,MATCH($B$2,Nhập!$A:$A,0)+ROWS($1:1)-2,COLUMN()-1,,)

Tuyệt vời, bác Thương lại 1 lần nữa ra tay giúp em. Nợ bác nhiều quá , hiii

Hoàng Trọng Nghĩa · 20/8/11

motorolavn đã viết:
Thank bạn nhiều, nhưng cần phải sửa lại 1 chút ở B2 thì chạy ngon, vì B2 là Validation mà.

Tuyệt vời, bác Thương lại 1 lần nữa ra tay giúp em. Nợ bác nhiều quá , hiii

Cũng còn một cách này nữa, cũng khá thú vị: Dùng VLOOKUP

Mã:

[COLOR=#0000ff]=VLOOKUP([/COLOR][COLOR=#006400]$B6[/COLOR][COLOR=#0000FF],OFFSET([/COLOR][COLOR=#ff0000][B]DuLieuGoc[/B][/COLOR][COLOR=#0000FF],([/COLOR][COLOR=#800080]$B$2[/COLOR][COLOR=#0000FF]-1)*11,,,),COLUMN()-1,0)[/COLOR]

Lê Duy Thương đã viết:
DÙNG CÔNG THỨC NÀY CHO SHEET THỐNG KÊ B6 BẠN NHÉ
CÒN NHIỀU CÁCH NỮA

PHP:

=OFFSET(Nhập!$A$1,MATCH($B$2,Nhập!$A:$A,0)+ROWS($1:1)-2,COLUMN()-1,,)

Cái này thì hay, nhưng tại sheet Thống Kê, lỡ dại sort từ Z đến A cột LỚP hoặc cũng là các tên lớp đó mà thử đảo lộn trật tự thì "má nhìn hỏng ra" kekekekeke

=====================================================================================

Đối với dạng này, nên làm một cơ sở dữ liệu thì không cần phải cứ mỗi tuần mỗi copy từng bảng một. Sau đó dùng Pivot Table thống kê, hoặc AutoFilter là đẹp.

Lê Duy Thương · 20/8/11

minhthien321 đã viết:
cũng còn một cách này nữa, cũng khá thú vị: Dùng vlookup

Mã:

[COLOR=#0000ff]=vlookup([/COLOR][COLOR=#006400]$b6[/COLOR][COLOR=#0000ff],offset([/COLOR][COLOR=#ff0000][B]dulieugoc[/B][/COLOR][COLOR=#0000ff],([/COLOR][COLOR=#800080]$b$2[/COLOR][COLOR=#0000ff]-1)*11,,,),column()-1,0)[/COLOR]

Mã:

[COLOR=#000000][COLOR=#007700]=[/COLOR][COLOR=#0000BB]OFFSET[/COLOR][COLOR=#007700]([/COLOR][COLOR=#0000BB]Nhập[/COLOR][COLOR=#007700]![/COLOR][COLOR=#0000BB]$A[/COLOR][COLOR=#007700]$[/COLOR][COLOR=#0000BB]1[/COLOR][COLOR=#007700],[/COLOR][COLOR=#0000BB]MATCH[/COLOR][COLOR=#007700]([/COLOR][COLOR=#0000BB]$B[/COLOR][COLOR=#007700]$[/COLOR][COLOR=#0000BB]2[/COLOR][COLOR=#007700],[/COLOR][COLOR=#0000BB]Nhập[/COLOR][COLOR=#007700]![/COLOR][COLOR=#0000BB]$A[/COLOR][COLOR=#007700]:[/COLOR][COLOR=#0000BB]$A[/COLOR][COLOR=#007700],[/COLOR][COLOR=#0000BB]0[/COLOR][COLOR=#007700])+[/COLOR][COLOR=#0000BB]ROWS[/COLOR][COLOR=#007700]($[/COLOR][COLOR=#0000BB]1[/COLOR][COLOR=#007700]:[/COLOR][COLOR=#0000BB]1[/COLOR][COLOR=#007700])-[/COLOR][COLOR=#0000BB]2[/COLOR][COLOR=#007700],[/COLOR][COLOR=#0000BB]COLUMN[/COLOR][COLOR=#007700]()-[/COLOR][COLOR=#0000BB]1[/COLOR][COLOR=#007700],,)[/COLOR][/COLOR]

cái này thì hay, nhưng tại sheet thống kê, lỡ dại sort từ z đến a cột lớp hoặc cũng là các tên lớp đó mà thử đảo lộn trật tự thì "má nhìn hỏng ra" kekekekeke

=====================================================================================

đối với dạng này, nên làm một cơ sở dữ liệu thì không cần phải cứ mỗi tuần mỗi copy từng bảng một. Sau đó dùng pivot table thống kê, hoặc autofilter là đẹp.

làm sao sort được mà lỡ mới chả không minhthien. Vì công thức luôn cập nhật mà . Sort cũng như không thôi
trừ khi sheet "nhập thay đổi'' hàm match tìm không thấy . Hay là bạn có cách gì khác chăng ?

ndu96081631 · 20/8/11

Bôi đen vùng B4:F13 rồi gõ vào thanh Formula công thức:

PHP:

=OFFSET(Nhập!$B$3:$F$12,($B$2-1)*11,)

Bấm tổ hợp phím Ctrl + Shift + Enter
Có phải gọn không? 1 phát ra toàn bộ

Ba Tê · 20/8/11

Ôi! Nhiều cách quá, tham gia thêm cho vui.
Nhập công thức vào ô B4 rồi kéo ngang kéo dọc. Nó lấy nguyên xi nội dung trong cái bảng bên kia giống như ndu... "chơi" nguyên một mảng, hì hì...

PHP:

=OFFSET(Nhập!$A$1;$B$2*11-(13-ROWS($1:4));COLUMNS($A:A))

Hoàng Trọng Nghĩa · 21/8/11

Xin vui lòng xóa giúp bài này! Cảm ơn SMOD/ MOD

Hoàng Trọng Nghĩa · 21/8/11

ndu96081631 đã viết:
Bôi đen vùng B4:F13 rồi gõ vào thanh Formula công thức:

PHP:

=OFFSET(Nhập!$B$3:$F$12,($B$2-1)*11,)

Bấm tổ hợp phím Ctrl + Shift + Enter
Có phải gọn không? 1 phát ra toàn bộ

Đúng là công thức mãng này cũng quái chiêu thiệt! Không cho chạy tên nào hết! Bao trọn gói! Hay!

hockhiem · 23/8/11

Cái nút nhập liệu trọng bảng tính này đã record như thế nào?

motorolavn · 24/8/11

thêm 1 cách tính hơi kì cục, mình suy nghĩ hoài chẳng ra cái hàm ( 1 phát ăn ngay) nào cho phù hợp cả,
Tính giá trị Trung bình dựa theo điều kiện.

bebo021999 · 24/8/11

motorolavn đã viết:
thêm 1 cách tính hơi kì cục, mình suy nghĩ hoài chẳng ra cái hàm ( 1 phát ăn ngay) nào cho phù hợp cả,
Tính giá trị Trung bình dựa theo điều kiện.

Dùng cái này tại cột C nhé:

Mã:

=SUMPRODUCT(($B$15:$B$51>=$B$53)*($B$15:$B$51<=$D$53),C$15:C$51)/SUMPRODUCT(($B$15:$B$51>=$B$53)*($B$15:$B$51<=$D$53))

motorolavn · 24/8/11

bebo021999 đã viết:
Dùng cái này tại cột C nhé:

Mã:

=SUMPRODUCT(($B$15:$B$51>=$B$53)*($B$15:$B$51<=$D$53),C$15:C$51)/SUMPRODUCT(($B$15:$B$51>=$B$53)*($B$15:$B$51<=$D$53))

chính xác, hay thật, mình mới làm quen với excel và viết hàm theo các bài hướng dẫn nên ko biết các "biến hóa" này, đúng là hay. hehe mê rồi $-\\/.$

ndu96081631 · 24/8/11

bebo021999 đã viết:
Dùng cái này tại cột C nhé:

Mã:

=SUMPRODUCT(($B$15:$B$51>=$B$53)*($B$15:$B$51<=$D$53),C$15:C$51)/SUMPRODUCT(($B$15:$B$51>=$B$53)*($B$15:$B$51<=$D$53))

Chỉ cần ngắn thế này thôi:

PHP:

=AVERAGE(IF(($B$15:$B$51>=$B$53)*($B$15:$B$51<=$D$53),C$15:C$51,""))

Kết thúc công thức bằng tổ hợp phím Ctrl + Shift + Enter

phihndhsp · 24/8/11

Góp vui thêm công thức nữa nếu sài 2007 thì có công thức AverageIfs
=AVERAGEIFS($C$15:$C$51,$B$15:$B$51,">="&$B$53,$B$15:$B$51,"<="&$D$53)

hoangluong · 24/8/11

Xử lý lỗi #value

Kính gửi: ACE

Mong các Anh/Chị hướng dẫn về việc bỏ lỗi #value trong file đính kèm

Cảm ơn các Anh/Chị nhiều

phihndhsp · 24/8/11

vì dữ liệu trong cột F của bạn là chuỗi nên nó báo lỗi #Value, chính vì vậy bạn nên dùng bẫy lỗi
nếu dùng 2007
=IFERROR(C10*D10*F10,"")
dùng 2003
=IF(ISERROR(C10*D10*F10),"",C10*D10*F10)

dhn46 · 4/9/11

Em xin chào diễn đàn. E đang mon men tìm hiểu công thức mảng, các anh chị có thể giải thích cụ thể cho e công thức trích lọc duy nhất được không ạ (e muốn tìm hiểu bản chất của nó nhưng chưa hình dung được
Công thức của bác NDU hay dùng

Mã:

=INDEX(TenNV,SMALL(IF(MATCH(TenNV,TenNV,0)=ROW(INDIRECT("1:"&ROWS(TenNV))),MATCH(TenNV,TenNV,0),""),ROWS($1:1)))

ptm0412 · 4/9/11

hoangluong đã viết:
Kính gửi: ACE

Mong các Anh/Chị hướng dẫn về việc bỏ lỗi #value trong file đính kèm

Cảm ơn các Anh/Chị nhiều

Sửa công thức F10 thành:
=IF(E10<>0; VLOOKUP(E10; $B$3:$C$6;2;0); 0)
Thì cột G tự nhiên sẽ hết lỗi. Nghĩa là dữ liệu trong cùng 1 cột nên là cùng kiểu.

Phi đã viết:
vì dữ liệu trong cột F của bạn là chuỗi nên nó báo lỗi #Value, chính vì vậy bạn nên dùng bẫy lỗi

Bao giờ cũng nên sửa gốc, không nên sửa ngọn. Sửa gốc chỉ sửa 1 lần, sửa ngọn thì có bao nhiêu ngọn phải sửa hết, ngoài ra có những ngọn sau đó mới nảy sinh thêm.

ptm0412 · 4/9/11

dhn46 đã viết:
Em xin chào diễn đàn. E đang mon men tìm hiểu công thức mảng, các anh chị có thể giải thích cụ thể cho e công thức trích lọc duy nhất được không ạ (e muốn tìm hiểu bản chất của nó nhưng chưa hình dung được
Công thức của bác NDU hay dùng

Mã:

=INDEX(TenNV,SMALL(IF(MATCH(TenNV,TenNV,0)=ROW(INDIRECT("1:"&ROWS(TenNV))),MATCH(TenNV,TenNV,0),""),ROWS($1:1)))

Hãy tìm hiểu từ trong ra ngoài:
Rows(TenNV) = 1 con số, chỉ số dòng của vùng TenNV, thí dụ 10
Indirect("1:10") = 1:10
Row(1:10) = 1 mảng 10 phần tử từ 1 đến 10 (Mảng 1)

MATCH(TenNV,TenNV,0) = vị trí đầu tiên tìm thấy của từng nhân viên trong mảng TenNV (vì Match chỉ lấy vị trí đầu tiên)
Kết quả của Match cũng là 1 mảng 10 phần tử, trong đó sẽ có những phần tử giống nhau, giá trị trong phạm vi 1-10. (Mảng 2)

Hàm If: So sánh từng phần tử của mảng 1 và mảng 2, nếu giống nhau (chỉ vị trí đầu của NV mới giống, vị trí thứ 2 trở đi không giống nữa), thì lấy vị trí đầu tiên. Nếu không giống (các vị trí thứ 2 trở đi), thì thay giá trị (Match) bằng chuỗi rỗng ""
Kết quả của hàm If sẽ là mảng 3: Chỉ gồm các số duy nhất, là vị trí đầu tiên của mỗi NV trong TenNV, các phần tử khác là giá trị rỗng

ROWS($1:1) = số dòng của vùng $1:1. Nếu fill xuống sẽ là số dòng của vùng $1:2, $1:3, ... Kết quả sau khi fill sẽ là 1, 2, 3, ... nhưng giá trị tại ô đang xét = 1
Small(Mảng 3, i) = 1 con số nhỏ thứ i trong mảng 3, là vị trí đầu tiên tìm thấy của NV thứ i.

Index(TenNV, vị trí) = .... (không biết, ai biết chỉ dùm)

bebo021999 · 4/9/11

Chào bạn dhn46,
Để tìm hiểu cách trích lọc duy nhất dùng công thức mảng, đầu tiên bạn cần tìm hiểu từng thành phần của công thức trên.
Giả sử TenNV là vùng A1:A7, gồm 3 cái tên lặp lại trong 7 dòng:
Nguyen Van A
Tran Thi B
Tran Thi B
Nguyen Van A
Le Van C
Nguyen Van A
Le Van C

Mục đích chúng ta là trích xuất tại C1,C2 và C3:
Nguyen Van A
Tran Thi B
Le Van C

Có nhiều công thức tính, công thức của bạn là 1 trong nhiều cách:

Mã:

=INDEX(TenNV,SMALL(IF(MATCH(TenNV,TenNV,0)=ROW(INDIRECT("1:"&ROWS(TenNV))),MATCH(TenNV,TenNV,0),""),ROWS($1:1)))

Trong đó, thành phần chính là hàm MATCH(TenNV,TenNV,0)

Theo cấu trúc của hàm MATCH, ta dịch ra là: tìm vị trí chính xác của các phần tử có trong TenNV trong tập hợp TenNV, trả về kết quả là vị trí trong mảng.

Mảng TenNV có 7 phần tử nên sẽ trả về 7 giá trị vị trí.

Dùng F9 để xem kết quả: Bôi đen phần hàm MATCH, nhấn F9, bạn sẽ thấy kết quả như sau: {1;2;2;1;5;1;5}

Vì đặc tính của hàm MATCH là luôn trả về vị trí của giá trị đầu tiên tìm thấy trong mảng, do đó Trong TenNV, Nguyen Van A nằm ở vị trí 1,4,6 sẽ trả về giá trị 1 nằm ở vị trí 1,4,6 tương ứng.

Quan sát mảng kết quả, dễ dàng nhận thấy 3 giá trị tên duy nhất xuất hiện đầu tiên tại 3 vị trí 1,2 và 5.
Đây chính là tham số vị trí trong hàm INDEX đễ truy xuất ra giá trị trong TenNV
C1=INDEX(TenNV,1) = Nguyen Van A
C2=INDEX(TenNV,2) = Tran Thi B
C3=INDEX(TenNV,5) = Le Van C
Đến đây phát sinh ra yêu cầu: dùng cách nào để lấy giá trị 1,2,5 trong mảng kết quả tương ứng với ô C1,C2,C3?

Hàm ROW: Ta thường dùng để tạo 1 mảng bao gồm n số liên tục
ROW(1:7) = {1;2;3;4;5;6;7}
Tổng quát hơn: tương ứng với số phần tử của TenNV
ROW(INDIRECT("1:"&ROWS(TenNV)))= {1;2;3;4;5;6;7} (Dùng F9 để xem)

Đặt 2 mảng cạnh nhau để so sánh 1 cách trực quan:
{1;2;2;1;5;1;5} = MATCH(TenNV,TenNV,0)
{1;2;3;4;5;6;7} = ROW(INDIRECT("1:"&ROWS(TenNV)))
Dể dàng nhận ra các giá trị cần lấy trùng nhau :
Dùng IF(MATCH(TenNV,TenNV,0)=ROW(INDIRECT("1:"&ROWS(TenNV))),MATCH(TenNV,TenNV,0),"")
= {1;2;"";"";5;"";""} (Dùng F9 để xem)
Dùng hàm SMALL để lần lượt lấy các giá trị trong mảng:
SMALL(IF(MATCH(TenNV,TenNV,0)=ROW(INDIRECT("1:"&ROWS(TenNV))),MATCH(TenNV,TenNV,0),""),ROWS($1:1))
sẽ có KQ tại C1 = 1 (tương ứng với ROWS($1:1)=1)
C2 = 2 (tương ứng với ROWS($1:2)=2)
C3 = 5 (tương ứng với ROWS($1:3)=3)

Dùng INDEX ta sẽ có kết quả cuối cùng.

dhn46 · 4/9/11

Hay quá. Công thức mảng hay thật. Bây giờ thì em ("cháu" - chú PTM) đã hiểu. Cảm ơn chú, anh rất nhiều!

HYDT · 5/9/11

Xin cho em hỏi, em đang thử sử dụng hàm index và match để tìm và lấy dữ lệu nhưng không ra được kết quả, vấn đề cụ thể như file đính kèm ( View attachment GP-EXCEL.xls ) em sử dụng mã để truy tìm, công thức sử dụng là

=INDEX(THDT!A2:J5;MATCH(LAM!A2;THDT!A2:A5;0);2)

Em đã chuyển mã truy xuất sang định dạng text nhưng vẫn không được, nhờ anh, em, cô, chú, cậu, dì giúp đỡ. Cảm ơn nhều ạ.

bebo021999 · 5/9/11

HYDT đã viết:
Xin cho em hỏi, em đang thử sử dụng hàm index và match để tìm và lấy dữ lệu nhưng không ra được kết quả, vấn đề cụ thể như file đính kèm ( View attachment 69465 ) em sử dụng mã để truy tìm, công thức sử dụng là

=INDEX(THDT!A2:J5;MATCH(LAM!A2;THDT!A2:A5;0);2)

Em đã chuyển mã truy xuất sang định dạng text nhưng vẫn không được, nhờ anh, em, cô, chú, cậu, dì giúp đỡ. Cảm ơn nhều ạ.

Công thức của bạn:

Mã:

=INDEX(THDT!A2:J5,MATCH(LAM!A3,THDT!A2:A5,0),0)

sửa lại như sau, sửa tham số 0 thành 2, cố định địa chỉ lại để copy xuống được chính xác:

Mã:

=INDEX(THDT!$A$2:$J$5,MATCH(LAM!A3,THDT!$A$2:$A$5,0),2)

tansi12h · 6/9/11

Giúp em một chút về công thức sum !

Tình hình là hôm qua em post bài này :
Hi all !
Em có một chút rắc rối với file báo cáo nhờ anh chị có ai biết giải thích giùm em.
Không hiểu sao kết quả ở cột AE vẫn còn một số lẻ rất nhỏ, nếu em paste value giá trị ở cột AC thì AE sẽ không còn nữa.
Em đã kiểm tra rất kỹ các phần tử trong Sum ở AC nhưng vẫn không thấy chỗ nào bị dư như thế
Anhchị giúp em với !
Đang làm báo cáo gấp quá mà nếu cứ paste value kiểu này thì chỉ có nước mà về vườn quá
Cảm ơn mọi người nha !

Nhưng lần đầu attach file bị lỗi, chưa kịp chỉnh thì đã bị move
Giờ vào em mới biết
Em attach file đây ạh , mọi người giúp em với.

ndu96081631 · 6/9/11

tansi12h đã viết:
Tình hình là hôm qua em post bài này :
Hi all !
Em có một chút rắc rối với file báo cáo nhờ anh chị có ai biết giải thích giùm em.
Không hiểu sao kết quả ở cột AE vẫn còn một số lẻ rất nhỏ, nếu em paste value giá trị ở cột AC thì AE sẽ không còn nữa.
Em đã kiểm tra rất kỹ các phần tử trong Sum ở AC nhưng vẫn không thấy chỗ nào bị dư như thế
Anhchị giúp em với !
Đang làm báo cáo gấp quá mà nếu cứ paste value kiểu này thì chỉ có nước mà về vườn quá
Cảm ơn mọi người nha !

Nhưng lần đầu attach file bị lỗi, chưa kịp chỉnh thì đã bị move
Giờ vào em mới biết
Em attach file đây ạh , mọi người giúp em với.

Công thức tại cell AC4 của bạn đang là:

PHP:

=W4+X4+Y4+Z4+AB4+V4

Sao không sửa thành:

PHP:

=SUM(V4:Z4,AB4)

vu_tuan_manh_linh · 6/9/11

Có thể do tính toán trong excel vẫn có sai số mà bạn, do giới hạn của giá trị các kiểu dữ liệu. Bạn làm thế này nhé: Đóng ngoặc phần cộng từ T4 đến hết công thức. Công thức sẽ như sau:
=SUM(L4:O4)+(T4-AC4-AF4-AG4-AH4).

lethuycaylua · 6/9/11

Dùng hàm gì

Chào BQT và các thành viên trong diễn đàn. Tôi có một nhu cầu cho công việc như trong File đính kèm, mọi người xem và cho ý kiến có thể dùng hàm được không, nếu được thì dùng hàm gì.Cảm ơn mọi người

bebo021999 · 6/9/11

Dùng công thức lằng ngoằng này tại G2 nhé:

Mã:

=OFFSET(Data!$C$1,,MATCH(1E+102,INDIRECT("Data!C"&MATCH($C2,Data!$C$1:$C$19,0)&":M"&MATCH($C2,Data!$C$1:$C$19,0)),1)-1)

kim1234 · 6/9/11

Giúp đỡ về công thức SUMIFS

Chào các bạn,

Theo dữ liệu trong file đính kèm thì mình muốn thống kê tất cả nhân viên trong tháng 08/2011 đã xuất được bao nhiêu hóa đơn (Ngày xuất hd ở cột D, tính tổng ở cột Q).
Mình có làm công thức trong sheet 2 nhưng kết quả ko chính xác.

Mọi người chỉnh lại giúp nhé

Thanks 4 all.

phihndhsp · 6/9/11

kim1234 đã viết:
Chào các bạn,

Theo dữ liệu trong file đính kèm thì mình muốn thống kê tất cả nhân viên trong tháng 08/2011 đã xuất được bao nhiêu hóa đơn (Ngày xuất hd ở cột D, tính tổng ở cột Q).
Mình có làm công thức trong sheet 2 nhưng kết quả ko chính xác.

Mọi người chỉnh lại giúp nhé

Thanks 4 all.

Hi hi trong 2003 làm sao dùng hàm Sumifs được bạn
Bạn thử làm như vầy xem sao
B2=SUMPRODUCT(('HD 2011'!$Q$5:$Q$43)*(MONTH('HD 2011'!$D$5:$D$43)=8))

tansi12h · 6/9/11

Em cảm ơn mọi người đã nhiệt tình trả lời
Em đã thử các cách trên nhưng vẫn có trường hợp được, trường hợp không
Anh chị nào cao tay xin chỉ giùm em với
Em attach file mà em đã thử công thức đây ạ !

Ba Tê · 6/9/11

tansi12h đã viết:
Em cảm ơn mọi người đã nhiệt tình trả lời
Em đã thử các cách trên nhưng vẫn có trường hợp được, trường hợp không
Anh chị nào cao tay xin chỉ giùm em với
Em attach file mà em đã thử công thức đây ạ !

Sao bạn không xem số liệu trong cột L của bạn, trong ô L5 nó là -9,05941988094128E-14, ô L7 là -5,47117906535277E-13, công thức ô AE5 =SUM(L5:O5)+(T5-AC5-AF5-AG5-AH5) có cả đống số lẻ của L5 trong đó.

kim1234 · 7/9/11

phihndhsp đã viết:
Hi hi trong 2003 làm sao dùng hàm Sumifs được bạn
Bạn thử làm như vầy xem sao
B2=SUMPRODUCT(('HD 2011'!$Q$5:$Q$43)*(MONTH('HD 2011'!$D$5:$D$43)=8))

hi, file thì của 2003 nhưng mình dùng 2010 bạn ạ. thanks ban nhé

lethuycaylua · 8/9/11

bebo021999 đã viết:
Dùng công thức lằng ngoằng này tại G2 nhé:

Mã:

=OFFSET(Data!$C$1,,MATCH(1E+102,INDIRECT("Data!C"&MATCH($C2,Data!$C$1:$C$19,0)&":M"&MATCH($C2,Data!$C$1:$C$19,0)),1)-1)

Cảm ơn mọi người đã nhiệt tình trả lời dạy bảo. Xin bậc thầy giải thích cho 1E+102 có nghĩa là gì.

bebo021999 · 8/9/11

lethuycaylua đã viết:
Cảm ơn mọi người đã nhiệt tình trả lời dạy bảo. Xin bậc thầy giải thích cho 1E+102 có nghĩa là gì.

1E+102 là số 1 và 102 số 0 phía sau, là số gần lớn nhất.
MATCH(1E102,MẢNG,1) là tìm giá trị số cuối cùng trong mảng.

ptm0412 · 8/9/11

bebo đã viết:
Dùng công thức lằng ngoằng này tại G2 nhé:
=OFFSET(Data!$C$1;;MATCH(1E+102;INDIRECT("Data!C"&MATCH($C2;Data!$C$1:$C$19;0)&":M"&MATCH($C2;Data!$C$1:$C$19;0));1)-1)

Cái này đỡ loằng ngoằng hơn nè:
=INDEX(Data!$C$1:$M$1;1;MATCH(10^10;OFFSET(Data!$C$1:$M$1;MATCH('Dich den'!$C2;Data!$C$2:$C$19;0);0);1))

Ngoài ra nếu đặt Name đoạn màu đỏ = data thì công thức sẽ gọn hơn:
=INDEX(Data!$C$1:$M$1;1;MATCH(10^10;Data1;1))

NH_DK · 13/9/11

Sửa dùm cho em công thức tính duy nhất

Em có ví dụ nhỏ này không hiểu sai chỗ nào mà không cho kết quả theo ý muốn?

ndu96081631 · 13/9/11

NH_DK đã viết:
Em có ví dụ nhỏ này không hiểu sai chỗ nào mà không cho kết quả theo ý muốn?

Vầy mới đúng:

PHP:

=IF(OR(COUNTIF($E$5:E5,aaa)+(LEFT(aaa)="A")=1),INDEX(aaa,MATCH(1,COUNTIF($E$5:E5,aaa)+(LEFT(aaa)="A"),0)),"")

downloader91 · 16/9/11

Làm sao cho nó tự tính theo kiểu
Ô màu xanh 28.37 - 28.35
rồi xuống dưới 28.37 - 28.4
v.v.v
Đánh cộng thức vào từng ô lâu quá.
Giúp mình với nha thanks mấy bạn

Luc Van · 16/9/11

downloader91 đã viết:
Làm sao cho nó tự tính theo kiểu
Ô màu xanh 28.37 - 28.35
rồi xuống dưới 28.37 - 28.4
v.v.v
Đánh cộng thức vào từng ô lâu quá.
Giúp mình với nha thanks mấy bạn

Thì cố định cell C14 (38.37) lại bằng cách nhấn F4.
nó sẽ thành ra vầy:

PHP:

 = ($C$14 - C4)*10^3

bebo021999 · 16/9/11

Cố định C14 lại thôi:
Thay C14 bằng $C$14.

downloader91 · 23/9/11

ô màu Đen là Sum cái khung màu đỏ. Sao nó ko ra = 0 mà nó ra số -2.1..... vậy mấy anh . giúp em với
cám ơn mấy anh ạ

ndu96081631 · 23/9/11

downloader91 đã viết:
ô màu Đen là Sum cái khung màu đỏ. Sao nó ko ra = 0 mà nó ra số -2.1..... vậy mấy anh . giúp em với
cám ơn mấy anh ạ

Chỉ là định dạng thôi mà bạn
Muốn 0 thì làm vầy: chọn cell màu đen rồi bấm tổ hợp phím Ctrl + Shift + !

thuypt1901 · 26/9/11

Chào các anh chị! }}}}}

Trong quá trình làm việc em có 1 vướng mắc sau, nhờ các anh chị trả lời giúp.

Em có 1 sheet tổng hợp tiền lương chẳng hạn bằng tiền VND. Trong sheet này có rất nhiều số và em đã subtotal các dữ liệu trong sheet này rồi.

Giờ em muốn tạo 1 sheet với các tiêu chí y như thế nhưng giá trị tính theo đồng USD. Tức là các giá trị trong sheet 1 sẽ phải chia cho tỷ giá ( cùng 1 tỷ giá ví dụ 20.000 ) . Em muốn tạo 2 sheet theo dõi theo VND và USD.

Các anh chị giúp em với, làm thế nào để giải quyết được vấn đề trên.

tansi12h · 6/10/11

Ba Tê đã viết:
Sao bạn không xem số liệu trong cột L của bạn, trong ô L5 nó là -9,05941988094128E-14, ô L7 là -5,47117906535277E-13, công thức ô AE5 =SUM(L5:O5)+(T5-AC5-AF5-AG5-AH5) có cả đống số lẻ của L5 trong đó.

Bạn ơi,mình biết chứ, mình cố tình để L5, L6, L7 vì đó là số dư đầu kỳ, nên dĩ nhiên là nó bị, còn dòng số 7 và 8, thì nó vẫn bị trong khi mọi thứ đều bình thường, bạn xem thử giùm mình

tanhaukg · 12/10/11

Nhờ giải thích dùm công thức

Em có công thức này nhưng không hiểu xin anh chị giải thích dùm em cảm ơn nhiều!
=IF(INFO("release")*1<11,SUBTOTAL(1,$E$7:$E$9629),SUBTOTAL(101,$E$7:$E$9629))

ndu96081631 · 12/10/11

tanhaukg đã viết:
Em có công thức này nhưng không hiểu xin anh chị giải thích dùm em cảm ơn nhiều!
=IF(INFO("release")*1<11,SUBTOTAL(1,$E$7:$E$9629),SUBTOTAL(101,$E$7:$E$9629))

Hàm INFO("release") để kiểm tra xem Excel của bạn là version nào ---> Nếu trả về kết quả =11 là Excel 2003, kết quả nhỏ hơn là Excel 2002, 2000...
Vậy công thức trên có thể phát biểu là:
Nếu (Version của Excel < 11 thì dùng SUBTOTAL(1, ....), ngược lại dùng SUBTOTAL(101,...))

nghiaphuc · 12/10/11

ndu96081631 đã viết:
Hàm INFO("release") để kiểm tra xem Excel của bạn là version nào ---> Nếu trả về kết quả =11 là Excel 2003, kết quả nhỏ hơn là Excel 2002, 2000...
Vậy công thức trên có thể phát biểu là:
Nếu (Version của Excel < 11 thì dùng SUBTOTAL(1, ....), ngược lại dùng SUBTOTAL(101,...))

Kể cũng lạ, dùng SUBTOTAL thì có liên quan gì đến vesion của Excel nhỉ?
(Công thức này cho biết rằng: Nếu version của Excel < 11 thì tính giá trị trung bình của tất cả các ô trong vùng $E$7:$E$9629, ngược lại thì tính giá trị trung bình của tất cả các ô hiện (không bị ẩn) trong vùng $E$7:$E$9629).

ndu96081631 · 12/10/11

nghiaphuc đã viết:
Kể cũng lạ, dùng SUBTOTAL thì có liên quan gì đến vesion của Excel nhỉ?

Đương nhiên là có liên quan rồi
Tham số Function_num trong SUBTOTAL của các version từ 2002 trở về trước chỉ từ 1 đến 11 mà thôi, chẳng có vụ 101, 102.. gì đâu
Cách đây vài năm, khi Excel 2003 còn thống soái, mỗi khi dùng SUBTOTAL phải tính cho các version trước đó nữa ---> Nếu viết =SUBTOTAL(101,...) rồi mở file trên Excel 2002 thì... tèo

tuantu711211 · 17/10/11

[help]sử dụng hàm sumì tính tổng??

chào moị người.
mình có một bảng tính lộn xộn lắm mình mún dùng hàm sum if để tính các ô chẳn trong một cột dài có nhiều dử liệu thì điều kiện trong hàm ssumif là gì ah.
VD mình tính tổng các ô A1 C1 E1.. bỏ qua các ô B1 D1...vì các ô B1,D1 có dử liệu số nên mình không biết làm sao để tính tổng các ô A,C,E
Mong mọi người giúp đỡ ah

bebo021999 · 17/10/11

Dùng cái này:

Mã:

=SUMPRODUCT(MOD(COLUMN(A1:E1),2)*A1:E1)

syro_dau77 · 18/10/11

Lấy số từ chuỗi text

Cho mình hỏi nếu bài tập yêu cầu lấy số lượng là các ký tự sau dấu " -" trong mã hàng. Vd như v18-003, v96-1450,us-1450,dm-0028. Dùng hàm gì các bạn?

phihndhsp · 19/10/11

syro_dau77 đã viết:
Cho mình hỏi nếu bài tập yêu cầu lấy số lượng là các ký tự sau dấu " -" trong mã hàng. Vd như v18-003, v96-1450,us-1450,dm-0028. Dùng hàm gì các bạn?

Bạn thử dùng công thức này xem sao
RIGHT(A1,LEN(A1)-FIND("-",A1))

syro_dau77 · 19/10/11

mình làm được ùi, cám ơn bạn!

Ba Tê · 20/10/11

phihndhsp đã viết:
Bạn thử dùng công thức này xem sao
RIGHT(A1,LEN(A1)-FIND("-",A1))

Như vầy thì bớt được một cái Len()

=MID(A1;FIND("-";A1)+1;10)

Số 10 màu đỏ muốn bi nhiêu cho vừa thì chọn.

sonltdb · 21/10/11

Giúp em về hàm excel

Chào các anh chị, +-+-+-+

em có một bảng excel như sau: ô A1 có 6 con số: 012345, ô A2 có 5 số: 23456. Em muốn thêm số 0 vào đằng trước ô A2 thì làm thế nào. Tức là nếu ô nào có 6 số thì giữ nguyên còn ô nào có 5 hoặc 4 số thì thêm số 0 vào đằng trước. Có anh chị nào biết giúp em với. Em cảm ơn các anh chị nhiều.

Hoàng Trọng Nghĩa · 21/10/11

sonltdb đã viết:
Chào các anh chị, em có một bảng excel như sau: ô A1 có 6 con số: 012345, ô A2 có 5 số: 23456. Em muốn thêm số 0 vào đằng trước ô A2 thì làm thế nào. Tức là nếu ô nào có 6 số thì giữ nguyên còn ô nào có 5 hoặc 4 số thì thêm số 0 vào đằng trước. Có anh chị nào biết giúp em với. Em cảm ơn các anh chị nhiều.

Định dạng thôi: Format Cells, Custom, gõ vào Type là : 000000 (sáu số không) rồi OK

sonltdb · 21/10/11

cảm ơn bạn nhiều nhé.

oanh2011 · 24/10/11

Moi nguoi chi giao nhe
minh co hai sheet co mot ten khach hang nam tren 2 sheet khac nhau minh muon co cong thuc 1 khach hang co 2 ma o 2 sheet kac nhau ve mot cho

syro_dau77 · 25/10/11

CÁC BẠN ƠI CHO MÌNH HỎI, NẾU ĐỀ BÀI YÊU CẦU XÉT TUYỂN THEO NGUYÊN TẮC SAU:
nếu các môn thi ( vd 3 môn Toán, văn, anh), chỉ có 1 môn lớn hơn 4 và nhỏ hơn 6, các môn còn lại phải lớn hơn 6 thì đậu, còn lại thì rớt. Mình dùng côn thức gì?

bebo021999 · 25/10/11

syro_dau77 đã viết:
CÁC BẠN ƠI CHO MÌNH HỎI, NẾU ĐỀ BÀI YÊU CẦU XÉT TUYỂN THEO NGUYÊN TẮC SAU:
nếu các môn thi ( vd 3 môn Toán, văn, anh), chỉ có 1 môn lớn hơn 4 và nhỏ hơn 6, các môn còn lại phải lớn hơn 6 thì đậu, còn lại thì rớt. Mình dùng côn thức gì?

Giả sử A1,B1,C1 chứa điểm của 3 môn, D1 chứa kết quả:

D1 bằng:

Mã:

=IF(AND(SUM(--(A1:C1>6))>1,MIN(A1:C1)>4),"Đậu","Tèo")

Kết thúc bằng giữ Ctrl-Shift và nhấn enter.

doanthuha203 · 28/10/11

Giúp mình xử lý công thức sau

Mình gặp một file có 2 công thức sau mình không hiểu. Mong các bạn giúp mình hiểu ý nghĩa 2 công thức và cách dùng các hàm trên. Chân thành cảm ơn các bạn!
=IF(TYPE(MATCH($H$1,NKChungTu!$A$6:$A$89,0))=16,"",MATCH($H$1,NKChungTu!$A$6:$A$89,0))
=IF(TYPE(MATCH($H$1,OFFSET(NKChungTu!$A$6,H12,0):NKChungTu!$A$89,0)+H12)=16,"",MATCH($H$1,OFFSET(NKChungTu!$A$6,H12,0):NKChungTu!$A$89,0)+H12)

==========================
domfootwear: Lần sau viết tiêu đề cho rõ ràng nha bạn.

hoamattroicoi · 28/10/11

Bạn phải đưa file cùng công thức nên thì mới giải thích cho bạn được chứ.
Hơn nữa trước khi hỏi mọi người bạn nên tìm hiểu cách sử dụng của những hàm đó trước, ví dụ như hàm Match, Type, Offset... Khi mọi người giải thích bạn sẽ nắm nhanh hơn.
Bạn mà đăng câu hỏi thế này thì mọi người khó giải thích lắm, mà hình như mấy công thức này của bạn là trong 1 file hướng dẫn tạo sổ cái tài khoản chạy tự động đúng không?

Ba Tê · 28/10/11

doanthuha203 đã viết:
Mình gặp một file có 2 công thức sau mình không hiểu. Mong các bạn giúp mình hiểu ý nghĩa 2 công thức và cách dùng các hàm trên. Chân thành cảm ơn các bạn!
=IF(TYPE(MATCH($H$1,NKChungTu!$A$6:$A$89,0))=16,"",MATCH($H$1,NKChungTu!$A$6:$A$89,0))
=IF(TYPE(MATCH($H$1,OFFSET(NKChungTu!$A$6,H12,0):NKChungTu!$A$89,0)+H12)=16,"",MATCH($H$1,OFFSET(NKChungTu!$A$6,H12,0):NKChungTu!$A$89,0)+H12)

Chỉ bạn một chỗ khi nào muốn thì nghiên cứu nhé.
http://www.giaiphapexcel.com/forum/showthread.php?7971-Tra-Cứu-Hàm-Excel&p=54708#post54708

doanthuha203 · 29/10/11

Đây là file mình update lên. Công thức ở ô H17, H18. Mong các bạn giúp mình. Cảm ơn các bạn!

doanthuha203 · 29/10/11

Mong các bạn giúp minh.Thanks!

mouse_vt99 · 1/11/11

công thức này nhằm không thể hiện khi hàm match bị lổi thôi bạn type(match(..))=16 nghĩa là match(...)khi có kết quả = #n/a thì nó lấy "" còn ko thì thể hiện bình thường

Lê Duy Thương · 1/11/11

doanthuha203 đã viết:
đây là file mình update lên. Công thức ở ô h17, h18. Mong các bạn giúp mình. Cảm ơn các bạn!

file bạn up lên lỗi nhiều quá chắc do xóa sheet trước khi đưa lên

doanthuha203 · 1/11/11

Đúng rồi.Mình xóa bớt cho nhẹ file mới up lên được.

black0 · 2/11/11

ham index

giup minh giai bai toan nay nhe! minh khong hieu ham index.

==============
domfootwear: Lần sao viết tiêu đề cho rõ ràng nha bạn.

leonguyenz · 2/11/11

Hàm HLOOKUP kết hợp IF cũng được, muốn dùng hàm INDEX bạn phải sắp xếp và đặt điều kiện cho dữ liệu.

bebo021999 · 2/11/11

black0 đã viết:
giup minh giai bai toan nay nhe! minh khong hieu ham index.

Công thức tại E7:

Mã:

=INDEX($B$23:$E$26,IF(C7<10,2,IF(C7<20,3,4)),MATCH(D7,$B$23:$E$23,0))

phihndhsp · 2/11/11

đối với bài này có thể không dùng if cũng được hi hi
HLOOKUP(D7,$C$23:$E$26,MIN(INT(C7/10)+2,4),0)

myhappyfamily2007 · 2/11/11

Mọi người thông thái cho em hỏi. Em đang lập một file báo cáo của tàu biển theo đó tàu thường báo về công ty giờ tại cảng đó. Em muốn lập cột bên cạnh để quy về GMT thì lập công thức thế nào ạ.

Ví dụ

Cột A 9:00 (tại TQ là GMT + 8) thì cột B là A-8 .

Nhưng làm thế nào để trừ được ạ.

Cảm ơn mọi người

leonguyenz · 2/11/11

Cột B: A-8/24, bạn thử đưa vào file xem nhé, vì ở cột A hiểu dạng ngày, bạn phải trừ 8/24 ngày.

Loan1989 · 10/11/11

Sử dụng công thức IF cho trường hợp này như thế nào?

Mình có 1 bài toán về sử dụng hàm IF, câu hỏi mình ghi trong file đính kèm nhờ mọi người xem giúp mình nhé !
Many thanks !

Ba Tê · 10/11/11

Loan1989 đã viết:
Mình có 1 bài toán về sử dụng hàm IF, câu hỏi mình ghi trong file đính kèm nhờ mọi người xem giúp mình nhé !
Many thanks !

Cho ví dụ và kết quả cụ thể đi. Kết quả bạn tính bằng thủ công kèm giải thích cách tính.
Chỉ giải thích không thì có khi chỉ mình bạn hiểu, người khác đọc chẳng hiểu bạn muốn sao nữa.
Ví dụ tất cả các trường hợp có thể xảy ra để mọi người hiểu nguyên lý của nó.

Loan1989 · 10/11/11

Mình gửi kết quả mong muốn cho từng trường hợp như file đính kèm đây, mọi người xem giúp mình nhé.

Luc Van · 10/11/11

Loan1989 đã viết:
Mình gửi kết quả mong muốn cho từng trường hợp như file đính kèm đây, mọi người xem giúp mình nhé.

Đọc bài này chả hiểu gì cả...
- D thì biết rồi: D=A+B+C
- Nhưng A, B, C là cái gì? Giá trị của nó tương ứng với cột C, hay D hay cột nào khác nữa.

darkmage163vn · 10/11/11

à giúp mình kiểm tra lại công thức ở Sheet 6 chỗ ghi chú với mình sửa hoài mà không được

nghiaphuc · 11/11/11

darkmage163vn đã viết:
à giúp mình kiểm tra lại công thức ở Sheet 6 chỗ ghi chú với mình sửa hoài mà không được

Đây là một tham khảo cho ô M7:

Mã:

=IF(OR(AND(B7<=DATE(2002,4,30),B7+C7>=DATE(2002,4,30)),AND(B7<=DATE(2002,5,1),B7+C7>=DATE(2002,5,1))),"Tham quan","")

Loan1989 · 11/11/11

Luc Van đã viết:
Đọc bài này chả hiểu gì cả...
- D thì biết rồi: D=A+B+C
- Nhưng A, B, C là cái gì? Giá trị của nó tương ứng với cột C, hay D hay cột nào khác nữa.

Mình giải thích lại thế này nhé, nếu bạn nào làm kế toán sẽ dễ hiểu hơn :
DN có thu nhập từ 3 hoạt động :
- Hoạt động được ưu đãi (A) - Thuế suất thuế TNDN 5%
- Hoạt động không được ưu đãi (B) - Thuế suất thuế TNDN 25%
- Thu nhập khác (C) - Thuế suất thuế TNDN 25%
D =A+B+C
Nếu D<0 =>Thuế TNDN =0
Nếu D>0 =>Phải nộp thuế tuy nhiên cách tính cụ thể cho từng trường hợp thì văn bản quy định như thế này :"doanh nghiệp có phát sinh hoạt động kinh doanh được hưởng ưu đãi thuế bị lỗ, hoạt động kinh doanh không được hưởng ưu đãi thuế, thu nhập khác của các hoạt động kinh doanh
có thu nhập thì doanh nghiệp bù trừ vào thu nhập chịu thuế của các hoạt động có thu nhập do doanh nghiệp lựa chọn. Phần thu nhập còn lại sau khi bù trừ áp dụng mức thuế suất thuế TNDN theo mức thuế suất của hoạt động còn thu nhập."
Vấn đề của mình là tìm công thức tính thuế theo đúng quy định trên...

Ba Tê · 11/11/11

Loan1989 đã viết:
Mình gửi kết quả mong muốn cho từng trường hợp như file đính kèm đây, mọi người xem giúp mình nhé.

Nhìn một đống "Nếu" mà tối hù con mắt, không nghĩ ra cách nào "túm gọn nó", cứ thấy "Nếu" thì chuyển thành IF() cho nhanh, bạn kiểm tra lại thử xem nhé.

Loan1989 · 11/11/11

Ba Tê đã viết:
Nhìn một đống "Nếu" mà tối hù con mắt, không nghĩ ra cách nào "túm gọn nó", cứ thấy "Nếu" thì chuyển thành IF() cho nhanh, bạn kiểm tra lại thử xem nhé.

Cám ơn bạn rất nhiều, công thức chạy đúng theo ý mình rồi, dù nhìn công thức thấy khó hiểu quá...

toanmihaba · 15/11/11

Hàm sumif sai

nhờ các cao thủ chỉ giùm hàm sumif này .công thức thì đúng rồi nhưng khị cộng lại kết quả là sai .xin cảm ơn

huuthang_bd · 15/11/11

toanmihaba đã viết:
nhờ các cao thủ chỉ giùm hàm sumif này .công thức thì đúng rồi nhưng khị cộng lại kết quả là sai .xin cảm ơn

Tôi đã xem file và không thấy chỗ nào sai cả. Bạn muốn kết quả như thế nào?

ndu96081631 · 15/11/11

toanmihaba đã viết:
nhờ các cao thủ chỉ giùm hàm sumif này .công thức thì đúng rồi nhưng khị cộng lại kết quả là sai .xin cảm ơn

SUMIF thường bị sai khi điều kiện là dạng number
Thay SUMIF bằng SUMPRODUCT là được rồi:

PHP:

=SUMPRODUCT(($A$2:$A$100=I2)*($G$2:$G$100))

hophoang · 15/11/11

toanmihaba đã viết:
nhờ các cao thủ chỉ giùm hàm sumif này .công thức thì đúng rồi nhưng khị cộng lại kết quả là sai .xin cảm ơn

Hàm sum trên là đúng,ý bạn mscn 0084 phải là 15 còn 0205 là 17 phải ko.Nếu vậy bạn sữa ct cột G như sau:=IF(OR(E3>"05:00:00",F3>"05:00:00"),1,0)

bebo021999 · 15/11/11

toanmihaba đã viết:
nhờ các cao thủ chỉ giùm hàm sumif này .công thức thì đúng rồi nhưng khị cộng lại kết quả là sai .xin cảm ơn

* Dòng số 11 và 20 không có giờ vào nên không chấm công, nếu có thì kết quả sẽ là 15 và 17 ngày công. Đây là kết quả mong muốn của bạn chăng?
* Thay vì dùng SUMIF với 1 cột phụ (cột G), bạn bỏ cột phụ đi và dùng SUMPRODUCT như sau:

Mã:

=SUMPRODUCT(($A$2:$A$33=I2)*($E$2:$E$33>"05:00:00"))

Hỏi nhanh - đáp nhanh về công thức (phần 1) (4 người xem)

Người dùng đang xem chủ đề này

Thành viên gạo cội

Thành viên mới

Thành viên mới

Thành viên mới

Thành viên mới

Thành viên mới

Hướng tới tương lai

Thành viên gạo cội

Thành viên mới

Thành viên mới

File đính kèm

Thành viên gạo cội

Cạo lấy gì gội (Dịch quá không gội được)

Thành viên mới

Chuyên gia GPE

File đính kèm

Cạo lấy gì gội (Dịch quá không gội được)

Huyền thoại GPE

Cạo Rồi Khỏi Gội

File đính kèm

Chuyên gia GPE

Chuyên gia GPE

Thành viên mới

File đính kèm

Thành viên mới

File đính kèm

Thành viên gạo cội

Thành viên mới

Huyền thoại GPE

Thành viên gạo cội

Thành viên mới

File đính kèm

Thành viên gạo cội

Hướng tới tương lai

Bad Excel Member

Bad Excel Member

Thành viên gạo cội

File đính kèm

Hướng tới tương lai

Thành viên mới

Thành viên gạo cội

Thành viên mới

File đính kèm

Huyền thoại GPE

linhvtm84@gmail.com

Thành viên chính thức

File đính kèm

Thành viên gạo cội

File đính kèm

Thành viên mới

File đính kèm

Thành viên gạo cội

Thành viên mới

File đính kèm

Cạo Rồi Khỏi Gội

Thành viên mới

Thành viên chính thức

Thành viên gạo cội

Bad Excel Member

Let's patience

File đính kèm

Huyền thoại GPE

Thành viên mới

Thành viên tiêu biểu

Thành viên gạo cội

Thành viên mới

Huyền thoại GPE

Thành viên mới

Thành viên mới

Thành viên mới

Huyền thoại GPE

Thành viên gạo cội

Huyền thoại GPE

Thành viên mới

Thành viên gạo cội

Thành viên mới

Thành viên gạo cội

Thành viên mới