Đếm hỗn hợp các ô thường và đã merge trong excel

[madoffvn]

Cụ thể trong file của mình:
gồm 3 cột, cộtA: số hộ, cột B: tên, cột C: giới tính
1 hộ có thể có nhiều hơn 1 người với các giới tính khác nhau
Câu hỏi là: - đếm xem có bao nhiêu hộ có người có giới tính nam, có bao nhiêu hộ có người giới tính nữ.
(Lưu ý; ko phải là có bao nhiêu nam, bao nhiêu nữ đâu)
cảm ơn mọi người đã quan tâm giúp đỡ

 

[Phan Thế Hiệp]

Cụ thể trong file của mình:
gồm 3 cột, cộtA: số hộ, cột B: tên, cột C: giới tính
1 hộ có thể có nhiều hơn 1 người với các giới tính khác nhau
Câu hỏi là: - đếm xem có bao nhiêu hộ có con trai, có bao nhiêu hộ có con gái.
(Lưu ý; ko phải là có bao nhiêu nam, bao nhiêu nữ đâu)
cảm ơn mọi người đã quan tâm giúp đỡ

Vậy theo dữ liệu bạn đưa, đối tượng "nam" nào trong file là "con trai"!? và đối tượng "nữ" nào trong file là "con gái"!?

Thân

 

[madoffvn]

Vậy theo dữ liệu bạn đưa, đối tượng "nam" nào trong file là "con trai"!? và đối tượng "nữ" nào trong file là "con gái"!?

Thân

Nam là con trai còn nữ là con gái đó bạn, cùng nghĩa mà bạn

 

[Phan Thế Hiệp]

Nam là con trai còn nữ là con gái đó bạn, cùng nghĩa mà bạn

Thử:

C14=COUNT(1/(FREQUENCY(IF($C$2:$C$12=A14,COUNTIF(OFFSET($A$2,,,ROW($1:$11)),">0")),ROW($1:$11))))
Hoặc
C14=COUNT(MATCH(ROW($1:$11),IF($C$2:$C$12=A14,COUNTIF(OFFSET($A$2,,,ROW($1:$11)),">0")),))

Kết thúc bằng Ctrl+Shift+Enter, rồi fill xuống 1 hàng.

Thân

 

[madoffvn]

Thử:

C14=COUNT(1/(FREQUENCY(IF($C$2:$C$12=A14,COUNTIF(OFFSET($A$2,,,ROW($1:$11)),">0")),ROW($1:$11))))

Kết thúc bằng Ctrl+Shift+Enter, rồi fill xuống 1 hàng.

Thân

thanks bạn nha. quá nhiều bài học trong 1 câu trả lời :3

 

[Phan Thế Hiệp]

Cảm ơn bạn nha. nhưng mà bạn giúp mình xíu nữa, giải thích hộ mình đoạn:
"C14=COUNT(1/(FREQUENCY..."
ý nghĩa của "1/" là gì bạn ?

Công thức:
=COUNT( 1/ FREQUENCY( IF($C$2:$C$12=A14, COUNTIF(OFFSET($A$2,,,ROW($1:$11)),">0")) ,ROW($1:$11)) )

1. IF($C$2:$C$12=A14, COUNTIF(OFFSET($A$2,,,ROW($1:$11)),">0") ): Nhằm tạo ra 'Mảng Số thứ tự của hộ thỏa điều kiện Nam/Nữ', trong đó:
   • COUNTIF(OFFSET($A$2,,,ROW($1:$11)),">0") điền đầy đủ "Số thự tự các hộ", thay vì dữ liệu Vùng A2: A12 đang bị 'merge cell', nên chỉ có các ô A2=1, A5=2, A7=3, A8=4, A9=5 và A11=6, các ô giữa đó không có giá trị. Nay, dùng hàm Countif(Offset()) này sẽ tạo một Mảng có "số thự tự của các hộ" liền lạc hơn, bạn có thể hình dung rằng nó thay thế giá trị tương ứng vùng A2: A12 như sau: {1;1;1;2;2;3;4;5;5;6;6}.
   • Lệnh IF(C2: C12=A14,....) với A14 chứa giá trị "nam", sẽ chỉ chọn Mảng vừa tìm từ Countif() trên nếu tương ứng dòng cột C có giá trị "nam". Nó sẽ trả về kết quả như bài bạn gửi: {1;1;FALSE;FALSE;2;FALSE;4;FALSE;5;FALSE;6} (Xem thêm cột D file đính kèm)
2. FREQUENCY( 'Mảng Số thứ tự của hộ thỏa điều kiện Nam/Nữ' ,ROW($1:$11)) ): Nhằm đếm (tương tự như hàm Countif()) các số thứ tự của các hộ hiện hữu thỏa mãn điều kiện Nam/Nữ.
3. COUNT( 1/ 'Mảng đếm hộ thỏa điều kiện' ): Sau cùng sẽ đếm những giá trị số, phớt lờ các giá trị báo lỗi có trong Mảng bởi phép tính: 1/ 'Mảng đếm hộ thỏa điều kiện'.

Xem thêm phần giải thích chi tiết các công thức có trong file.

Thân

 

[madoffvn]