Hàm kết hợp thời gian

[Nhật Ming]

Nhờ các anh/ chị

Em có file này cần tìm giá trị như sau:
- Tại sheet Thời gian hoàn thành (cột P) em cần lấy giá trị từ Sheet1
- Điều kiện theo thời gian (cột B) và Số xe (cột C)

Em làm hoài mà ra giá trị False, nhờ các anh/ chị giúp đỡ ạ

 

[Nhattanktnn]

Nhờ các anh/ chị

Em có file này cần tìm giá trị như sau:
- Tại sheet Thời gian hoàn thành (cột P) em cần lấy giá trị từ Sheet1
- Điều kiện theo thời gian (cột B) và Số xe (cột C)

Em làm hoài mà ra giá trị False, nhờ các anh/ chị giúp đỡ ạ

Công thức tại P3. Kết thúc bằng Ctrl+Shift+Enter:

=VLOOKUP(B3&"_"&C3,CHOOSE({1,2},Sheet1!$B$2:$B$7&"_"&Sheet1!$C$2:$C$7,Sheet1!$E$2:$E$7),2,0)

 

[phan van tai]

Nhờ các anh/ chị

Em có file này cần tìm giá trị như sau:
- Tại sheet Thời gian hoàn thành (cột P) em cần lấy giá trị từ Sheet1
- Điều kiện theo thời gian (cột B) và Số xe (cột C)

Em làm hoài mà ra giá trị False, nhờ các anh/ chị giúp đỡ ạ

mình có tạo thêm cột trung gian trong sheet1,rồi dùng hàm Vlookup để dò tìm

 

[kelacloi]

Nhờ các anh/ chị

Em có file này cần tìm giá trị như sau:
- Tại sheet Thời gian hoàn thành (cột P) em cần lấy giá trị từ Sheet1
- Điều kiện theo thời gian (cột B) và Số xe (cột C)

Em làm hoài mà ra giá trị False, nhờ các anh/ chị giúp đỡ ạ

Nếu dùng Office 365 hoặc 2016 trở lên thì thử:

=XLOOKUP(B3&C3,Sheet1!$B$2:$B$7&Sheet1!$C$2:$C$7,Sheet1!$E$2:$E$7)

 

[Phan Thế Hiệp]

Công thức tại P3. Kết thúc bằng Ctrl+Shift+Enter:

=VLOOKUP(B3&"_"&C3,CHOOSE({1,2},Sheet1!$B$2:$B$7&"_"&Sheet1!$C$2:$C$7,Sheet1!$E$2:$E$7),2,0)

1/ Ai cũng quên Lookup() rồi! Sở trường của ẻm mờ! Lại chỉ nhấn "én tờ" thôi!

2/ Nếu muốn ghép chỉ 2 mảng theo 2 cột, thì cũng có thể dùng If({1,0}, 'mảng 1', 'mảng 2'); Nếu ghép theo 2 hàng thì {1;0}.

 

[Nhattanktnn]

1/ Ai cũng quên Lookup() rồi! Sở trường của ẻm mờ! Lại chỉ nhấn "én tờ" thôi!

2/ Nếu muốn ghép chỉ 2 mảng theo 2 cột, thì cũng có thể dùng If({1,0}, 'mảng 1', 'mảng 2'); Nếu ghép theo 2 hàng thì {1;0}.

Cảm ơn những chia sẻ của anh, em nghĩ tới vlookup đầu tiên nên "quất" luôn đó anh

 

[VetMini]

1/ Ai cũng quên Lookup() rồi! Sở trường của ẻm mờ! Lại chỉ nhấn "én tờ" thôi!

2/ Nếu muốn ghép chỉ 2 mảng theo 2 cột, thì cũng có thể dùng If({1,0}, 'mảng 1', 'mảng 2'); Nếu ghép theo 2 hàng thì {1;0}.

1/ Hàm Lookup dùng vào việc dò tìm nhiều điều kiện là đúng rồi. Ngoài việc đó thì nó hơi nguy hiểm.

2/ Bình thường thì If là hàm dễ sử dụng, dễ hiểu, và hiệu quả nhất trong tất cả các hàm.
Nhưng If trong trường hợp này chẳng khác gì Choose. Mất đi tính chất hiệu quả vì nó bị ép tính cả hai 1/0. Và về mặt dễ hiểu, dễ sử dụng thì nó thua Choose.
Vì chỉ có hai vế cho nên If chỉ ghép được mảng hai cột hoặc hai dòng. Muốn nhiều hơn thì phải lồng từng If vào nhau.
Choose bản thân có thể kéo dài nhiều vế cho nên không cần lồng.
IF({1,0}, IF({1,0}, $A$1:$A$5, $B$1:$B$5), $C$1:$C$5)
tương đương với:
Choose({1,2,3}, $A$1:$A$5, $B$1:$B$5, $C$1:$C$5)

 

[VetMini]

... em nghĩ tới vlookup đầu tiên nên "quất" luôn đó anh

Thực ra, nếu bạn theo nhiều người trên diễn đàn này, dùng Index/Match thì cũng có cách không phải CSE.

(gợi ý: 2 hàm Index, 1 hàm Match)

 

[Nhattanktnn]

Thực ra, nếu bạn theo nhiều người trên diễn đàn này, dùng Index/Match thì cũng có cách không phải CSE.

(gợi ý: 2 hàm Index, 1 hàm Match)

Như vậy cũng được nhưng coi bộ cồng kềnh hơn lookup anh ạ, cái match nó đã ngang cái lookup rồi

 

[VetMini]

Như vậy cũng được nhưng coi bộ cồng kềnh hơn lookup anh ạ, cái match nó đã ngang cái lookup rồi

"Cồng kềnh" tuỳ theo cái nhìn.
Index và Lookup đều nằm trong nhóm 4 hàm mảng.
Lookup dùng mẹo cho nên chưa chắc đã dễ hiểu.

- Mẹo dùng Lookup buộc Excel phải dò suốt mảng 2 lần, 1 lần cho mỗi điều kiện. Lần dò thứ ba, tìm 1/0 theo nhị phân rất hiệu quả nên không tính.

- Dùng hàm match tuy phải ghép chuỗi suốt mảng, chậm hơn dò suốt mảng 1 tí, nhưng bù lại trung bình chỉ phải dò 1/2 mảng. Match tuyệt đối dò đến khi gặp thì dừng lại.

 

[Phuocam]

Thực ra, nếu bạn theo nhiều người trên diễn đàn này, dùng Index/Match thì cũng có cách không phải CSE.

(gợi ý: 2 hàm Index, 1 hàm Match)

.
Theo gợi ý:

=INDEX(Sheet1!$E$2:$E$70,MATCH(B3&"|"&C3,INDEX(Sheet1!$B$2:$B$70&"|"&Sheet1!$C$2:$C$70,0),0))

Hoặc:

=INDEX(Sheet1!$E$2:$E$70,MATCH(1,INDEX((Sheet1!$B$2:$B$70=B3)*(Sheet1!$C$2:$C$70=C3),0),0))

.

 

[Nhật Ming]

Cám ơn các tiền bối nhiều ạ. Cách nào cũng hay và em đã làm được rồi ạ