Giải hộ mình câu này với ! (T_T)

[thinhpcr]

Yêu cầu là tính Tổng thành tiền từ ngày 5 đến ngày 12 !
Các bạn giúp mình với nhé ! Mình cần gấp mà ! Có đúng một câu thôi ! (T_T)
Xin cảm ơn các bạn !

 

[chibi]

1, Nếu chỉ dùng công thức của Excel thì cần bổ sung thêm cột tổng tiền trong thời gian giới hạn (Từ ngày 5 đến 12), công thức tính tiền là: =Nếu ngày trong khoảng thì tính tiền, ngược lại bằng 0
Tổng tiền sẽ bằng SUM của cột vừa tính.
2, Nếu dùng VBA: Xây dựng một hàm
Function tinhtong()
tong=0
for i=4 to 12
if day(cells(i,5).value)>4 and day(cells(i,5).value)<13 then
tong=tong+cells(i,8).value
endif
next
tinhtong=tong
End Function

 

[thb.58]

Giải quyết bằng đặt công thức cho bài toán của bạn

Mình chỉ có thể đặt công thức "củ chuối" giúp bạn thôi, vì trình độ còn abc về VBA lắm. Nếu cần thì meo cho mình: trec.58@gmail.com

 

[thinhpcr]

Cám ơn các bạn. Mình vừa đọc bài "Tính tổng theo nhiều điều kiện trong diễn đàn và đã giải được câu này với công thức sau:
=SUMPRODUCT((DAY($E$5:$E$12)>=5)*(DAY($E$5:$E$12)<=12)*($H$5:$H$12))
Cám ơn các bạn nhiều !

 

[thinhpcr]

Xong câu hỏi trên kia rùi nhưng mình lại gặp thêm một câu hỏi nữa khoai khoai. Chưa nghĩ ra cách giải quyết. Vậy mình post lên nhờ các bạn nhé !

 

[thinhpcr]

Và cả câu này nữa nè ! Trời ạ khó thế !

 

[thinhpcr]

OK. Mình đọc rồi. Đó cũng là một cách hay nhưng lại phải tạo thêm mấy cột nữa. Bạn xem thử công thức mảng của mình (hàm Sumproduct ở trên nhé). Ngắn gọn thật (học ở diễn đàn đấy).
Mà bạn giúp mình bài về Chi_Phi_NGuyen_Vat_Lieu.xls nhé. Mình còn vướng mắc mỗi bài đó thôi đấy ! (T_T)

 

[thinhpcr]

Mình upload lại bài Chi_Phi_Nguyen_Vat_Lieu.xls lên rùi đấy. Các bạn giúp mình với nhé ! Cảm ơn các bạn !
http://files.myopera.com/thinhpcr/files/Chi_Phi_Nguyen_Vat_Lieu.xls

 

[ThuNghi]

H5==SUMPRODUCT(($E5:$G5)*OFFSET(($G$14:$I$14),MID($C5,5,1),0))
Format Custom #,##0 "đồng"

 

[darkmoon]

OK. Mình đọc rồi. Đó cũng là một cách hay nhưng lại phải tạo thêm mấy cột nữa. Bạn xem thử công thức mảng của mình (hàm Sumproduct ở trên nhé). Ngắn gọn thật (học ở diễn đàn đấy).
Mà bạn giúp mình bài về Chi_Phi_NGuyen_Vat_Lieu.xls nhé. Mình còn vướng mắc mỗi bài đó thôi đấy ! (T_T)

