Hỏi nhanh - đáp nhanh về công thức (phần 1) (2 người xem)

dat_butmuc · 3/5/10

tqt đã viết:
Tôi dùng hàm SUMIF để thực hiện việc tính tổng cho bảng số liệu (Công thức đặt tại cột G231) nhưng không biết đã sai ở đâu nên không ra được kết quả. Mong mọi người giúp đỡ.

Đổi: =SUMIF($B$8:$H$229,$J$8,$G$8:$G$229) chữ màu đỏ

Thành: =SUMIF($H$8:$H$229,$J$8,$G$8:$G$229)

hienminh09 · 4/5/10

e đang cần đếm tổng các ô chẵn có bao nhiêu ô có chữ mình chỉ đinh
vú dụ: đếm tổng các ô 2 4 6 8 10 có bao nhiêu chữ H chẳng hạn
e biêt công thức tinh chẵn la
= SUM(IF(MOD(ROW(Range), 2) = 0, Range, 0))
và công thức đếm tổng các chữ
=COUNTIF(Range,criteria)
nhưgn không biết thay thế nào để đếm tổng các chữ H trong nhưng ô chăn đó, nhờ các bác trợ dúp e cái. thank nhìu

Ba Tê · 4/5/10

hienminh09 đã viết:
e đang cần đếm tổng các ô chẵn có bao nhiêu ô có chữ mình chỉ đinh
vú dụ: đếm tổng các ô 2 4 6 8 10 có bao nhiêu chữ H chẳng hạn
e biêt công thức tinh chẵn la
= SUM(IF(MOD(ROW(Range), 2) = 0, Range, 0))
và công thức đếm tổng các chữ
=COUNTIF(Range,criteria)
nhưgn không biết thay thế nào để đếm tổng các chữ H trong nhưng ô chăn đó, nhờ các bác trợ dúp e cái. thank nhìu

Đưa file dữ liệu mẫu lên đi, trong mỗi ô dữ liệu như thế nào, có khi nào một ô mà có 2 hoặc 3,4... chữ H không? nói suông khó hiểu lắm.

sealand · 4/5/10

Bạn dùng công thức này cũng đươc (Cần đếm ô B10 có bao nhiêu chữ a)

=LEN(B10)-LEN(SUBSTITUTE(B10,"a",""))

Đếm số ô có chữ chỉ định dùng công thức mảng sau(Đếm số ô có chữ "w" trong vùng C2:F3)

=SUM(IF(ISERROR(FIND("w",C2:F3)),0,1))

Công thức mảng nên nhập xong nhấn Ctrl+Shift+Enter

sealand · 4/5/10

Bạn có thể dùng hàm UDF (Vì nội dung câu hỏi có liên quan đến Code) như sau:

Mã:

Option Explicit
Function dem(Rg As range, Kt As String) As Integer
Dim i
For i = IIf(Rg.Cells(1, 1).Row Mod 2 = 0, 1, 2) To Rg.Rows.Count Step 2
If InStr(1, Rg.Cells(i, 1), Kt) > 0 Then dem = dem + 1
Next
End Function

Đếm số ô chẵn có ký tự a trong vùng A1:A100
Ta viết: =dem(A1:A100,"a")

hienminh09 · 4/5/10

mình gửi file các bạn kiểm tra giúp mình,

dat_butmuc · 4/5/10

hienminh09 đã viết:
mình gửi file các bạn kiểm tra giúp mình,

Tại K3, dùng công thức này:

PHP:

=SUM((MOD(COLUMN(A3:J3),2)=0)*(NOT(ISERR(FIND("a",A3:J3)))))

Kết thúc công thức với Ctrl+Shift+Enter

Hoặc:

PHP:

=SUMPRODUCT((MOD(COLUMN(A3:J3),2)=0)*(NOT(ISERR(FIND("a",A3:J3)))))

sealand · 4/5/10

Bạn kiểm tra xem được không

chucuoi92 · 4/5/10

hienminh09 đã viết:
mình gửi file các bạn kiểm tra giúp mình,

Thêm công thức này nữa cho bạn tham khảo
{=SUM((A3:J3="a")*ISEVEN(COLUMN(A3:J3)))} Công thức mảng kết thúc bằng Ctrl+Shift+Enter

dat_butmuc · 4/5/10

Chu.cuoi92 đã viết:
Thêm công thức này nữa cho bạn tham khảo
{=SUM((A3:J3="a")*ISEVEN(COLUMN(A3:J3)))} Công thức mảng kết thúc bằng Ctrl+Shift+Enter

Dear Chu.cuoi92, công thức rất hay !
Ý kiến chút: Cái này chỉ thực hiện đúng đối với các trường hợp trong Cell chỉ riêng có mỗi chữ a, giả sử có abc trong cell đó thì "tèo" (lúc đó có thế sửa: IF(ISERROR(FIND("a",A4:J4)),0,1)) như sealand hoặc thêm NOT(ISERR(FIND("a",A4:J4)))
Không biết trong Cell của tác giả 1 chữ a hay là có các ký tự khác...

chucuoi92 · 4/5/10

cứ "giả sử" thì không được đâu!
Phải hỏi lại tác giả đã
Nếu như tác giả chỉ phân biệt giữa số Number và TEXT thì sao? khi đó CT của bạn cũng "Tèo"
Khi đó lại phải sửa thế này:{=SUM(ISTEXT(A3:J3)*ISEVEN(COLUMN(A3:J3)))}

dat_butmuc · 4/5/10

Chu.cuoi92 đã viết:
cứ "giả sử" thì không được đâu!
Phải hỏi lại tác giả đã

Cái này thì đồng ý

Nếu như tác giả chỉ phân biệt giữa số Number và TEXT thì sao? khi đó CT của bạn cũng "Tèo"

Cái này thì không đồng ý
- Chữ a thì không thể là number được (trừ trường hợp nó chuyển code)
- Với lại công thức của tôi là "phủ định" của "cái không có" nên không sao cả...

hienminh09 · 4/5/10

Chu.cuoi92 đã viết:
Thêm công thức này nữa cho bạn tham khảo
{=SUM((A3:J3="a")*ISEVEN(COLUMN(A3:J3)))} Công thức mảng kết thúc bằng Ctrl+Shift+Enter

công thức của bác này nhìn có vẻ đơn gian nhưng em thử nhập thử nó báo lỗi #name?, không biết sai ở chỗ nào hay thiếu gì đấy.
Thực ra bảng của em là bảng chấm công nên em cần tính tổng nhưng ô có chữ "VL" còn chữ khác không quan tâm.
files bác "sealand" là ổn kết quả ra đúng rồi

chucuoi92 · 4/5/10

hienminh09 đã viết:
công thức của bác này nhìn có vẻ đơn gian nhưng em thử nhập thử nó báo lỗi #name?, không biết sai ở chỗ nào hay thiếu gì đấy.
Thực ra bảng của em là bảng chấm công nên em cần tính tổng nhưng ô có chữ "VL" còn chữ khác không quan tâm.
files bác "sealand" là ổn kết quả ra đúng rồi

Nó là công thức mảng khi kết thúc phải gõ tổ hợp phím Ctrl+Shift+Enter (xem file đính kèm)

toat_butmuc
Bạn nói cT của bạn không sao. Vậy thử gõ chữ "B" thay cho chữ "a" xem có đếm được không.

hienminh09 · 4/5/10

Chu.cuoi92 đã viết:
Nó là công thức mảng khi kết thúc phải gõ tổ hợp phím Ctrl+Shift+Enter (xem file đính kèm)

