Chuyên đề giải đáp các bài tập

[BNTT]

Mình đang làm 1 bài về tính tiền điện. mình mới học nên chưa hiểu sâu lắm mong các bạn chỉ giáo cho bài này. mình đã up file bài lên rùi. yêu cầu của bài là hãy tính điền vào ô Phụ trội : bằng 0 nếu chỉ số cuối trừ đi chỉ số đầu <=50. thành tiền *35% nếu 50<chỉ số cuối trừ chỉ số đầu<=100. thành tiền *100% nếu chỉ số cuối trừ chỉ số đầu >100.
Mình đã làm bằng hàm If Lồng 2 lần vào rùi nhưng ko đc. vẫn còn gà mong các bạn chỉ giáo.

Bạn dùng thử cái này (tại F3):

= E3 * IF(C3-B3<=50, 0, IF(C3-B3>100, 100%, 35%))​

- Nếu Chỉ số đầu - Chỉ số cuối <=50 thì nhân với 0
- Nếu Chỉ số đầu - Chỉ số cuối >100 thì nhân với 100%
- Còn không thì nhân với 35%​

Tức là chỉ xét trường hợp thứ I và thứ III, nếu không trúng thì đó là trường hợp II (dùng phép loại trừ í mà).

 

[locpro]

Cảm ơn bạn. công thức bạn cho đúng rồi. nhưng mình muốn hỏi sao công thức này mình cho vào lại sai:
=IF(C3-B3<=50, 0, IF(50<C3-B3<=100,E3*35%,E3*100%))
mà công thức này lại đúng:
=IF(C3-B3<=50, 0, IF(C3-B3>100,E3*100%,E3*35%))
Mình ko hiểu lắm.mong đc giải đáp.hic

 

[miss_ltk]

Cảm ơn bạn. công thức bạn cho đúng rồi. nhưng mình muốn hỏi sao công thức này mình cho vào lại sai:
=IF(C3-B3<=50, 0, IF(50<C3-B3<=100,E3*35%,E3*100%))
mà công thức này lại đúng:
=IF(C3-B3<=50, 0, IF(C3-B3>100,E3*100%,E3*35%))
Mình ko hiểu lắm.mong đc giải đáp.hic

công thức của bạn sai vì không thể ghi là 50<C3-B3<=100 mà phải dùng hàm AND.
còn công thức của BNTT thì mệnh đề if sau đã bao hàm luôn 50<C3-B3 nên không cần ghi lại^^
mong bạn hiểu!!!!
thân,
Miss_ltk.

 

[BNTT]

Cảm ơn bạn. công thức bạn cho đúng rồi. nhưng mình muốn hỏi sao công thức này mình cho vào lại sai:
=IF(C3-B3<=50, 0, IF(50<C3-B3<=100,E3*35%,E3*100%))
mà công thức này lại đúng:
=IF(C3-B3<=50, 0, IF(C3-B3>100,E3*100%,E3*35%))
Mình ko hiểu lắm.mong đc giải đáp.hic

Excel không bao giờ hiểu được kiểu viết 50<C3-B3<=100. Kiểu này, chỉ có chúng ta (người đọc) mới hiểu được mà thôi.

Ban sửa lại cái này:

50<C3-B3<=100​

Bằng cái này:

AND(C3-B3>50, C3-B3<=100)​

Thì công thức của bạn sẽ đúng, tuy là hơi dài hơn cái của tôi.

 

[locpro]

Mình hiẻu rồi,cảm ơn các bạn nhiều nhé.Thanks!

 

[thanhxt2009]

Gởi các bạn một bài tập Excel nè! Giải nhé!

Mình mới soạn bài này đó, các bạn xem và giải rồi cho biết ý kiến nha!

 

[Kim.Nguyen]

Mình mới soạn bài này đó, các bạn xem và giải rồi cho biết ý kiến nha!

Vẫn chưa gửi file đính kèm được, bực thật! Bạn đọc tạm công thức ở đây nghe.

Câu 1: Số thứ tự

=COUNTA($B$4:B4)

Câu 2: Tên hàng & Hãng SX

=VLOOKUP(MID(B4,FIND("-",B4)+1,FIND("*",B4)-FIND("-",B4)-1),$A$13:$C$18,2,0) & " " & HLOOKUP(LEFT(B4,FIND("-",B4)-1),$H$12:$K$13,2,0)

Câu 3: Số lượng

=RIGHT(B4,LEN(B4)-FIND("*",B4))*1

Câu 4: Đơn giá

