Hỏi nhanh - đáp nhanh về công thức (phần 1) (6 người xem)

  • Thread starter Thread starter SA_DQ
  • Ngày gửi Ngày gửi
Liên hệ QC

Người dùng đang xem chủ đề này

Status
Không mở trả lời sau này.
_Câu hỏi như sau:
Tính Giảm Giá, biết rằng khách hàng nào mua từ lần thứ 4 trở đi thì "Giảm 10%", ngược lại để trống.
Không biết mình viết công thức ra sao ?? Thanks
 
_Câu hỏi như sau:
Tính Giảm Giá, biết rằng khách hàng nào mua từ lần thứ 4 trở đi thì "Giảm 10%", ngược lại để trống.
Không biết mình viết công thức ra sao ?? Thanks

Ô I4 (Giảm giá) gõ công thức sau (thể hiện bằng % giảm giá):
PHP:
I4 = (COUNTIF($B$4:$B4,$B4)>=4)*10%
Sau đó copy công thức xuống dưới.
Nếu bạn muốn thể hiện số tiền thì công thức trên nhân thêm cột doanh thu nữa là xong.
VÀ một điều dĩ nhiên là dữ liệu của bạn phải được sắp xếp theo thứ tự nghiệp vụ pháp sinh!
 
Ô I4 (Giảm giá) gõ công thức sau (thể hiện bằng % giảm giá):
PHP:
I4 = (COUNTIF($B$4:$B4,$B4)>=4)*10%
Sau đó copy công thức xuống dưới.
Nếu bạn muốn thể hiện số tiền thì công thức trên nhân thêm cột doanh thu nữa là xong.
VÀ một điều dĩ nhiên là dữ liệu của bạn phải được sắp xếp theo thứ tự nghiệp vụ pháp sinh!
Cực kỳ chính xác, mình đã viết một vài công thức nhưng lại không thỏa được từ lần thứ 4 trở đi, mà giảm từ lần 1 trở đi khi thỏa điều kiện 4 lần mua. Ca-dafi có thể giải nghĩa công thức này được không? Thanks
 
Ca-dafi có thể giải nghĩa công thức này được không?
PHP:
I4 = (COUNTIF($B$4:$B4,$B4)>=4)*10%
Trong công thức này ta chia làm hai phần:
1. COUNTIF($B$4:$B4,$B4): Đây là công thức để đếm số thứ tự xuất hiện của một ô trong cùng một cột dữ liệu. Bạn thử làm một cột phụ rồi gõ công thức này vào, và copy công thức xuống dưới sẽ thấy! Chú ý cái dấu "$", công thức này đã cố định ô $B$4, nghĩa là càng xuống các dòng dưới, độ rộng của dữ liệu càng lớn

2. (COUNTIF($B$4:$B4,$B4)>=4): Đây là biểu thức logic trả về giá trị là TRUE nếu giá trị countIf đó >=4 hoặc FALSE nếu giá trị countif đó <4

Và:
True*10% = 1*10% = 10%
False*10% = 0*10% = 0%


Chúc vui.
 
Đưa dữ liệu hàng về cột

Mình có bảng dữ liệu như file đính kèm, muốn dữ liệu 2 cột B và C thành cột D thì phải làm sao? Mặc dù mình có thể dùng công thức này if
nhưng có cách nào khác không vì nếu có trên 10 cột thì không thể dùng hàm if rồi
 
Mình có bảng dữ liệu như file đính kèm, muốn dữ liệu 2 cột B và C thành cột D thì phải làm sao? Mặc dù mình có thể dùng công thức này if
nhưng có cách nào khác không vì nếu có trên 10 cột thì không thể dùng hàm if rồi

Bài này Bạn có thể dùng Index và Match để giải quyết nhé! 100 cột cũng chẳng sao! Bạn xem file đính kèm nhé!
 
Lần chỉnh sửa cuối:
Nhưng nếu có ô bị rỗng dữ liệu thì làm sao? giống như cell A7 (rỗng toàn bộ giá trị của Act 6)
Thì bạn lồng một hàm IF để bẫy lỗi vào.
Ví dụ (xem bài của Ca_Dafi nhé), công thức trong ô L2 đang là:
=INDEX($B$1:$K$1, MATCH("X",$B2:$K2,0))​
Bạn sợ rằng nó báo lỗi #NA! khi gặp toàn ô rỗng, thì bạn lồng hàm IF(ISNA... vào:
=IF(ISNA(INDEX($B$1:$K$1, MATCH("X",$B2:$K2,0))), "", INDEX($B$1:$K$1, MATCH("X",$B2:$K2,0)))​
Nếu bạn dùng Excel2007 thì còn ngắn hơn nữa:
=IFERROR(INDEX($B$1:$K$1, MATCH("X",$B2:$K2,0)), "")​
Cả hai công thức trên, nếu gặp toàn ô trống thì cũng trả về kết quả là ô trống.
 
Nhưng nếu có ô bị rỗng dữ liệu thì làm sao? giống như cell A7 (rỗng toàn bộ giá trị của Act 6)
Có rất nhiều cách để bẫy lỗi mà bạn! Bài trên, do mình không bẫy lỗi nên nếu không tìm thấy chữ "X" trong vùng cần tìm kiếm thì hàm Match sẽ trả về giá trị là #N/A.

Bạn có thể sử dụng cách của anh BNTT là thông dụng nhất, dễ hiểu nhất! Nó cũng giống như bẫy lỗi trong Vlookup, Hlookup mà thôi!

Ngoài ra, bạn còn có thể dùng COUNTIF, COUNTA để bẫy lỗi, cũng khá đơn giản không có gì là khó hiểu cả, ví dụ:
PHP:
=IF(COUNTIF($B2:$K2,"X")<1,"",INDEX($B$1:$K$1,MATCH("X",$B2:$K2,0)))
Hoặc:
PHP:
=IF(COUNTA($B2:$K2)<1,"",INDEX($B$1:$K$1,MATCH("X",$B2:$K2,0)))
Còn không thích dùng IF thì dùng CHOOSE cũng xong:
PHP:
=CHOOSE((COUNTIF($B2:$K2,"X")>0)+1,"",INDEX($B$1:$K$1,MATCH("X",$B2:$K2,0)))
Hoặc:
PHP:
=CHOOSE((COUNTA($B2:$K2)>0)+1,"",INDEX($B$1:$K$1,MATCH("X",$B2:$K2,0)))
 
