Đếm giá trị không tính giá trị trùng (1 người xem)

[Phamanh1998]

EM xin phép chào cá nhà. Hiện nay em đang cần đếm giá trị không trùng nhau trong bảng dữ liệu kèm theo truy xuất top 3 nhân viên xuất sắc nhất mà chưa biết làm thế nào, em mong được anh chị giúp đỡ ạ. Em chân thành cảm ơn
Câu 1,2: Đếm số lượng nhân viên trên cùng địa bàn bỏ qua giá trị trùng nhau em dùng hàm SUMPRODUCT với COUNTIF cho kết quả chưa chính xác
Cấu 3: Em chưa làm được ạ .

 

[Nhattanktnn]

EM xin phép chào cá nhà. Hiện nay em đang cần đếm giá trị không trùng nhau trong bảng dữ liệu kèm theo truy xuất top 3 nhân viên xuất sắc nhất mà chưa biết làm thế nào, em mong được anh chị giúp đỡ ạ. Em chân thành cảm ơn
Câu 1,2: Đếm số lượng nhân viên trên cùng địa bàn bỏ qua giá trị trùng nhau em dùng hàm SUMPRODUCT với COUNTIF cho kết quả chưa chính xác
Cấu 3: Em chưa làm được ạ .

Bạn thêm cái ID không trùng cho nhân viên rồi tính tiếp nhé, bạn tên "Anh" người khác cũng tên "Anh" là chuyện rất thường

 

[bebo021999]

J7, Đếm:

=SUM(IF($C$2:$C$31="HN",IF($D$2:$D$31="TP",1/COUNTIFS($C$2:$C$31,"HN",$D$2:$D$31,"TP",$B$2:$B$31,$B$2:$B$31),0),0))

Ctrl-shift-enter.
J10, Tìm:

=LOOKUP(2,1/($E$2:$E$31+ROW($E$2:$E$31)*10^-6=AGGREGATE(14,6,($E$2:$E$31+ROW($E$2:$E$31)*10^-6)/($C$2:$C$31="HN")/($D$2:$D$31="NV"),ROW(1:1))),$B$2:$B$31)

 

[bebo021999]

Bạn thêm cái ID không trùng cho nhân viên rồi tính tiếp nhé, bạn tên "Anh" người khác cũng tên "Anh" là chuyện rất thường

Bài tập của thầy mà. Công nhận thầy nào ra đề ác ghê, chắc cũng là thành viên của GPE.

 

[phuongvq123]

Bạn thêm cái ID không trùng cho nhân viên rồi tính tiếp nhé, bạn tên "Anh" người khác cũng tên "Anh" là chuyện rất thường

Bài tập hay, mỗi tội không có ID nên không thực tế

 

[Phamanh1998]

Bạn thêm cái ID không trùng cho nhân viên rồi tính tiếp nhé, bạn tên "Anh" người khác cũng tên "Anh" là chuyện rất thường

Em chào anh, em có thiếu sót khi bỏ qua mã NV ạ, em đã bổ sung mã nhân viên, em mong anh chị giúp đỡ em 3 câu trong file đính kèm ạ. Em chân thành cảm ơn

Bài đã được tự động gộp: 27/11/20

J7, Đếm:

=SUM(IF($C$2:$C$31="HN",IF($D$2:$D$31="TP",1/COUNTIFS($C$2:$C$31,"HN",$D$2:$D$31,"TP",$B$2:$B$31,$B$2:$B$31),0),0))

Ctrl-shift-enter.
J10, Tìm:

=LOOKUP(2,1/($E$2:$E$31+ROW($E$2:$E$31)*10^-6=AGGREGATE(14,6,($E$2:$E$31+ROW($E$2:$E$31)*10^-6)/($C$2:$C$31="HN")/($D$2:$D$31="NV"),ROW(1:1))),$B$2:$B$31)

Anh xem lại cấu 3 giúp em ạ vì em thử chạy kết quả chưa ra đúng yêu cầu ạ, em cảm ơn anh

 

[Nhattanktnn]

em đã bổ sung mã nhân viên

Ở đâu mà tôi không thấy nhỉ

 

[Phamanh1998]

Ở đâu mà tôi không thấy nhỉ

Hix em có đính kèm file ạ. Em gửi anh file, mong được anh hỗ trợ ạ

 

[leonguyenz]

Hix em có đính kèm file ạ. Em gửi anh file, mong được anh hỗ trợ ạ

Công thức K3:

=SUMPRODUCT(N(FREQUENCY(MATCH($C$2:$C$31,$C$2:$C$31,)*($D$2:$D$31=K2),ROW($1:$30))>0))

Công thức K7:

=SUMPRODUCT(N(FREQUENCY(MATCH($C$2:$C$31,$C$2:$C$31,)*($D$2:$D$31=K6)*($E$2:$E$31="TP"),ROW($1:$30))>0))

 

[leonguyenz]

Câu 3, tìm NV có Doanh số lớn nhất ở HN, kéo xuống, (phiên bản Excel 2010+)

=INDEX($C$2:$C$31,MATCH(AGGREGATE(14,6,($F$2:$F$31)/($D$2:$D$31="HN"),ROW(1:1)),$F$2:$F$31,0))

Nếu phiên bản Excel dưới 2010 thì dùng công thức sau:

=INDEX($C$2:$C$31,MATCH(LARGE(INDEX(($D$2:$D$31="HN")*$F$2:$F$31,0),ROW(1:1)),$F$2:$F$31,0))

Tên NV thì dùng VLOOKUP là được.

 

[Nhattanktnn]

Hix em có đính kèm file ạ. Em gửi anh file, mong được anh hỗ trợ ạ

Cũng có thể thế này:

K3=SUMPRODUCT((1/COUNTIFS(C2:C31,C2:C31,D2:D31,D2:D31))*(D2:D31="HN"))
K7=SUMPRODUCT((1/COUNTIFS(C2:C31,C2:C31,D2:D31,D2:D31,E2:E31,E2:E31))*(D2:D31="HN")*(E2:E31="TP"))
K11=INDEX($C$2:$C$31,MATCH(1,FREQUENCY(0,1/$F$2:$F$31-COUNTIF($K$10:K10,$C$2:$C$31)),0))

 

[bebo021999]

Anh xem lại cấu 3 giúp em ạ vì em thử chạy kết quả chưa ra đúng yêu cầu ạ, em cảm ơn anh

Kết quả đây sai chỗ nào bạn? điều kiện là "HN" và "NV" đúng không?

 

[Phamanh1998]

Công thức K3:

=SUMPRODUCT(N(FREQUENCY(MATCH($C$2:$C$31,$C$2:$C$31,)*($D$2:$D$31=K2),ROW($1:$30))>0))

Công thức K7:

=SUMPRODUCT(N(FREQUENCY(MATCH($C$2:$C$31,$C$2:$C$31,)*($D$2:$D$31=K6)*($E$2:$E$31="TP"),ROW($1:$30))>0))

Em cảm ơn anh ạ

Bài đã được tự động gộp: 27/11/20

Kết quả đây sai chỗ nào bạn? điều kiện là "HN" và "NV" đúng không?

Dạ vâng ạ, vì em cần tìm ba nhân viên có doanh thu lớn nhất tại khu vực HN ạ

Bài đã được tự động gộp: 27/11/20

Cũng có thể thế này:

K3=SUMPRODUCT((1/COUNTIFS(C2:C31,C2:C31,D2:D31,D2:D31))*(D2:D31="HN"))
K7=SUMPRODUCT((1/COUNTIFS(C2:C31,C2:C31,D2:D31,D2:D31,E2:E31,E2:E31))*(D2:D31="HN")*(E2:E31="TP"))
K11=INDEX($C$2:$C$31,MATCH(1,FREQUENCY(0,1/$F$2:$F$31-COUNTIF($K$10:K10,$C$2:$C$31)),0))

Em cảm ơn anh nhiều ạ

 

[bebo021999]

Cũng có thể thế này:
...

Câu 3, tìm NV có Doanh số lớn nhất ở HN, kéo xuống, (phiên bản Excel 2010+)
...

Hai đồng chí:
1- Đọc kỹ đề là có điều kiện "Nhân viên" nhé
2- Nếu Doanh số trùng thì bỏ sót người thứ hai.

 

[bebo021999]

Dạ vâng ạ, vì em cần tìm ba nhân viên có doanh thu lớn nhất tại khu vực HN ạ

Kết quả vầy có đúng không? Bạn mong muốn số nào?

 

[Phamanh1998]

Kết quả vầy có đúng không? Bạn mong muốn số nào?

View attachment 250130

Dạ do câu văn em ghi không rõ ràng, ý em ở đây tức là 3 người doanh thu cao nhất ạ không phân biệt chức vụ, hjx. Em cảm ơn anh

 

[VetMini]

Bài tập hay, mỗi tội không có ID nên không thực tế

HAY? Nhìn vào muốn bịnh.
Đến bào #16 mà vẫn thấy chưa xong. Chứng tỏ là bài rất LỦNG CỦNG.

 

[hocexcel_1991]

EM xin phép chào cá nhà. Hiện nay em đang cần đếm giá trị không trùng nhau trong bảng dữ liệu kèm theo truy xuất top 3 nhân viên xuất sắc nhất mà chưa biết làm thế nào, em mong được anh chị giúp đỡ ạ. Em chân thành cảm ơn
Câu 1,2: Đếm số lượng nhân viên trên cùng địa bàn bỏ qua giá trị trùng nhau em dùng hàm SUMPRODUCT với COUNTIF cho kết quả chưa chính xác
Cấu 3: Em chưa làm được ạ .

Bạn nên dùng PivotTable, chỉ cần kéo thả, lọc theo điều kiện là được

 

[Nhattanktnn]

Đọc kỹ đề là có điều kiện "Nhân viên" nhé

Nhanh nhẩu ẩu đoảng thật bác ạ

3 người doanh thu cao nhất ạ không phân biệt chức vụ

K11=INDEX($C$2:$C$31,MATCH(1,FREQUENCY(0,1/$F$2:$F$31-(COUNTIF($K$10:K10,$C$2:$C$31)+($D$2:$D$31<>"HN"))),0))

 

[Phamanh1998]

Bạn nên dùng PivotTable, chỉ cần kéo thả, lọc theo điều kiện là được
View attachment 250133

Dạ, tại em đang học Exel để phục vụ công việc nên muốn tập luyện các vấn đề trong công việc cần giải quyết qua hàm ạ