Xin hỏi công thức tách chuỗi ký tự ra khỏi dãy ký tự

[KhoiSMC]

Kính gửi anh em,

Xin hỏi tôi có các chuỗi ký tự bất kỳ như sau:
ô A1 = 25FS+36
ô A2 = 63SS+96
ô A3 = 65FS -35

Mong muốn tạo công thức excel nào tách được ra kết quả như sau:
ô B1 = FS
ô B2 = SS
ô B3 = FS

 

[Nhattanktnn]

Kính gửi anh em,

Xin hỏi tôi có các chuỗi ký tự bất kỳ như sau:
ô A1 = 25FS+36
ô A2 = 63SS+96
ô A3 = 65FS -35

Mong muốn tạo công thức excel nào tách được ra kết quả như sau:
ô B1 = FS
ô B2 = SS
ô B3 = FS

Nếu chuẩn như dữ liệu đưa ra thì tại B1 dùng hàm:

=MID(A1,3,2)

Nếu không chuẩn thì anh hãy đưa đầy đủ các kiểu dữ liệu lên đây

 

[KhoiSMC]

oh cảm ơn bạn nhưng số có thể biến động bạn ạ
ví dụ
A4 = 1FS+362
A5 = 123SS+32
A6 = 2364SF-362

 

[Phuocam]

oh cảm ơn bạn nhưng số có thể biến động bạn ạ
ví dụ
A4 = 1FS+362
A5 = 123SS+32
A6 = 2364SF-362

1. Ký tự luôn hoa, hay vừa hoa vừa thường?

2. Phiên bản excel của bạn là 365?

.

 

[Nhattanktnn]

oh cảm ơn bạn nhưng số có thể biến động bạn ạ
ví dụ
A4 = 1FS+362
A5 = 123SS+32
A6 = 2364SF-362

Vậy thì bạn đưa vào file, nhiều kiểu dữ liệu như mình nói rồi tính tiếp nha

 

[KhoiSMC]

1. Ký tự luôn hoa, hay vừa hoa vừa thường?

2. Phiên bản excel của bạn là 365?

.

- Ký tự luôn hoa ạ
- Phiên bản tôi dùng là 365

 

[hocexcel_1991]

- Ký tự luôn hoa ạ
- Phiên bản tôi dùng là 365

Thử dùng công thức sau:

=MAP(A2:A4,LAMBDA(a,LET(m,MID(a,SEQUENCE(LEN(a)),1),ch,CHAR(SEQUENCE(26,,65)),CONCAT(XLOOKUP(m,ch,ch,"")))))

 

[Phuocam]

- Ký tự luôn hoa ạ
- Phiên bản tôi dùng là 365

Hoặc thử :

TEXTJOIN("";1 ;IF( ABS(CODE(MID(A1;SEQUENCE(LEN(A1));1))-77,5)<13;MID(A1;SEQUENCE(LEN(A1));1);""))

 

[KhoiSMC]

Vậy thì bạn đưa vào file, nhiều kiểu dữ liệu như mình nói rồi tính tiếp nha

Mình đã đưa file lên rồi ạ

 

[Nhattanktnn]

Mình đã đưa file lên rồi ạ

Công thức tại B2:

=TRIM(MID(SUBSTITUTE(SUBSTITUTE(MID(A2,MATCH(FALSE,INDEX(ISNUMBER(--MID(A2,ROW($A$1:$A$99),1)),),0),20),"+","-"),"-",REPT(" ",99)),1,99))

 

[KhoiSMC]

Hoặc thử :

TEXTJOIN("";1 ;IF( ABS(CODE(MID(A1;SEQUENCE(LEN(A1));1))-77,5)<13;MID(A1;SEQUENCE(LEN(A1));1);""))

bạn giúp mình thử đưa vào dữ liệu của mình xem nhé.
Mình đưa công thức vào mà không được.

 

[Phuocam]

bạn giúp mình thử đưa vào dữ liệu của mình xem nhé.
Mình đưa công thức vào mà không được.

Thử thay dấu chấm phẩy bằng dấu phẩy xem sao.

.

 

[KhoiSMC]

Công thức tại B2:

=TRIM(MID(SUBSTITUTE(SUBSTITUTE(MID(A2,MATCH(FALSE,INDEX(ISNUMBER(--MID(A2,ROW($A$1:$A$99),1)),),0),20),"+","-"),"-",REPT(" ",99)),1,99))

ồ công thức này work rồi bạn ạ
Cảm ơn bạn nhiều nhé.

 

[VetMini]

Công nhận nhìn hàm khủng lạnh cả ngươi.

Mình chỉ giản dị Flash Fill thôi Trước khi làm, dời cột "kết quả mong muốn" sang chỗ khác, kẻo nó gây ngộ nhận cho Flash Fill):

 

[KhoiSMC]

Xin phép được nhờ sự trợ giúp thêm của các pro với ạ,



Có hàm nào tách được như vậy không ạ?

 

[NT Ngoc Yen]

Kính gửi anh em,

Xin hỏi tôi có các chuỗi ký tự bất kỳ như sau:
ô A1 = 25FS+36
ô A2 = 63SS+96
ô A3 = 65FS -35

Mong muốn tạo công thức excel nào tách được ra kết quả như sau:
ô B1 = FS
ô B2 = SS
ô B3 = FS

Thử công thức này:
B2=MID(A2,IFERROR(FIND("+",A2),(FIND("-",A2)))-2,2)

 

[KhoiSMC]

Cảm ơn bạn phản hồi

Thử công thức này:
B2=MID(A9,IFERROR(FIND("+",A9),FIND("-",A9))-2,2)

,

ý mình muốn hỏi bài toán này cơ ạ

 

[Phuocam]

Có hàm nào tách được như vậy không ạ?

Thử công thức này:

=--REPLACE(A2,1,AGGREGATE(14,6,FIND({"+","-"},A2),1)-1,"")

.

 

[KhoiSMC]

Thử công thức này:

=--REPLACE(A2,1,AGGREGATE(14,6,FIND({"+","-"},A2),1)-1,"")

.

được rồi bạn ạ nhưng công thức không có dấu -- ở sau dấu = thì chạy ạ

 

[NT Ngoc Yen]

Xin phép được nhờ sự trợ giúp thêm của các pro với ạ,

View attachment 287474

Có hàm nào tách được như vậy không ạ?

Thử công thức này:
B2=--RIGHT(A2,LEN(A2)-IFERROR(FIND("+",A2),(FIND("-",A2)))+1)