Lần chỉnh sửa cuối:
cho mình hỏi cách thêm cột trong excel 2003
bởi vì mình đang tạo lịch làm việc cho 1 năm (>365 cột)
hiện tại trong office 2003 chỉ có 256 cột
thank!
 
cho mình hỏi cách thêm cột trong excel 2003
bởi vì mình đang tạo lịch làm việc cho 1 năm (>365 cột)
hiện tại trong office 2003 chỉ có 256 cột
thank!

Chuyễn sang Excel 2007 đi cho rông nhe !
hi hi .Bạn làm lịch làm việc gì mà khủng thế ?
 
cho mình hỏi cách thêm cột trong excel 2003
bởi vì mình đang tạo lịch làm việc cho 1 năm (>365 cột)
hiện tại trong office 2003 chỉ có 256 cột
thank!
Theo tôi thì cách hay nhất không phải là tìm 1 phần mềm đáp ứng được nhu cầu (số cột >256) mà nên xem lại cấu trúc dử liệu ---> Nên chăng thay đổi cách bố trí sao cho phù hợp
Bạn nghĩ xem, với 1 bảng tính có chừng 200 cột thì xem làm sao, in ấn làm sao
???
Tôi mà nhìn bảng tính như thế tôi cho vào sọt rác chứ khỏi cần xem ---> Mỏi mắt
 
Cái này thì dùng CT ntn?

Mình có 2 cột A và B, mình muốn là khi nhập dữ liệu vào cột A thì tự động bên Cột B ở cùng dòng sẽ hiện lên chữ OK, còn nếu chưa nhập thì sẽ không hiện gì cả.
Vậy phải dùng công thức ntn?
Các bạn chỉ giúp mình với. Thanks!
 
Bạn dùng hàm If nhe:
=IF(A1="","","OK")
Thân
 
Mình đã làm được rồi, phải là dấu ; chứ k phải dấu , đâu
Dấu nào, thì còn phụ thuộc vào khai báo Regional and Language Options trong Control Panel, nhất là ở mục List Seperator của từng máy. Không thể nói rằng dấu phẩy (,) hay là dấu chấm phẩy (;) thì mới đúng hay là sai.
 
Hóa ra là thế, mặc định khi cài Win xong thì sẽ là dấu , hay dấu ; vậy?
 
Hóa ra là thế, mặc định khi cài Win xong thì sẽ là dấu , hay dấu ; vậy?

Khi bạn cài WIN xong! Hãy vào Control Panel --> Regional and Language Options sẽ thấy!

Nói thêm nữa: trong quá trình cài đặt Window, Chương trình sẽ hỏi bạn có setup Regional and Language Options hay không! Cho nên nếu bạn có setup lúc này thì sau khi cài WIN hệ thống sẽ căn cứ vào lần setup này làm mặc định!.
 
Hóa ra là thế, mặc định khi cài Win xong thì sẽ là dấu , hay dấu ; vậy?
Còn tùy, bạn ơi. Tùy là tùy bạn xài cái đĩa cài đặt nào nữa kia.

Ví dụ, hiện nay ngoài chợ có bán đầy những đĩa Windows XP đã được bào chế lại, của các chuyên gia Thái Lan hay Ấn độ gì đó... Khi cài, khỏe lắm, chẳng phải gõ cái gì hết (kể cả Activate Key), cứ việc đút cái đĩa vào, chọn cho nó cài vào ổ nào, rồi yên tâm đi uống cafe, khoảng nửa tiếng sau về là có Windows XP xài rồi. Khỏe thì có khỏe, nhưng hệ điều hành trong đó, những cái mặc định á, thì có trời mới biết là thứ gì. Có khi, ngày tháng năm toàn là tiếng Thái Lan! Lại phải bỏ công ra ngồi chỉnh sửa lại theo kiểu Việt Nam, không thì chí ít cũng phải là kiểu Mỹ...

Ví du khác, bạn mua một laptop chính hãng có cài sẵn WindowsXP bản quyền, thì dấu List Seperator là dấu phẩy (,) bởi vì chắc chắn Windows XP cài sẵn trên máy bạn là Windows kiểu Mỹ. Và đây cũng là định dạng cho đa số các máy cài Windows XP mà chưa chỉnh sửa gì hết...

Còn nếu như bạn không thích xài định dạng số kiểu Mỹ (dấu phẩy là dấu phân cách hàng nghìn) mà bạn chỉnh sửa (có thể là ngay khi cài đặt Windows) định dạng số theo kiểu Việt Nam (dấu phẩy là dấu phân cách số lẻ thập phân), thì khi đó hệ thống sẽ dùng dấu chấm phẩy (;) làm List Seperator.

Tôi thì thường có gì xài đó, định dạng số kiểu Mỹ cũng chả sao, miễn là đọc thì hiểu đó là số mấy... Hơi cổ hủ tí, nhưng vì tôi không thích (đúng hơn là không dám) can thiệp vào những cài đặt trong Control Panel. Chỉ trừ mỗi chuyện thiết lập giấy in là A4 (thay vì mặc định là Letter) thì tôi nhờ thằng bạn làm dùm, để in ra vừa với tờ giấy thường bán đầy ngoài chợ...
 
Của mình là vista bản quyền, chưa chỉnh sửa gì ở trong mục Region... cả, nhưng vẫn cứ phải dùng dấu ;
 
Có bạn nào làm ơn chỉ giúp, mình có các giá trị 0,20,40,100 tương ứng là gán đặc tính:
1. =0 thì là E
2. 0<D=<20
3. 20<C=<40
4.40<B<100
5.100=<A
Vậy trong vùng giá trị điền vào ô đầu tiên tôi phải dùng công thức thế nào? Xin cảm ơn
 
Có bạn nào làm ơn chỉ giúp, mình có các giá trị 0,20,40,100 tương ứng là gán đặc tính:
1. =0 thì là E
2. 0<D=<20
3. 20<C=<40
4.40<B<100
5.100=<A
Vậy trong vùng giá trị điền vào ô đầu tiên tôi phải dùng công thức thế nào? Xin cảm ơn

