Xin hỏi về hàm if and ạ (1 người xem)

[Quy$^$]

Nhờ các bạn xem giúp mình hàm if and này mình sai ở đâu mà trả kết quả sai với ạ, xin cảm ơn mọi người.

 

[thuytrangbp28]

Bạn sửa công thức ở I3 thành thế này xem

=IF(H3>=8.5,4,IF(H3>=7,3,IF(H3>=5.5,2,IF(H3>=4,1,0))))

 

[Quy$^$]

Bạn sửa công thức ở I3 thành thế này xem

=IF(H3>=8.5,4,IF(H3>=7,3,IF(H3>=5.5,2,IF(H3>=4,1,0))))

Cảm ơn bạn, mình thử rồi mà không được. Vấn đề có thể nằm ở chỗ điều kiện lấy hai số sau dấu thập phân, ví dụ ô điều kiện H5=8.45 mà trong công thức không thể làm tròn lên 8.50 nên nó hiểu là không thuộc điều kiện trả về kết quả "0.0". Mà mình không biết sửa thế nào. Nếu làm tròn cột H cũng không được. có ai biết chỉ giúp mình nhé, cảm ơn mọi người.

Bài đã được tự động gộp: Thứ hai lúc 16:52

Cảm ơn bạn, mình thử rồi mà không được. Vấn đề có thể nằm ở chỗ điều kiện lấy hai số sau dấu thập phân, ví dụ ô điều kiện H5=8.45 mà trong công thức không thể làm tròn lên 8.50 nên nó hiểu là không thuộc điều kiện nào nên trả về kết quả "0.0". Mà mình không biết sửa thế nào. Nếu làm tròn cột H cũng không được. Nhờ chỉ giúp mình nhé, cảm ơn mọi người.

 

[Hoàng Tuấn 868]

Nếu làm tròn cột H cũng không được.

Bạn đã thử làm tròn cột H chưa mà bảo không được nhỉ?

 

[Quy$^$]

Bạn đã thử làm tròn cột H chưa mà bảo không được nhỉ?

m làm tròn rồi mà kết quả vẫn trả sai b ạ

 

[Hoàng Tuấn 868]

m làm tròn

Câu này nghĩa là gì vậy?

 

[Quy$^$]

Câu này nghĩa là gì vậy?

mình viết đầy đủ mà nhỉ,

 

[Hoàng Tuấn 868]

View attachment 307691
mình viết đầy đủ mà nhỉ,

Câu đầy đủ của bạn đây.

 

[Quy$^$]

Câu đầy đủ của bạn đây.
View attachment 307692

Cảm ơn bạn đã xem bài mình, thực sự là m cũng chưa hiểu ý bạn. Với câu hỏi về hàm "if and" của mình như ở đầu bài nếu được nhờ bạn hỗ trợ nhé, cảm ơn bạn.

 

[lethuy281988]

.

 

[thuytrangbp28]

Cảm ơn bạn, mình thử rồi mà không được.

Trong hình bên dưới là kết quả của công thức mình viết. Theo bạn kết quả sai chỗ nào?

 

[tieutuvodanh192]

Chủ thớt thử công thức này xem sao nha:

=LOOKUP(H3,{0;4;5.5;7;8.5},{0;1;2;3;4})

 

[Phan Thế Hiệp]

Cảm ơn bạn, mình thử rồi mà không được. Vấn đề có thể nằm ở chỗ điều kiện lấy hai số sau dấu thập phân, ví dụ ô điều kiện H5=8.45 mà trong công thức không thể làm tròn lên 8.50 nên nó hiểu là không thuộc điều kiện nào nên trả về kết quả "0.0". Mà mình không biết sửa thế nào. Nếu làm tròn cột H cũng không được. Nhờ chỉ giúp mình nhé, cảm ơn mọi người.

1/ Nếu sửa công thức của bạn thì phải như vầy:
=IF(H5>=8.5,"4.0",IF(AND(H5>=7,H5<8.5),"3.0",IF(AND(H5>=5.5,H5<7),"2.0",IF(AND(H5>=4,H5<5.5),"1.0","0.0"))))

2/ Bạn lúng túng trong việc xác định các mốc để so sánh, cho nên đặt công thức dư thừa hàm AND(...), cụ thể:
- Mốc 1: nếu "số cần so" >=8.5, "đúng" thì kết quả 4, "sai" thì thực hiện If("mốc 2").
- Mốc 2: ở đây chỉ cần lập duy nhất điều kiện "số cần so" >=7 thôi, vì mốc 1 đã khống chế các số >=8.5 rồi, nên các số từ >=7 và <8.5 sẽ rơi vào trường hợp xét tại mốc này. Do đó bạn không cần thêm hàm AND(H5>=7,H5<8.5).

Tương tự cho các mốc còn lại phía sau.

Vậy, công thức của bạn sẽ giản lược lại và giống như bạn bài #2 đã làm:
=IF(H5>=8.5,4,IF(H5>=7,3,IF(H5>=5.5,2,IF(H5>=4,1,0))))

3/ Ngoài ra, bạn có thể tham khảo thêm hàm Match(), hoặc Sum(), như sau:
=MATCH(H3,{0,4,5.5,7,8.5})-1
=SUM(--(H3>={4,5.5,7,8.5}))

Thân

 

[Quy$^$]

1/ Nếu sửa công thức của bạn thì phải như vầy:
=IF(H5>=8.5,"4.0",IF(AND(H5>=7,H5<8.5),"3.0",IF(AND(H5>=5.5,H5<7),"2.0",IF(AND(H5>=4,H5<5.5),"1.0","0.0"))))

2/ Bạn lúng túng trong việc xác định các mốc để so sánh, cho nên đặt công thức dư thừa hàm AND(...), cụ thể:
- Mốc 1: nếu "số cần so" >=8.5, "đúng" thì kết quả 4, "sai" thì thực hiện If("mốc 2").
- Mốc 2: ở đây chỉ cần lập duy nhất điều kiện "số cần so" >=7 thôi, vì mốc 1 đã khống chế các số >=8.5 rồi, nên các số từ >=7 và <8.5 sẽ rơi vào trường hợp xét tại mốc này. Do đó bạn không cần thêm hàm AND(H5>=7,H5<8.5).

Tương tự cho các mốc còn lại phía sau.

Vậy, công thức của bạn sẽ giản lược lại và giống như bạn bài #2 đã làm:
=IF(H5>=8.5,4,IF(H5>=7,3,IF(H5>=5.5,2,IF(H5>=4,1,0))))

3/ Ngoài ra, bạn có thể tham khảo thêm hàm Match(), hoặc Sum(), như sau:
=MATCH(H3,{0,4,5.5,7,8.5})-1
=SUM(--(H3>={4,5.5,7,8.5}))

Thân

Câu trả lời thật chi tiết và dễ hiểu. Mình đã hiểu và làm được. Cảm ơn bạn nhiều!