toat_butmuc
Bạn nói cT của bạn không sao. Vậy thử gõ chữ "B" thay cho chữ "a" xem có đếm được không.

bảng tính của mình thì coi như song rui nhưng cũng muốn tìm hiểu cho nắm rõ hàm thêm,
mình down bản của bạn về, híc nhấn vào để xem hàm thế nào sau đó nhân ctrl + shift + enter lại hiện lỗi #name?, chắc là offce của mình lỗi nên

chucuoi92 · 4/5/10

hienminh09 đã viết:
bảng tính của mình thì coi như song rui nhưng cũng muốn tìm hiểu cho nắm rõ hàm thêm,
mình down bản của bạn về, híc nhấn vào để xem hàm thế nào sau đó nhân ctrl + shift + enter lại hiện lỗi #name?, chắc là offce của mình lỗi nên

Không phải office của bạn bị lỗi mà do bạn thao tác không đúng thôi.
Bây giờ bạn chọn vào ô có công thức rồi nhấn phím F2 sau đó đồng thời nhấn giữ 3 phím nói trên xem!
(Nhớ nhấn rồi thì buông tay ra nhé! đừng có giữ mãi đến tối thì "toi")

Lê Duy Thương · 4/5/10

dat_butmuc đã viết:
Dear Chu.cuoi92, công thức rất hay !
Ý kiến chút: Cái này chỉ thực hiện đúng đối với các trường hợp trong Cell chỉ riêng có mỗi chữ a, giả sử có abc trong cell đó thì "tèo" (lúc đó có thế sửa: IF(ISERROR(FIND("a",A4:J4)),0,1)) như sealand hoặc thêm NOT(ISERR(FIND("a",A4:J4)))
Không biết trong Cell của tác giả 1 chữ a hay là có các ký tự khác...

Theo tôi công thức của bác SeaLand là tạm được nhưng tôi xin bổ sung thêm tý
=SUM(IF(ISERROR(FIND("a",LOWER(A3:J3))),0,1)*IF(MOD(COLUMN(A3:J3),2),0,1))
để phòng người dùng gõ chữ hoa vào dữ liệu

dat_butmuc · 4/5/10

Le duy Thuong đã viết:
Theo tôi công thức của bác SeaLand là tạm được nhưng tôi xin bổ sung thêm tý
=SUM(IF(ISERROR(FIND("a",LOWER(A3:J3))),0,1)*IF(MOD(COLUMN(A3:J3),2),0,1))
để phòng người dùng gõ chữ hoa vào dữ liệu

Nếu như muốn phân biệt chữ hoa hay chữ thường như công thức của Thương thì không cần Lower mà đổi hàm Find thành Search thôi:

PHP:

=SUM(IF(ISERROR(SEARCH("a",A3:J3)),0,1)*IF(MOD(COLUMN(A3:J3),2),0,1))

Hoặc:

PHP:

=SUM((MOD(COLUMN(A3:J3),2)=0)*(NOT(ISERR(SEARCH("a",A3:J3)))))

lammtv · 4/5/10

cho em hỏi có hàm nào bỏ các ký tự bên phải trong 1 chuỗi ko?ví dụ em có các số sau
5m
50m
500m
1000m
bây giờ em muốn bỏ chữ "m" đi thì làm sao?chỉ để số thôi!dùng hàm chứ ko phải dùng công cụ FIND nhé!

dat_butmuc · 4/5/10

lammtv đã viết:
cho em hỏi có hàm nào bỏ các ký tự bên phải trong 1 chuỗi ko?ví dụ em có các số sau
5m
50m
500m
1000m
bây giờ em muốn bỏ chữ "m" đi thì làm sao?chỉ để số thôi!dùng hàm chứ ko phải dùng công cụ FIND nhé!

Cho dữ liệu trên tại cột A (bắt đầu từ A1), dùng công thức tại B1:
=LEFT(A1,SEARCH("m",A1)-1) rồi fill xuống.

Hai Lúa Miền Tây · 4/5/10

lammtv đã viết:
cho em hỏi có hàm nào bỏ các ký tự bên phải trong 1 chuỗi ko?ví dụ em có các số sau
5m
50m
500m
1000m
bây giờ em muốn bỏ chữ "m" đi thì làm sao?chỉ để số thôi!dùng hàm chứ ko phải dùng công cụ FIND nhé!

có thể dùng hàm SUBSTITUTE
=SUBSTITUTE(Chuoicuaban,"m","")

Lê Duy Thương · 4/5/10

domfootwear đã viết:
có thể dùng hàm SUBSTITUTE
=SUBSTITUTE(Chuoicuaban,"m","")

=--SUBSTITUTE(SUBSTITUTE(Chuoicuaban,"m",""),"M","")
cho em bổ sung thêm tý nha bác domfootwear
cái này em học của bác NDU và anh DAT_butmuc

hon7643 · 8/5/10

Bài tóan chia chẵn.

Mình muốn làm bài tóan chia chẵn giữa (1 số bị chia) và (1 dãy số chia).
Mình chỉ làm được việc công trừ nhân chia - đã có kết quả, nhưng cùi bắp và lượm thượm quá, nhờ các bạn giúp giùm để cho nó khoa học hơn, xin cảm ơn.

thanh_tks · 8/5/10

hon7643 đã viết:
Bài tóan chia chẵn.

Mình muốn làm bài tóan chia chẵn giữa (1 số bị chia) và (1 dãy số chia).
Mình chỉ làm được việc công trừ nhân chia - đã có kết quả, nhưng cùi bắp và lượm thượm quá, nhờ các bạn giúp giùm để cho nó khoa học hơn, xin cảm ơn.

Không hiểu cách chia của bạn ra sao, nhưng muốn thay công thức để ra kết quả như của bạn thì bạn chép Công thức này vào C3 =IF(C$13=0,0,ROUNDDOWN(($A3-SUMPRODUCT($B$2:B$2,$B3:B3))/C$2,0))
rồi fill cho tất cả bảng của bạn.

hon7643 · 9/5/10

thanh_tks đã viết:
Không hiểu cách chia của bạn ra sao, nhưng muốn thay công thức để ra kết quả như của bạn thì bạn chép Công thức này vào C3 =IF(C$13=0,0,ROUNDDOWN(($A3-SUMPRODUCT($B$2:B$2,$B3:B3))/C$2,0))
rồi fill cho tất cả bảng của bạn.

Cảm ơn bạn thanh_tks
Thật là tài tình, bạn không hiểu mình chia ra sao nhưng khi bạn chia thì tuyệt vời, mình không biết về hàm SUMPRODUCT, bạn vui lòng giải thích cho mình hiểu thêm với.

khoavu87 · 9/5/10

hon7643 đã viết:
Cảm ơn bạn thanh_tks
Thật là tài tình, bạn không hiểu mình chia ra sao nhưng khi bạn chia thì tuyệt vời, mình không biết về hàm SUMPRODUCT, bạn vui lòng giải thích cho mình hiểu thêm với.

View attachment 45643
bạn xem cái ảnh đó rùi làm theo.

dctrkmhp · 9/5/10

bạn nào giải giúp mình bài tập excel này với http://www.mediafire.com/download.php?uyzgeoizzyi
thank các bạn nhé

hon7643 · 9/5/10

khoavu87 đã viết:
View attachment 45643
bạn xem cái ảnh đó rùi làm theo.

Mình hiểu là bạn khoavu87 muốn gợi ý search sumproduct để đọc bài, nhưng thú thiệt mình tiếp thu kém quá.
Bạn có thể giải thích giùm mình ý nghĩa của sumproduct($B$2:B$2,$B3:B3), giống như là 1 bài tập nhỏ, để mình hiểu thấu đáo giúp mình đọc tiếp các phần khác mà không bị rối.

