Chuyên đề giải đáp các bài tập

[tuanphusixd]

Có ai chỉ giúp cho mình

ví dụ tiền lương là 1166000đ mình muốn chia làm 2 cột tiền chẵn và tiền lẻ như 1150000 là tiền chẵn còn 16000 là tiền lẻ

 

[duongdv]

Bạn xem file đính kèm

 

[ndu96081631]

Có ai chỉ giúp cho mình

ví dụ tiền lương là 1166000đ mình muốn chia làm 2 cột tiền chẵn và tiền lẻ như 1150000 là tiền chẵn còn 16000 là tiền lẻ

Bạn đưa file lên cho dể ---> Nếu tự làm được, hãy thử với hàm INT và MOD nhé

 

[huuthang_bd]

Có ai chỉ giúp cho mình

ví dụ tiền lương là 1166000đ mình muốn chia làm 2 cột tiền chẵn và tiền lẻ như 1150000 là tiền chẵn còn 16000 là tiền lẻ

Bạn dùng các công thức sau:

TienChan=FLOOR(TienLuong,50000)

TienLe=TienLuong-TienChan

Hoặc:

TienLe==MOD(TienLuong,50000)

 

[vuongcoi]

Gửi bạn mountain84, bài toán Cà phê, Đường, Gạo, Hạt điều... của tuankeuqt hỏi, bạn làm vậy cũng được, nhưng công thức của bạn dài quá. Có cách làm cho nó ngắn hơn. Bạn so sánh các công thức sau (công thức của bạn ở hàng trên, còn công thức của tôi ở hàng dưới):

Câu 2, Loại Hàng (cột D):

= VALUE(RIGHT(B2,1))
= RIGHT(B2)*1
​

Câu 3, Tên Hàng (cột C):

= VLOOKUP(LEFT(B2,1),$A$13:$E$16,2,0)
= VLOOKUP(LEFT(B2),$A$13:$E$16,2,0)
​

Câu 4, Thành tiền (cột F):

= E2 * IF(AND(D2=1, C2=VLOOKUP(LEFT(B2,1),$A$13:$E$16,2,0)), VLOOKUP(LEFT(B2,1),$A$13:$E$16,3,0), VLOOKUP(LEFT(B2,1),$A$13:$E$16,4,0))
= E2 * VLOOKUP(LEFT(B2),$A$13:$D$16,D2+2,0)
​

Câu 5, Thuế (cột G):

= F2 * IF(AND(VLOOKUP(LEFT(B2,1),$A$13:$E$16,2,0)=C2, VLOOKUP(C2,$B$13:$E$16,4,0)="x"), 0, VLOOKUP(VALUE(MID(B2,2,1)),$I$13:$J$16,2,0))
= F2 * VLOOKUP(MID(B2,2,1)*1,$I$13:$J$16,2,0) * (VLOOKUP(LEFT(B2),$A$13:$E$16,5,0)<>"x")
​

Câu 10, Thống kê (C34:C37):

= SUMIF($C$2:$C$8,B34,$H$2:$H$8)
= SUMIF($C$2:$C$8,B34,$H$2)
​

lộn hàng rui sory nnhe

 

[vuongcoi]

mình dang hoc bài này nè mọi người giải quyết dùm

 

[huuthang_bd]

mình dang hoc bài này nè mọi người giải quyết dùm

Dùng công thức này:

E4=VLOOKUP(LEFT(B4),$B$14:$G$17,3+(MID(B4,2,1)="L"),)*D4

 

[httminh]

Có gì các bạn gửi thêm các bài tập

 

[thanhxt2009]

Có gì các bạn gửi thêm các bài tập

Điều này thì dễ thôi. Đây nè tha hồ làm nhé!@
Thân chào!

 

[duongdv]

Các bạn giải giúp mình câu này nhé. Xin cảm ơn nhiều.

file dữ liệu
http://www.mediafire.com/?zgeezmjnz2g

