Các câu hỏi về thời gian, tính toán giờ, ngày, tháng, năm được post ở đây (1 người xem)

[thuyoc]

Cách cộng trừ hàm ngày tháng trong Ecxel

Em cần xử lý một bảng định dạng ngày tháng theo kiểu:
Cột A1 là: Ngày 10 tháng 10 năm 2012
Cột A2: Ngày 11 tháng 10 năm 2012.
Làm thế nào để em cộng cột A1 ra Cột A2 được!
Em đã thử làm mãi mà không được!
Rất mong mọi người giúp đỡ!
View attachment XL.xlsx
VD: ở cột A em có ngày tháng định dạng theo kiểu trên
Em muốn cột B sẽ cộng thêm một ngày để thành ngày 11 tháng 1 năm 2102

 

[dhn46]

Em cần xử lý một bảng định dạng ngày tháng theo kiểu:
Cột A1 là: Ngày 10 tháng 10 năm 2012
Cột A2: Ngày 11 tháng 10 năm 2012.
Làm thế nào để em cộng cột A1 ra Cột A2 được!
Em đã thử làm mãi mà không được!
Rất mong mọi người giúp đỡ!

Ý bạn muốn tìm cái gì? Tốt nhất bạn đưa File mô tả rồi nêu rõ xem bạn muốn tìm cái gì.
Thân!

 

[nhapmon]

ngày 10 + thêm 1 ra ngày 11 phải không,
thí dụ cell A1 là ngày 10 tháng 10 năm 2012.
cell A2 đặc cthức = LEFT(A1,4) & " " & MID(A1,6,2)+1 & " " & RIGHT(A1,17)
với điều kiên là các khoảng trắng giữa các cụm là như nhau

 

[quynhtlbp]

Công thức này cũng đơn giản bạn làm như thế này nhé.
A5 = TODAY()
B5 = DATE(YEAR(A5),MONTH(A5),DAY(A5)+1)
chúc bạn thành công.

 

[thuyoc]

Em có vừa thử sao không nó ra một dãy số thôi ạ!

 

[thuyoc]

Em đã thử mà NÓ ra kết quả #NUM#, hàm này em đã dùng nhưng không có kết quả quynhtlbp ạ

 

[dhn46]

Dữ liệu của bạn thì dùng công thức này

=DATE(RIGHT(A1,4),MID(A1,3,2),LEFT(A1,2))+1

 

[batien]

chào các bạn, mình là thành viên mới , mình ko biết box bài mới chổ nào cả, mình có câu này hơi khó mong các bạn giúp cho:
mình có tổng là 10 cột gồm tất cả các môn:[TABLE="width: 450"]
Toán , lý , hóa , văn , sử , địa, anh , pháp , trung , sinh
6 5 9 4 5 6 9 6 6 7
giờ mình muốn tìm giá trị cho cột thi lại biết rằng:
Học sinh nào bị Thi Lại thì ghi tên môn thi lại đó (Tức là tên môn thi có điểm <5).
nếu dùng hàm if thì vẫn ra, nhưng quá dài, bạn có cách nào khác không. giúp mình nhé.

 

[Good-Luck]

Em cần xử lý một bảng định dạng ngày tháng theo kiểu:
Cột A1 là: Ngày 10 tháng 10 năm 2012
Cột A2: Ngày 11 tháng 10 năm 2012.
Làm thế nào để em cộng cột A1 ra Cột A2 được!
Em đã thử làm mãi mà không được!
Rất mong mọi người giúp đỡ!
View attachment 95333
VD: ở cột A em có ngày tháng định dạng theo kiểu trên
Em muốn cột B sẽ cộng thêm một ngày để thành ngày 11 tháng 1 năm 2102

sao mà phiền thế, cái đó đâu cần công thức, chọn ô a1 kéo chuột xuống dưới là có kết quả thôi mà, microsoft làm cho công việc đố kô cần mình làm

 

[leonguyenz]

Em cần xử lý một bảng định dạng ngày tháng theo kiểu:...
Em muốn cột B sẽ cộng thêm một ngày để thành ngày 11 tháng 1 năm 2102

[gpebaiviet=Hỏi:] Theo bạn thì ô A1 có kiểu dữ liệu gì? Chuỗi, Số, Ngày tháng ????
Trong Excel, định dạng là để cho dễ nhìn, dễ tìm thôi, quan trọng nhất là nó phải thể hiện đúng ý nghĩa của nó. Nếu bạn muốn cột A là ngày tháng thì bạn gõ đúng ngày tháng 10/10/2012, sau đó Format nó thành "Ngày" dd "tháng" mm "năm" yyyy. Cột B bạn muốn tăng giảm bao nhiêu thì cộng số đó vào, coppy định dạng cột A cho côt B.
Như bài của bạn, bạn gõ một chuỗi số rồi định dạng "Ngày" 00 "tháng" 00 "năm" 0000 mục đích để làm gì? [/gpebaiviet]

 

[nhapmon]

chào các bạn, mình là thành viên mới , mình ko biết box bài mới chổ nào cả, mình có câu này hơi khó mong các bạn giúp cho:
mình có tổng là 10 cột gồm tất cả các môn:

cái này hôm trước tôi có đọc một lần rồi, không hiểu gì hết, cái cột đó là gì vậy, sao bạn ko up file lên?

 

[leonguyenz]

chào các bạn, mình là thành viên mới , mình ko biết box bài mới chổ nào cả, mình có câu này hơi khó mong các bạn giúp cho:
mình có tổng là 10 cột gồm tất cả các môn:[TABLE="width: 450"]
Toán , lý , hóa , văn , sử , địa, anh , pháp , trung , sinh
6 5 9 4 5 6 9 6 6 7
giờ mình muốn tìm giá trị cho cột thi lại biết rằng:
Học sinh nào bị Thi Lại thì ghi tên môn thi lại đó (Tức là tên môn thi có điểm <5).
nếu dùng hàm if thì vẫn ra, nhưng quá dài, bạn có cách nào khác không. giúp mình nhé.

hàm IF sao mà dài? =IF(B1<5,A1,"") với cột A là Môn học, cột B là điểm thi.

 

[thuyoc]

dhn46 ơi! em vừa thử, định dạng đúng nhưng ngày tháng thì sai!
Không ra kết quả ngày 11 tháng 10 năm 2012

 

[dhn46]

dhn46 ơi! em vừa thử, định dạng đúng nhưng ngày tháng thì sai!
Không ra kết quả ngày 11 tháng 10 năm 2012

Góp ý với dữ liệu của bạn
Khi bạn sắp xếp cơ sở dữ liệ của bạn thì nên "Chuẩn" về format
Khi dùng công thức trên sẽ cho kết quả là định dạng ngày tháng năm "Chuẩn"
Còn việc định dạng lại thì bạn có thể làm được (ví dụ như: "Ngày" dd "tháng" mm "năm" yyyy)
Thân!

 

[Good-Luck]

chào các bạn, mình là thành viên mới , mình ko biết box bài mới chổ nào cả, mình có câu này hơi khó mong các bạn giúp cho:
mình có tổng là 10 cột gồm tất cả các môn:[TABLE="width: 450"]
Toán , lý , hóa , văn , sử , địa, anh , pháp , trung , sinh
6 5 9 4 5 6 9 6 6 7
giờ mình muốn tìm giá trị cho cột thi lại biết rằng:
Học sinh nào bị Thi Lại thì ghi tên môn thi lại đó (Tức là tên môn thi có điểm <5).
nếu dùng hàm if thì vẫn ra, nhưng quá dài, bạn có cách nào khác không. giúp mình nhé.

Không biết ý bạn có phải vậy ko, tham khảo file dưới đây, nhưng mình gửi ý bạn dùng if nối thì dễ hơn nhiều

 

[l01012011]

Em chào mọi người! Em muốn nhờ mọi người chỉ em cách xác định ô A2 - ngày kết thúc đơn hàng.