hon7643 · 9/5/10

ý nghĩa của sumproduct($B$2:B$2,$B3:B3), các bạn giải thích giúp mình với

Ba Tê · 9/5/10

hon7643 đã viết:
Mình hiểu là bạn khoavu87 muốn gợi ý search sumproduct để đọc bài, nhưng thú thiệt mình tiếp thu kém quá.
Bạn có thể giải thích giùm mình ý nghĩa của sumproduct($B$2:B$2,$B3:B3)), giống như là 1 bài tập nhỏ, để mình hiểu thấu đáo giúp mình đọc tiếp các phần khác mà không bị rối

| A
| B
| C
| D
| E
|
1
| 1
| 7
|| A1*B1=
| 7
|
2
|

2

|

8

| |

A2*B2=

|

16

|
3
|

3

|

9

| |

A3*B3=

|

27

|
4
|

4

|

10

| |

A4*B4=

|

40

|

SUMPRODUCT((A1:A4)*(B1:B4))=90
SUM(E1:E4) =90

| A

| B

| C

| D

| E

|
1

| A

| 7

|

| Nếu A1="A" thì E1=B1

| 7

|
2

|B|

8

| |

Nếu A2="A" thì E2=B2

|

0

|
3

|A|

9

| |

tương tự như trên

|

9

|
4

|B|

10

| |

tương tự như trên

|

0

|

SUMPRODUCT((A1:A4="A")*(B1:B4)) =16
SUM(E1:E4) =16
Xem bảng trên và kết quả bên dưới rồi Bạn tự suy ngẫm xem sao

hon7643 · 9/5/10

Cảm ơn Ba tê. mình đang nghiệm
Bạn sửa giúp mình công thức cùi bắp này với:
IF(AND($E$3=$E$4,$F$3=$F$4,$G$3=$G$4,$H$3=$H$4,$I$3=$I$4,$J$3=$J$4,$K$3=$K$4,$M$3=$M$4),0,1)
Mình muốn nếu các giá trị (từ E3 đến M3) mà = (từ E4 đến M4), thì ... nhưng không biết dùng công thức nào thay cho một mớ cái = kia

Ba Tê · 9/5/10

hon7643 đã viết:
Cảm ơn Ba tê. mình đang nghiệm
Bạn sửa giúp mình công thức cùi bắp này với:
IF(AND($E$3=$E$4,$F$3=$F$4,$G$3=$G$4,$H$3=$H$4,$I$3=$I$4,$J$3=$J$4,$K$3=$K$4,$M$3=$M$4),0,1)
Mình muốn nếu các giá trị (từ E3 đến M3) mà = (từ E4 đến M4), thì ... nhưng không biết dùng công thức nào thay cho một mớ cái = kia

=IF(E3:M3=E4:M4;0;1)

Vì là công thức mảng nên khi nhập xong phải ấn Ctrl+Shift+Enter

hon7643 · 9/5/10

Ba Tê đã viết:
Vì là công thức mảng nên khi nhập xong phải ấn Ctrl+Shift+Enter

Mình đang nghiệm, công thức chi đúng khi E3<>E4, còn các cặp ô khác (không bằng nhau) thì kết quả không đúng
Nếu trong dãy E3:M3 và E4:M4 vừa có dữ liệu số vừa có dữ liệu chữ thì sao, bác Ba Tê ơi!

Ba Tê · 9/5/10

hon7643 đã viết:
Mình đang nghiệm, công thức chi đúng khi E3<>E4, còn các cặp ô khác (không bằng nhau) thì kết quả không đúng
Nếu trong dãy E3:M3 và E4:M4 vừa có dữ liệu số vừa có dữ liệu chữ thì sao, bác Ba Tê ơi!

Rất xin lỗi vì không kiểm tra hết các trường hợp, sẽ tìm cách khác vậy.
Xem thử file đính kèm.

thanh_tks · 9/5/10

Ba Tê đã viết:
Vì là công thức mảng nên khi nhập xong phải ấn Ctrl+Shift+Enter

=IF(E3:M3=E4:M4;0;1)

Ba Tê ơi! cái hàm if mảng này chỉ cần thêm Max nữa là đạt yêu cầu thôi!

PHP:

{=MAX(IF(E3:M3=E4:M4;0;1))}

hon7643 · 9/5/10

Ba Tê đã viết:
Xem thử file đính kèm.

ok rồi Ba Tê ơi, bài tập đã được giải, mình học thêm 1 name của bác.
Nhưng có lẻ do ít thời gian quá nên bác phải xuất chiêu dùng name, nếu có giải pháp khác - chỉ dùng công thức, thì bác bày cho anh em với nhé

Ba Tê · 9/5/10

hon7643 đã viết:
ok rồi Ba Tê ơi, bài tập đã được giải, mình học thêm 1 name của bác.
Nhưng có lẻ do ít thời gian quá nên bác phải xuất chiêu dùng name, nếu có giải pháp khác - chỉ dùng công thức, thì bác bày cho anh em với nhé

Bạn thanh_tks đã có công thức ở bài trên đấy rồi!
Đúng là rối thật, phát hiện sai rồi không dám nghỉ đến nó nữa, tìm cách khác hóa ra lu bu...

Dark Ghost · 10/5/10

Giải Nhanh Bài EXcel!

View attachment 45721

Hoàn thành cột đơn giá!
Mình làm như vầy: =VLOOKUP(C6,$B$21:$E$25,IF(E6="x",2,3),0)
Mà kết quả sai, nó chỉ lấy giá trị của cột nhập chứ ko lấy kqua của cột xuất
Ko hiểu tại sao sai, xin giúp đỡ

VHA · 10/5/10

Dark Ghost đã viết:
View attachment 45721

Hoàn thành cột đơn giá!
Mình làm như vầy: =VLOOKUP(C6,$B$21:$E$25,IF(E6="x",2,3),0)
Mà kết quả sai, nó chỉ lấy giá trị của cột nhập chứ ko lấy kqua của cột xuất
Ko hiểu tại sao sai, xin giúp đỡ

Bạn phải nhập là =VLOOKUP(C6,$B$21:$E$25,IF(E6="x",3,4),0) chứ, vì trong bảng hàng hóa bên dưới thì cột tên hàng là cột B&C gộp lại, giá nhập là cột thứ 3, giá xuất là cột thứ 4 tính từ cột tên hàng. Tuy nhiên với công thức này, khi cả cột nhập và xuất đều ko có đánh dấu x thì đơn giá vẫn lấy giá xuất.

BNTT · 10/5/10

Dark Ghost đã viết:
View attachment 45721

Hoàn thành cột đơn giá!
Mình làm như vầy: =VLOOKUP(C6,$B$21:$E$25,IF(E6="x",2,3),0)
Mà kết quả sai, nó chỉ lấy giá trị của cột nhập chứ ko lấy kqua của cột xuất
Ko hiểu tại sao sai, xin giúp đỡ

Bạn có chắc là nó lấy giá trị của cột nhập không? Bạn thử dò lại thử xem cái kết quả của hàm VLOOKUP này và cái bạn dò thực tế bằng mắt, nó có bằng nhau không?

Dark Ghost · 10/5/10

VHA đã viết:
Bạn phải nhập là =VLOOKUP(C6,$B$21:$E$25,IF(E6="x",3,4),0) chứ, vì trong bảng hàng hóa bên dưới thì cột tên hàng là cột B&C gộp lại, giá nhập là cột thứ 3, giá xuất là cột thứ 4 tính từ cột tên hàng. Tuy nhiên với công thức này, khi cả cột nhập và xuất đều ko có đánh dấu x thì đơn giá vẫn lấy giá xuất.

