Hàm SUBSTITUTE

Liên hệ QC
Hàm SUBSTITUTE

Dùng để thay thế một chuỗi này bằng một chuỗi khác. Hàm này cũng tương tự hàm REPLACE(), nhưng dễ sử dụng hơn.

Công thức:
=SUBSTITUTE(text, old_text, new_text [,instance_num])

Trong đó:
text: chuỗi văn bản gốc, cần được xử lý
old_text: chuỗi văn bản cần được thay thế
new_text: chuỗi văn bản sẽ thay thế vào
instance_num: số lần thay thế old_text bằng new_text, nếu không khai báo thì tất cả old_text tìm được sẽ được thay thế bằng new_text

Ví dụ: Đế thay số 2007 bằng 2014 trong câu “Xin chào GPE 2007” tại ô A1

Dùng công thức như sau:
=SUBSTITUTE(A1, "2007", "2014") → Xin chào GPE 2014
substitute_1.JPG

Ví dụ: Tạo số tài khoản công ty dựa trên 3 ký tự dạng chữ đầu tiên và số thứ tự dòng có thêm các số 0 vào trước cho đủ 4 ký tự số.
=UPPER(LEFT(SUBSTITUTE(SUBSTITUTE(A2, ".", ""), " ", ""), 3)) & TEXT(ROW(A2), "0000")
substitute_2.JPG

Ví dụ: Loại bỏ các mã xuống dòng trong chuỗi.
=SUBSTITUTE(A2, CHAR(10), " ")
substitute_3.JPG

Ví dụ: Tách họ, chữ lót và Tên trong chuỗi Họ và Tên (Tiếng Việt)

Đầu tiên chúng ta tách chữ đầu tiên trong chuỗi làm Họ
=IFERROR(LEFT(A4,FIND(" ",A4)-1)," ")

Tách chữ sau cùng bên phải làm Tên
=IFERROR(RIGHT(A4,LEN(A4)-FIND("*",SUBSTITUTE(A4," ","*",LEN(A4)-LEN(SUBSTITUTE(A4," ",""))))),A4)

Tách các họ và họ lót (nếu có)
=IF(LEN(B4&D4)+2>=LEN(A4),"",MID(A4,LEN(B4)+2,LEN(A4)-LEN(B4&D4)-2))

substitute_4.jpg
 

File đính kèm

  • HamVanBan_Substitute.xlsx
    18.6 KB · Đọc: 533
Lần chỉnh sửa cuối:
Trích chuỗi ký tự bên phải (Trích tên) với SUBSTITUTE (nhiều người dùng):
Mã:
=TRIM(RIGHT(SUBSTITUTE(A1," ",REPT(" ",255)),255))
Tương tự với trích chuỗi ký tự bên trái (hàm LEFT) và ở giữa (MID).
 
Em chào anh chị,
Theo em nghĩ ^^ chỉ số instance_num : là vị trí thay thế old_text bằng new_text thì hợp lý hơn ạ.
Ví dụ như trong chuỗi ban đầu old_text xuất hiện 5 lần. Chọn instance_num =2 thì vị trí xuất hiện lần hai (tính từ bên trái sang) sẽ được thay thế ạ ^^

1598769755038.png


Nếu có gì sai sót mong anh chị thông cảm và chỉ giúp em ạ :)
 
instance_num (instance number) có nghĩa đen là "lần xuất hiện thứ", ở trong ngữ cảnh này có thể dịch là "vị thứ"
Dịch ra "số lần" là hoàn toàn sai:

Substitute("hôm qua qua nói qua qua mà qua hổng có qua", "qua", "kia", 4)
Nếu hiểu 4 là số lần thì kết quả là "hôm kia kia nói kia kia mà qua hổng có qua"
Hiểu là lần xuất hiện thứ 4 thì kết quả là "hôm qua qua nói qua kia mà qua hổng có qua"

Chú: nếu microsoft muốn nói "số lần" thì họ có lẽ đã dùng từ "num_instances"
 
Web KT
Back
Top Bottom