Không biết ý bạn có phải như thế này không?
|
A​
|
B​
|
1​
|
Biên độ​
|
Giá trị​
|
2​
|= 0|E|
3​
|0 < X <=20|D|
4​
|20 < X <=40|C|
5​
|40 < X <= 100|B|
6​
|X > 100|A|
7​
|---------------|----|
8​
|X = |
45​
|
9​
|Giá trị (X)|???|

Nếu đúng vậy thì bạn dùng công thức sau:
PHP:
=CHOOSE(($B$8>0)+($B$8>20)+($B$8>40)+($B$8>100)+1,"E","D","C","B","A")
 
Cảm ơn bạn nhiều. Tuy nhiên tôi vẫn phân vân chưa áp dụng đúng được. Vậy phiền bạn xem file đính kèm.

HạngWS-AWS-BTT-ATT-BTT-CDS Trung BìnhHạngDoanh Số10041402004
 
Cho mình hỏi muốn lập công thức nâng lương theo hệ số của từng người: VD Ng.V.A trình độ Trung cấp, thì 2 năm tăng 1 lần và hệ số lương một lần tăng là 0,3. Ng.V.B trình độ đại học thì 3 năm tăng 1 lần và hệ số tăng 0,5. Lập công thức làm sao báo cho biết từng tháng có bao nhiêu người tháng đó nâng lương (có thể chữ mầu đỏ hoặc nhấp nháy...) Xin cảm ơn
 
Chào các anh, chị trong diễn đàn GPE !

Em đang tổng hợp dữ liệu từ một sheet vào một biểu tổng hợp (như trong file em đính kèm theo), nhưng em phải làm thủ công nên mất nhiều thời gian quá, trong khi đó công việc thì gấp, yêu cầu của sếp em là phải bắt báo cáo ngay. Vì vậy em mong muốn các anh, chị chỉ giúp em cách làm để hoàn thành nhanh công việc trong ngày hôm nay.

Em xin chân thành cảm ơn các anh, chị.
 
Chào các anh, chị trong diễn đàn GPE !

Em đang tổng hợp dữ liệu từ một sheet vào một biểu tổng hợp (như trong file em đính kèm theo), nhưng em phải làm thủ công nên mất nhiều thời gian quá, trong khi đó công việc thì gấp, yêu cầu của sếp em là phải bắt báo cáo ngay. Vì vậy em mong muốn các anh, chị chỉ giúp em cách làm để hoàn thành nhanh công việc trong ngày hôm nay.

Em xin chân thành cảm ơn các anh, chị.

Minh làm thử cho bạn 1 cột (cột B), các cột khác bạn làm tuơng tự nhé, có gì khó khăn thì báo để anh em giúp đỡ nha.

B6=IF(ISNA(HLOOKUP(A6;nam2004_tinh!$D$3:$K$4;2;0));0;HLOOKUP(A6;nam2004_tinh!$D$3:$K$4;2;0))
 
Chào bạn cop_kh

xin chân thành cảm ơn bạn đã giúp cách sử dụng công thức.
Mình mong muốn bạn có thể giải thích cho mình ý nghĩa của công thức mà bạn đã viết không để giúp mình hiểu được bản chất của công thức như thế nào từ đó mính có thể áp dụng được vào những công việc khác.

Xin chân thành cảm ơn bạn

Bạn ơi

Mình nghiên cứu công thức của bạn, nhưng mình chưa hiểu ý nghĩa của công thức này nền mình có áp dụng cho các cột khác thì đều không cho kết quả. Bạn giúp mình làm thêm công thức cho cột C để mình tìm hiểu bản chất của công thức nhé.

Xin cảm ơn bạn
 
Chỉnh sửa lần cuối bởi điều hành viên:
Bạn ơi

Mình nghiên cứu công thức của bạn, nhưng mình chưa hiểu ý nghĩa của công thức này nền mình có áp dụng cho các cột khác thì đều không cho kết quả. Bạn giúp mình làm thêm công thức cho cột C để mình tìm hiểu bản chất của công thức nhé.

Xin cảm ơn bạn

Gởi lại File hoàn chỉnh luôn cho bạn nè, xem thử OK không nhé.
 
Lần chỉnh sửa cuối:
Chào bạn cop_kh

xin chân thành cảm ơn bạn đã giúp cách sử dụng công thức.
Mình mong muốn bạn có thể giải thích cho mình ý nghĩa của công thức mà bạn đã viết không để giúp mình hiểu được bản chất của công thức như thế nào từ đó mính có thể áp dụng được vào những công việc khác.

Xin chân thành cảm ơn bạn

Bạn ơi

Mình nghiên cứu công thức của bạn, nhưng mình chưa hiểu ý nghĩa của công thức này nền mình có áp dụng cho các cột khác thì đều không cho kết quả. Bạn giúp mình làm thêm công thức cho cột C để mình tìm hiểu bản chất của công thức nhé.

Xin cảm ơn bạn

Mình lấy ví dụ công thức sau để giải thích cho bạn rõ nhé:


B6=IF(ISNA(HLOOKUP(A6;nam2004_tinh!$D$3:$K$4;2;0)) ;0;HLOOKUP(A6;nam2004_tinh!$D$3:$K$4;2;0))