Bạn xem công thức này nhé! Nó hơi dài một chút
Công thức tại ô G3
INDEX($B$24:$E$27,MATCH("VL"&MID(B3,3,1),$B$24:$B$27),MATCH(--MID(B3,3,1),$B$24:$E$24,0))+INDEX($B$24:$E$27,MATCH("VL"&MID(B3,4,1),$B$24:$B$27),MATCH(--MID(B3,4,1),$B$24:$E$24,0))+INDEX($B$24:$E$27,MATCH("VL"&MID(B3,5,1),$B$24:$B$27),MATCH(--MID(B3,5,1),$B$24:$E$24,0))
Copy công thức cho các ô còn lại

 

[cop_kh]

Các bạn giải giúp mình câu này nhé. Xin cảm ơn nhiều.

file dữ liệu
http://www.mediafire.com/?zgeezmjnz2g

Theo mình bạn dùng công thức này là OK:
G3=HLOOKUP(--MID(B3;3;1);$C$24:$E$25;2;0)*D3+HLOOKUP(--MID(B3;4;1);$C$24:$E$26;3;0)*E3+HLOOKUP(--MID(B3;5;1);$C$24:$E$27;4;0)*F3

 

[cop_kh]

Xin cảm ơn các bạn, nhưng mình thấy công thức này là đúng nhất.
Trị giá ô đầu tiên là: 12.600đ

=D2*VLOOKUP(MID(B2,3,1),$A$21:$D$23,2,0)+E2*VLOOKUP(MID(B2,4,1),$A$21:$D$23,3,0)+F2*VLOOKUP(MID(B2,5,1),$A$21:$D$23,4,0)

Bạn xem lại KQ thử, theo mình ô đầu tiên phải là: =100*100+60*30+8*20=11960

 

[duongdv]

Bạn xem file đính kèm.

 

[thanhxt2009]

Cho mình hỏi nhé:
Mình có cột Mã hàng và cột Số lượng (trong đó Số lượng là chuỗi ký tự số cuối cùng của Mã hàng)
Vậy mình dùng công thức như thế nào? Các bạn giúp mình với!

Mã hàng ________ Số lượng
HPLT03 _____________?
CISW20
KSRA100
HPPR30
ITMA20
KMRA120
KSRA50
CINE300
HPLT15
GIMA60
KMRA40
CIHB130
HPPR25
ITMA15

Khi mình hỏi thì tự nhiên mình lại tìm ra rồi.
=value(mid(B5,5,3))

Nếu dữ liệu lúc nào cũng có 4 ký tự ở đầu thì bạn có thể dùng công thức này!

