Xin tư vấn cách dò tìm số liệu theo 3 điều kiện đầu vào

[vinhtamqb]

Em đang lập 1 form bảng tính mà khi nhập 3 điều kiện vào các cột: E, J và K thì yêu cầu phải viết hàm ở cột L để lấy đúng số liệu yêu cầu từ 3 điều kiện đó theo dữ liệu ở sheet Data. Em đính kèm file mang các bác vui lòng xem chỉ giùm em.

 

[ThuNghi]

Em đang lập 1 form bảng tính mà khi nhập 3 điều kiện vào các cột: E, J và K thì yêu cầu phải viết hàm ở cột L để lấy đúng số liệu yêu cầu từ 3 điều kiện đó theo dữ liệu ở sheet Data. Em đính kèm file mang các bác vui lòng xem chỉ giùm em.

Vậy hỏi bạn điều này:
1/ "Cắt Piping vật liệu CS" có phải Mã hiệu là BA... và "Lắp Ống nối Ống, Ống nối Reducer vật liệu CS" là BB...
2/ Phần dòng mã hiệu: 10S--10-....- XXS của 2 phần có giống nhau và là duy nhất?
Tôi thiết kế data lại 1 chút nhé
Cám ơn bạn!
Bạn xem thử file nhé, do làm vội nên ct hơi dài và chưa test.

 

[dat_butmuc]

Em đang lập 1 form bảng tính mà khi nhập 3 điều kiện vào các cột: E, J và K thì yêu cầu phải viết hàm ở cột L để lấy đúng số liệu yêu cầu từ 3 điều kiện đó theo dữ liệu ở sheet Data. Em đính kèm file mang các bác vui lòng xem chỉ giùm em.

Tại Ô L8 của Sheet "Bang tinh..." bạn dùng công thức sau:
=INDEX('Data DM Piping'!$D$4:$S$65,MATCH('Bang tinh LSX P&M'!$J8,'Data DM Piping'!$B$4:$B$65,0)+MATCH($E8,'Data DM Piping'!$A$1:$A$65,0)-1,MATCH($K8,'Data DM Piping'!$D$3:$S$3,0))

Hoặc:
=HLOOKUP(K8,'Data DM Piping'!$D$3:$S$65,MATCH('Bang tinh LSX P&M'!$J8,'Data DM Piping'!$B$4:$B$65,0)+MATCH($E8,'Data DM Piping'!$A$1:$A$65,0),0)

 

[huuthang_bd]

Em đang lập 1 form bảng tính mà khi nhập 3 điều kiện vào các cột: E, J và K thì yêu cầu phải viết hàm ở cột L để lấy đúng số liệu yêu cầu từ 3 điều kiện đó theo dữ liệu ở sheet Data. Em đính kèm file mang các bác vui lòng xem chỉ giùm em.

Bạn dùng công thức này thử xem:

L8=VLOOKUP(J8,CHOOSE((E8='Data DM Piping'!$A$1)+1,'Data DM Piping'!$B$36:$S$65,'Data DM Piping'!$B$3:$S$32),MATCH(K8,CHOOSE((E8='Data DM Piping'!$A$1)+1,'Data DM Piping'!$B$36:$S$36,'Data DM Piping'!$B$3:$S$3),0),)

 

[vinhtamqb]

Tại Ô L8 của Sheet "Bang tinh..." bạn dùng công thức sau:
=INDEX('Data DM Piping'!$D$4:$S$65,MATCH('Bang tinh LSX P&M'!$J8,'Data DM Piping'!$B$4:$B$65,0)+MATCH($E8,'Data DM Piping'!$A$1:$A$65,0)-1,MATCH($K8,'Data DM Piping'!$D$3:$S$3,0))

Hoặc:
=HLOOKUP(K8,'Data DM Piping'!$D$3:$S$65,MATCH('Bang tinh LSX P&M'!$J8,'Data DM Piping'!$B$4:$B$65,0)+MATCH($E8,'Data DM Piping'!$A$1:$A$65,0),0)

Dear Bác dat_butmuc, bác giúp em xử lý nếu số liệu ở sheet Data DM Piping thay đổi như file này thì làm sao????

 

[huuthang_bd]

Dear Bác dat_butmuc, bác giúp em xử lý nếu số liệu ở sheet Data DM Piping thay đổi như file này thì làm sao????

Thì làm công thức như bài #4

 

[dat_butmuc]

Dear Bác dat_butmuc, bác giúp em xử lý nếu số liệu ở sheet Data DM Piping thay đổi như file này thì làm sao????

Thì dùng:
=INDEX('Data DM Piping'!$D$4:$S$65,MATCH($J8,'Data DM Piping'!$B$4:$B$65,0)+MATCH($E8,'Data DM Piping'!$A$1:$A$65,0)-1,MATCH($K8,OFFSET('Data DM Piping'!$D$3,MATCH($E8,'Data DM Piping'!$A$1:$A$65,0)-1,,,16),0))

Hoặc, càng ngắn gọn hơn:
=HLOOKUP(K8,OFFSET('Data DM Piping'!$D$3,MATCH($E8,'Data DM Piping'!$A$1:$A$65,0)-1,,29,16),MATCH($J8,'Data DM Piping'!$B$4:$B$32,0)+1,0)

 

[vinhtamqb]

Thank bác nhiều, em dùng công thức sau ngắn gọn mà đúng theo yêu cầu.