hàm sumproduct cho kết quả bằng 0 (2 người xem)

[mobiq]

ở cột số tiền mình dùng hàm sumproduct nhưng tính kiểu gì cũng bằng 0.

=IF(J3="thu";SUMPRODUCT($D$2:$D$8)*($B$2:$B$8="thu")*($C$2:$C$8="USD");(SUMPRODUCT($D$2:$D$8)*($B$2:$B$8="chi")*($C$2:$C$8="usd")))

ai có cách tính khác cho cột tính tiền thì giúp mình nhé

 

[mobiq]

quên mất không gửi file

 

[hoangminh86th]

Công thức đúng nè bạn!
=IF(J3="thu",SUMPRODUCT(($D$2:$D$8)*($B$2:$B$8="thu ")*($C$2:$C$8="USD")),(SUMPRODUCT(($D$2:$D$8)*($B$2: $B$8="chi")*($C$2:$C$8="usd"))))

 

[volga]

quên mất không gửi file

Bạn xem thử như thế này đúng không ?

 

[mobiq]

Bạn xem thử như thế này đúng không ?

bạn giải thích đi, mình mới học nên k hiểu chỗ dấu trừ lắm
còn công thức ở trên nếu thay * bằng ; thì lại k ra kết quả, đúng như theo công thức thì trong hàm SUMPRODUCT là dùng ; chứ

 

[Ba Tê]

bạn giải thích đi, mình mới học nên k hiểu chỗ dấu trừ lắm
còn công thức ở trên nếu thay * bằng ; thì lại k ra kết quả, đúng như theo công thức thì trong hàm SUMPRODUCT là dùng ; chứ

Nếu dùng dấu * hoặc dấu ; thì 2 công thức này cho kết quả giống nhau, Bạn tự "ngâm cứu" nhé:

=SUMPRODUCT(--($C$2:$C$8=$I3);--($B$2:$B$8=$J3);$D$2:$D$8)

=SUMPRODUCT(($C$2:$C$8=$I3)*($B$2:$B$8=$J3)*$D$2:$D$8)

 

[mobiq]

=SUMPRODUCT(--($C$2:$C$8=$I3);--($B$2:$B$8=$J3);$D$2:$D$8)
hàm trên nếu thay * bằng ; thì kq đúng là giống nhau ý mình muôn nói là hàm này cơ

=IF(J3="thu",SUMPRODUCT(($D$2:$D$8)*($B$2:$B$8="th u ")*($C$2:$C$8="USD")),(SUMPRODUCT(($D$2:$D$8)*($B$ 2: $B$8="chi")*($C$2:$C$8="usd"))))

 

[concogia]

=SUMPRODUCT(--($C$2:$C$8=$I3);--($B$2:$B$8=$J3);$D$2:$D$8)
hàm trên nếu thay * bằng ; thì kq đúng là giống nhau ý mình muôn nói là hàm này cơ

=IF(J3="thu",SUMPRODUCT(($D$2:$D$8)*($B$2:$B$8="th u ")*($C$2:$C$8="USD")),(SUMPRODUCT(($D$2:$D$8)*($B$ 2: $B$8="chi")*($C$2:$C$8="usd"))))

Công thức trong bài đầu tiên của bạn: thiếu dấu ngoặc sau SUMPRODUCT
Công thức sau cùng : có thể do Ký tự "thu" dư khoảng trắng ( dư dấu ngoặc trước SUMPRODUCT thứ hai, dù không ảnh hưởng đến kết quả)
Công thức chỉnh lại
=IF(J3="thu",SUMPRODUCT(($D$2:$D$8)*($B$2:$B$8="thu")*($C$2:$C$8="USD")),SUMPRODUCT(($D$2:$D$8)*($B$2:$B$8="chi")*($C$2:$C$8="usd")))
Nếu muốn gọn hơn tý ( vẫn theo hướng giải của bạn) ta có thể dùng :
=SUM(($D$2:$D$8)*($C$2:$C$8="USD")*IF(J3="thu",($B$2:$B$8="thu"),($B$2:$B$8="chi")))
Kết thúc bằng: Ctrl+Shift+Enter

 

[mobiq]

đây là hàm chuẩn:

=IF(J4="thu";SUMPRODUCT(($D$2:$D$8)*($B$2:$B$8="thu")*($C$2:$C$8="USD"));(SUMPRODUCT(($D$2:$D$8)*($B$2:$B$8="chi")*($C$2:$C$8="usd"))))

nếu thay * bằng ; thì k ra kết quả

cách giải của bạn Volga mình thấy đúng nhưng k hiểu dấu trừ và đoạn ($C$2:$C$8=$I4) vì ô I4 trống

 

[concogia]

đây là hàm chuẩn:



nếu thay * bằng ; thì k ra kết quả

cách giải của bạn Volga mình thấy đúng nhưng k hiểu dấu trừ và đoạn ($C$2:$C$8=$I4) vì ô I4 trống

nếu thay * bằng ; thì k ra kết quả
Sao không ra:
=SUMPRODUCT(--($C$2:$C$8=$I3)*(--($B$2:$B$8=$J3))*$D$2:$D$8)
k hiểu dấu trừ và đoạn ($C$2:$C$8=$I4) vì ô I4 trống
Dấu "--" sẽ tạo giá trị số cho biểu thức đi sau nó. Trong bài bạn có thể thay "--" bằng Value hay 1*
Ô I4 không rỗng, font của dữ liệu được định dạng trùng với màu nền
Cái hàm chuẩn của bạn dư cặp ngoặc ( trước SUPRODUCT thứ 2)

 