Cám ơn bạn, thế mà mình ko nghĩ ra. Đúng rồi, may là đề cho ko nhập thì xuất, ko xuất xuất thì nhập. Vậy lỡ nếu trường hợp vừa có nhập và xuất, vừa ko nhập, ko xuất thì bạn có cách giải nào khác không?

BNTT · 10/5/10

Dark Ghost đã viết:
Cám ơn bạn, thế mà mình ko nghĩ ra. Đúng rồi, may là đề cho ko nhập thì xuất, ko xuất xuất thì nhập. Vậy lỡ nếu trường hợp vừa có nhập và xuất, vừa ko nhập, ko xuất thì bạn có cách giải nào khác không?

Nếu "vừa có nhập và xuất, vừa ko nhập, ko xuất", chỉ có mỗi cách là có 2 cột đơn giá, đơn giá nhập, và đơn giá xuất, chứ không nhập chung vào một chỗ như thế được, vì nhỡ như vừa nhập vừa xuất, thì sẽ điền giá của chuyện nào? điền giá nhập hay điền giá xuất?

Dark Ghost · 10/5/10

Ừm, cám ơn Bạn, Tiện đây cho mình hỏi thêm là:
Cột Khuyến mãi: Nếu hàng xuất trong khoảng từ ngày 10 đến 20 của tháng 1 thì ghi là "Có khuyến mãi", ngược lại để trống.

Mình làm: =IF(AND(F6="x",10<=DAY(D6)<=20),"CO KHUYEN MAI"," ")
Nếu đúng thì 2 cái kmai, Nhưng làm chẳng có cái nào khuyến mãi cả, Mình đoán là sai chỗ điều kiện ngày?

VHA · 10/5/10

Dark Ghost đã viết:
Ừm, cám ơn Bạn, Tiện đây cho mình hỏi thêm là:
Cột Khuyến mãi: Nếu hàng xuất trong khoảng từ ngày 10 đến 20 của tháng 1 thì ghi là "Có khuyến mãi", ngược lại để trống.

Mình làm: =IF(AND(F6="x",10<=DAY(D6)<=20),"CO KHUYEN MAI"," ")
Nếu đúng thì 2 cái kmai, Nhưng làm chẳng có cái nào khuyến mãi cả, Mình đoán là sai chỗ điều kiện ngày?

Cái vụ 10<=DAY(D6)<=20 là có vấn đề đó nha.
10<=DAY(D6)<=20 phải viết thành AND(DAY(D6)>=10,DAY(D6)<=20))

Dark Ghost · 11/5/10

View attachment 45758
Các bác giúp giải câu này với?
Tính tiền phòng= Số ngày ở * giá phòng
Mình làm theo công thức VLOOKUP + IF thì ra, nhưng làm theo INDEX + match thì bị lỗi, sửa giúp mình:
=INDEX($A$16:$E$20,MATCH(LEFT(C4,2),$A$18:$B$20,0),MATCH(MID(C4,3,1),$C$16:$E$17,0))
Tiện thể, cho mình hỏi thêm: Bảng thống kê tiền phòng thì nên xài sumif hay dsum thì cách nào nhanh và gọn nhất, cho mình xin cthuc luôn nhé!
Xin Cảm ơn!

BNTT · 11/5/10

Dark Ghost đã viết:
View attachment 45758
Các bác giúp giải câu này với?
Tính tiền phòng= Số ngày ở * giá phòng
Mình làm theo công thức VLOOKUP + IF thì ra, nhưng làm theo INDEX + match thì bị lỗi, sửa giúp mình:
=INDEX($A$16:$E$20,MATCH(LEFT(C4,2),$A$18:$B$20,0),MATCH(MID(C4,3,1),$C$16:$E$17,0))
Tiện thể, cho mình hỏi thêm: Bảng thống kê tiền phòng thì nên xài sumif hay dsum thì cách nào nhanh và gọn nhất, cho mình xin cthuc luôn nhé!
Xin Cảm ơn!

Thay vì gửi hình, bạn gửi dùm cái file lên được không? Sửa công thức mà cứ Alt+Tab nhảy qua nhảy lại.. cực quá hà.

Dark Ghost · 11/5/10

Xin lỗi, mình ko biết, cứ tưởng up hình thay vì up file cho bạn đỡ mất công down.
Đây file đây!

Ba Tê · 11/5/10

Dark Ghost đã viết:
Xin lỗi, mình ko biết, cứ tưởng up hình thay vì up file cho bạn đỡ mất công down.
Đây file đây!

Tiền phòng:

G4=VLOOKUP(LEFT(C4;2);$A$18:$E$20;MATCH(MID(C4;3;1);$C$16:$E$16;0)+2;0)*F4

Thống kê tiền phòng:

=SUMPRODUCT((LEFT($C$4:$C$13;2)=$G21)*(MID($C$4:$C$13;3;1)=H$20);($G$4:$G$13))

Kéo copy sang các ô khác

phamtrieuduy · 11/5/10

Giúp mình cách kết hợp hàm if và hàm and !!!!!

CỘT THƯỞNG A: thưởng 200000 cho những nhân viên NỮ, còn lại không được thưởng.
CỘT THƯỞNG B: thưởng 100000 cho nhân viên NAM có ngày công >24, còn lại không được thưởng.
CỘT THƯỞNG C: thưởng 300000 cho nhân viên có ngày công >=25 hoặc nhân viên NỮ có ngày công =25.

BNTT · 11/5/10

Dễ quá mà bạn, cứ đọc sao thì viết ra vậy thôi:

phamtrieuduy đã viết:
CỘT THƯỞNG A: thưởng 200000 cho những nhân viên NỮ, còn lại không được thưởng.

=IF(D3="NỮ", 200000, 0)
CỘT THƯỞNG B: thưởng 100000 cho nhân viên NAM có ngày công >24, còn lại không được thưởng.

=IF(AND(D3="NAM",E3>24), 100000, 0)
CỘT THƯỞNG C: thưởng 300000 cho nhân viên có ngày công >=25 hoặc nhân viên NỮ có ngày công =25.

=IF(OR(E3>=25, AND(D3="NỮ",E3=25)), 300000, 0)

Ba Tê · 11/5/10

phamtrieuduy đã viết:
CỘT THƯỞNG A: thưởng 200000 cho những nhân viên NỮ, còn lại không được thưởng.
CỘT THƯỞNG B: thưởng 100000 cho nhân viên NAM có ngày công >24, còn lại không được thưởng.
CỘT THƯỞNG C: thưởng 300000 cho nhân viên có ngày công >=25 hoặc nhân viên NỮ có ngày công =25.

Đề bài ngộ ghê: CỘT THƯỞNG C Nữ có ngày công Lớn hơn 25 không được thưởng?! Làm đúng 25 ngày thì nghỉ, ngu sao làm thêm!

dat_butmuc · 12/5/10

Dark Ghost đã viết:
Xin lỗi, mình ko biết, cứ tưởng up hình thay vì up file cho bạn đỡ mất công down.
Đây file đây!

Bắt đầu từ dòng 4
- Tiền phòng:

PHP:

=F4*HLOOKUP(MID(C4,3,1),$C$16:$E$20,MID(C4,2,1)+2,0)

- Tiền ăn:

PHP:

=F4*HLOOKUP(RIGHT(C4,2),$H$16:$J$17,2,0)

- Tiền phục vụ:

PHP:

=IF(B4="Việt Nam",0,F4*2)

- Thống kê tiền phòng (tại ô H21):

PHP:

=SUMIF($C$4:$C$13,$G21&H$20&"*",$J$4:$J$13)

Lê Duy Thương · 12/5/10

Ba Tê đã viết:
Tiền phòng:

Thống kê tiền phòng:
Kéo copy sang các ô khác

như thế này thi không cần công thêm 2 đâu bác BATE ơi
=VLOOKUP(LEFT(C4,2),$A$18:$E$20,MATCH(MID(C4,3,1 ),$A$16:$E$16,0),0)*F4

toanlonely1990 · 12/5/10

Các bạn giúp mình sửa lỗi công thức excel này với

Chào tất cả các bạn
Mình đang làm 1 file excel nhưng làm hoài vẫn ko ra
Đạ khái phần mình ko làm ra đó là, khi mình gõ số HĐ, thì nó sẽ lấy các dữ liệu từ một bảng khác để nhập qua cái form. Trường hợp, 1 HĐ bán nhiều sp thì phải dc thể hiện đầy đủ...
Các bạn xem file đính kèm và giúp mình nha
Mình xin cảm ơn

Dark Ghost · 12/5/10

Le duy Thuong đã viết:
như thế này thi không cần công thêm 2 đâu bác BATE ơi
=VLOOKUP(LEFT(C4,2),$A$18:$E$20,MATCH(MID(C4,3,1 ),$A$16:$E$16,0),0)*F4

Công thức của Bác hay thật, nhưng mà mình hok hiểu chô màu đỏ, sao lại lấy A16->E16. Vì ô 16 và 17 gộp lại thành 1 ô rồi mà, khi kéo thì nó lấy cả 2 rồi?

MinhCong · 13/5/10

toanlonely1990 đã viết:
Chào tất cả các bạn
Mình đang làm 1 file excel nhưng làm hoài vẫn ko ra
Đạ khái phần mình ko làm ra đó là, khi mình gõ số HĐ, thì nó sẽ lấy các dữ liệu từ một bảng khác để nhập qua cái form. Trường hợp, 1 HĐ bán nhiều sp thì phải dc thể hiện đầy đủ...
Các bạn xem file đính kèm và giúp mình nha
Mình xin cảm ơn

Bạn đưa dữ liệu vào file và nên ghi cụ thể trong file như thế nào đi, không biết cái form mà Bạn muón nói là ở sheet nào? Hãy ghi càng cụ thể thì sẽ càng sớm nhận được kết quả.

Lê Duy Thương · 13/5/10

dark ghost đã viết:
công thức của bác hay thật, nhưng mà mình hok hiểu chô màu đỏ, sao lại lấy a16->e16. Vì ô 16 và 17 gộp lại thành 1 ô rồi mà, khi kéo thì nó lấy cả 2 rồi?

Trong trường hợp trộn thành 1 ô thì excel vẫn lấy giá trị ô nhỏ hơn

nmhung49 · 14/5/10

format % thành kiểu số

Em có một file, file này em được từ một người khác em không biết kiểu số được đinh dạng % như thế nào mà em đã dùng công thức value() công thức text() chuyển đổi thành số để nhân với số khác mà vẫn bị lỗi value. Mong các anh chị trên diễn đàn giúp đỡ chuyển thành số để nhân không bị lỗi value Thanks

trungkienchat · 14/5/10

Hỏi đáp về hàm tham chiếu

Chào tất cả mọi người.

Mình có 1 file excel trong đó ở sheet Use và sheet Payment mình đã comment những vướng mắc của mình rồi. Rất mong mọi người xem và giúp mình với.

Hai Lúa Miền Tây · 14/5/10

nmhung49 đã viết:
Em có một file, file này em được từ một người khác em không biết kiểu số được đinh dạng % như thế nào mà em đã dùng công thức value() công thức text() chuyển đổi thành số để nhân với số khác mà vẫn bị lỗi value. Mong các anh chị trên diễn đàn giúp đỡ chuyển thành số để nhân không bị lỗi value Thanks

Do gõ số không đúng dịnh dạng dấu chấm(.) và dấu phẩy(,)
Nếu định dạng máy của bạn là #,###.## thì dùng hàm sau:

B1=--SUBSTITUTE(A1,",",".") --> Kéo xuống là được

dat_butmuc · 14/5/10

trungkienchat đã viết:
Chào tất cả mọi người.

Mình có 1 file excel trong đó ở sheet Use và sheet Payment mình đã comment những vướng mắc của mình rồi. Rất mong mọi người xem và giúp mình với.

Bạn dùng công thức này:

PHP:

=SUM(OFFSET($C$10,,MATCH(D6,$C$9:$N$9,0)-1,5,))

P/s: Lưu ý ngày tháng năm trong Name "months" của bạn so với các dòng tham chiếu về ngày tháng năm!

Lê Duy Thương · 14/5/10

nmhung49 đã viết:
em có một file, file này em được từ một người khác em không biết kiểu số được đinh dạng % như thế nào mà em đã dùng công thức value() công thức text() chuyển đổi thành số để nhân với số khác mà vẫn bị lỗi value. Mong các anh chị trên diễn đàn giúp đỡ chuyển thành số để nhân không bị lỗi value thanks

bạn làm như thế này thử xem
=a1*100

dat_butmuc · 14/5/10

Le duy Thuong đã viết:
bạn làm như thế này thử xem
=a1*100

Cái a1*100 của Thương "to thế" nhưng mà không được, Thương ạ. Thử fill xuống xem?
Nên làm theo cách của bác Dom

Lê Duy Thương · 14/5/10

dat_butmuc đã viết:
cái a1*100 của thương "to thế" nhưng mà không được, thương ạ. Thử fill xuống xem?
Nên làm theo cách của bác dom

em hiểu là tác giả muốn chuyển thành số tự nhiên nên nhân cho 100 đẠi ca à

Hai Lúa Miền Tây · 15/5/10

Le duy Thuong đã viết:
em hiểu là tác giả muốn chuyển thành số tự nhiên nên nhân cho 100 đẠi ca à

Dữ liệu không đồng nhất nên không thể làm theo cách này được bạn à.

nguyennb · 15/5/10

Dùng hàm sumif với vùng so sánh điều kiện không đúng

Giả sử mình có bảng này
A B
a4 5
b4 6
a7 7

Muốn tính tổng các giá trị ở cột B mà cột A bắt đầu bởi kí tự "a" (a4,a7). Dùng hàm sumif như thế nào

MinhCong · 15/5/10

nguyennb đã viết:
Giả sử mình có bảng này
A B
a4 5
b4 6
a7 7

Muốn tính tổng các giá trị ở cột B mà cột A bắt đầu bởi kí tự "a" (a4,a7). Dùng hàm sumif như thế nào

Bạn dùng công thức sau nhé!

Mã:

=SUMIF(A1:A3,"a*",B1:B3)

teresa huyen · 15/5/10

Cho mình hỏi là có cách nào tách họ và tên trong excell mà dùng nút nào trên thanh công cụ không? chỉ giúp mình ?????

Hoàng Trọng Nghĩa · 15/5/10

teresa huyen đã viết:
Cho mình hỏi là có cách nào tách họ và tên trong excell mà dùng nút nào trên thanh công cụ không? chỉ giúp mình ?????

Bạn dùng chức năng Text to Column trong Data. Thử xem nhé!

dat_butmuc · 15/5/10

teresa huyen đã viết:
Cho mình hỏi là có cách nào tách họ và tên trong excell mà dùng nút nào trên thanh công cụ không? chỉ giúp mình ?????