1. HLOOKUP(A6;nam2004_tinh!$D$3:$K$4;2;0))
Hàm HLOOKUP dùng để tìm kiếm ô A6 trên bảng từ D3:K4 (trong Sheet nam2004_tinh), nếu có trì lấy giá trị tương ứng trên hàng 2 của bảng D3:K4.
2. ISNA(HLOOKUP(A6;nam2004_tinh!$D$3:$K$4;2;0)
Mục đích của hàm kết hợp với IF trước nó để bẫy lỗi để khi tìm không thấy giá trị như câu 1 thì sẽ không báo lỗi mà thôi.

Viết sơ sơ như vậy để bạn tham khảo, theo mình bạn cần học hỏi thêm nhiều để tiến bộ phục vụ tốt công việc bạn nhé. Có gì khó khăn cứ hỏi, đừng ngại.

Thân!
 
Các anh xem lại giùm em công thức tô màu vàng bị sai chổ nào mà không cho ra kết quả .
Trong đó có 2 cách rồi ,rất hay ,em muốn hiểu thêm ?
Thanks
Mượn File của bạn tonggiap!
 
Các anh xem lại giùm em công thức tô màu vàng bị sai chổ nào mà không cho ra kết quả .
Trong đó có 2 cách rồi ,rất hay ,em muốn hiểu thêm ?
Thanks
Mượn File của bạn tonggiap!
Công thức màu vàng:
=INDEX($A$16:$D$19, MATCH(LEFT(C5,2),$A$16:$A$19,0), MATCH(MID(C5,5,1),$C$15:$D$15,0))​
Sai ở chỗ đó. Tại sao lại lấy LEFT(C5,2) đi dò ? Cột C đâu có chứa mã số đâu?
 
Các anh xem lại giùm em công thức tô màu vàng bị sai chổ nào mà không cho ra kết quả .
Trong đó có 2 cách rồi ,rất hay ,em muốn hiểu thêm ?
Thanks
Mượn File của bạn tonggiap!
1. Ô tham chiếu phải là [B5] chứ không phải là [C5]
2. Cái hàm Match sau cùng phải cộng thêm số 2 vào
3. Cái hàm Match sau cùng không cần thiết
Bạn xem công thức đã sửa lại như sau:
PHP:
=INDEX($A$16:$D$19,MATCH(LEFT(B5,2),$A$16:$A$19,0),2+MID(B5,5,1))
 
To: Anh BNTT
Nếu sữa lại củng không cho kết quả anh ơi !
Công thức chia làm hai vế ,vế phía sau bị sai ? nhưng không biết lý do ?+-+-+-++-+-+-++-+-+-+
MATCH(MID(B5;5;1);$C$15:$D$15;0) ?
 
Anh có thể giải thích giùm em lý do tại sao nó bị sai không ? vế phía trước vẫn đúng ?lạ kỳ ?+-+-+-++-+-+-++-+-+-++-+-+-++-+-+-+
Thanks !
 
MATCH(MID(B5;5;1);$C$15:$D$15;0)
2 cái sai:
- MID(B5;5;1) là 1 chuỗi, đi tìm trong vùng $C$15:$D$15 có giá trị số, nên không tìm thấy
- Nếu thay bằng tìm MID(B5;5;1)*1 trong vùng $C$15:$D$15 sẽ thấy, và cho kết quả là 1 hoặc 2
- InDex trong vùng $A$16:$D$19, tham số cột là 1, hoặc 2, thì Volga xem thử nó ra kết quả gì?
 
Anh có thể giải thích giùm em lý do tại sao nó bị sai không ? vế phía trước vẫn đúng ?lạ kỳ ?+-+-+-++-+-+-++-+-+-++-+-+-++-+-+-+
Thanks !
Thứ nhất cái hàm MID(B5;5;1) nó trả về dạng TEXT --> phải chuyển sang dạng số. Vì hai giá trị tại hai ô C15 và D15 là dạng số.

Thứ hai, cái vế thứ hai phải trả về số thứ tự column trong hàm Index trước đó. mà giá trị Index là từ A15:D19 --> nghĩa là có 4 cột, cái cần tìm là cột 3 và cột 4. Chắc nói tới đây là bạn hiểu rồi phải không?
 
Anh có thể giải thích giùm em lý do tại sao nó bị sai không ? vế phía trước vẫn đúng ?lạ kỳ ?+-+-+-++-+-+-++-+-+-++-+-+-++-+-+-+
Thanks !
Trong công thức INDEX(Bang, dòng, cột)
Chỉ cần sai 1 tham số là toàn bộ sai hết ---> Vậy thôi
MID(B5,5,1) cho ra giá trị là Text, trong khi bảng dò là Number ---> Nó không hiểu cũng phải
Có thể sửa lại bằng cách nhân Mid(...) với 1
Tức:
=INDEX($A$16:$D$19,MATCH(LEFT(B5,2),$A$16:$A$19,0),MATCH(1*MID(B5,5,1),$A$15:$D$15,0))
Tuy nhiên, bài này dùng VLOOKUP sẽ gọn hơn!
 
Lập công thức trong excel

Mình muốn làm một công thức tính trong excel nhưng không biết dùng hàm gì cho đúng
mong được hướng dẫn
vd: (A+B)*2 >= 1700 thi cộng thêm 100, còn nhỏ hơn 1700 thì cộng 50
 
Bạn nói, thì mình viết công thức như vầy ha!
=IF((A+B)*2>=1700,cái gì + 100, cái gì + 50)
Thân.
 
Bạn nói, thì mình viết công thức như vầy ha!
=IF((A+B)*2>=1700,cái gì + 100, cái gì + 50)
Thân.
Bác Po_Pikachu vui tính quá --=0

Chắc ý bạn là như này chứ gì ?

Mã:
[B]=IF((A+B)*2>=1700,(A+B)*2 +100,(A+B)*2+50) [/B]
 
Lần chỉnh sửa cuối:
Không biết ý bạn có phải như vậy không
 
Nhờ các bác dành tí tẹo thời gian giúp e với!
E có một bảng dài, khi e đánh được một vài chữ vào một ô trong bảng nó hiện lên cả đoạn luôn, có nghĩa là phía trên e đã đánh cái nội dung này rồi. Làm thế nào để e tìm xem nội dung đã bị lặp lại ở ô nào phía trên.
 
Lám thế nào để đếm được số liệu trong trường hợp bị trùng

Em nhờ các anh chị trên diễn đàn GPE chỉ em cách đếm số liệu có trong từng ô, trong trường hợp trùng số liệu thì chỉ đếm là một lần. Cụ thể câu hỏi em có lấy ví dụ trong file gửi kèm, mong anh chị nghiên cứu và giúp em cách đếm thông tin.

Em xin chân thành cảm ơn!
 
Bạn dùng thử công thức này xem!
PHP:
[F4]=SUMPRODUCT(1/COUNTIF(F5:K5,F5:K5))
Và mình nghĩ dòng tháng và ngày có thể viết chung được đó. Đừng tách ra. Vì nếu trùng ngày mà không trùng tháng thì nó vẫn báo sai đó.
Tốt nhất là nên viết chung chúng lại. Và định dạng là: dd/mm là xong.
Thân.
 
Bạn dùng thử công thức này xem!
PHP:
[F4]=SUMPRODUCT(1/COUNTIF(F5:K5,F5:K5))
Và mình nghĩ dòng tháng và ngày có thể viết chung được đó. Đừng tách ra. Vì nếu trùng ngày mà không trùng tháng thì nó vẫn báo sai đó.
Tốt nhất là nên viết chung chúng lại. Và định dạng là: dd/mm là xong.
Thân.

Cách của Bác thiệt hay, em xin góp thêm ý kiến để tránh trùng ngày mà không trùng tháng thì thêm 1 hàng phụ ở dưới (VD ở hàng 7 dùng công thức F7=F5&"-"&F6), rồi dùng lại công thức của Bác cho hàng 7 là OK.
 
Cộng giá trị của một chỉ tiêu ở nhiều cột khác nhau

Chào các anh, chị trên GPE!

Mấy hôm nay các anh, chị đã hướng dẫn em cách viết công thức để tổng hợp, xử lý số liệu trên file excel. Đến nay em đã hoàn thành được một số công việc.
Em xin cảm ơn các anh, chị

Bây giờ em lại gặp fải một số vấn đề mới fát sinh. Vấn đề nay em để ở trong file gửi kèm, em mong anh chị hướng dẫn tiếp em cách viết công thức để xử lý số liệu trong excel.

Em cảm ơn anh, chị
 
Lập công thức trong excel

vd: ta có 3 số: A; B; C; D; F: TÍNH TỔNG CỦA F
giờ mình muốn lập một công thức tính như sau nhưng không biết phải dùng hàm như thế nào cho đúng mong được chỉ giáo. Xin cám ơn

F=(A+B x 2+100) x (1/2B+C+30), chia tất cả cho 1000000 rồi nhân với số D sau đó cộng tiếp cho (A+ hai lần C+30) x (B+ hai lần C+30), chia tất cả cho 1000000 x số D
 
vd: ta có 3 số: A; B; C; D; F: TÍNH TỔNG CỦA F
giờ mình muốn lập một công thức tính như sau nhưng không biết phải dùng hàm như thế nào cho đúng mong được chỉ giáo. Xin cám ơn

F=(A+B x 2+100) x (1/2B+C+30), chia tất cả cho 1000000 rồi nhân với số D sau đó cộng tiếp cho (A+ hai lần C+30) x (B+ hai lần C+30), chia tất cả cho 1000000 x số D
Bạn nói là có 3 số, mà lại có: A, B, C, D, là 4 số cơ mà...

Nếu những gì bạn trình bày là đúng, thì tôi sẽ làm theo như bạn trình bày nhé, không có dùng hàm gì hết:

Giả sử 4 con số đang nằm ở 4 ô A1, B1, C1 và D1. Ô cần tính là ô F1.
[F1] = (A1+B1*2+100)*(B1/2+C1+30)/1000000*D1 + (A1+C1*2+30)*(B1+C1*2+30)/1000000*D1
Giả sử A1=B1=C1=D1=1 (4 con số 1 nằm trong 4 ô), thì F1 = 0.004334
Phải vậy không?
 
Bạn nói là có 3 số, mà lại có: A, B, C, D, là 4 số cơ mà...

Nếu những gì bạn trình bày là đúng, thì tôi sẽ làm theo như bạn trình bày nhé, không có dùng hàm gì hết:

Giả sử 4 con số đang nằm ở 4 ô A1, B1, C1 và D1. Ô cần tính là ô F1.
[F1] = (A1+B1*2+100)*(B1/2+C1+30)/1000000*D1 + (A1+C1*2+30)*(B1+C1*2+30)/1000000*D1
Giả sử A1=B1=C1=D1=1 (4 con số 1 nằm trong 4 ô), thì F1 = 0.004334
Phải vậy không?


/-*+/ xin cám ơn bạn BNTT đã gợi ý, nhưng theo mình thấy nếu lập công thức theo như bạn thì kết quả sẽ ra sai vì: (A1+C1*2+30) trong excel sẽ hiểu là giá trị của A1+C1 nhân thêm cho 2 sẽ khác với (A1+(C1*2)+30)
 
/-*+/ xin cám ơn bạn BNTT đã gợi ý, nhưng theo mình thấy nếu lập công thức theo như bạn thì kết quả sẽ ra sai vì: (A1+C1*2+30) trong excel sẽ hiểu là giá trị của A1+C1 nhân thêm cho 2 sẽ khác với (A1+(C1*2)+30)
Nguyên tắc tính toán các biểu thức toán học là: Nhân chia trước, cộng trừ sau!
Vậy A1+C1*2+30 cũng chẳng có gì khác so với A1+(C1*2)+30
Không tin bạn thử xem
Khi nào ta viết thế này:
(A1+C1)*2+30
thì nó mới làm phép cộng trước phép nhân
 
/-*+/ xin cám ơn bạn BNTT đã gợi ý, nhưng theo mình thấy nếu lập công thức theo như bạn thì kết quả sẽ ra sai vì: (A1+C1*2+30) trong excel sẽ hiểu là giá trị của A1+C1 nhân thêm cho 2 sẽ khác với (A1+(C1*2)+30)
Bạn có thể kiểm chứng bằng số liệu thực cơ mà! Thử xem nó sẽ là gì?
A1+C1*2+30 = A1+(C1*2)+30​
hay là
A1+C1*2+30 = (A1+C1)*2+30​

Bạn chưa kiểm chứng, mà bạn chỉ kết luận theo "như bạn thấy"... thì tội nghiệp Excel quá.

Thôi để tôi chứng minh cho bạn thấy là Excel biết làm toán lớp 3, chứ không phải nó "ngu" như bạn nghĩ đâu:
000-2485.jpg

Bạn yên tâm rồi chứ?
 
Lần chỉnh sửa cuối:
Bẫy lỗi cho sumproduct

Công thức của em có vấn đề gì không mà sao nó lại bị lỗi nhỉ? Em muốn bẫy lỗi cho sumproduct thì phải làm sao? Có dùng ISNA như hàm IF được không các bác?
 
Công thức của em có vấn đề gì không mà sao nó lại bị lỗi nhỉ? Em muốn bẫy lỗi cho sumproduct thì phải làm sao? Có dùng ISNA như hàm IF được không các bác?

Do vùng tính tổng (C8:I8 có lỗi chia 0) của bạn bị lỗi, nên không tính tổng được bạn à.
 
Chào mọi người, mình có bài toán này muốn hỏi mong mọi người giúp đỡ

Mình đã lọc ra được một danh sách các số nguyên tố cho vào 1 cột. Mình muốn đưa các số trong cột đó vào một bảng hình vuông từ 0 -> 100 như hình dưới.

Các số nào có trong cột sẽ hiện lên đúng với dòng và cột đúng với nó và tô màu lên.

Mình dùng công thức này, ví dụ với số 83 có trong cột số nguyên tố nhưng vẫn thủ công.
Mã:
=IF(COUNTIF(A3:A14,83), 83, "")
snt-1.jpg


Rất mong mọi người giúp đỡ.
 
Chào mọi người, mình có bài toán này muốn hỏi mong mọi người giúp đỡ

Mình đã lọc ra được một danh sách các số nguyên tố cho vào 1 cột. Mình muốn đưa các số trong cột đó vào một bảng hình vuông từ 0 -> 100 như hình dưới.

Các số nào có trong cột sẽ hiện lên đúng với dòng và cột đúng với nó và tô màu lên.

Mình dùng công thức này, ví dụ với số 83 có trong cột số nguyên tố nhưng vẫn thủ công.
Mã:
=IF(COUNTIF(A3:A14,83), 83, "")
Rất mong mọi người giúp đỡ.

Bạn xem trong file kèm nhé.
 
Cho mình hỏi muốn tính độ nhạy của dự án thì dùng hàm nào??? và dùng thế nào???
 
Hàm sum, countif kết hợp với Advanced Filter

Hi, mọi người giúp mình bài tập này nhé. Mình xin gửi file đính kèm
 
Lần chỉnh sửa cuối:
Cám ơn bạn nhiều. Bình thường mình làm thì sẽ phải chèn thêm 2 cột phụ nữa thì mới tính được. Mình không rành về hàm sumproduct lắm nhưng mình thường thấy mọi người thường dùng hàm này có thể thay thế cho công thức mảng. Không biết là công thức mảng của bạn có thể thay được bằng hàm sumproduct không vậy???
{=SUM(IF(MATCH(A2:A12,A2:A12)=ROW(A2:A12)-1,1,0)*B2:B12)}
 
Công thức hơi bị ác liệt nha!
=SUMPRODUCT((1/COUNTIF($A$2:$A$9,$A$2:$A$9))*$B$2:$B$9)
Bạn xem file!
Thân.
 
Đúng rồi! Công thức này của bạn hay thật đấy. Mình nghĩ mãi mới hình dung ra 1/countif để làm gì.--=0
 
Nhờ các bác giúp em dùng hàm gì để đếm số lần xuất hiện của một số trong một dãy số cho trước.
Ví dụ: có một dãy số cho trước: 1,2,3,1,5,7,9,11,3,8,5,10,9,7
em muốn biết có bao nhiêu lần số 1, số 5, số 7, số 11 xuất hiện trong dãy số này
Mong các bác chỉ giúp
 
Nhờ các bác giúp em dùng hàm gì để đếm số lần xuất hiện của một số trong một dãy số cho trước.
Ví dụ: có một dãy số cho trước: 1,2,3,1,5,7,9,11,3,8,5,10,9,7
em muốn biết có bao nhiêu lần số 1, số 5, số 7, số 11 xuất hiện trong dãy số này
Mong các bác chỉ giúp
Bạn phải cho biết trước:
- Các số trong dãy, mổi số nằm 1 cell
Hay
- Dãy số nằm gọn trong 1 cell
 
Nhờ các bác giúp em dùng hàm gì để đếm số lần xuất hiện của một số trong một dãy số cho trước.
Ví dụ: có một dãy số cho trước: 1,2,3,1,5,7,9,11,3,8,5,10,9,7
em muốn biết có bao nhiêu lần số 1, số 5, số 7, số 11 xuất hiện trong dãy số này
Mong các bác chỉ giúp
Nếu dãy số của bạn ở các ô khác nhau thì chỉ cần dùng hàm countif(day so,1) là được cong trong 1 ô thì phải nghiên cứu đã.
 
Trường hợp 2: (đếm trên cùng 1 cell)
Bác test dùm em con số "1" và nhớ là kết quả = 3 chứ không phải =7.
Thân.
 
Trường hợp 2: (đếm trên cùng 1 cell)
Bác test dùm em con số "1" và nhớ là kết quả = 3 chứ không phải =7.
Thân.
Hơi căng à nha! Lại sơ ý vụ này! Sửa lại:
PHP:
=(LEN(","&SUBSTITUTE($H$2,",",",,")&",")-LEN(SUBSTITUTE(","&SUBSTITUTE($H$2,",",",,")&",",","&$K$9&",","")))/(LEN($K$9)+2)
 
Lần chỉnh sửa cuối:
Trường hợp 2: (đếm trên cùng 1 cell)
Bác test dùm em con số "1" và nhớ là kết quả = 3 chứ không phải =7.
Thân.
Tạm dùng thử CT củ chuối này trước đã.
Mã:
=INT((LEN(H2)-LEN(SUBSTITUTE(H2,","&K10&",","")))/3)+IF(SUBSTITUTE(LEFT(H2,2),",","")*1=K10,1,0)+IF(SUBSTITUTE(RIGHT(H2,2),",","")*1=K10,1,0)
Nhờ file của Bác ndu96081631.
 
Trường hợp 2: (đếm trên cùng 1 cell)
Bác test dùm em con số "1" và nhớ là kết quả = 3 chứ không phải =7.
Thân.
Cái này sửa lại một chút thôi mà! Po này làm biếng rồi nha!
PHP:
=(LEN($H$2)+2-LEN(SUBSTITUTE(","&$H$2&",",","&$K$9&",","")))/(LEN($K$9)+2)
Ẹc Ẹc... công thức trên cũng sai luôn! Trong trường hợp có Hai (nhiều) số cần đếm đứng kế nhau!?
 
Lần chỉnh sửa cuối:
Góp 1 cách dùng VBA cho vui nha!
PHP:
Function tach(cel As String, Optional kt As String = ",")
Dim arr() As String
arr() = Split(cel, kt)
tach = arr
End Function
PHP:
{=SUM(--(tach(H2)=TEXT(K9,"@")))}
Xem file!
Xin bổ sung rằng không phải làm biếng, mà bệnh lười nó đang cao? Vì còn đang ở trên trường! hi hi hi hi--=0
Thân.
 
Tạm dùng thử CT củ chuối này trước đã.
Mã:
=INT((LEN(H2)-LEN(SUBSTITUTE(H2,","&K10&",","")))/3)+IF(SUBSTITUTE(LEFT(H2,2),",","")*1=K10,1,0)+IF(SUBSTITUTE(RIGHT(H2,2),",","")*1=K10,1,0)
Nhờ file của Bác ndu96081631.
Code của bác Salam cũng sai ở số 2 và số 6.
Thân.
 
Lần chỉnh sửa cuối:
Công thức này sai khi đếm các số 2, 6 và 10
Kiệt kiểm tra lại xem!
Đúng vậy anh ơi! Hic! Các số cần đếm mà đứng kế nhau thì coi như sai bét! Vì xài chung vách (dấu ",")! Thôi chắc xài hàm tự tạo như Po_Pikachu cho nhanh!
 
Đúng vậy anh ơi! Hic! Các số cần đếm mà đứng kế nhau thì coi như sai bét! Vì xài chung vách (dấu ",")! Thôi chắc xài hàm tự tạo như Po_Pikachu cho nhanh!
Kiệt làm như sau:
- Thay dấu phẩy thành 2 dấu phẩy
- Thêm vào 2 đầu dãy số 1 dấu phẩy nữa
Giống như bài #958 tôi đã làm đấy
 
cộng các cột có mã giống nhau

em có nhiều cột chữa dữ liệu, em muốn tỉnh tổng cộng các cột có mã giông nhau thì dùng công thức gì để tính. Em thấy Khó quá.....!!!!
Mong cac anh chị giúp em
 
em có nhiều cột chữa dữ liệu, em muốn tỉnh tổng cộng các cột có mã giông nhau thì dùng công thức gì để tính. Em thấy Khó quá.....!!!!
Mong cac anh chị giúp em

Nhìn 1 đóng dử liệu của bạn, không hiểu phải cộng cái gì.. điều kiện cộng là gì... Và quan trọng nhất là đặt công thức vào cell nào
 
em có nhiều cột chữa dữ liệu, em muốn tỉnh tổng cộng các cột có mã giông nhau thì dùng công thức gì để tính. Em thấy Khó quá.....!!!!
Mong cac anh chị giúp em

Bạn dùng hàm SUMPRODUCT nhé, VD mã 5 tính số người chết:
=SUMPRODUCT(($E$6:$AQ$6=5)*$E$11:$AQ$11)


Lần sau bạn cố gắng yêu cầu rõ ràng, chi tiết như Bác ndu96081631 đề cập nhé, đã giúp bạn mà còn phải "nát óc" suy nghĩ bạn cần gì thì khổ lắm.
 
Trong những ngày vừa qua, em liên tục nêu những câu hỏi về xủ lý dữ liệu trong excel mà em gặp phải nhưng ko biết cách làm. Mỗi câu hỏi em nêu lên đều được các anh chị hướng dẫn chi tiết cách làm, có những câu hỏi em nêu ra rất chung chung, nhưng các anh chị còn đưa ra nhiều tỉnh huống, mỗi tình huống đều đưa ra cách để giải quyết. Nhờ có sự hướng dẫn đó mà em đã hoàn thành công việc được giao. Em xin chân thành cảm ơn các anh, chị đã giúp đỡ . Em cũng rất mong nhận được nhiều sự giúp đỡ của các anh, chị.
Em kính chúc các anh, chị trên diễn đàn luôn tràn đầy sức khỏe, hạnh phúc và thành đạt trên vị trí công tác của mình.
 
Chào các bạn!
Tôi có câu hỏi này muốn nhờ các bạn giúp. Tôi có một danh sách họ tên CBCNV trong cty xếp theo thứ tự abc, giờ tôi cần lấy ra tên của những người nữ thôi. Tôi đã dùng công thức này mà không được, cũng chẳng báo lỗi gì cả. Giả sử họ tên ở cột B, danh sách nữ lấy ra tôi để ở cột C, ở C2 tôi gõ:
=IF(B2="*Thị*",B2,"")
Danh sách nữ ở đây ai cũng có chữ lót là Thị, vậy tôi dùng *Thị* có đúng không?
Xin cảm ơn các bạn.
 
Chào các bạn!
Tôi có câu hỏi này muốn nhờ các bạn giúp. Tôi có một danh sách họ tên CBCNV trong cty xếp theo thứ tự abc, giờ tôi cần lấy ra tên của những người nữ thôi. Tôi đã dùng công thức này mà không được, cũng chẳng báo lỗi gì cả. Giả sử họ tên ở cột B, danh sách nữ lấy ra tôi để ở cột C, ở C2 tôi gõ:
=IF(B2="*Thị*",B2,"")
Danh sách nữ ở đây ai cũng có chữ lót là Thị, vậy tôi dùng *Thị* có đúng không?
Xin cảm ơn các bạn.
Phài vầy mới đúng nè:
=IF(ISERROR(SEARCH("Thị",B2,1)),"",B2)
 
Hy vọng công ty bạn không có anh nào tên Thịnh ...
 
Hy vọng công ty bạn không có anh nào tên Thịnh ...
Để đề phòng Excel nhầm lẫn giữa Thị và Thịnh, thì thay vì dùng SEARCH, bạn dùng hàm FIND, hàm FIND sẽ tìm chính xác chứ không tìm chung chung như SEARCH.
=IF(ISERROR(FIND("Thị", B2, 1)), "", B2)
 
An toàn nhất là nên có khoảng trắng theo sau: "Thị "
 
Một cách khác không cần công thức ---> Dùng AutoFilter cho cột B, với điều kiện lọc Contants = * Thị *
 
Cảm ơn các bạn ndu96081631, dhs88BNTT rất nhiều. Thật sự tôi chưa dùng 2 hàm này bao giờ vì chưa có dịp, tôi vừa tìm xem lại bài "hàm FIND và hàm SEARCH" của bạn BNTT. Rất thú vị. Một lần nữa xin cảm ơn các bạn.
 
Để đề phòng Excel nhầm lẫn giữa Thị và Thịnh, thì thay vì dùng SEARCH, bạn dùng hàm FIND, hàm FIND sẽ tìm chính xác chứ không tìm chung chung như SEARCH.
=IF(ISERROR(FIND("Thị", B2, 1)), "", B2)
An toàn nhất là nên có khoảng trắng theo sau: "Thị "
Theo em thì dùng hàm search vì hàm này tìm cả chữ hoa lẫn thường không tìm tuyệt đối như hàm find (Tránh trường hợp viết Thị - thị)và thêm khoảng trắng như bạn dhs88 đã nói.
 
Nhờ các bác vấn đề này:
Mình có 1 cột A và B bao gồm các số
A1 10% tương ứng là B1 10,000
A2 05% tương ứng là B2 100,000
A3 03% tương ứng là B3 500,000
A4 00% tương ứng là B4 >500,000

Bây giờ mình sẽ có một loạt các giá trị ở cột C là
10,000
400,000
3,000
500,000
1,000,000
...
Mình muốn ở cột D có so sánh giá trị cột C với cột B để
Nếu C < B1 thì D = A1
Nếu B1 > C < B2 thì D = A2
Nếu B2 > C < B3 thì D = A3
....


Bác nào giúp em phát nhé :D
 
Nhờ các bác vấn đề này:
Mình có 1 cột A và B bao gồm các số
A1 10% tương ứng là B1 10,000
A2 05% tương ứng là B2 100,000
A3 03% tương ứng là B3 500,000
A4 00% tương ứng là B4 >500,000

Bây giờ mình sẽ có một loạt các giá trị ở cột C là
10,000
400,000
3,000
500,000
1,000,000
...
Mình muốn ở cột D có so sánh giá trị cột C với cột B để
Nếu C < B1 thì D = A1
Nếu B1 > C < B2 thì D = A2
Nếu B2 > C < B3 thì D = A3

....


Bác nào giúp em phát nhé :D

C là C nào vậy bạn? Chỗ mình tô màu đỏ, bạn nêu yêu cầu rõ ràng nhé.
 
C ở đây là

Bây giờ mình sẽ có một loạt các giá trị ở cột C là
C1 = 10,000
C2 = 400,000
C3 = 3,000
C4 = 500,000
C5 = 1,000,000
Cxx = ...
Còn phần SS thì thế này
Tại cell D1
Nếu C1 < B1 thì D1 = A1 or Nếu B1 > C1 < B2 thì D1 = A2 or Nếu B2 > C1 < B3 thì D1 = A3 or Nếu C1>B3 thì D1 = A4

Bác giúp em phát nha :)
 