Em có 2 ô là A1: ngày giao hàng lên tàu - khách hàng quy định sẵn trong hợp đồng
ô A2: ngày kết thúc đơn hàng tại nhà máy - cần xác định.
(cả ô A1, A2 đều có dạng dd/mm/yyyy ạ)


ngày kết thúc đơn hàng sẽ luôn luôn là thứ 4 của tuần liền trước tuần giao hàng.

- Ví dụ nếu ngày giao hàng là thứ 3, thứ 4, 5, 6, 7, Cn của tuần 2 thì ngày kết thúc đơn hàng phải là thứ 4 của tuần 1.
Ví dụ nếu ngày giao hàng rơi vào các ngày ngày 15 (thứ 3), 16 (thứ 4), 17( thứ 5), 18 (thứ 6), 19 (thứ 7), 20 (chủ nhật) tháng 1/2013 thì ngày kết thúc đơn hàng -A2 sẽ là thứ thứ 4, ngày 9 tháng 1 năm 2013.

-Nếu ngày giao hàng (A1) rơi vào thứ 2, thì coi như nó là ngày chủ nhật trước đó, và ngày giao hàng (A2) sẽ là thứ 4 của tuần trước tuần chứa ngày chủ nhật đó.
(Ví dụ nếu ngày giao hàng là thứ 2, ngày 21/1/2013 thì vẫn điền vào ô A1 là 21/1/2013 nhưng ngày giao hàng sẽ là thứ 4 ngày 9/01/2013 (chứ không phải là thứ 4 ngày 16/1/2013)

Em muốn hỏi có cách nào để xác định ô A2- ngày kết thúc đơn hàng dựa vào ô A1- ngày giao hàng lên tàu bằng công thức được không ạ? (Vì hằng ngày mọi người phòng Merchandise làm việc với rất nhiều đơn hàng, tra lịch để nhập vào excel cũng mất rất nhiều thời gian nên em muốn hỏi xem có cách nào để tiết kiệm thời gian không ạ)

Em cảm ơn mọi người!

 

[dhn46]

Khó hình dung quá, nhưng bạn thử công thức này xem

=IF(WEEKDAY(A1)=2,INDEX(A1-ROW(7:14),MATCH(4,WEEKDAY($A$1-ROW(7:14)),0)),INDEX(A1-ROW(1:7),MATCH(4,WEEKDAY($A$1-ROW(1:7)),0)))

Kết thúc Ctrl + Shift + Enter

 

[ptm0412]

Khó hình dung quá, nhưng bạn thử công thức này xem

=IF(WEEKDAY(A1)=2,INDEX(A1-ROW(7:14),MATCH(4,WEEKDAY($A$1-ROW(7:14)),0)),INDEX(A1-ROW(1:7),MATCH(4,WEEKDAY($A$1-ROW(1:7)),0)))

Kết thúc Ctrl + Shift + Enter

Thử công thức này:

=A1-7+(4-WEEKDAY(A1))-7*(WEEKDAY(A1)<3)

 

[l01012011]

Với sự hướng dẫn của anh và Thầy, em đã làm được rồi. Em cảm ơn thầy Ptm0412 và anh dhn46 ạ!

 

[thuyoc]

Mọi người giúp em với, trong file đính kèm em có cột thời gian A, hiện giờ và phút, số phút cách nhau là 5. Như vậy sẽ lần lượt như trong bảng. Bây giờ muốn 8h 60p = 9h, 9h 30p = 10h.... (giống
cột B) mà số phút vẫn cách nhau là 5 thì em làm thế nào.View attachment thơigian.xlsx

 

[Hoàng Trọng Nghĩa]

Mọi người giúp em với, trong file đính kèm em có cột thời gian A, hiện giờ và phút, số phút cách nhau là 5. Như vậy sẽ lần lượt như trong bảng. Bây giờ muốn 8h 60p = 9h, 9h 30p = 10h.... (giống
cột B) mà số phút vẫn cách nhau là 5 thì em làm thế nào.View attachment 95705

Hỏng hiểu gì hết, 8h60 thì bằng 9h là OK, còn 9h30 sao bằng 10h, lại còn mỗi cái cách nhau 5m là sao? nếu 9h30 = 10h thì 9h35 bằng mấy giờ????

 

[leonguyenz]

Bạn thuyoc này định dạng giờ chẳng ra làm sao, không có ý nghĩa gì cả. Hôm trước cũng định dạng ngày từ số 10102012, bạn sử dụng Excel phải hiểu được kiểu dữ liệu của nó mà sử dụng chứ?
Bạn xem trong cột F có đúng ý bạn hay không?

 

[Ba Tê]

Mọi người giúp em với, trong file đính kèm em có cột thời gian A, hiện giờ và phút, số phút cách nhau là 5. Như vậy sẽ lần lượt như trong bảng. Bây giờ muốn 8h 60p = 9h, 9h 30p = 10h.... (giống
cột B) mà số phút vẫn cách nhau là 5 thì em làm thế nào.View attachment 95705

Time thì phải nhập liệu kiểu time, rồi muốn xem nó kiểu nào thì định dạng nó kiểu đó, bạn nhập kiểu tùy ý thì sao Anh Bill hiểu nó là Time?
Thử xem trong file này coi có vận dụng được vào chuyện gì không.

 

[Hoàng Trọng Nghĩa]

Bạn thuyoc này định dạng giờ chẳng ra làm sao, không có ý nghĩa gì cả. Hôm trước cũng định dạng ngày từ số 10102012, bạn sử dụng Excel phải hiểu được kiểu dữ liệu của nó mà sử dụng chứ?
Bạn xem trong cột F có đúng ý bạn hay không?

Nếu đúng là vậy thì chẳng cần gì phải nói, chỉ cần định dạng:

hh "h" mm "m"

Sau đó ô trên cùng gõ 8:0, ô kế tiếp gõ 8:05 rồi kéo xuống, cần gì công thức chứ.

Vấn đề là đã ghi là GIỜ = h thì ghi PHÚT = m, chứ nửa nạc, nửa mỡ kỳ cục vậy ta?

 

[leonguyenz]

Nếu đúng là vậy thì chẳng cần gì phải nói, chỉ cần định dạng:

hh "h" mm "m"

Sau đó ô trên cùng gõ 8:0, ô kế tiếp gõ 8:05 rồi kéo xuống, cần gì công thức chứ.

Vấn đề là đã ghi là GIỜ = h thì ghi PHÚT = m, chứ nửa nạc, nửa mỡ kỳ cục vậy ta?

Haha, em cũng nghiệp dư như chủ thớt mà.
Fill xuống như anh nói cũng được, nhưng em cố tình làm thêm +5/1440 là để bạn ấy biết bước nhảy của phút (5 phút).

 

[thuyoc]

Woa, chưa gì em đã nức tiếng không hiểu chuyện rồi đây, còn học dài dài, mong các anh chỉ giáo, coi em còn khù khờ quá các anh không được nóng giận nhé! Thanks các a nhìu nhìu!

 

[l01012011]

Em chào mọi người! Em muốn nhờ mọi người chỉ em cách xác định ô A2 - ngày kết thúc đơn hàng.

Em có 2 ô là A1: ngày giao hàng lên tàu - khách hàng quy định sẵn trong hợp đồng
ô A2: ngày kết thúc đơn hàng tại nhà máy - cần xác định.
(cả ô A1, A2 đều có dạng dd/mm/yyyy ạ)


ngày kết thúc đơn hàng sẽ luôn luôn là thứ 4 của tuần liền trước tuần giao hàng.

- Ví dụ nếu ngày giao hàng là thứ 3, thứ 4, 5, 6, 7, Cn của tuần 2 thì ngày kết thúc đơn hàng phải là thứ 4 của tuần 1.
Ví dụ nếu ngày giao hàng rơi vào các ngày ngày 15 (thứ 3), 16 (thứ 4), 17( thứ 5), 18 (thứ 6), 19 (thứ 7), 20 (chủ nhật) tháng 1/2013 thì ngày kết thúc đơn hàng -A2 sẽ là thứ thứ 4, ngày 9 tháng 1 năm 2013.

-Nếu ngày giao hàng (A1) rơi vào thứ 2, thì coi như nó là ngày chủ nhật trước đó, và ngày giao hàng (A2) sẽ là thứ 4 của tuần trước tuần chứa ngày chủ nhật đó.
(Ví dụ nếu ngày giao hàng là thứ 2, ngày 21/1/2013 thì vẫn điền vào ô A1 là 21/1/2013 nhưng ngày giao hàng sẽ là thứ 4 ngày 9/01/2013 (chứ không phải là thứ 4 ngày 16/1/2013)

Em muốn hỏi có cách nào để xác định ô A2- ngày kết thúc đơn hàng dựa vào ô A1- ngày giao hàng lên tàu bằng công thức được không ạ? (Vì hằng ngày mọi người phòng Merchandise làm việc với rất nhiều đơn hàng, tra lịch để nhập vào excel cũng mất rất nhiều thời gian nên em muốn hỏi xem có cách nào để tiết kiệm thời gian không ạ)

Em cảm ơn mọi người!

Thử công thức này:

=A1-7+(4-WEEKDAY(A1))-7*(WEEKDAY(A1)<3)

Em thưa Thầy, lúc sáng vì công việc nhiều quá nên em chỉ mới thử công thức và thấy đúng nên dùng luôn.
Giờ em mới ngồi suy nghĩ để hiểu công thức để vận dụng cho những trường hợp về sau.

Không biết em hiểu ý nghĩa của công thức thế này đúng chưa ạ:
Đầu tiên, từ ngày lên tàu A1, lùi về quá khứ 1 tuần bằng phép tính A1 -7 (gọi là ngày A1').
Từ ngày A1' ta tiến/lùi (4- weekday(A1)) ngày thì ta sẽ đứng tại thứ 4 của tuần trước tuần cần giao hàng lên tàu.

Trường hợp ngày lên tàu không rơi vào thứ 2 thì ngày thứ 4 trên là kết quả cuối cùng, còn nếu ngày lên tàu A1 rơi vào thứ 2 (tức weekday(A1)<3) thì ta tiếp tục lùi kết quả này về quá khứ 1 tuần nữa bằng phép trừ 7*weekday(A1)<3)phải không ạ!?

Như vậy, tổng quát nếu ngày giao hàng của em là ngày A1, cũng với những giả thiết như trên nhưng ngày kết thúc đơn hàng là A2 = thứ n nào đó trong tuần, thì công thức sẽ là A2= A1-7+(n-WEEKDAY(A1))-7*(WEEKDAY(A1)<3) phải không ạ?

Em cảm ơn Thầy mà mọi người ạ!

 

[ndu96081631]

Em thưa Thầy, lúc sáng vì công việc nhiều quá nên em chỉ mới thử công thức và thấy đúng nên dùng luôn.
Giờ em mới ngồi suy nghĩ để hiểu công thức để vận dụng cho những trường hợp về sau.

Test thử công thức này xem đúng không nha:

=A1-WEEKDAY(A1-2)-5

 

[l01012011]

Test thử công thức này xem đúng không nha:

=A1-WEEKDAY(A1-2)-5

Dạ, công thức của Thầy đúng và rất dễ nhớ ạ.......nhưng mà em chưa hiểu ý nghĩa của nó, nếu dùng mà dùng như con vẹt thì không được. Hi vọng là giờ tới ngày mai em sẽ hiểu ra. Nếu không hiểu, em nhờ Thầy Ndu giải thích giúp em ạ! Em cảm ơn Thầy!

 

[ptm0412]

Như vậy, tổng quát nếu ngày giao hàng của em là ngày A1, cũng với những giả thiết như trên nhưng ngày kết thúc đơn hàng là A2 = thứ n nào đó trong tuần, thì công thức sẽ là A2= A1-7+(n-WEEKDAY(A1))-7*(WEEKDAY(A1)<3) phải không ạ?

Đúng rồi. Bây giờ Giải thích công thức ndu:

Công thức này viết theo suy luận ban đầu để nhóc dễ hiểu (mà nhóc hiểu thật):

=A1-7+(4-WEEKDAY(A1))-7*(WEEKDAY(A1)<3)

Từ đó triển khai ra: (-7 + 4 = -3):

=A1-3-WEEKDAY(A1)-7*(WEEKDAY(A1)<3)

Suy luận tiếp:

Nếu A1 nhằm vào chủ nhật hoặc thứ hai (weekday = 1 hoặc 2, weekday <3) thì coi như nó là tuần trước. Vậy trừ béng A1 cho 2 cho qua tuần trước luôn, coi như tuần bắt đầu từ thứ 3.

= A1-3-WEEKDAY(A1-2) - 2

-2 - 3 = -5 chứ gì, vậy

= A1-5-WEEKDAY(A1-2)

Đây là công thức cuối cùng của ndu.

 

[ndu96081631]

Dạ, công thức của Thầy đúng và rất dễ nhớ ạ.......nhưng mà em chưa hiểu ý nghĩa của nó, nếu dùng mà dùng như con vẹt thì không được. Hi vọng là giờ tới ngày mai em sẽ hiểu ra. Nếu không hiểu, em nhờ Thầy Ndu giải thích giúp em ạ! Em cảm ơn Thầy!

Công thức được triển khai thành:
=A1-2 - WEEKDAY(A1-2)-3
Đặt A1 - 2 là X, ta được biểu thức =X-WEEKDAY(X)-3
Xuất phát từ nguyên tắc:
- Với X là 1 ngày nào đó thì X - WEEKDAY(X) sẽ luôn luôn là ngày thứ 7 trước ngày X (tự kiểm chứng nhé)
- Thứ 7 trừ đi 3 sẽ là Thứ tư
Thế thôi

 

[l01012011]

Dạ, em hiểu rồi ạ.
Vậy là xuất phát từ nguyên tắc mà Thầy Ndu nói:

Với X là 1 ngày nào đó thì X - WEEKDAY(X) sẽ luôn luôn là ngày thứ 7 trước ngày X

Từ Thứ 7 muốn về thứ 4 thì phải trừ đi 3- tức : X - WEEKDAY(X) - 3

Và như Thầy Ptm0412:

Nếu A1 nhằm vào chủ nhật hoặc thứ hai (weekday = 1 hoặc 2, weekday <3) thì coi như nó là tuần trước. Vậy trừ béng A1 cho 2 cho qua tuần trước luôn, coi như tuần bắt đầu từ thứ 3.

Nên ở đây ta có X = A1-2

Kết hợp lại ta được A2= ((A1-2) - WEEKDAY(A1-2)) - 3 nếu A2 cần phải rơi vào thứ n nào đó thì 3 = 7-n
Như vậy công thức tổng quát sẽ là:

A2= ((A1-2) - WEEKDAY(A1-2)) - (7-n)

A2= A1 - WEEKDAY(A1-2)-9+n

Em cảm ơn 2 Thầy ạ!
Vậy là bây giờ khi nhập đơn hàng vào máy, em có thể dùng công thức mà không cần phải lôi tờ lịch bàn ra tra nữa rồi.

 

[l01012011]

Đúng rồi. Bây giờ Giải thích công thức ndu:

Công thức này viết theo suy luận ban đầu để nhóc dễ hiểu (mà nhóc hiểu thật):

=A1-7+(4-WEEKDAY(A1))-7*(WEEKDAY(A1)<3)

Từ đó triển khai ra: (-7 + 4 = -3):

=A1-3-WEEKDAY(A1)-7*(WEEKDAY(A1)<3)

Suy luận tiếp:

Nếu A1 nhằm vào chủ nhật hoặc thứ hai (weekday = 1 hoặc 2, weekday <3) thì coi như nó là tuần trước. Vậy trừ béng A1 cho 2 cho qua tuần trước luôn, coi như tuần bắt đầu từ thứ 3.

= A1-3-WEEKDAY(A1-2) - 2

-2 - 3 = -5 chứ gì, vậy

= A1-5-WEEKDAY(A1-2)

Đây là công thức cuối cùng của ndu.

Thưa Thầy và mọi người, hôm nay em gặp đơn hàng thế này ạ: cho ngày A1- ngày lên tàu.
Ngày A2 là ngày kết thúc đơn hàng tại nhà máy. A2 sẽ là ngày thứ 5 trong tuần kề ngày A1 nhưng phải sớm hơn ngày A1. (không cần trước 1 tuần như bài toán hôm trước ạ)
Em thay đổi công thức của Thầy thành A2=A1+5-WEEKDAY(A1)-7*(WEEKDAY(A1)<=5)
Em nhờ Thầy xem giúp công thức như vậy đúng chưa ạ! Em đã thay nhiều ngày khác nhau vào A1 để kiểm tra rồi nhưng để chắc chắn, em mong Thầy và mọi người xem giúp em ạ!

Em cảm ơn Thầy và mọi người ạ!

 

[Hoàng Trọng Nghĩa]

Thưa Thầy và mọi người, hôm nay em gặp đơn hàng thế này ạ: cho ngày A1- ngày lên tàu.
Ngày A2 là ngày kết thúc đơn hàng tại nhà máy. A2 sẽ là ngày thứ 5 trong tuần kề ngày A1 nhưng phải sớm hơn ngày A1. (không cần trước 1 tuần như bài toán hôm trước ạ)
Em thay đổi công thức của Thầy thành A2=A1+5-WEEKDAY(A1)-7*(WEEKDAY(A1)<=5)
Em nhờ Thầy xem giúp công thức như vậy đúng chưa ạ! Em đã thay nhiều ngày khác nhau vào A1 để kiểm tra rồi nhưng để chắc chắn, em mong Thầy và mọi người xem giúp em ạ!

Em cảm ơn Thầy và mọi người ạ!

Tự tin lên đi cô bé, thử 1 trường hợp thấy đúng, thử thêm 1 vài lần nữa mà đúng nữa thì OK, đừng thiếu lòng tin vào mình như vậy chứ!

 

[thanh260292]

Mình muốn hỏi là
Ngày Gửi Tiền : 01/01/2012
Kỳ hạn : 3 tháng
=> Ngày đáo hạn : =?
dùng công thức nào ạ
----------------------
1 combobox trên form txtngaylamviec thì viết code như nào để khi chạy form txt hiện ra datenow(ngày hiện tại hệ thống)

 

[bebo021999]

=EDATE(A1,3) sẽ trả kết quả ngày này 3 tháng sau của ô A1

 

[thanh260292]

=EDATE(A1,3) sẽ trả kết quả ngày này 3 tháng sau của ô A1

A1;3 mới đúng

Bạn giúp mình lun là Cột Kỳ hạn của mình có nhiều mức 3t,6t,9t,12t,24t thì phải làm như nào
và Ngày đáo hạn phải hiện thị ngày/tháng/năm nữa

 

[hoamattroicoi]

A1;3 mới đúng

Bạn giúp mình lun là Cột Kỳ hạn của mình có nhiều mức 3t,6t,9t,12t,24t thì phải làm như nào
và Ngày đáo hạn phải hiện thị ngày/tháng/năm nữa

Là (A1,3) hay (A1;3) là do định dạng dấu phân cách hàm trong máy tính của bạn thôi, có thể điều chỉnh tùy ý trong Control panel đó.
Kỳ hạn 3T, 6T...thì thay vào Hàm EDATE để tính thôi, sau khi tính thì định dạng lại ô đó kiểu DATE theo cách Vào Menu FORMAT/CELLS/ Thẻ NUMBER/ Chọn DATE

 

[bebo021999]

Nếu A1 chứa ngày bắt đầu, B1 chứa ký hạn dạng 3T,6T,...
=EDATE(A1;--LEFT(B1,LEN(B1)-1))
Định dạng DATE trong thẻ FORMAT (cTRL-1)

 

[thanh260292]

Nếu A1 chứa ngày bắt đầu, B1 chứa ký hạn dạng 3T,6T,...
=EDATE(A1;--LEFT(B1,LEN(B1)-1))
Định dạng DATE trong thẻ FORMAT (cTRL-1)

e làm mà báo lỗi #value!
a chỉnh dùm ạ

http://up.4share.vn/f/6b595c5353525c59/BT2.xlsm

 

[ndu96081631]

e làm mà báo lỗi #value!
a chỉnh dùm ạ

Lúc đầu bạn hỏi vầy:

Bạn giúp mình lun là Cột Kỳ hạn của mình có nhiều mức 3t,6t,9t,12t,24t thì phải làm như nào

Nhưng trong file của bạn thì lại ghi là 3 tháng, 6 tháng, 9 tháng ---> Bạn có thấy bạn hỏi chẳng ăn nhậu gì với dữ liệu thật không?
Trường hợp này thì dùng: =EDATE(E11,LEFT(G11,2))

http://up.4share.vn/f/6b595c5353525c59/BT2.xlsm

Mai mốt đừng gửi lên trang này nữa. Chẳng ai đủ kiên nhẫn để chờ đợi vài phút đâu
Muốn nhanh hãy gửi file trực tiếp lên GPE hoặc www.mediafire.com cũng được

 

[nhung huệ]

mọi người cho e hỏi tí ạ. em muốn tính lượng hàng hóa tiêu thụ trong 1 tháng nhất định thì dùng hàm như thế nào ạ
vd:
a b c
1 loại hàng số lượng thời gian
2 đường 5 1/1/2010
3 sữa 3 2/3/2010
4 đường 4 5/1/2010
bây giờ e muốn tính số đường bán trong tháng 1 thì làm như thế nào ạ?

 

[nhapmon]

thử hàm này

=SUMPRODUCT((A2:A4="đường")*(MONTH(C2:C4)=1)*(B2:B4))

 

[nhung huệ]

thử hàm này

=SUMPRODUCT((A2:A4="đường")*(MONTH(C2:C4)=1)*(B2:B4))

mình thử hàm này rôi nhưng kết quả ra là tổng hàng hóa trong tất cả các tháng chứ không phải riêng tháng 1, mình nghĩ vấn đề không phải hàm mà là do chế độ để ngày tháng không đúng vì mình viết hàm =month(C1) thì kết quả ra là #value nhưng không biết giải quyết thế nào

 

[ndu96081631]

mình thử hàm này rôi nhưng kết quả ra là tổng hàng hóa trong tất cả các tháng chứ không phải riêng tháng 1, mình nghĩ vấn đề không phải hàm mà là do chế độ để ngày tháng không đúng vì mình viết hàm =month(C1) thì kết quả ra là #value nhưng không biết giải quyết thế nào

Mô tả lòng vòng, cuối cùng bạn cũng không đưa file của mình lên ---> Biết cóc khô gì đâu mà giúp

 

[lephuonganh]

Cell F1 được định dạng là "dddd, dd-mm-yyyy". Ngày 1-1-1900 là Chủ Nhật. Trong khi đó lịch trên mạng không chỉ của Hồ Ngọc Đức thì hiển thị đó là thứ Hai. Em nhờ mọi người giải thích hộ

 

[anchoi9]

Nhờ các anh chỉ giúp em cách thêm cột tuần trong sheet data (cột E) theo 52 tuần theo từng năm bên cột ghi chú (file đính kèm)

cảm ơn các anh

file đính kèm

http://www.mediafire.com/view/?3aa6j6zifno48bl

 

[nhapmon]

bạn thử dùng công thức sau
E2=WEEKNUM(D2,1) (tính tuần lể bắt đầu từ ngày cn)
hoặc
E2=INT((D2-WEEKDAY(D2,2)-DATE(YEAR(D2+4-WEEKDAY(D2,2)),1,4))/7)+2 (tính tuần lể bắt đầu từ thứ 2)

có điều mình fai để ở định dạng "mm/dd/yyyy" theo kiểu mỹ nó mới chịu
bạn test thử xem được ko

ah, mình set lại trong control panel được rồi, hàm thứ 2 chạy đúng theo các ví dụ của bạn rùi đó

 

[anchoi9]

Cảm ơn anh rất nhiều

anh thật là siêu đẳng

 

[jakusa]

Các bác cho em hỏi một chút.
Em đang có 1 vấn đề cần lọc dữ liệu sang sheet mới với điều kiện là tuổi của trẻ tính tới ngày hôm nay nhỏ hơn 6 tuổi.
Cho em hỏi thêm là dữ liệu sau khi lọc thì mỗi lần mở file nó sẽ thực hiện hay chỉ thực hiện lọc 1 lần ạ?

 

[leonguyenz]

Các bác cho em hỏi một chút.
Em đang có 1 vấn đề cần lọc dữ liệu sang sheet mới với điều kiện là tuổi của trẻ tính tới ngày hôm nay nhỏ hơn 6 tuổi.
Cho em hỏi thêm là dữ liệu sau khi lọc thì mỗi lần mở file nó sẽ thực hiện hay chỉ thực hiện lọc 1 lần ạ?

Điều kiện (tô màu đỏ) nên bạn phải mở file mới cập nhật (ngày hiện tại lấy theo ngày hệ thống máy tính. Trong file đính kèm có một Name (nhấn Ctrl+F3) để xem.

 

[ndu96081631]

Các bác cho em hỏi một chút.
Em đang có 1 vấn đề cần lọc dữ liệu sang sheet mới với điều kiện là tuổi của trẻ tính tới ngày hôm nay nhỏ hơn 6 tuổi.

Dùng Advanced Filter với công thức điều kiện là: =DATEDIF('du lieu'!$H4,TODAY(),"y")<6

[video=youtube;WjkXahp6GKk]http://www.youtube.com/watch?v=WjkXahp6GKk&feature=youtu.be[/video]

Cho em hỏi thêm là dữ liệu sau khi lọc thì mỗi lần mở file nó sẽ thực hiện hay chỉ thực hiện lọc 1 lần ạ?

Bạn phải tự làm bằng tay thôi, muốn tự động ta lập trình VBA

 

[jakusa]

Cảm ơn sự nhiệt tình giúp đỡ của 2 bác leonguyenz & ndu96081631

 

[minhhoang72]

Tính số ngày tham gia trong từng tháng nếu biết ngày bắt đầu và ngày kết thúc

Các anh chị và các bạn cho mình hỏi chút,

Mình đang có việc phải tính số ngày tham gia của nhân viên. Mình có 1 sheet gồm các cột như sau:

- Ngày bắt đầu tham gia
- Ngày kết thúc
Với dữ liệu input như thế này có thể tính được số ngày tham gia của từng tháng không?

VD với nhân viên tham gia ngày 1-Feb-2012 và kết thúc vào 1-Aug- 2012.

Các anh chị có cách nào vui lòng chỉ mình với.

Xin chân thành cảm ơn!

 

[ndu96081631]

Các anh chị và các bạn cho mình hỏi chút,

Mình đang có việc phải tính số ngày tham gia của nhân viên. Mình có 1 sheet gồm các cột như sau:

- Ngày bắt đầu tham gia
- Ngày kết thúc
Với dữ liệu input như thế này có thể tính được số ngày tham gia của từng tháng không?

VD với nhân viên tham gia ngày 1-Feb-2012 và kết thúc vào 1-Aug- 2012.

Các anh chị có cách nào vui lòng chỉ mình với.

Xin chân thành cảm ơn!

Nếu tôi làm bài này thì đầu tiên tôi sẽ thiết kế lại vùng G3:R3, cụ thể:
- Cell G3, gõ 1-Jan-2012
- Cell H3, gõ 1-Feb-2012
- Quét chọn G3:H3, kéo fill đến R3
- Quét chọn G3:R3, Format Cells với định dạng tùy ý (chẳng hạn là "T"m)
---------------
Xong phần chuẩn bị, giờ là công thức tại G4:

=MAX(MIN(EOMONTH(G$3,0),$F4)-MAX($E4,G$3)+1,0)

kéo fill đến R4

 

[trantuananh]

tính số ngày thứ 7 và chủ nhật trong một khoảng thời gian bằng cách nào vậy các bạn.... mình đã tìm và thử rất nhiều cách nhưng vẫn chưa chính xác, mong các bạn giúp đỡ

 

[ndu96081631]

tính số ngày thứ 7 và chủ nhật trong một khoảng thời gian bằng cách nào vậy các bạn.... mình đã tìm và thử rất nhiều cách nhưng vẫn chưa chính xác, mong các bạn giúp đỡ

Xem bài này nhé:

http://www.giaiphapexcel.com/forum/...-trong-một-quãng-T-G-bất-kỳ&p=16111#post16111
Hoặc công thức "đời mới":

Tính số ngày chủ nhật:      [B]=INT((B2-A2-MOD(B2-[COLOR=#ff0000]1[/COLOR],7)+7)/7)[/B]
Tính số ngày thứ hai:       [B]=INT((B2-A2-MOD(B2-[COLOR=#ff0000]2[/COLOR],7)+7)/7)[/B]
Tính số ngày thứ ba:    [B]    =INT((B2-A2-MOD(B2-[COLOR=#ff0000]3[/COLOR],7)+7)/7)[/B]
Tính số ngày thứ tư:        [B]=INT((B2-A2-MOD(B2-[COLOR=#ff0000]4[/COLOR],7)+7)/7)[/B]
Tính số ngày thứ năm:       [B]=INT((B2-A2-MOD(B2-[COLOR=#ff0000]5[/COLOR],7)+7)/7)[/B]
Tính số ngày thứ sáu:  [B]     =INT((B2-A2-MOD(B2-[COLOR=#ff0000]6[/COLOR],7)+7)/7)[/B]
Tính số ngày thứ bảy:       [B]=INT((B2-A2-MOD(B2-[COLOR=#ff0000]7[/COLOR],7)+7)/7)[/B]

Với A2 là ngày bắt đầu và B2 là ngày kết thúc

Công thức này có thể dễ nhớ hơn

 

[tlrc]

Mình có post nhầm ở topic bên kia, xin Mod xóa hộ, xin post lại ở đây.



Mình bị lỗi khi chuyển đổi ngày tháng trong mail merge giờ không biết phải chỉnh ở đâu cho đúng

Trong Excel, ngày tháng định dạng theo kiểu dd/mm/yyyy, mình muốn chuyển nó sang dạng tiếng anh và còn cẩn thận làm thêm một cột phụ cắt lọc chuyển lại định dạng ngày theo hàm date
10/09/1990 September 10, 1990
17/12/1991 December 17, 1991
19/01/1992 January 19, 1992



Nhưng khi chuyển sang mail merge trong Word, đối với những ngày <=12 thì nó hiểu đảo lại hết, ngày 10/09 nó hiểu thành tháng 10 ngày 09. Những ngày khác thì hiển thị bình thường.
Trong mailmerge mình cũng đã dùng định dạng toogle thế này {MERGEFIELD "DATE" \@ "MMMM dd, yyyy"} nhưng cũng không hiệu quả.

cột bên phải hiển thị bình thường do mình buộc phải đổi định dạng trong excel theo kiểu text bằng cách thêm dấu ' ở đầu '10/09/1990
October 09, 1990 10/09/1990
December 17, 1991 17/12/1991

Mình định làm thủ công bằng các hàm month day... nhưng không dùng được, ví dụ month(mid(A2,4,2)) tương đương với month(7) nhưng kết quả nó cứ trả về 1 chứ không phải là July

có đính kèm tập tin

 

[conangbian]

bạn ơi cho mình hỏi bây giờ mình muốn tính từ ngày 12/05/2010 đến ngày 07/06/2010 là bao nhiêu ngày thì mình dùng hàm hàm nào, sao mình dùng hàm datedif ma fkhoong được
Cảm ơn

 

[nghiaphuc]

bạn ơi cho mình hỏi bây giờ mình muốn tính từ ngày 12/05/2010 đến ngày 07/06/2010 là bao nhiêu ngày thì mình dùng hàm hàm nào, sao mình dùng hàm datedif ma fkhoong được
Cảm ơn

Nếu muốn biết bao nhiêu tháng, bao nhiêu năm hay bao nhiêu ngày lẻ (không tính tháng) thì mới dùng đến DATEDIF chứ nếu chỉ muốn biết bao nhiêu ngày thì cần gì, chỉ cần lấy ngày sau trừ ngày trước là ra thôi mà.

 

[nhocdaudat]

E đang làm xếp loại khách hàng vay vốn

1. Loại A nếu KH trả gốc đúng hạn (hoặc có quá hạn thì không quá 10 ngày) + trả lãi đúng hạn

2. Loại B nếu KH: - TH1 trả gốc đúng hạn nhưng ngày trả lãi quá 3 tháng

- TH2 trả gốc quá hạn từ 10 đến < 30 ngày
3. Loại C nếu KH quá hạn từ 30 đến < 90 ngày

4. Loại D nếu KH quá hạn từ 90 đến < 180 ngày

5. Loại E nếu KH quá hạn > 180 ngày


E có ý tưởng, câu hỏi sau:
- Các điều kiện từ 1-5 của e có thể làm chung một công thức tại một ô trong cột xếp loại KH được không?

- Nếu không được thì a giúp e tách ra xếp loại của việc trả lãi và việc trả gốc sau đó kết hợp hai kết quả đó và đánh giá tổng một cái e vd: Lãi được xếp loại A + gốc loại A --> KH này loại A, còn A-B --> KH này loại B có được không?

E có một file excel e làm a thử xem cho e xem ý tưởng của e như thế có được không? Và e xin nhờ a giúp e hoàn thiện giúp e. E xin chân thành nhờ anh, mong a giúp đỡ e.

E xin chân thành cám ơn anh rất nhiều!

 

[doquoctung]

Nội dung là mình có bảng Excel ngày giờ làm việc hành chính, giờ muốn tính tổng thời gian giải quyết công việc đó trong thời gian bao lâu (tính bằng giờ) mà trong đó một ngày chỉ làm việc 8 giờ từ 8h00 đến16h00. ACE xử lý giúp mình nhé! Thaks!

 

[Lasderybi]

Anh em cho hỏi với ạ. Ví dụ em muốn tính từ 27/01/2018 cộng thêm 45 ngày nữa thì tính kiểu gì ạ? Em cảm ơn.

 

[bactu]

Anh em cho hỏi với ạ. Ví dụ em muốn tính từ 27/01/2018 cộng thêm 45 ngày nữa thì tính kiểu gì ạ? Em cảm ơn.

Ví dụ A1 = 25/01/2018
B1 = A1 + 45
Tại B1 định dạng lại là dd/mm/yyyy

 

[quangtuyen92]

Các bạn giúp mình với mình muốn cột bên trong excel giờ bắt đầu và giờ kết thúc hiện theo số giờ ghi tăng ca ngoài giờ hành chính 07h30-17h00,
vd 1: tài xế tăng ca bắt đầu 06h30 kết thúc 13h00, sẽ sẽ hiện 2 cột là bắt đầu 06h30 kết thúc 07h30
vd 2: bắt đầu 13h00 kết thúc 20h00, sẽ sẽ hiện 2 cột là bắt đầu 1700 kết thúc 20h00

 

[tutoong]

anh huuthang giup em, khi ra viện sẽ được nghỉ thêm ngày, em thêm cột anh giúp em sửa lại hàm để ra số ngày nghỉ với ạ, cho em hỏi thêm tạo form cho dễ nhìn ntn ạ

 

[vitcoipro]

A/C giúp em với ạ!
Em muốn chuyển số thứ tự từ 1-30 (tương ứng với 30 ngày/tháng) sang CN, Thứ 2… thì dùng công thức ntn ạ?

 

[nthxe]

Em chào các bác, Em có đọc topic này khoảng 10 trang nhưng chưa thấy câu trả lời cho vấn đề em đang gặp phải. Nên em đưa luôn câu hỏi nhờ các bác trả lời giúp hoặc chỉ cho em chỗ đã trả lời rồi để em tham khảo. Đa tạ các bác.

Vấn đề của em là:

Em có dữ liệu theo ngày dạng: dd/mm/yyyy hh:mm:ss ví dụ 04/05/2021 18:22:01. Em muốn tính số phút từ thời điểm kia so với thời điểm dd/mm/yyyy 16:50:00 hàng ngày. Như ví dụ kia, kết quả mong muốn trả về là 92 phút (không cần tính số giây ạ)
Kính nhờ các bác trợ giúp ạ

 

[vanthinh3101]

Em chào các bác, Em có đọc topic này khoảng 10 trang nhưng chưa thấy câu trả lời cho vấn đề em đang gặp phải. Nên em đưa luôn câu hỏi nhờ các bác trả lời giúp hoặc chỉ cho em chỗ đã trả lời rồi để em tham khảo. Đa tạ các bác.

Vấn đề của em là:

Em có dữ liệu theo ngày dạng: dd/mm/yyyy hh:mm:ss ví dụ 04/05/2021 18:22:01. Em muốn tính số phút từ thời điểm kia so với thời điểm dd/mm/yyyy 16:50:00 hàng ngày. Như ví dụ kia, kết quả mong muốn trả về là 92 phút (không cần tính số giây ạ)
Kính nhờ các bác trợ giúp ạ

Giả sử có 2 mốc thời gian nằm ở ô A1 và A2
Công thức tính: =CONVERT(A2-A1,"day","mn")

Bạn thử xem ổn không?

 

[Phuocam]

Như ví dụ kia, kết quả mong muốn trả về là 92 phút (không cần tính số giây ạ)

Hên xui?

=(MOD(A1,1)-"16:50:00")*1440

.

 

[nthxe]

Cảm ơn các bác Phuocam và vanthinh3101. Em thử công thức của 2 bác thì ra kết quả 01/04/1900 04:00:00. Có vẻ công thức chưa đúng hoặc em gõ sai công thức. Các bác chỉ giúp em.

Em thử sang công thức khác, nếu A1 (04/05/2021 18:22:01) và B1 chứa kết quả thì em dùng công thức: = A1-Time(16:50:00). Kết quả được là 04/05/2021 01:32:00. Kết quả này đúng ạ.

Tuy nhiên, em muốn bổ sung điều kiện:
- Nếu giá trị giờ, phút, giây ở A1 sớm hơn 16:50:00 thì giá trị trả về bằng 0.
- Nếu là ngày thứ 7 và chủ nhật thì nhân đôi số giờ và phút kết quả ạ

Em chưa làm được điều này, nhờ các bác giúp

 

[nthxe]

Em vẫn chưa giải được bài toán trên, em gửi lại yêu cầu kèm file minh họa, nhờ các bác giải giúp.

Data em có: Giờ vào và giờ ra của nhiều lao động trong nhiều ngày. Em cần tính thời gian làm thêm giờ từng ngày của từng người.

Thời gian làm thêm giờ (theo phút) được tính từ thời điểm 16:50:00 trở đi. Nếu là ngày thứ 7, chủ nhật thì thời gian làm thêm giờ được tính bằng: (Giờ ra - giờ vào) x 2. Kính nhờ các bác trợ giúp. Đa tạ

 

[bebo021999]

C8= 92.17 phút làm tròn là 92

=ROUND((MAX(MOD(B8,1),TIME(16,50,0))-TIME(16,50,0))*1440*(1+(WEEKDAY(B8,2)>5)*2),0)

 

[nthxe]

C8= 92.17 phút làm tròn là 92

=ROUND((MAX(MOD(B8,1),TIME(16,50,0))-TIME(16,50,0))*1440*(1+(WEEKDAY(B8,2)>5)*2),0)

Cảm ơn bác ạ. Bác ơi, nếu là cuối tuần thì thời gian làm thêm được tính bằng: (giờ ra - giờ vào) * 2 ạ.

Em sửa công thức thành:

=IF(WEEKDAY(B8,2)<5,ROUND((MAX(MOD(B8,1),TIME(16,50,0))-TIME(16,50,0))*1440,0),ROUND((B8-A8)*1440,0)*2))

nhưng kết quả báo sai nếu là cuối tuần. Bác chỉnh sửa giúp em với ạ

 

[vanthinh3101]

Cảm ơn bác ạ. Bác ơi, nếu là cuối tuần thì thời gian làm thêm được tính bằng: (giờ ra - giờ vào) * 2 ạ.

Em sửa công thức thành:

=IF(WEEKDAY(B8,2)<5,ROUND((MAX(MOD(B8,1),TIME(16,50,0))-TIME(16,50,0))*1440,0),ROUND((B8-A8)*1440,0)*2))

nhưng kết quả báo sai nếu là cuối tuần. Bác chỉnh sửa giúp em với ạ

Giả sử tôi để giá trị của ô C6 là 16:50:00
Bạn thử công thức cho ô C8 như sau:

C8=IF(WEEKDAY(B8,2)>5,ROUND(CONVERT(B8-A8,"day","mn"),0)*2,IF(MOD(B8,1)<=$C$6,0,ROUND(CONVERT(MOD(B8,1)-$C$6,"day","mn"),0)))

Fill xuống.

 

[bebo021999]

Cảm ơn bác ạ. Bác ơi, nếu là cuối tuần thì thời gian làm thêm được tính bằng: (giờ ra - giờ vào) * 2 ạ.

Em sửa công thức thành:

=IF(WEEKDAY(B8,2)<5,ROUND((MAX(MOD(B8,1),TIME(16,50,0))-TIME(16,50,0))*1440,0),ROUND((B8-A8)*1440,0)*2))

nhưng kết quả báo sai nếu là cuối tuần. Bác chỉnh sửa giúp em với ạ

(1+(WEEKDAY(B8,2)>5)*2
Là cuối tuần x2 rồi đó bạn.

 

[nthxe]

(1+(WEEKDAY(B8,2)>5)*2
Là cuối tuần x2 rồi đó bạn.

Dạ, công thức của bác Vanthinh3101 ở trên đã giải quyết được công việc của em. Em cũng muốn tìm hiểu thêm công thức của bác để hiểu và có thể áp dụng cho những công việc khác. Xin báo chỉ dẫn thêm ạ.

Trong công thức của bác, tính làm thêm cuối tuần vẫn là giờ ra - 16:50:00 trong khi đề bài là giờ vào - giờ ra.

Em có sửa lại công thức thành
=IF(WEEKDAY(B8,2)<5,ROUND((MAX(MOD(B8,1),TIME(16,50,0))-TIME(16,50,0))*1440,0),ROUND((B8-A8)*1440,0)*2))
nhưng ra kết quả sai. Không biết em sai ở đâu ạ?

 

[Phan Thế Hiệp]

Dạ, công thức của bác Vanthinh3101 ở trên đã giải quyết được công việc của em. Em cũng muốn tìm hiểu thêm công thức của bác để hiểu và có thể áp dụng cho những công việc khác. Xin báo chỉ dẫn thêm ạ.

Trong công thức của bác, tính làm thêm cuối tuần vẫn là giờ ra - 16:50:00 trong khi đề bài là giờ vào - giờ ra.

Em có sửa lại công thức thành
=IF(WEEKDAY(B8,2)<5,ROUND((MAX(MOD(B8,1),TIME(16,50,0))-TIME(16,50,0))*1440,0),ROUND((B8-A8)*1440,0)*2))
nhưng ra kết quả sai. Không biết em sai ở đâu ạ?

Thử như vầy:

=ROUND(IF(WEEKDAY(B8,2)>5,(B8-A8)*2,MAX(MOD(B8,1)-"16:50",))*1440,)

Enter, fill xuống.

Thân

 

[HieuCD]

Thử như vầy:

=ROUND(IF(WEEKDAY(B8,2)>5,(B8-A8)*2,(MAX(MOD(B8,1),--"16:50")-"16:50"))*1440,)

Enter, fill xuống.

Thân

Dùng 2 lần "16:50", chơi quá sang

 

[Phan Thế Hiệp]

Dùng 2 lần "16:50", chơi quá sang

Đã là con nhà nghèo mà bày đặt sang chảnh nữa! anh há!

Cảm ơn anh nhiều. (Đã sửa lại bài trên)
Chúc anh ngày thiệt vui.

 

[congthanhhp97]

Các a chị cho em hỏi, em muốn hạn chế thời gian chỉnh sửa của 1 ô trong excel thì làm thế nào ạ. Ví dụ như ô đó là của ngày 26/10 thì đến ngày 27 không chỉnh sửa được nữa
em xin cảm ơn ạ

 

[Ngoc9112]

Mình có thời gian bắt đầu làm việc là 01/04/2021 và ngày kết thúc là 31/12/2021. Mình có viết công thức:
=datedif($D36;$I$6;"y")&" năm " &datedif($D36;$I$6;"ym")&" tháng " &$I$6-date(year($I$6);month($I$6);0)&" ngày "
Nó cho ra kết quả là 0 năm 8 tháng 31 ngày
Làm cách nào để nó ghi thành 0 năm 9 tháng 0 ngày ạ

 

[Ngoc9112]

Số năm = DATEDIF($C20,$D20,"y")
Số tháng = DATEDIF($C20,$D20,"ym")
Số ngày = DATEDIF($C20,$D20,"md")

Rồi nối lại cho theo ý của bạn thôi, nối giúp bạn luôn nhé:
=DATEDIF(C20;D20;"y")&" năm, "&DATEDIF(C20;D20;"ym")&" tháng "&DATEDIF(C20;D20;"md")&" và ngày"

bạn ơi mình làm công thức này với trường hợp 01/04/2021 đến 31/12/2021 nó trả kết quả 0 năm 8 tháng 30 ngày. và đang thiếu 1 ngày thì làm cách nào bạn nhỉ

 

[VetMini]

Khoảng cách giữa 1 và 10 là 9 (10-1)
Từ 1 đến 10 có 10 số (10-1+1)

Muốn tính cách biệt thì trừ thẳng. Muốn tính gộp cả hai đầu thì phải cộng thêm 1.

 

[Ngoc9112]

Khoảng cách giữa 1 và 10 là 9 (10-1)
Từ 1 đến 10 có 10 số (10-1+1)

Muốn tính cách biệt thì trừ thẳng. Muốn tính gộp cả hai đầu thì phải cộng thêm 1.

View attachment 271258

Cám ơn bạn nhiều nhé

 

[Ngoc9112]

Khoảng cách giữa 1 và 10 là 9 (10-1)
Từ 1 đến 10 có 10 số (10-1+1)

Muốn tính cách biệt thì trừ thẳng. Muốn tính gộp cả hai đầu thì phải cộng thêm 1.

View attachment 271258

Bạn ơi, mình bị phát sinh 1 vấn đề
Từ ngày 01/11/2021 đến 31/12/2021 thì nó ra 1 tháng 0 ngày là đúng
Nhưng từ ngày 11/11/2021 đến 31/12/2021 thì nó ra 1 tháng 21 ngày thì bị thừa 1 ngày
Có cách nào để nó không bị lỗi như vậy không

 

[VetMini]

Bạn ơi, mình bị phát sinh 1 vấn đề
Từ ngày 01/11/2021 đến 31/12/2021 thì nó ra 1 tháng 0 ngày là đúng
Nhưng từ ngày 11/11/2021 đến 31/12/2021 thì nó ra 1 tháng 21 ngày thì bị thừa 1 ngày
Có cách nào để nó không bị lỗi như vậy không

Chịu thua. Đối với tôi:
01/11 đến 31/12 phải là 1 tháng 31 ngày mới đúng.
11/11 đến 31/12 thì là 1 tháng 21 ngày đúng rồi. Không thừa ngày nào cả.

Nếu bạn muốn ra con số khác thì bắt buộc phải lập bảng tra. Không tính toán được.

 

[batman1]

Bạn ơi, mình bị phát sinh 1 vấn đề
Từ ngày 01/11/2021 đến 31/12/2021 thì nó ra 1 tháng 0 ngày là đúng
Nhưng từ ngày 11/11/2021 đến 31/12/2021 thì nó ra 1 tháng 21 ngày thì bị thừa 1 ngày
Có cách nào để nó không bị lỗi như vậy không

Đó không phải là lỗi. Mỗi người tự lập cho mình một qui tắc rồi tự xoay xở sao cho đúng qui tắc của mình là được.

Qui tắc của tôi là: TOÀN BỘ ngày bắt đầu, TOÀN BỘ ngày tiếp theo, ...., TOÀN BỘ ngày cuối cùng. Nó tương đương với: tính từ 0 giờ ngàu bắt đầu tới 24 giờ ngày cuối cùng.

Nếu theo qui tắc của tôi thì bạn cầm một hộp diêm rồi đếm: TOÀN BỘ ngày 11/11/2021, TOÀN BỘ ngày tiếp theo, ...., TOÀN BỘ ngày 31/12/2021. Tổng cộng 21 ngày.

 

[Ngoc9112]

Chịu thua. Đối với tôi:
01/11 đến 31/12 phải là 1 tháng 31 ngày mới đúng.
11/11 đến 31/12 thì là 1 tháng 21 ngày đúng rồi. Không thừa ngày nào cả.

Nếu bạn muốn ra con số khác thì bắt buộc phải lập bảng tra. Không tính toán được.

mình viết sai kết quả của 01/11/2021 đến 31/12/2021 nó ra đáp án là 2 tháng 0 ngày

Còn cách bạn nói mình hiểu là 1 tháng là 30 ngày nên 11/11 đến 31/12 là 1 tháng 21 ngày

Cám ơn bạn đã giúp đỡ nhé

 

[vanle33]

Tôi muốn tính đúng ra số năm sinh ở cột O tương ứng với các cell bôi nền vàng cột B. Mong các thành viên trợ giúp. Xin cảm ơn.

 

[cantl]

Tôi muốn tính đúng ra số năm sinh ở cột O tương ứng với các cell bôi nền vàng cột B. Mong các thành viên trợ giúp. Xin cảm ơn.

Cái gì kỳ vậy, gạo cội mà ta.

Sai chính tả thôi, I N T chứ không phải L E N.

=--IF(LEN(C15)>=9,YEAR(C15),RIGHT(C15,4))
→→→
=--IF(INT(C15)>=9,YEAR(C15),RIGHT(C15,4))

 

[vanle33]

Cái gì kỳ vậy, gạo cội mà ta.

Sai chính tả thôi, I N T chứ không phải L E N.

=--IF(LEN(C15)>=9,YEAR(C15),RIGHT(C15,4))
→→→
=--IF(INT(C15)>=9,YEAR(C15),RIGHT(C15,4))

Cảm ơn bạn. Gạo cội ra mỗi công thức ở cột O đấy bạn. kakaka.

 

[Phuocam]

Tôi muốn tính đúng ra số năm sinh ở cột O tương ứng với các cell bôi nền vàng cột B. Mong các thành viên trợ giúp. Xin cảm ơn.

Có thể dùng: =--IF(LEN(C15)<8,YEAR(C15),RIGHT(C15,4))

Hoặc ngắn hơn: =--RIGHT(TEXT(C15,"d/m/yyyy"),4)
.

 

[vanle33]

@cantl @Phuocam : Sử dụng 3 công thức trên cho toàn bộ cell từ O15 đến O1014 thì ra lỗi là có 250 dòng ra kết quả là 1905. Hai bạn và các thành viên có cách nào để sử dụng cho toàn bộ cell trên để ra kết quả đúng không?

 

[Phuocam]

@cantl @Phuocam : Sử dụng 3 công thức trên cho toàn bộ cell từ O15 đến O1014 thì ra lỗi là có 250 dòng ra kết quả là 1905. Hai bạn và các thành viên có cách nào để sử dụng cho toàn bộ cell trên để ra kết quả đúng không?

Thử lại lần nữa:

=--IF(C15-2024<0,C15,RIGHT(TEXT(C15,"d/m/yyyy"),4))

bởi vì có một số dòng chỉ có năm sinh.

 

[cantl]

@cantl @Phuocam : Sử dụng 3 công thức trên cho toàn bộ cell từ O15 đến O1014 thì ra lỗi là có 250 dòng ra kết quả là 1905. Hai bạn và các thành viên có cách nào để sử dụng cho toàn bộ cell trên để ra kết quả đúng không?

Sửa INT xong thì sửa tiếp 9 thành 10000 nhé.

 

[cantl]

1905

Hic, không hiểu tại sao sửa 10000 mà kết quả đúng hết. Hóa ra,
15/02/1978 là ngày.
04/01/1926 là chữ.
Bao nhiêu năm gạo cội thành gạo nứt zồi.

Vậy nên công thức điều chỉnh tí nhé:
=--IF(INT(C15)>=2100,YEAR(C15),RIGHT(C15,4))

2100 là năm dự kiến mà đồng chí còn tồn tại trên đời nhé, suy nghĩ kỹ rồi đặt phím vào.

 

[vanle33]

Hic, không hiểu tại sao sửa 10000 mà kết quả đúng hết. Hóa ra,
15/02/1978 là ngày.
04/01/1926 là chữ.
Bao nhiêu năm gạo cội thành gạo nứt zồi.

Vậy nên công thức điều chỉnh tí nhé:
=--IF(INT(C15)>=2100,YEAR(C15),RIGHT(C15,4))

2100 là năm dự kiến mà đồng chí còn tồn tại trên đời nhé, suy nghĩ kỹ rồi đặt phím vào.

Cảm ơn bạn. 2100 là dành cho những người trong Danh sách ở #590

 

[tieuthubuongbinh]

Mình cần đếm tháng, nếu trừ nhau thì ra 7 tháng, nhưng mình muốn đếm luôn tháng đầu, ý là tháng 2 là tháng thứ 1, tháng 9 là tháng thứ 8, thì cần sửa CT như nào [ =DATEDIF(A45,B45,"M")+1 ] để ko dùng +1, nhờ mọi người giúp giùm

 

[VetMini]

Theo toán học thì kết quả của con toán trừ là difference (viết theo phản phản xạ) chỉ gộp cái minuend chứ không gộp cái subtrahend.
Như vậy, từ 2 lên 9 chỉ có 3,4,5,6,7,8,9 chứ không có 2. Nói cách khác 9 chỉ differs from 2 ở chỗ kể từ số 3 đến 9.

Nhưng không sao, chúng ta có hàm edate:
=DATEDIF(EDATE(A45,-1),B45,"M")
hoàn toàn không (từ này thì khỏi phản phản xạ) có bóng dáng +1 nhé.