[mobiq]

với đề trên của mình, tính riêng ô K3, nhập hàm này

=SUMPRODUCT(($D$2:$D$8);($B$2:$B$8="thu");($C$2:$C$8="USD"))

sẽ ra kq là 0

 

[Ba Tê]

với đề trên của mình, tính riêng ô K3, nhập hàm này

sẽ ra kq là 0

Trời đất, =SUMPRODUCT(($D$2:$D$8);($B$2:$B$8="thu");($C$2:$C $8="USD")) không ra kết quả vì thiếu mấy cái dấu --, còn dấu -- đó có tác dụng gì thì Bạn concogia đã nói ở trên (bài #10) rồi.
Tóm lại: nếu sử dụng dấu * thì không cần dấu --, nếu sử dụng dấu ; thì phải có dấu -- hoặc hàm Value()..., Bài #6 bên trên đã ghi rõ 2 cách.

 

[mobiq]

k đọc kỹ post #6 nên thế. nhưng còn 1 chỗ vẫn chưa hiểu là ô I4

 

[Ba Tê]

k đọc kỹ post #6 nên thế. nhưng còn 1 chỗ vẫn chưa hiểu là ô I4

nếu thay * bằng ; thì k ra kết quả
Sao không ra:
=SUMPRODUCT(--($C$2:$C$8=$I3)*(--($B$2:$B$8=$J3))*$D$2:$D$8)
k hiểu dấu trừ và đoạn ($C$2:$C$8=$I4) vì ô I4 trống
Dấu "--" sẽ tạo giá trị số cho biểu thức đi sau nó. Trong bài bạn có thể thay "--" bằng Value hay 1*
Ô I4 không rỗng, font của dữ liệu được định dạng trùng với màu nền
Cái hàm chuẩn của bạn dư cặp ngoặc ( trước SUPRODUCT thứ 2)

Bạn có chọn ô I4 xem trong nó có gì hay chưa? I4, I6, I8 vẫn có dữ liệu trong đó còn cách làm thì xem bài #10 của concogia nhé

 

[mobiq]

Ô I4 không rỗng, font của dữ liệu được định dạng trùng với màu nền

k hiểu đoạn này, ô I4 I6 I8 k có gì mà

 

[concogia]

k hiểu đoạn này, ô I4 I6 I8 k có gì mà

I4= USD
I6= FR
I8= DM
Bạn Volga phải làm thế thì công thức mới ngắn gọn và copy công thức (fill) xuống mới được
Thân
Thò anh tý chọn I4 nhìn lên thanh công thức xem cái gì ở "trỏng" nhé bạn

 

[mobiq]

uh file của bạn volga thì I4 là usd còn của mình gửi lên lúc đầu thì k có. làm thế nào để đc như thế?

 

[saobang1902]

Mình có file dữ liệu này và muốn dùng hàm sumproduct nhưng lại k ra kết quả. Các bạn xem giúp mình nhé. Rất mong nhận được sự giúp đỡ của các bạn

 

[Lê Duy Thương]

hình như cấu trúc sumproduct của bạn sai

bạn thử thay cái công thức này xem sao
'=SUMPRODUCT(('NK t9'!$C$2:$C$5079="mh")*('NK t9'!$C$2:$C$5079="pn")*('NK t9'!$C$2:$C$5079="pn")*('NK t9'!$G$2:$G$5079='nxt t9'!$C2),('NK t9'!$K$2:$K$5079))
hình như 1 cột không thể lấy cùng lúc 3 điều kiện

thay bằng cái này thì ra kq nhưng bạn thử test lại nhé
=SUMPRODUCT(('NK t9'!$C$2:$C$5079="mh")*('NK t9'!$G$2:$G$5079='nxt t9'!$C2),('NK t9'!$K$2:$K$5079))+SUMPRODUCT(('NK t9'!$C$2:$C$5079="pn")*('NK t9'!$G$2:$G$5079='nxt t9'!$C2),('NK t9'!$K$2:$K$5079))

 

[dat_butmuc]

Mình có file dữ liệu này và muốn dùng hàm sumproduct nhưng lại k ra kết quả. Các bạn xem giúp mình nhé. Rất mong nhận được sự giúp đỡ của các bạn

Bảng tính của bạn lớn vậy mà dùng Sumproduct thì sẽ chậm đấy.

Trở lại công thức của bạn:

=SUMPRODUCT(('NK t9'!$C$2:$C$5079="mh")*('NK t9'!$C$2:$C$5079="pn")*('NK t9'!$C$2:$C$5079="pn")*('NK t9'!$G$2:$G$5079='nxt t9'!$C2),('NK t9'!$K$2:$K$5079))

ra kết quả = 0 là phải rồi
Sẽ không thể thỏa mãn được trong cột C - sheet NK t9 trong một ô vừa thỏa mãn "mh" vừa "pn".
Có chăng thì thế này:

=SUMPRODUCT(('NK t9'!$C$2:$C$5079="mh")*('NK t9'!$G$2:$G$5079='nxt t9'!$C2),('NK t9'!$K$2:$K$5079))

Hoặc thế này:

=SUMPRODUCT((('NK t9'!$C$2:$C$5079="mh")+('NK t9'!$C$2:$C$5079="pn"))*('NK t9'!$G$2:$G$5079='nxt t9'!$C2),('NK t9'!$K$2:$K$5079))