Công thức tính giá trị hàng tồn theo phương pháp FIFO

[mraleno]

Chào các anh em trong diễn đàn. Mặc dù em đã đọc các bài viết liên quan đến giá trị hàng tồn kho trong diễn đàn nhưng thực sự các bài viết này có cấu trúc công thức khá phức tạp. Em vẫn chưa hiểu được để áp dụng. Em gửi ví dụ của em lên đây mong anh em giúp em viết giùm công thức ở cột giá trị hàng tồn theo phương pháp FIFO. Hoặc code VBA hoặc hàm UDF đều ổn. Mong anh em ngó qua giúp đỡ giùm:

Ngày	Loại Hàng	Số lượng	Giá	Giá trị tồn kho	Giá mua Bình Quân
1/1/2023	But bi	100	10	1000​	10.0​
2/1/2023	But bi	200	11	3200​	10.7​
3/1/2023	But bi	-150	12	1650​	11.0​
4/1/2023	But bi	-100	13	550​	11.0​
5/1/2023	But bi	50	14	1250​	12.5​

 

[HieuCD]

Chào các anh em trong diễn đàn. Mặc dù em đã đọc các bài viết liên quan đến giá trị hàng tồn kho trong diễn đàn nhưng thực sự các bài viết này có cấu trúc công thức khá phức tạp. Em vẫn chưa hiểu được để áp dụng. Em gửi ví dụ của em lên đây mong anh em giúp em viết giùm công thức ở cột giá trị hàng tồn theo phương pháp FIFO. Hoặc code VBA hoặc hàm UDF đều ổn. Mong anh em ngó qua giúp đỡ giùm:

Ngày	Loại Hàng	Số lượng	Giá	Giá trị tồn kho	Giá mua Bình Quân
1/1/2023	But bi	100	10	1000​	10.0​
2/1/2023	But bi	200	11	3200​	10.7​
3/1/2023	But bi	-150	12	1650​	11.0​
4/1/2023	But bi	-100	13	550​	11.0​
5/1/2023	But bi	50	14	1250​	12.5​

Function GiaTriTon_FiFo(ByVal LoaiHang As Range, ByVal SoLuong As Range, ByVal DonGia As Range) As Variant
  Dim aSl(), TongXuat#, ton#, sRow&, i&, DK$
 
  sRow = LoaiHang.Rows.Count
  DK = LoaiHang(sRow, 1)
  If sRow = 1 Then aSl = SoLuong.Resize(1, 2).Value Else aSl = SoLuong.Value
  For i = 1 To sRow
    If LoaiHang(i, 1) = DK Then
      If aSl(i, 1) < 0 Then TongXuat = TongXuat - aSl(i, 1)
    End If
  Next i
  For i = 1 To sRow
    If LoaiHang(i, 1) = DK Then
      If aSl(i, 1) > 0 Then
        If aSl(i, 1) >= TongXuat Then
          aSl(i, 1) = aSl(i, 1) - TongXuat
          TongXuat = 0
          ton = ton + aSl(i, 1) * DonGia(i, 1)
        Else
          TongXuat = TongXuat - aSl(i, 1)
        End If
      End If
    End If
  Next i
  If TongXuat > 0 Then
    GiaTriTon_FiFo = "Ton Kho Am"
  Else
    GiaTriTon_FiFo = ton
  End If
End Function

Công thức ngoài sheet

E2 =GiaTriTon_FiFo($B$1:B2,$C$1:C2,$D$1:D2)

Copy xuống

 

[mraleno]

Chân thành cảm ơn anh @HieuCD . Anh thức khuya dữ vậy.

 

[HieuCD]

Chân thành cảm ơn anh @HieuCD . Anh thức khuya dữ vậy.

Lúc đó là trưa bên mình