Bạn vào Data -> Text to columns -> Delimited -> Next -> Space (hay kiểu khác tùy dữ liệu của bạn) -> Finish
Bạn nghiên cứu tiếp có nhiều cách với kiểu dữ liệu khác nhau

ngoductuan01 · 15/5/10

Chào bạn !
Mình có 1 danh sách hoc sinh gồm nhiều lớp 6/1 ,6/2 v.v.v....... Mình dùng Fitter để lọc danh sách theo lớp. Bây giờ sau khi lọc theo lớp. Mình muốn ghi phía trên dòng tựa đề DANH SÁCH HỌC SINH LỚP 6/1. Nếu mình chọn lọc 6/1 thì phía trên danh sách ghi lớp 6/1. Còn nếu chọn 6/2 thì danh sách sẽ ghi 6/2. Cứ như thế ở các lớp khác ......Có nghĩa là ở dưới chọn gì thì trên chạy theo đó . Mục đích là mình muốn in ra đấy mà. Mình sẽ dùng công thức gì ? Các bạn giúp mình với nhé !
Chào các bạn !

Hai Lúa Miền Tây · 15/5/10

ngoductuan01 đã viết:
Chào bạn !
Mình có 1 danh sách hoc sinh gồm nhiều lớp 6/1 ,6/2 v.v.v....... Mình dùng Fitter để lọc danh sách theo lớp. Bây giờ sau khi lọc theo lớp. Mình muốn ghi phía trên dòng tựa đề DANH SÁCH HỌC SINH LỚP 6/1. Nếu mình chọn lọc 6/1 thì phía trên danh sách ghi lớp 6/1. Còn nếu chọn 6/2 thì danh sách sẽ ghi 6/2. Cứ như thế ở các lớp khác ......Có nghĩa là ở dưới chọn gì thì trên chạy theo đó . Mục đích là mình muốn in ra đấy mà. Mình sẽ dùng công thức gì ? Các bạn giúp mình với nhé !
Chào các bạn !

Bạn dùng UDF sau nhé:

Mã:

Function AutoFilter_Criteria(Header As Range) As String
Dim strCri1 As String, strCri2 As String
    Application.Volatile
    With Header.Parent.AutoFilter
        With .Filters(Header.Column - .Range.Column + 1)
            If Not .On Then Exit Function
                strCri1 = .Criteria1
            If .Operator = xlAnd Then
                strCri2 = " AND " & .Criteria2
            ElseIf .Operator = xlOr Then
                strCri2 = " OR " & .Criteria2
            End If
        End With
    End With
    AutoFilter_Criteria = UCase(Header) & ": " & strCri1 & strCri2

End Function

Cú pháp:
=AutoFilter_Criteria(TieuDeCuaCotBangTinh)

ptm0412 · 15/5/10

Làm theo DomFootwear là làm ngược, thử làm xuôi xem: Chọn lớp, filter theo lớp đã chọn.

ngoductuan01 · 15/5/10

Cám ơn bạn đã giúp mình . Tuy nhiên mình muốn dùng thủ thuật hay công thức chứ vba hay bạn dùng hàm mình chưa hiểu lắm . Bạn có thể hướng dẫn về các hàm mà làm không . Cám ơn bạn nhiều !

chucuoi92 · 15/5/10

ngoductuan01 đã viết:
Cám ơn bạn đã giúp mình . Tuy nhiên mình muốn dùng thủ thuật hay công thức chứ vba hay bạn dùng hàm mình chưa hiểu lắm . Bạn có thể hướng dẫn về các hàm mà làm không . Cám ơn bạn nhiều !

Rất đơn giản.
ví dụ như danh sách trong file của ptm0412 (mượn file của anh làm ví dụ)
Ô A6 (Cột số TT)bạn gõ công thức sau:=IF(B6<>"",SUBTOTAL(3,$B$6:B6),"")
rồi fill cho đến cuối bảng, như vậy ta có một cột số thứ tự tự động.
Tiếp theo ở ô B3 (dưới dòng DANH "SÁCH HỌC SINH") bạn gõ công thức:=VLOOKUP(1,A6:C24,3,0)
Bây giờ trong bảng dữ liệu bạn lọc theo lớp nào thì ô B3 sẽ thể hiện tên lớp đó.

ndu96081631 · 16/5/10

ngoductuan01 đã viết:
Cám ơn bạn đã giúp mình . Tuy nhiên mình muốn dùng thủ thuật hay công thức chứ vba hay bạn dùng hàm mình chưa hiểu lắm . Bạn có thể hướng dẫn về các hàm mà làm không . Cám ơn bạn nhiều !

Đương nhiên công thức vẫn làm được!
Tôi sẽ dùng công thức này (Mượn file của bạn domfootwear)

PHP:

=IF(COUNT($A$5:$A$23)=SUBTOTAL(3,$A$5:$A$23),"",VLOOKUP(SUBTOTAL(5,$A$5:$A$23),$A$5:$C$23,3,0))

Xem file

ngoductuan01 · 16/5/10

ndu96081631 đã viết:
Đương nhiên công thức vẫn làm được!
Tôi sẽ dùng công thức này (Mượn file của bạn domfootwear)

PHP:

=IF(COUNT($A$5:$A$23)=SUBTOTAL(3,$A$5:$A$23),"",VLOOKUP(SUBTOTAL(5,$A$5:$A$23),$A$5:$C$23,3,0))

Xem file

Cám ơn các bạn đã giúp mình . Bây giờ , mình muốn ngược lại . Mình chọn lớp phía trên và sau đó sẽ lọc ra danh sách lớp phía dưới. các bạn giúp mình nhé.

ndu96081631 · 16/5/10

ngoductuan01 đã viết:
Cám ơn các bạn đã giúp mình . Bây giờ , mình muốn ngược lại . Mình chọn lớp phía trên và sau đó sẽ lọc ra danh sách lớp phía dưới. các bạn giúp mình nhé.

Ngược lại thì buộc phải dùng VBA như sư phụ ptm0412 đã làm!
Mà nghĩ cũng lạ! AutoFilter đã có sẳn lại chẳng chịu dùng... cứ muốn dùng list ở nơi khác là sao?

Chu.cuoi92 đã viết:
Rất đơn giản.
ví dụ như danh sách trong file của ptm0412 (mượn file của anh làm ví dụ)
Ô A6 (Cột số TT)bạn gõ công thức sau:=IF(B6<>"",SUBTOTAL(3,$B$6:B6),"")
rồi fill cho đến cuối bảng, như vậy ta có một cột số thứ tự tự động.
Tiếp theo ở ô B3 (dưới dòng DANH "SÁCH HỌC SINH") bạn gõ công thức:=VLOOKUP(1,A6:C24,3,0)
Bây giờ trong bảng dữ liệu bạn lọc theo lớp nào thì ô B3 sẽ thể hiện tên lớp đó.

Thử sức với trường hợp này xem nha:
- Trong sheet chẳng có cột STT nào cả
- Cũng không được dùng thêm cột phụ
===> Vậy phải làm sao để ra kết quả?
Giải bài toán trong trường hợp này là hơi bị hay à nha!

chucuoi92 · 16/5/10

ndu96081631 đã viết:
Thử sức với trường hợp này xem nha:
- Trong sheet chẳng có cột STT nào cả
- Cũng không được dùng thêm cột phụ
===> Vậy phải làm sao để ra kết quả?
Giải bài toán trong trường hợp này là hơi bị hay à nha!

Em nhớ là anh đã làm một bài tương tự như thế này trong phần "
Những điều lý thú của công thức mảng."