=VLOOKUP(MID(B4,FIND("-",B4)+1,FIND("*",B4)-FIND("-",B4)-1),$A$13:$C$18,3,0)*(1-(HLOOKUP(LEFT(B4,FIND("-",B4)-1),$H$12:$K$13,2,0)="LG")*2%)

Câu 5: Thành tiền

=E4*F4*(1-OR(E4>=100,WEEKDAY(D4,2)>5)*10%)

Câu 6: Bảng thống kê

Số lượng: =SUMPRODUCT((LEFT($C$4:$C$9,FIND(" ",$C$4:$C$9,6)-1)=H$15)*$E$4:$E$9)

Doanh số: =SUMPRODUCT((LEFT($C$4:$C$9,FIND(" ",$C$4:$C$9,6)-1)=H$15)*$G$4:$G$9)

 

[Ba Tê]

Mình mới soạn bài này đó, các bạn xem và giải rồi cho biết ý kiến nha!

------
Bạn soạn đề bài dữ quá, có lẽ để thử các công thức chứ nếu là một bảng tính thật sự của một công ty thì xin "Bái", bảng dò dọc, bảng dò ngang, mã hàng, hãng SX, số lượng kết nối thành text chung một cột, lại giảm 2%, 10%, thứ bảy, chủ nhật...
Mới thử một công thức tính đơn giá đã bị "tẩu hỏa".
Chạy thôi.

=IF(LEFT(B4;FIND("-";B4)-1)=$J$12;VLOOKUP(MID(B4;FIND("-";B4)+1;FIND("*";B4)-FIND("-";B4)-1);$A$13:$C$18;3;0)*98%;VLOOKUP(MID(B4;FIND("-";B4)+1;FIND("*";B4)-FIND("-";B4)-1);$A$13:$C$18;3;0))

 

[Kim.Nguyen]

------
Bạn soạn đề bài dữ quá, có lẽ để thử các công thức chứ nếu là một bảng tính thật sự của một công ty thì xin "Bái", bảng dò dọc, bảng dò ngang, mã hàng, hãng SX, số lượng kết nối thành text chung một cột, lại giảm 2%, 10%, thứ bảy, chủ nhật...
Mới thử một công thức tính đơn giá đã bị "tẩu hỏa".
Chạy thôi.

=IF(LEFT(B4;FIND("-";B4)-1)=$J$12;VLOOKUP(MID(B4;FIND("-";B4)+1;FIND("*";B4)-FIND("-";B4)-1);$A$13:$C$18;3;0)*98%;VLOOKUP(MID(B4;FIND("-";B4)+1;FIND("*";B4)-FIND("-";B4)-1);$A$13:$C$18;3;0))

Đâu đến nỗi như thế, Ba Tê ơi? Bạn xem bài giải của Kim.Nguyen chưa? Bài toán này khó thật, nhưng chưa đến nỗi khó lắm đâu. Tinh ý một chút, sẽ thấy hướng để giải quyết à.

 

[tranttoan]

các bạn ơi !
Tôi thấy hình như bài này là do tác giả tự đặt ra thì phải, nếu có gì sai đừng giận mình nhe, lí do ư :
- Các dữ liệu trong bài trong thực tế là Hiếm có trường hợp như thế
- Các dạng bài này của tác giả lập lại nhiều lần thì phải.
- Tác giả muốn đố các bạn trên GPE, sau khi đặt ra bài toán và đã có cách giải của bài toán mặc dù cách giải đó của tác giả dài lê thê.
Về cách giải thì bạn Kim Nguyên đã làm hết rồi thì phải
...............................................................................
Tôi đề xuất cách thêm công thức số TT khác

=IF(B4="","",ROW()-3)

 

[BNTT]

các bạn ơi !
Tôi thấy hình như bài này là do tác giả tự đặt ra thì phải, nếu có gì sai đừng giận mình nhe, lí do ư :
- Các dữ liệu trong bài trong thực tế là Hiếm có trường hợp như thế
- Các dạng bài này lcủa tác giả ập lại nhiều lần thì phải.
- Tác giả muốn đố các bạn trên GPE, sau khi đặt ra bài toán và đã có cách giải của bài toán mặc dù cách giải đó của tác giả dài lê thê.
Về cách giải thì bạn Kim Nguyên đã làm hết rồi thì phải
...............................................................................
Tôi đề xuất cách thêm công thức số TT khác

=IF(B4="","",ROW()-3)