=Value(Right(Mã hàng,Len(Mã hàng)-4)

Mã hàng thì bạn thay bằng địa chỉ ô chứa nhé! Vd: B5
Hoặc công thức:

Right(Mã hàng,Len(Mã hàng)-4)*1

 

[caoky1]

Công thức này:

=VLOOKUP(LEFT(C2),$C$13:$F$15,MATCH("tầng "&RIGHT(C2),$C$12:$F$12,0),0)

Có thể sửa lại:

=VLOOKUP(LEFT(C2),$C$13:$F$15,RIGHT(C2)+1,0)

Và công thức này:

=VLOOKUP(LEFT(C2),$C$13:$I$15,MATCH("tầng "&RIGHT(C2),$G$12:$I$12,0)+4,0)

Có thể sửa lại:

=VLOOKUP(LEFT(C2),$C$13:$I$15,RIGHT(C2)+4,0)

Mới gọn hơn chứ ---> Trừ phi bảng tra cứu được sắp xếp theo kiểu khác, lúc ấy ta hãy dùng MATCH vẫn chưa muộn
Còn công thức:

=SUMPRODUCT((LEFT(C2:C7)=C19)*$J$2:$J$7)

thì hình như quên $
Như thế này đúng hơn:

=SUMPRODUCT((LEFT($C$2:$C$7)=C19)*$J$2:$J$7)

Và mặc khác ta vẫn có thể dùng SUMIF... như vầy đây:

=SUMIF($C$2:$C$7,$C19&"*",$J$2:$J$7)

Em ko hiểu cái công thức =Vlookup(LEFT(C2),$C$13:$F$15,RIGHT(C2)+1,0) . Em ko hiểu cái ý nghĩa của Right(C2)+1 . Các cao thủ giải thích hộ em Right(C2)+1 là gì ko ạ ?

 

[BNTT]

Em ko hiểu cái công thức =Vlookup(LEFT(C2),$C$13:$F$15,RIGHT(C2)+1,0) . Em ko hiểu cái ý nghĩa của Right(C2)+1 . Các cao thủ giải thích hộ em Right(C2)+1 là gì ko ạ ?

• LEFT(C2): Ký tự ngoài cùng bên trái của ô C2 (ký tự đầu tiên)
• RIGHT(C2): Ký tự ngoài cùng bên phải của ô C2 (ký tự cuối cùng, mà trong trường hợp này thì nó là một con số)
• RIGHT(C2)+1: Lấy con số nằm ở ngoài cùng bên phải của ô C2 cộng thêm 1.

Vậy:

=VLOOKUP(LEFT(C2),$C$13:$F$15,RIGHT(C2)+1,0)​

Có nghĩa là: Lấy ký tự ngoài cùng bên trái (ký tự đầu tiên) của ô C2, đi dò với cột đầu tiên trong dãy ô $C$13:$F$15, nếu dò ra, lấy giá trị ở bên cái cột nào (của dãy ô $C$13:$F$15), thì dựa vào kết quả công thức RIGHT(C2)+1 trả về. Ví dụ, con số cuối cùng của chuỗi ký tự trong ô C2 là 1, thì lấy kết quả ở cột 2 (của dãy ô $C$13:$F$15); con số cuối cùng của chuỗi ký tự trong ô C2 là 2, thì lấy kết quả ở cột 3...

 

[caoky1]

• LEFT(C2): Ký tự ngoài cùng bên trái của ô C2 (ký tự đầu tiên)
• RIGHT(C2): Ký tự ngoài cùng bên phải của ô C2 (ký tự cuối cùng, mà trong trường hợp này thì nó là một con số)
• RIGHT(C2)+1: Lấy con số nằm ở ngoài cùng bên phải của ô C2 cộng thêm 1.

Vậy:

=VLOOKUP(LEFT(C2),$C$13:$F$15,RIGHT(C2)+1,0)​

Có nghĩa là: Lấy ký tự ngoài cùng bên trái (ký tự đầu tiên) của ô C2, đi dò với cột đầu tiên trong dãy ô $C$13:$F$15, nếu dò ra, lấy giá trị ở bên cái cột nào (của dãy ô $C$13:$F$15), thì dựa vào kết quả công thức RIGHT(C2)+1 trả về. Ví dụ, con số cuối cùng của chuỗi ký tự trong ô C2 là 1, thì lấy kết quả ở cột 2 (của dãy ô $C$13:$F$15); con số cuối cùng của chuỗi ký tự trong ô C2 là 2, thì lấy kết quả ở cột 3...

Hi hi, bây giờ thì em đã hiểu. Cám ơn anh ( chị ) rất nhiều

 

[babylien]

chỉ cho em các hàm của excel đi... em không nhớ ....mai em thi rồi...

 

[caoky1]

Bạn dùng hàm left là biết được Toán, Lý hoặc Hóa thôi bạn nhé. Bạn toán của Bạn phải dùng công thức mảng.
1/Điểm cao nhất
=MAX(IF(LEFT($F$7:$F$18)=D21;$G$7:$G$18;""))
2/Điểm thấp nhất
=MIN(IF(LEFT($F$7:$F$18)=D21;$G$7:$G$18;""))
3/Điểm trung bình
=AVERAGE(IF(LEFT($F$7:$F$18)=D21;$G$7:$G$18;""))

Khi gõ công thức xong bấm tổ hợp phím: Ctrl+Shift+Enter nhé bạn!

Bạn ơi, mình thử làm theo các công thức này và thấy nếu ko nhấn tổ hợp phím Ctrl+Shift+Enter thì máy sẽ báo lỗi. Bạn giải thích hộ mình tại sao đc ko?

 

[duongdv]

Bạn ơi, mình thử làm theo các công thức này và thấy nếu ko nhấn tổ hợp phím Ctrl+Shift+Enter thì máy sẽ báo lỗi. Bạn giải thích hộ mình tại sao đc ko?

Vấn đề là bạn áp dụng công thức trên vào bài tập nào? Bạn gửi kèm bài tập đó lên xem sao?