dùng CF để tô màu cho các điều kiện trong bảng dữ liệu

[nga xoan]

chào A/C trong diễn đàn nhé,
em có 2 câu hỏi mong A/C xem để giải nó giúp em với.
trong file đính kèm, em muốn tô màu cho những ô đó bằng conditional Formating.
Giúp em nhé,
em cảm ơn ạ,
Nga xoăn

 

[VMH0307]

Tại ô A3 dùng công thức sau trong CF

=ISERROR(MATCH(A3,$B$3:$B$55,0))

Tại ô B3 dùng công thức sau trong CF

=COUNTIF(C3:N3,"X")>=3

Định dạng như mong muốn rồi Format Painter cho các ô còn lại.

 

[nga xoan]

em cảm ơn câu trả lời của bác"tttmuahmuah" nhé.
rất đúng với ý của em
bác cho em hỏi thêm một điều kiện cho câu thứ 2, tại ô B3 em muốn tô màu khác để chú ý cho SP có tần suất xuât hiện trong 3 tháng liên tiếp. Mong nhận được sự chỉ giáo của bác.
em cảm ơn

 

[VMH0307]

Bạn xem theo file đính kèm nhé

 

[nga xoan]

em đã xem file của bác gửi cho em nhưng em thấy vẫn chưa hiểu hàm dùng cho DK 1, sao em làm không ra nhỉ. bác chỉ dẫn cho em thêm được không ạ? em cảm ơn nhiều
Thân

 

[VMH0307]

Trước tiên để con trỏ ở ô B3 và bạn đặt những name sau:
(chắc cách đặt name bạn biết chứ: Insert/Name/Define...)
Thứ nhất: ID_1

=(Sheet1!$C3:$O3="X")*1

Thứ hai: ID_2

=(Sheet1!$B3:$N3="X")*1

Thứ ba: MA1

=SMALL(IF(ID_1=1,IF(ID_2=0,COLUMN(Sheet1!$A:$M),""),""),COLUMN(Sheet1!$A:$M))

Thứ tư: MA2

=SMALL(IF(ID_1=0,IF(ID_2=1,COLUMN(Sheet1!$A:$M)-1,""),""),COLUMN(Sheet1!$A:$M))

Sau đó tại Conditional Format mới sử dụng công thức sau:

=IF(ISERROR(LOOKUP(11,1/(MA2-MA1>=2),COLUMN($A:$M))),0,1)

Tôi giải thích sơ bộ như sau:
giả sử có dữ liệu như sau:

ID_1 sẽ cho 1 mảng như sau:
{0,1,1,1,0,1,0,1,0,0,0,0,0}
ID_2 sẽ cho 1 mảng khác là:
{0,0,1,1,1,0,1,0,1,0,0,0,0}
MA1 sẽ cho giá trị:
{2,6,8,#NUM!,#NUM!,#NUM!,#NUM!,#NUM!,#NUM!,#NUM!,#NUM!,#NUM!,#NUM!}
MA2 sẽ cho giá trị:
{4,6,8,#NUM!,#NUM!,#NUM!,#NUM!,#NUM!,#NUM!,#NUM!,#NUM!,#NUM!,#NUM!}
Và như thế công thức trong CF sẽ trả về 1 khi tìm thấy có 1 dãy số ít nhất 3 phần tử liên tục (tức MA2-MA1>=2) và ô sẽ định dạng theo mong muốn của bạn, nếu không trả về 0 và không có hiện tượng gì xảy ra cả.