HÀM COUNTIF

Quảng cáo

leonguyenz

Thành viên mới
Thành viên BQT
Moderator
Tham gia ngày
2 Tháng tám 2010
Bài viết
5,029
Được thích
8,603
Điểm
3,218
Nơi ở
Bình Dương
COUNTIF

Đếm số lượng các ô trong một vùng thỏa một điều kiện cho trước.

Cú pháp: =COUNTIF(range, criteria)

Range
: Dãy các ô để đếm, có thể là ô chứa số, text, tên, mảng, hay tham chiếu đến các ô chứa số. Ô rỗng sẽ được bỏ qua.

Criteria : Điều kiện để đếm. Có thể ở dạng số, biểu thức, hoặc text. Ví dụ, criteria có thể là 32, "32", "> 32", hoặc "apple", v.v...

Lưu ý :
• Có thể dùng các ký tự đại diện trong điều kiện: dấu ? đại diện cho một ký tự, dấu * đại diện cho nhiều ký tự (nếu như điều kiện là tìm những dấu ? hoặc *, thì gõ thêm dấu ~ ở trước dấu ? hay *)
• Khi điều kiện để đếm là những ký tự, COUNTIF() không phân biệt chữ thường hay chữ hoa.

Ví dụ : Có bảng tính như sau
1573273696235.png


Đếm số ô có chữ "Táo" trong dãy A2:A5
=COUNTIF(A2:A5, "Táo") → 2

Đếm số ô có chữ "Lê" trong dãy A2:A5
=COUNTIF(A2:A5, A4) → 1

Đếm số ô có chữ "Táo" vào số ô có chứa chữ "Lê" trong dãy A2:A5)
=COUNTIF(A2:A5, A3) + COUNTIF(A2:A5, A2) → 3


Đếm số ô có giá trị > 55 trong dãy B2:B5
=COUNTIF(B2:B5, "> 55") → 2

Đếm số ô có giá trị khác 75 trong dãy B2:B5
=COUNTIF(B2:B5, "<>" & B4) → 3

Đếm số ô có giá trị lớn hơn hoặc bằng 32, nhưng không lớn hơn 85, trong dãy B2:B5
=COUNTIF(B2:B5, ">=32") - COUNTIF(B2:B5, ">85") → 3

Ví dụ : Có bảng tính như sau
1573273729553.png


Đếm số ô có 2 chữ cuối là "es" trong dãy A2:A7
=COUNTIF(A2:A7, "*es") → 4

Đếm số ô có 2 chữ cuối là "es" trong dãy A2:B7
=COUNTIF(A2:B7, "*es") → 6

Đếm số ô có 2 chữ cuối là "es" trong dãy A2:A7 mà có chính xác 7 chữ ký tự
=COUNTIF(A2:A7, "?????es") → 2

Đếm số ô có chữ (text) trong dãy A2:A7
=COUNTIF(A2:A7, "*") → 4

Đếm số ô không chứa chữ (text) trong dãy A2:A7
=COUNTIF(A2:A7, "<>"&"*") → 2

Tính tỷ lệ số ô chứa chữ "No" trong dãy ô B2:B7, bao gồm cả những ô rỗng
=COUNTIF(B2:B7, "No") / ROWS(B2:B7) → 33%

Tính tỷ lệ số ô chứa chữ "Yes" trong dãy ô B2:B7, không tính những ô rỗng
=COUNTIF(B2:B7, "Yes") / (ROWS(B2:B7) - COUNTIF(B2:B7, "<>" & "*")) → 0.5 = 50%
 

File đính kèm

  • COUNTIF.xlsx
    10.2 KB · Đọc: 168

Nguyễn Hồng Quang

Thành viên GPE Hà Nội
Tham gia ngày
8 Tháng sáu 2007
Bài viết
1,206
Được thích
875
Điểm
0
Tuổi
36
Nơi ở
Hà Nội
Cảm ơn anh leonguyenz đã mô tả hàm countif với nhiều ví dụ cụ thể và sinh động. Nếu có thể, nhờ anh leonguyenz cho thêm 1 vài mở rộng của hàm countif trong các ứng dụng công thức mảng, dạng như 1/(countif(A:B;A:B))...... Với dạng này em vẫn còn chưa hiểu được vấn đề. 1 lần nữa rất Cảm ơn anh leonguyenz
 

leonguyenz

Thành viên mới
Thành viên BQT
Moderator
Tham gia ngày
2 Tháng tám 2010
Bài viết
5,029
Được thích
8,603
Điểm
3,218
Nơi ở
Bình Dương
Thêm ví dụ COUNTIF để đánh số thứ tự với chuỗi lặp lại:

Ví dụ: có danh sách với chuỗi lặp lại ký tự đầu được sắp xếp liên tục trong vùng C4:C10
1573609202319.png


Công thức đánh số thứ tự:
=COUNTIF($C$4:C4,LEFT(C4,1)&"*")

Lưu ý: cố định ô $C$4 để và trị đếm kết hợp chuỗi đại diện (&"*")

---
Cảm ơn anh leonguyenz đã mô tả hàm countif với nhiều ví dụ cụ thể và sinh động. Nếu có thể, nhờ anh leonguyenz cho thêm 1 vài mở rộng của hàm countif trong các ứng dụng công thức mảng, dạng như 1/(countif(A:B;A:B))...... Với dạng này em vẫn còn chưa hiểu được vấn đề. 1 lần nữa rất Cảm ơn anh leonguyenz