Chào bạn. Bài toán này, bạn thanhxt2009 có nói rõ là do chính bạn ấy soạn ra mà, đâu phải là "hình như"... Theo tôi thấy thì đây là một bài toán hay. Nếu làm được nó, nghĩa là các bạn đã có một kỹ năng vận dụng hàm để xử lý chuỗi ký tự rất tốt.

Công thức tính số thứ tự của bạn, đúng, nhưng chỉ đúng khi dữ liệu được bắt đầu ở hàng thứ 4, vì khi đó thì ROW()-3 của bạn mới đúng. Còn nếu, lỡ như, bạn chèn thêm vài hàng ở trên đầu bảng tính, thì cái trừ 3 (-3) của bạn sẽ không còn đúng nữa. Nên dùng COUNTA sẽ hay hơn, và không sợ chuyện chèn hàng hay xóa bớt hàng. Mà bản thân COUNTA cũng sẽ xét đến chuyện ô ở cột B có rỗng hay không, giống cái IF(B4="" ... của bạn.

Riêng bài giải của bạn Kim.Nguyen, có một công thức tôi rất tâm đắc: Công thức tính thành tiền. Trong đề bài, tác giả nói là giảm 10% cho những mặt hàng có số lượng bán ra lớn hơn hay bằng 100, hay là bán ra trong ngày thứ bảy, chủ nhật. Bình thường, có thể các bạn sẽ làm một cái IF và một cái OR cho trường hợp này, phải không?

Với: Số lượng ở E4, Đơn giá ở F4, và Ngày bán ở D4
- Số lượng bán ra lớn hơn hay bằng 100: E4>=100
- Ngày bán là thứ bảy: WEEKDAY(D4)=7
- Ngày bán là chủ nhật: WEEKDAY(D4)=1

Gom cả 3 cái lại:

OR(E4>=100, WEEKDAY(D4)=7, WEEKDAY(D4)=1)​

Dùng hàm IF bình thường, sẽ có công thức này:

Thành tiền = E4 * F4 * (1 - IF(OR(E4>=100, WEEKDAY(D4)=7, WEEKDAY(D4)=1), 10%, 0)​

Thế mà bài giải của Kim.Nguyen thì chỉ là như thế này:

Thành tiền = E4 * F4 * (1 - OR(E4>=100, WEEKDAY(D4,2)>5)*10%)​

Một kỹ năng vận dụng hàm rất hay! Chẳng cần IF, và chỉ cần 1 cái WEEKDAY.

 

[thanhxt2009]

Cám ơn bạn BNTT rất nhiều về cách giải thích của bạn.
Mình soạn bài tập này đưa lên là mong muốn được học hỏi cách sử dụng hàm sao cho đơn giản và hay thôi! Chứ cách làm của mình tuy giải quyết được vấn đề nhưng công thức sử dụng hàm hơi phức tạp một chút (phức tạp ở đây là hơi dài). Bài này mình soạn và đưa lên cốt lõi để học hỏi cách vận dụng các hàm Excel để giải quyết vấn đề một cách đơn giản hơn thôi, giống như bạn BNTT đã nói; chứ mình không có ý định thách đố ai cả. Tuy nhiên thì trên thực tế thì ít có trường hợp xãy ra như bài soạn của mình đâu, mình biết điều đó.
Diễn đàn chính là nơi học hỏi kinh nghiệm lẫn nhau mà, phải không các bạn!
Thân chào!

Đâu đến nỗi như thế, Ba Tê ơi? Bạn xem bài giải của Kim.Nguyen chưa? Bài toán này khó thật, nhưng chưa đến nỗi khó lắm đâu. Tinh ý một chút, sẽ thấy hướng để giải quyết à.

Cám ơn bài giải của bạn nhé!
Thân chào!

Sẳn đây mình gởi đáp án của mình để các bạn tham khảo nhé!
Mình cũng có vài câu giống với bạn Kim.Nguyen đã làm!
Thân ái!

Buồn ngủ quá rồi, mình ngủ đây!

 

[BNTT]

Sẳn đây mình gởi đáp án của mình để các bạn tham khảo nhé!
Mình cũng có vài câu giống với bạn Kim.Nguyen đã làm!
Thân ái!

Buồn ngủ quá rồi, mình ngủ đây!

Câu số 6, theo công thức của bạn:

=IF(AND(E4>=100,OR(WEEKDAY(D4)=1,WEEKDAY(D4)=7)),90%,100%)*E4*F4​

Thì: Mặt hàng được giảm 10% phải có số lượng bán >= 100 và bán ra trong ngày thứ 7 hoặc chủ nhật, hay nói cách khác, nếu số lượng bán >= 100 mà bán ra vào thứ Hai thì không được giảm, hoặc bán ra vào thứ 7, CN mà số lượng nhỏ hơn 100 cũng không được giảm, phải không?

Nhưng theo đề bài:

Nhưng giảm 10% cho các mặt hàng có số lượng >=100 và mặt hàng được bán trong ngày thứ bảy hoặc chủ nhật

Vì có đến 2 chữ "mặt hàng", nên người đọc sẽ hiểu đây là 2 mệnh đề độc lập, và đương nhiên (kể cả tôi) cũng sẽ hiểu rằng: Cả hai loại "mặt hàng" đó, cái nào cũng được hưởng giảm giá 10%. Nói cách khác, tôi sẽ hiểu rằng: Mặt hàng có số lượng >=100 (bán ngày nào cũng được) và Mặt hàng được bán trong ngày thứ bảy hoặc chủ nhật (số lượng bao nhiêu cũng được) đều được giảm 10%. Và nếu như thế, thì công thức của bạn Kim.Nguyen mới đúng (bạn xem lại bài tôi phân tích ở trên về cái hay của công thức này khi Kim.Nguyen chỉ dùng 1 hàm WEEKDAY và không dùng tới IF).

---------------------------------
Góp ý chân tình đây:

Hình như đây không phải là lần đầu bạn có vấn đề với "chữ nghĩa" khi ghi các điều kiện. Tôi nhớ cách đây không lâu, bạn đã nói (cũng với Kim.Nguyen):

Nếu bạn lý giải như vậy thì mình cũng muốn ngọng luôn đó! Bài này yêu cầu là chỉ được một trong hai thôi, chứ không thể cả hai được. Nếu nói như bạn thì người ta đã cho đk kèm theo rồi. Mà trường hợp xảy ra như thế thì hiếm lắm bạn ơi!
Cám ơn bạn đã cho mình một góp ý hay, mình sẽ suy nghĩ trường hợp này khi soạn đề!
Thân chào!

Với riêng tôi, về mặt khách quan mà nói, thì bạn sai, còn Kim.Nguyen đúng đấy. Bạn viết như thế nào, người ta sẽ hiểu như thế đó, không thể để đến khi người ta hiểu sai ý bạn, thì bạn mới lên tiếng, mà lại không đúng. Cụ thể cái bài toán mà bạn nói rằng bạn "muốn ngọng" đó, tôi có xem lại đề bài của bạn, chẳng có chỗ nào nói rằng "Bài này yêu cầu là chỉ được một trong hai thôi". Không tin, bạn xem lại thử nhé. Nếu bạn muốn rằng "chỉ được một trong hai", thì bạn phải ghi cụ thể ngay trong đề bài.

 

[LuanXT]

Pro Nào Giúp Em Giải Bài Hóc Búa Này Với!!

Pro Nào Giúp Em Giải Bài Hóc Búa Này Với!!
Em Đang Cần Gấp. File Em Đính Kèm Ở Dưới
Cám Ơn Rất Nhiều

 

[salam]

Pro Nào Giúp Em Giải Bài Hóc Búa Này Với!!
Em Đang Cần Gấp. File Em Đính Kèm Ở Dưới
Cám Ơn Rất Nhiều

Bạn xem trong file nhé.

 

[MinhCong]

Còn câu số 9 bạn tự làm nhé!

 

[thanhan_truong]

Công Thức EXcel

.

Các bạn có thể giúp mình giải cho mình 2 bài tập này được không, em mình kêu mình giải dùm nó, nhưng lâu quá rồi mình không làm nên chẳng nhớ, các bạn giúp mình nha. các bạn làm xong gửi cho mình qua email " ai113114@gmail.com nha. Cám ơn các bạ nhiều nha .

ai113114@gmail.com

 

[thanhan_truong]

Bài tập Excel về công thức hàm IF

Giúp mình giải bài tập Excel này nha.

 

[BNTT]

Giúp mình giải bài tập Excel này nha.

Giúp thôi, không làm dùm đâu nghe, làm dùm thì làm sao mà bạn giỏi được ?

- Số ngày ở:

Chỉ cần lấy ngày đi trừ ngày đến rồi cộng 1 thôi, không cần dùng đến hàm INT làm gì.​

- Số tuần ở:

Lấy số ngày ở chia cho 7, rồi lấy phần nguyên (dùng hàm INT, hoặc QUOTIENT)​

- Số ngày lẻ:

Giống như tính số tuần ở, nhưng lấy phần lẻ (dùng hàm MOD)​

- Giá phòng 1 tuần và 1 ngày:

Dùng hàm VLOOKUP, lấy 3 ký tự đầu của mã số đi dò với bảng Biểu Giá Phòng, để tính tiền tuần thì lấy giá ở cột thứ 2, tính tiền ngày thì lấy giá ở cột 3.​

- Tổng cộng = Tiền ăn + Tiền ở theo tuần + Tiền ở theo ngày

Tiền ăn + Tiền ở theo tuần thì quá dễ rồi. Chỉ có cái tiền ở theo ngày, bạn dùng hàm MIN để lấy giá trị nhỏ hơn giữa hai cái: Tiền ở 1 tuần (= giá phòng 1 tuần) và Tiền ở theo ngày thực tế (= số ngày lẻ x giá phòng 1 ngày lẻ)

Công thức tính Tổng cộng sẽ có dạng:

= (Tiền ăn) + (Giá phòng 1 tuần x Số tuần ở) + MIN(Giá phòng 1 tuần, (Giá phòng 1 ngày x Số ngày lẻ))​

- Tính tổng doanh thu của tầng trệt:

Dùng hàm SUMIF, với điều kiện tính tổng là "TR*"

Giải thích: TR chính là chữ viết tắt của tầng trệt (theo đề bài), do đó, nêu điều kiện TR* nghĩa là đi tìm những mã số nào bắt đầu bằng hai chữ TR thì cộng ô tương ứng bên cột doanh thu.​

 

[thanhxt2009]

Gởi bạn BNTT! Rất cám ơn lời nhận xét chân tình của bạn về bài tập mình gởi!

Câu số 6, theo công thức của bạn:

=IF(AND(E4>=100,OR(WEEKDAY(D4)=1,WEEKDAY(D4)=7)),90%,100%)*E4*F4​

Thì: Mặt hàng được giảm 10% phải có số lượng bán >= 100 và bán ra trong ngày thứ 7 hoặc chủ nhật, hay nói cách khác, nếu số lượng bán >= 100 mà bán ra vào thứ Hai thì không được giảm, hoặc bán ra vào thứ 7, CN mà số lượng nhỏ hơn 100 cũng không được giảm, phải không?

Nhưng theo đề bài:

Vì có đến 2 chữ "mặt hàng", nên người đọc sẽ hiểu đây là 2 mệnh đề độc lập, và đương nhiên (kể cả tôi) cũng sẽ hiểu rằng: Cả hai loại "mặt hàng" đó, cái nào cũng được hưởng giảm giá 10%. Nói cách khác, tôi sẽ hiểu rằng: Mặt hàng có số lượng >=100 (bán ngày nào cũng được) và Mặt hàng được bán trong ngày thứ bảy hoặc chủ nhật (số lượng bao nhiêu cũng được) đều được giảm 10%. Và nếu như thế, thì công thức của bạn Kim.Nguyen mới đúng (bạn xem lại bài tôi phân tích ở trên về cái hay của công thức này khi Kim.Nguyen chỉ dùng 1 hàm WEEKDAY và không dùng tới IF).

---------------------------------
Góp ý chân tình đây:

Hình như đây không phải là lần đầu bạn có vấn đề với "chữ nghĩa" khi ghi các điều kiện. Tôi nhớ cách đây không lâu, bạn đã nói (cũng với Kim.Nguyen):

Với riêng tôi, về mặt khách quan mà nói, thì bạn sai, còn Kim.Nguyen đúng đấy. Bạn viết như thế nào, người ta sẽ hiểu như thế đó, không thể để đến khi người ta hiểu sai ý bạn, thì bạn mới lên tiếng, mà lại không đúng. Cụ thể cái bài toán mà bạn nói rằng bạn "muốn ngọng" đó, tôi có xem lại đề bài của bạn, chẳng có chỗ nào nói rằng "Bài này yêu cầu là chỉ được một trong hai thôi". Không tin, bạn xem lại thử nhé. Nếu bạn muốn rằng "chỉ được một trong hai", thì bạn phải ghi cụ thể ngay trong đề bài.

Mình xin ghi nhận lời nhận xét của bạn nhưng Bài tập này ý mình là như bạn hỏi ở trên đấy! Nhưng ở hai bài tập là hoàn toàn khác nhau. Ở bài tập này bạn nên nhớ là mình dùng chữ "và" là điều kiện đấy nhé!
Cám ơn lời nhận xét nhé!
Thân chào!