Mà công thức đó rất ngắn gọn rồi, vậy thì như "cỡ" em làm sao tìm ra được cách nào hay hơn.

ndu96081631 · 16/5/10

Chu.cuoi92 đã viết:
Em nhớ là anh đã làm một bài tương tự như thế này trong phần "
Những điều lý thú của công thức mảng."

Mà công thức đó rất ngắn gọn rồi, vậy thì như "cỡ" em làm sao tìm ra được cách nào hay hơn.

Bài này phải không?
Bài đấy là TÔ MÀU theo điều kiện, cũng hơi khác 1 chút so với bài này đấy! (khác yêu cầu, giống về bản chất)
Bạn thử xem! Sao lại hạ thấp mình như vậy chứ... vì ai cũng có tuyệt chiêu riêng mà người khác cần phải học hỏi

chucuoi92 · 16/5/10

ndu96081631 đã viết:
Bài này phải không?
Bài đấy là TÔ MÀU theo điều kiện, cũng hơi khác 1 chút so với bài này đấy! (khác yêu cầu, giống về bản chất)
Bạn thử xem! Sao lại hạ thấp mình như vậy chứ... vì ai cũng có tuyệt chiêu riêng mà người khác cần phải học hỏi

em chỉ cần sửa lại name của anh đi chút là OK
Vẫn mượn bài cũ của ptm0412 đặt name LOC=IF(SUBTOTAL(3,OFFSET(Sheet1!$B$5,,,ROW(Sheet1!$B$5:$B$25)-4))>1,ROW(Sheet1!$B$5:$B$25)-4,"")
Sau đó ở trên sheet ta gõ công thức =INDEX(C6:C24,SMALL(LOC,1))
(Điều kiện là dữ liệu như trong bài đã được sort)

ndu96081631 · 16/5/10

Chu.cuoi92 đã viết:
em chỉ cần sửa lại name của anh đi chút là OK
Vẫn mượn bài cũ của ptm0412 đặt name LOC=IF(SUBTOTAL(3,OFFSET(Sheet1!$B$5,,,ROW(Sheet1!$B$5:$B$25)-4))>1,ROW(Sheet1!$B$5:$B$25)-4,"")
Sau đó ở trên sheet ta gõ công thức =INDEX(C6:C24,SMALL(LOC,1))
(Điều kiện là dữ liệu như trong bài đã được sort)

Tôi thấy đâu cần sort dữ liệu cũng ra được kết quả mà!

chucuoi92 · 16/5/10

ndu96081631 đã viết:
Tôi thấy đâu cần sort dữ liệu cũng ra được kết quả mà!

Sort chứ anh!
Vì những giá trị "ẩn" bằng những giá trị "hiện" đứng sau nó "hàm subtotal(3,)"
như vậy nếu dữ liệu không sort thì kết quả khi đúng khi sai.
Nếu theo như anh nói thì phải làm lại name:
LOC=SUBTOTAL(3,OFFSET(Sheet1!$B$5,,,ROW(Sheet1!$B$5:$B$25)-4))
và:=INDEX(C6:C24,MATCH(1,LOC,1))
Thật là hay! nếu anh không gợi ý thì em không nghĩ ra vừa rút gọn được CT mà vẫn đúng.

ndu96081631 · 16/5/10

Chu.cuoi92 đã viết:
Sort chứ anh!
Vì những giá trị "ẩn" bằng những giá trị "hiện" đứng sau nó "hàm subtotal(3,)"
như vậy nếu dữ liệu không sort thì kết quả khi đúng khi sai.
Nếu theo như anh nói thì phải làm lại name:
LOC=SUBTOTAL(3,OFFSET(Sheet1!$B$5,,,ROW(Sheet1!$B$5:$B$25)-4))
và:=INDEX(C6:C24,MATCH(1,LOC,1))
Thật là hay! nếu anh không gợi ý thì em không nghĩ ra vừa rút gọn được CT mà vẫn đúng.

Ẹc... Ẹc... Rất tốt
Góp thêm 1 công thức khác:

PHP:

=IF(COUNTA($A$5:$A$23)=SUBTOTAL(103,$A$5:$A$23),"",INDEX($B$5:$B$23,MATCH(1,SUBTOTAL(103,OFFSET($B$5,,,ROW(INDIRECT("1:"&ROWS($B$5:$B$23))),)),0)))

Công thức mảng, khỏi name luôn
Công thức dài là vì có rào trường hợp Show All dữ liệu, chứ thật sự công thức gốc chỉ có bi nhiêu:

PHP:

=INDEX($B$5:$B$23,MATCH(1,SUBTOTAL(103,OFFSET($B$5,,,ROW(INDIRECT("1:"&ROWS($B$5:$B$23))),)),0))