Cthức em làm như sau (&&@@
Đặt tên khối từ $F$15:$I$17 : LOAI

Tại cell Trị giá
=INDEX(LOAI,LEFT(MID(C5,3,3),1),2)*E5+INDEX(LOAI,MID(MID(C5,3,3),2,1),3)*F5+INDEX(LOAI,RIGHT(MID(C5,3,3),1),4)*G5

Không biết có công thức nào ngắn gọn hơn không

 

[thinhpcr]

H5==SUMPRODUCT(($E5:$G5)*OFFSET(($G$14:$I$14),MID($C5,5,1),0))
Format Custom #,##0 "đồng"

Kết quả của bạn sai rồi. Yêu cầu của bài là ví dụ nếu mã sản phẩm là SP321 thì:
Ký tự đầu tiên là sản phẩm làm từ VL1, số 3 tức là loại 3
Ký tự thứ hai là sản phẩm làm từ VL2, số 2 tức là loại 2
Ký tự thứ 3 là sản phẩm làm từ VL3, số 1 tức là loại 1
Dựa vào mã trên, căn cứ vào bảng Trị giá của VL1,2,3 theo loại 1,2,3 - Em đã nhờ một người viết ra công thức và cho ra kết quả đúng như sau:
=SUM(IF(MID(C5,3,1)="1",E5*$G$15,IF(MID(C5,3,1)="2",E5*$G$16,E5*$G$17)),IF(MID(C5,4,1)="1",F5*$H$15,IF(MID(C5,4,1)="2",F5*$H$16,F5*$H$17)),IF(MID(C5,5,1)="1",G5*$I$15,IF(MID(C5,5,1)="2",G5*$I$16,G5*$I$17)))

 

[thinhpcr]

Bởi vì công thức trên có sử dụng hàm Sum lồng với hàm If nên mình nghĩ rằng có thể sử dụng hàm Sumproduct cho trường hợp này. Nhưng công thức thế nào thì mình chưa nghĩ ra. Nhờ các bạn vậy ! Mình thích hàm Sumproduct này lắm !

 

[thinhpcr]

Hoặc có thể sử dụng hàm Vlookup thay thế được không vậy ?

 

[thinhpcr]

Cthức em làm như sau (&&@@
Đặt tên khối từ $F$15:$I$17 : LOAI

Tại cell Trị giá
=INDEX(LOAI,LEFT(MID(C5,3,3),1),2)*E5+INDEX(LOAI,MID(MID(C5,3,3),2,1),3)*F5+INDEX(LOAI,RIGHT(MID(C5,3,3),1),4)*G5

Không biết có công thức nào ngắn gọn hơn không

Công thức của bạn hay thật ! Cho ra kết quả quá đúng luôn.
Nhưng mình chẳng hiểu gì cái hàm Index cả, chỉ biết mỗi Vlookup, IF với cả Sumproduct thui. Bạn có thể giải thích cho mình được không ?

 

[ThuNghi]

Dùng CT của Darkmoon là gọn lắm rồi, còn có thể dùng:
=E5*OFFSET($G$14,MID($C5,3,1),0)+F5*OFFSET($G$14,MID($C5,4,1),1)+G5*OFFSET($G$14,MID($C5,5,1),2)
Xin lỗi bạn, vì trước chưa đọc kỹ đề.
OFFSET($G$14,MID($C5,3,1),0) nghĩa là G14 + MID($C5,3,1) dòng lấy thêm 0 cột, cụ thể MID($C5,3,1)=1, thì G14 là G15

 

[thinhpcr]

Trong trường hợp này có thể dùng hàm Vlookup hoặc Sumproduct không vậy ?

 

[SA_DQ]

/)/ó đây rồi:

Hoặc có thể sử dụng hàm Vlookup thay thế được không vậy ?

=VLOOKUP(INT(MID(C$5,3,1)),LoaiVL,2,0)+VLOOKUP(INT(MID(C$5,4,1)),LoaiVL,3,0)+VLOOKUP(INT(MID(C$5,5,1)),LoaiVL,4,0)
(ông thức có thể vầy, nếu như các số tại Name => VLieu được nhập thêm dấu nháy đơn fía trước (Lúc đó ta khỏi dùng hàm =INT(Text) để chuyển đổi
=VLOOKUP(MID(C$5,3,1),VLieu,2,0)+VLOOKUP(MID(C$5,4,1),VLieu,3,0)+VLOOKUP(MID(C$5,5,1),VLieu,4,0)

 

[BumBum]

Hoặc có thể sử dụng hàm Vlookup thay thế được không vậy ?

Dùng như thế này đi:

=VLOOKUP(VALUE(MID(C5,3,1)),$F$15:$I$17,2,0)*E5+VLOOKUP(VALUE(MID(C5,4,1)),$F$15:$I$17,3,0)*F5+VLOOKUP(VALUE(MID(C5,5,1)),$F$15:$I$17,4,0)*G5

 

[anhtuan1066]

Mình có 1 công thức tương đối "củ chuối" 1 chút, hy vọng có thễ giúp bạn... Ở cell H5 tạo công thức sau: =HLOOKUP("VL1",$F$14:$I$17,MID(C5,3,1)+1,0)*E5 + HLOOKUP("VL2",$F$14:$I$17,MID(C5,4,1)+1,0)*F5 + HLOOKUP("VL3",$F$14:$I$17,MID(C5,5,1)+1,0)*G5
Tôi nghĩ có thể làm cho công thức này gọn thêm nữa đấy... Các bạn tham khảo xem...
Chúc vui vẽ
ANH TUẤN