Ví dụ sử dụng COUNTIF mảng:
Có bảng dữ liệu A1:A8, đếm dữ liệu, loại bỏ giá trị trùng và giá trị rỗng.
Công thức: =SUMPRODUCT((A1:A8<>"")/COUNTIF(A1:A8,A1:A8&""))
Dùng chức năng Evaluate Formula (Tab Formulas) để hiểu rõ công thức hoạt động thế nào (hoặc nhấn F9 từng phần trong công thức).

1573609969730.png


Phần diễn giải:

1573609668720.png
 

File đính kèm

  • COUNTIF.xlsx
    12.9 KB · Đọc: 130

phuongloan0805

Thành viên mới
Tham gia ngày
27 Tháng mười hai 2019
Bài viết
2
Được thích
0
Điểm
0
Tuổi
33
Anh cho em hỏi hàm countif sử dụng như thế nào để đếm được tần suất xuất hiện ở nhiều sheet khác nhau
Cám ơn anh
 

File đính kèm

  • BH NĂM 2019 (2).xlsx
    50.2 KB · Đọc: 109

leonguyenz

Thành viên mới
Thành viên BQT
Moderator
Tham gia ngày
2 Tháng tám 2010
Bài viết
5,029
Được thích
8,603
Điểm
3,218
Nơi ở
Bình Dương
Anh cho em hỏi hàm countif sử dụng như thế nào để đếm được tần suất xuất hiện ở nhiều sheet khác nhau
Cám ơn anh
Hàm INDIRECT sẽ xảy ra lỗi ngoài tham chiếu (#REF) nếu không tìm đúng vùng tham chiếu và như trong ví dụ của bạn là tên sheet. Theo ví dụ, công thức bạn sửa lại như sau:
Mã:
=SUMPRODUCT(COUNTIF(INDIRECT("'"&$M$5:$M$7&"'!B3:B100"),$B4))
Với M5:M7 là THANG 1, THANG 2, THANG 3, là 3 sheet có sẵn. Khi bạn chèn thêm tên sheet có trong vùng M5:Mn thì sửa lại công thức cho phù hợp.
 

File đính kèm

  • BH NĂM 2019 (2).xlsx
    48.4 KB · Đọc: 105

truonganchem

Thành viên mới
Tham gia ngày
24 Tháng sáu 2010
Bài viết
2
Được thích
0
Điểm
0
Tuổi
43
Chao anh leonguyenz. Tôi muốn đếm số lượng kết quả mẫu Âm tính và Dương tính sau khi sử dụng lệnh lọc theo ngày xn giống như hàm countif đã làm trước khi lọc mà không được. Mong anh xem va giúp đỡ. Thanks
 

File đính kèm

  • 2020 XLSL subtotal.xls
    2.9 MB · Đọc: 42

anhduong9x9

Người qua đường. Xin cảm ơn!
Tham gia ngày
19 Tháng sáu 2012
Bài viết
24
Được thích
27
Điểm
303
Tuổi
28
Nơi ở
CauGiay_HN
Bạn
Chao anh leonguyenz. Tôi muốn đếm số lượng kết quả mẫu Âm tính và Dương tính sau khi sử dụng lệnh lọc theo ngày xn giống như hàm countif đã làm trước khi lọc mà không được. Mong anh xem va giúp đỡ. Thanks

Bạn dùng hàm countifs nhé: Công thức ô F4: =IF(COUNTIFS(N10:N19995,"Âm tính",M10:M19995,"="&D5)<>0,COUNTIFS(N10:N19995,"Âm tính",M10:M19995,"="&D5),COUNTIF(N10:N19995,"Âm tính"))
Công thức ô F5: =IF(COUNTIFS(N10:N19995,"Dương tính",M10:M19995,"="&D5)<>0,COUNTIFS(N10:N19995,"Dương tính",M10:M19995,"="&D5),COUNTIF(N10:N19995,"Dương tính"))
Do bài này là countif nên tôi ko giải thích để chủ thớt nói.
 
Lần chỉnh sửa cuối:

n0thing1988

Mù VBA
Tham gia ngày
30 Tháng chín 2013
Bài viết
1,567
Được thích
1,148
Điểm
868
Bạn dùng hàm countifs nhé: =COUNTIFS(N10:N19995,"Âm tính",M10:M19995,"="&D5). do bài này là countif nên tôi ko giải thích để chủ thớt nói.
Tôi thấy bạn hay viết công thức có "=". Sao bạn lại hay viết như vậy thế? Nó có tác dụng đặc biệt gì hay sao?
 

Tungcent

Thành viên mới
Tham gia ngày
31 Tháng tám 2020
Bài viết
9
Được thích
0
Điểm
0
Tuổi
27
Đếm cái ô không chứa dữ liệu hoặc (không chứa dữ liệu ngày tháng năm)

mong được bạn giúp đỡ
Thanks
 

truonganchem

Thành viên mới
Tham gia ngày
24 Tháng sáu 2010
Bài viết
2
Được thích
0
Điểm
0
Tuổi
43
Bạn


Bạn dùng hàm countifs nhé: Công thức ô F4: =IF(COUNTIFS(N10:N19995,"Âm tính",M10:M19995,"="&D5)<>0,COUNTIFS(N10:N19995,"Âm tính",M10:M19995,"="&D5),COUNTIF(N10:N19995,"Âm tính"))
Công thức ô F5: =IF(COUNTIFS(N10:N19995,"Dương tính",M10:M19995,"="&D5)<>0,COUNTIFS(N10:N19995,"Dương tính",M10:M19995,"="&D5),COUNTIF(N10:N19995,"Dương tính"))
Do bài này là countif nên tôi ko giải thích để chủ thớt nói.
Thanks bác
 
Quảng cáo
Top Bottom