Công thức này xem như gần tương tự với công thức của bạn... Chỉ khuyên nên dùng theo kiểu ROW(INDIRECT("1:"& ... sẽ hay hơn

chucuoi92 · 16/5/10

ndu96081631 đã viết:
Ẹc... Ẹc... Rất tốt
Góp thêm 1 công thức khác:

PHP:

=IF(COUNTA($A$5:$A$23)=SUBTOTAL(103,$A$5:$A$23),"",INDEX($B$5:$B$23,MATCH(1,SUBTOTAL(103,OFFSET($B$5,,,ROW(INDIRECT("1:"&ROWS($B$5:$B$23))),)),0)))

Công thức mảng, khỏi name luôn
Công thức dài là vì có rào trường hợp Show All dữ liệu, chứ thật sự công thức gốc chỉ có bi nhiêu:

PHP:

=INDEX($B$5:$B$23,MATCH(1,SUBTOTAL(103,OFFSET($B$5,,,ROW(INDIRECT("1:"&ROWS($B$5:$B$23))),)),0))

Công thức này xem như gần tương tự với công thức của bạn... Chỉ khuyên nên dùng theo kiểu ROW(INDIRECT("1:"& ... sẽ hay hơn

Thực ra em đã làm name LOC2=SUBTOTAL(3,INDIRECT("C6:C"&ROW(Sheet1!$C$6:$C$24)))
và =INDEX(C6:C24,MATCH(1,LOC2,0))
nhưng thấy cái"INDIRECT("C6:C"&.." nó không hay nên không đưa lên!
Rất cám ơn anh! vì được học hỏi ở anh rất nhiều!

kenichi2003 · 18/5/10

Ai chỉ Giùm mình cách Tính hàm Sumif 2 điều kiền với: Mình Cần tính tổng tiền của dịch vụ E-com năm 2010. Cám ơn nhiều!

Lê Duy Thương · 18/5/10

kenichi2003 đã viết:
Ai chỉ Giùm mình cách Tính hàm Sumif 2 điều kiền với: Mình Cần tính tổng tiền của dịch vụ E-com năm 2010. Cám ơn nhiều!

có 3 cách tính
=SUMIFS($P$11:$P$17,$U$11:$U$17,"NĂM 2010",$T$11:$T$17,"E-COM") dùng cho excel 2007

=SUM(IF(($U$11:$U$17="NĂM 2010")*($T$11:$T$17="E-COM"),$P$11:$P$17)) bấm CTRL+SHIFL+ENTER

=SUMPRODUCT(($U$11:$U$17="NĂM 2010")*($T$11:$T$17="E-COM"),$P$11:$P$17)

cuong0202 · 19/5/10

Mọi người coi giúp em file excel cua em không nặng lắm nhung sao nó chạy chậm cực kỳ luôn ah,, co cách nào khắc phục được không ah,, cảm ơn mọi người,,,

ndu96081631 · 19/5/10

cuong0202 đã viết:
Mọi người coi giúp em file excel cua em không nặng lắm nhung sao nó chạy chậm cực kỳ luôn ah,, co cách nào khắc phục được không ah,, cảm ơn mọi người,,,

Bạn xóa mấy công thức SUMPRODUCT ở sheet stores hoặc Copy, Paste Values toàn bộ thì nó nhanh lên ngay!
Cũng có thể nghĩ đến việc tồng hợp bằng PivotTable thay cho công thức

cuong0202 · 19/5/10

như vậy làm sao em nhập xuất dữ liệu ah,, có cách nào khác nữa không ah,, e dung pivotTable không quen,, em chon một hồi nó ra tùm lum het ah ,, cũng có thử vài chục lần nhưng ổn nên thôi,,, hichic

Lê Duy Thương · 19/5/10

cuong0202 đã viết:
như vậy làm sao em nhập xuất dữ liệu ah,, có cách nào khác nữa không ah,, e dung pivottable không quen,, em chon một hồi nó ra tùm lum het ah ,, cũng có thử vài chục lần nhưng ổn nên thôi,,, hichic

trong các name của bạn chọn địa chỉ vừa đủ thôi chọn chi trên 2500 rows cho nặng

trungkienchat · 19/5/10

Hỏi nhanh - Đáp nhanh về công thức

Chào tất cả mọi người.

Mình đang làm 1 file excel nhưng chưa hoàn thành. Rất mong mọi người xem và chỉ bảo giúp mình. Sự giúp đỡ mình đã comment trong sheet Flowup table rồi.

Cảm ơn tất cả mọi người.

cuong0202 · 19/5/10

thử cái này coi sao bạn
IF(OR(AD12>0.85,AD12=0.85),0,AD12)

Lê Duy Thương · 19/5/10

trungkienchat đã viết:
Chào tất cả mọi người.

Mình đang làm 1 file excel nhưng chưa hoàn thành. Rất mong mọi người xem và chỉ bảo giúp mình. Sự giúp đỡ mình đã comment trong sheet Flowup table rồi.

Cảm ơn tất cả mọi người.

đây là lần thứ 2 tôi làm bảng tính này
xem file nhé

ndu96081631 · 19/5/10

cuong0202 đã viết:
như vậy làm sao em nhập xuất dữ liệu ah,, có cách nào khác nữa không ah,, e dung pivotTable không quen,, em chon một hồi nó ra tùm lum het ah ,, cũng có thử vài chục lần nhưng ổn nên thôi,,, hichic

Thông thường nếu buộc phải dùng SUMPRODUCT mà dữ liệu nhiều thì đương nhiên file sẽ chậm!
Vậy chỉ có 2 cách:
- Dùng các công cụ có sẳn để tổng hợp (PivotTable chẳng hạn)
- Dùng VBA
-------------------
Bạn cảm thấy cái nào dể hiểu thì dùng
Mà thật ra, đã là kiến thức thì chẳng có cái nào dể hiểu cả! Mọi thứ đều phải học thôi

havietchuong · 20/5/10

binhdang đã viết:
Xin các bạn cho mình biết công thức tính tồng các số 1÷n

Chưa hiểu ý bạn là thế nào? Số nguyên hay số gì?
Từ 1 đến n hay 1+n, chứ 1+n thì sẽ bằng n+1.
Đùa một chút cho vui.
Vui vẻ.

ndu96081631 · 20/5/10

havietchuong đã viết:
Chưa hiểu ý bạn là thế nào? Số nguyên hay số gì?
Từ 1 đến n hay 1+n, chứ 1+n thì sẽ bằng n+1.
Đùa một chút cho vui.
Vui vẻ.

Viết 1÷n thì có nghĩa là từ 1 đến n rồi còn gì
Thêm nữa: hồi học phổ thông, đã nói đến chữ n thì mặc định ta xem là số tự nhiên (chắc chú tác giả này đang là học sinh cũng không chừng)
Mà công thức này lý nào tác giả không biết nhỉ? ---> n*(n+1)/2

thang24 · 20/5/10

Xin chỉ dạy công thức: indirect("'"&K8&"'G10"). sao khi kéo công thức chỉ K8 là nhẩy còn G10 lại ko có cách nào làm G10 cũng nhảy ko?

pttnhan1974 · 20/5/10

thang24 đã viết:
Xin chỉ dạy công thức: indirect("'"&K8&"'G10"). sao khi kéo công thức chỉ K8 là nhẩy còn G10 lại ko có cách nào làm G10 cũng nhảy ko?

Bạn không thấy cái G10 hắn nằm trong một cái cặp nháy nháy à? Như rứa hắn chỉ là một cái "Gờ Mười" không hơn không kém, mần răng mà hắn nhảy tưng tưng được?

thang24 · 20/5/10

mình biết nó không nhẩy vì nằm trong "'!G10" nhưng ý ở đây là có cách nào để thay đổi ko? vì K8 của mình là tến sh rồi jờ chỉ còn mỗi G10 thay đổi nữa là ok!

Hỏi nhanh - đáp nhanh về công thức (phần 1) (2 người xem)

Người dùng đang xem chủ đề này

weitə r ə'pɔn prɔvidəns

Thành viên mới

Cạo Rồi Khỏi Gội

Thành viên gạo cội

Thành viên gạo cội

Thành viên mới

weitə r ə'pɔn prɔvidəns

Thành viên gạo cội

Thành viên lười biếng

weitə r ə'pɔn prɔvidəns

Thành viên lười biếng

weitə r ə'pɔn prɔvidəns

Thành viên mới

Thành viên lười biếng

Thành viên mới

Thành viên lười biếng

Cạo lấy gì gội (Dịch quá không gội được)

weitə r ə'pɔn prɔvidəns

Thành viên hoạt động

weitə r ə'pɔn prɔvidəns

❆❆❆❆❆❆❆❆

Cạo lấy gì gội (Dịch quá không gội được)

Thành viên mới

Khó khăn biết dũng khí.

Thành viên mới

Vũ Trần Khoa

Thành viên mới

Thành viên mới

Thành viên mới

Cạo Rồi Khỏi Gội

Thành viên mới

Cạo Rồi Khỏi Gội

Thành viên mới

Cạo Rồi Khỏi Gội

Khó khăn biết dũng khí.

Thành viên mới

Cạo Rồi Khỏi Gội

Thành viên mới

Thành viên mới

Bùi Nguyễn Triệu Tường

Thành viên mới

Bùi Nguyễn Triệu Tường

Thành viên mới

Thành viên mới

Thành viên mới

Bùi Nguyễn Triệu Tường

Thành viên mới

Cạo Rồi Khỏi Gội

Thành viên mới

Bùi Nguyễn Triệu Tường

Cạo Rồi Khỏi Gội

weitə r ə'pɔn prɔvidəns

Cạo lấy gì gội (Dịch quá không gội được)

Thành viên mới

Thành viên mới

Thành viên gắn bó

Cạo lấy gì gội (Dịch quá không gội được)

Thành viên tích cực

Thành viên mới

❆❆❆❆❆❆❆❆

weitə r ə'pɔn prɔvidəns

Cạo lấy gì gội (Dịch quá không gội được)

weitə r ə'pɔn prɔvidəns

Cạo lấy gì gội (Dịch quá không gội được)

❆❆❆❆❆❆❆❆

Thành viên hoạt động

Thành viên gắn bó

Thành viên mới

Chuyên gia GPE

weitə r ə'pɔn prɔvidəns

Thành viên mới

❆❆❆❆❆❆❆❆