Nhờ các bác vấn đề này:
Mình có 1 cột A và B bao gồm các số
A1 10% tương ứng là B1 10,000
A2 05% tương ứng là B2 100,000
A3 03% tương ứng là B3 500,000
A4 00% tương ứng là B4 >500,000

Bây giờ mình sẽ có một loạt các giá trị ở cột C là
10,000
400,000
3,000
500,000
1,000,000
...
Mình muốn ở cột D có so sánh giá trị cột C với cột B để
Nếu C < B1 thì D = A1
Nếu B1 > C < B2 thì D = A2
Nếu B2 > C < B3 thì D = A3
....


Bác nào giúp em phát nhé :D
Không biết có đúng ý bạn không nữa:
Mã:
D1=IF(C1>=500000,A4,IF(C1>=100000,A3,IF(C1>=10000,A2,A1)))
 
C ở đây là

Bây giờ mình sẽ có một loạt các giá trị ở cột C là
C1 = 10,000
C2 = 400,000
C3 = 3,000
C4 = 500,000
C5 = 1,000,000
Cxx = ...
Còn phần SS thì thế này
Tại cell D1
Nếu C1 < B1 thì D1 = A1 or Nếu B1 > C1 < B2 thì D1 = A2 or Nếu B2 > C1 < B3 thì D1 = A3 or Nếu C1>B3 thì D1 = A4

