Đếm có điều kiện không tính các dòng ẩn

[KhaNhu1999]

Dạ em chào anh chị, anh chị giúp em hàm đếm để biết trong cột A có bao nhiêu ô có chứa các giá trị ở cột E, nhưng không tính các dòng bị ẩn ạ, kết quả trả về ô C5



Em xin cảm ơn anh chị rất nhiều ạ!

 

[Nhattanktnn]

Dạ em chào anh chị, anh chị giúp em hàm đếm để biết trong cột A có bao nhiêu ô có chứa các giá trị ở cột E, nhưng không tính các dòng bị ẩn ạ, kết quả trả về ô C5

View attachment 282436

Em xin cảm ơn anh chị rất nhiều ạ!

Công thức tại C1:

=COUNT(INDEX(1/SUBTOTAL(103,OFFSET(A1,ROW(A1:A12)-1,,1))/(MATCH(A1:A12,A1:A12,0)=ROW(A1:A12)),))

Hoặc:

=SUMPRODUCT(SUBTOTAL(103,OFFSET(A1,ROW(A1:A12)-1,,1))*(MATCH(A1:A12,A1:A12,0)=ROW(A1:A12)))

 

[87kilua]

Không phải thế này thì nó là thế kia
dulieu = A1:A12

=SUMPRODUCT((dulieu=E1)*(SUBTOTAL(103,OFFSET(INDEX(dulieu,1),ROW(dulieu)-MIN(ROW(dulieu)),0))))

 

[KhaNhu1999]

Công thức tại C1:

=COUNT(INDEX(1/SUBTOTAL(103,OFFSET(A1,ROW(A1:A12)-1,,1))/(MATCH(A1:A12,A1:A12,0)=ROW(A1:A12)),))

Hoặc:

=SUMPRODUCT(SUBTOTAL(103,OFFSET(A1,ROW(A1:A12)-1,,1))*(MATCH(A1:A12,A1:A12,0)=ROW(A1:A12)))

Em cám ơn anh đã hỗ trợ ạ
Dạ có vẻ anh hiểu nhầm ý em rồi ạ, ý em là đếm những ký tự trong cột E (A, B, C) xuất hiện tất cả bao nhiêu lần trong cột A (không tính dòng ẩn)
Nghĩa là theo hình, nó chỉ đếm A, B, C mà không đếm D, E (và các giá trị bị ẩn dòng).
Kết quả tại ô C1 là 6 mới đúng ạ!

Bài đã được tự động gộp: 25/10/22

Không phải thế này thì nó là thế kia
dulieu = A1:A12

=SUMPRODUCT((dulieu=E1)*(SUBTOTAL(103,OFFSET(INDEX(dulieu,1),ROW(dulieu)-MIN(ROW(dulieu)),0))))

View attachment 282441

Anh cũng hiểu nhầm ý em rồi ạ



Ô màu đỏ là ô sẽ được đếm ạ.

 

[Phan Thế Hiệp]

Em cám ơn anh đã hỗ trợ ạ
Dạ có vẻ anh hiểu nhầm ý em rồi ạ, ý em là đếm những ký tự trong cột E (A, B, C) xuất hiện tất cả bao nhiêu lần trong cột A (không tính dòng ẩn)
Nghĩa là theo hình, nó chỉ đếm A, B, C mà không đếm D, E (và các giá trị bị ẩn dòng).
Kết quả tại ô C1 là 6 mới đúng ạ!

Bài đã được tự động gộp: 25/10/22

Anh cũng hiểu nhầm ý em rồi ạ

View attachment 282480

Ô màu đỏ là ô sẽ được đếm ạ.

Thử:

=COUNT(1/SUBTOTAL(103,OFFSET(A1,ROW(A1:A12)-1,))/COUNTIF($E$1:$E$3,$A$1:$A$12))

Kết thúc bằng Ctrl +Shift +Enter.

Thân

 

[87kilua]

Biến thiên đi một chút là được

=SUMPRODUCT(((dulieu=E1)+(dulieu=E2)+(dulieu=E3))*(SUBTOTAL(103,OFFSET(INDEX(dulieu,1),ROW(dulieu)-MIN(ROW(dulieu)),0))))

(dulieu=E1) tính cho A
(dulieu=E2) tính cho B
(dulieu=E3) tính cho C

 

[87kilua]

Em cám ơn anh đã hỗ trợ ạ
Dạ có vẻ anh hiểu nhầm ý em rồi ạ, ý em là đếm những ký tự trong cột E (A, B, C) xuất hiện tất cả bao nhiêu lần trong cột A (không tính dòng ẩn)
Nghĩa là theo hình, nó chỉ đếm A, B, C mà không đếm D, E (và các giá trị bị ẩn dòng).
Kết quả tại ô C1 là 6 mới đúng ạ!

Bài đã được tự động gộp: 25/10/22

Anh cũng hiểu nhầm ý em rồi ạ

View attachment 282480

Ô màu đỏ là ô sẽ được đếm ạ.

Đưa công thức lên tầm mới

 

[KhaNhu1999]

Thử:

=COUNT(1/SUBTOTAL(103,OFFSET(A1,ROW(A1:A12)-1,))/COUNTIF($E$1:$E$3,$A$1:$A$12))

Kết thúc bằng Ctrl +Shift +Enter.

Thân

Dạ em đã áp dụng công thức này vào thành công rồi ạ. Em chân thành cảm ơn ạ!