Bác giúp em phát nha :)

Bạn có thể dùng công thức sau:
D1=IF(C1<=$B$1;$A$1;IF(C1<=$B$2;$A$2;IF(C1<=$B$3;$A$3;$A$4)))
 
cám ơn bác cop-kh cái, đã thành công rồi.
Hôm qua mình cũng đã làm như thế này nhưng mà ko ra, chắc là do viết sai :D
 
Chào các bạn, mình hiện nay đang có bài toán nhưng không giải được do kiến thức hạn hẹp quá, mong các bạn giúp đỡ:
Mình có 2 book, 1là kho hàng, một book là phiếu xuất các loại, làm sao để khi nhập số vào 1 ô nào đó trong phiếu xuất mà hàng trong kho tự trừ đi số hàng đã xuất kho, và làm thế nào để book A có thể trừ được cho book B.
Cảm ơn các bạn nhiều nha.
 
Help me hàm if..........or

Hi,

Hiện nay mình đang làm BH theo mẫu mới, việc theo dõi tăng giảm, điều chỉnh khó theo dõi quá.
Mình gửi file đính kèm lên. Mong nhận được sự giúp đỡ của các bạn
Mình cần công thức cho phần quỹ lương phát sinh trong tháng, với điều kiện của mức lương trần.

Cảm ơn sự giúp đỡ của các bạn
 
mình gửi file đính kèm bài tập của mình
ai tìm ra cách làm bài tập cho mình với, mình bó tay rùi.
vị trí dấu hỏi là cần điền công thức để trả ra kết quả đó.
thanks nhiều nhiều!
 
mình gửi file đính kèm bài tập của mình
ai tìm ra cách làm bài tập cho mình với, mình bó tay rùi.
vị trí dấu hỏi là cần điền công thức để trả ra kết quả đó.
thanks nhiều nhiều!

Mình làm cho bạn 2 câu ,câu kia mình bó tay ,IF Nhiều quá mệt lắm đi thôi |||||
Thân
Câu 1 có thể nghiên cứu hàm Choose đi !
 
Lần chỉnh sửa cuối:
mình gửi file đính kèm bài tập của mình
ai tìm ra cách làm bài tập cho mình với, mình bó tay rùi.
vị trí dấu hỏi là cần điền công thức để trả ra kết quả đó.
thanks nhiều nhiều!
Bạn xem file đính kèm nhé, ở đây mình lấy giá thuế số 1
 
Status
Không mở trả lời sau này.

Bài viết mới nhất

Back
Top Bottom