Tô màu ký tự trong dấu ngoặc

[hungdiep85]

Chào các Anh Chị trên diễn đàn

giúp em đoạn code tô màu ký tự trong dấu ngoặc ( ** ).

em cảm ơn các Anh Chị trước ạ

 

[huuthang_bd]

Chọn vùng muốn áp dụng và chạy code.

Sub ToMau()
Dim Cll As Range, Val As String, Pos1 As Long, Pos2 As Long
For Each Cll In Selection
    Val = Cll.Value
    Pos1 = InStr(Val, "(")
    Do While Pos1 > 0
        Pos2 = InStr(Pos1, Val, ")")
        If Pos2 = 0 Then Exit Do
        Cll.Characters(Pos1 + 1, Pos2 - Pos1 - 1).Font.Color = vbRed
        Pos1 = InStr(Pos2, Val, "(")
    Loop
Next
End Sub

 

[Cu Tồ]

Mình mới học Góp vui nha！

Bài đã được tự động gộp: 16/10/20

Chọn vùng muốn áp dụng và chạy code.

Sub ToMau()
Dim Cll As Range, Val As String, Pos1 As Long, Pos2 As Long
For Each Cll In Selection
    Val = Cll.Value
    Pos1 = InStr(Val, "(")
    Do While Pos1 > 0
        Pos2 = InStr(Pos1, Val, ")")
        If Pos2 = 0 Then Exit Do
        Cll.Characters(Pos1 + 1, Pos2 - Pos1 - 1).Font.Color = vbRed
        Pos1 = InStr(Pos2, Val, "(")
    Loop
Next
End Sub

Nhìn code của Bác xong quay qua nhìn cái code của em. thấy code em củ chuối quá

 

[HeSanbi]

Bạn tham khảo Hàm được viết bằng VBA trong tệp dưới đây:

Bạn sử dụng công thức:
=S_FindHL("\((.*?)\)",C3:C10000,1,255,FALSE,TRUE)

Công thức trên sử dụng biểu thức chính quy và VBA
Bạn cần có thêm kiến thức biểu thức chính quy nếu muốn ứng dụng thêm vào tìm kiếm chuỗi khác nhau

biểu thức chính quy rất đơn giản

 

[huuthang_bd]

Nhìn code của Bác xong quay qua nhìn cái code của em. thấy code em củ chuối quá

Ai cũng có thuở ban đầu thôi

 

[Cu Tồ]

Ai cũng có thuở ban đầu thôi

vâng em đang chăm lên đây học hỏi code từ mấy bác hihi

 

[Nhattanktnn]

Ai cũng có thuở ban đầu thôi

Bác có thể giúp em cái pattern được không? em xài cái này "(?<=\()(.*?)(?=\))" mà sao không lúc .execute(..) thì nó bị lỗi

 

[batman1]

Bác có thể giúp em cái pattern được không? em xài cái này "(?<=\()(.*?)(?=\))" mà sao không lúc .execute(..) thì nó bị lỗi

Trong mỗi ngôn ngữ hơi khác nhau.

Cái "VBScript.RegExp" mà bạn sử dụng chỉ phục vụ:

1. (?: pattern) - không có dấu cách trước p

2. Zero-width positive lookahead assertion: (?=pattern)

3. Zero-width negative lookahead assertion: (?!pattern)

Cái "VBScript.RegExp" mà bạn sử dụng KHÔNG phục vụ Positive and Negative Lookbehind: (?<=pattern) và (?<!pattern)

Bạn đang dùng dạng (?<=pattern) <- (?<=\()

Tôi cũng thấy buồn là không được dùng (?<=pattern) và (?<!pattern)

Tóm lại thì dùng được lookahead nhưng không được phép dùng̣ Lookbehind

 

[Nhattanktnn]

Trong mỗi ngôn ngữ hơi khác nhau.

Cái "VBScript.RegExp" mà bạn sử dụng chỉ phục vụ:

1. (?: pattern) - không có dấu cách trước p

2. Zero-width positive lookahead assertion: (?=pattern)

3. Zero-width negative lookahead assertion: (?!pattern)

Cái "VBScript.RegExp" mà bạn sử dụng KHÔNG phục vụ Positive and Negative Lookbehind: (?<=pattern) và (?<!pattern)

Bạn đang dùng dạng (?<=pattern) <- (?<=\()

Tôi cũng thấy buồn là không được dùng (?<=pattern) và (?<!pattern)

Cảm ơn bác đã phản hồi!
Em thấy regexp rất thú ví, nhưng "khó" quá
Đối với bài trên, bác có pattern nào xử lý được vấn đề này không chia sẻ cho em học hỏi với ạ

 

[batman1]

Cảm ơn bác đã phản hồi!
Em thấy regexp rất thú ví, nhưng "khó" quá
Đối với bài trên, bác có pattern nào xử lý được vấn đề này không chia sẻ cho em học hỏi với ạ

Thì dùng như HeSanbi giới thiệu thôi chứ xoay xở làm gì nữa? Tức "\((.*?)\)"
-------
Mà thôi, đã nói A thì làm luôn tới Z. Chạy sub test

Sub ToMau(ByVal vung As Range, Optional ByVal mau As Long = 255)
'    Vung: 1 hoặc nhiều cell
'    macro To Mau cac doan trong ngoac. Vd. o co gia tri "Ngay mai (em di). Bien nho (ten em) goi ve" thì 2 doan "Em di" va "ten em" se duoc to mau
Dim s As String, cell_ As Range, match As Object, re As Object
    Set re = CreateObject("VBScript.RegExp")
    With re
        .Global = True
        .Pattern = "\((.*?)\)"
    End With
    For Each cell_ In vung
        s = cell_.Value
        For Each match In re.Execute(s)
            cell_.Characters(match.FirstIndex + 2, match.Length - 2).Font.Color = mau
        Next match
    Next cell_
    Set re = Nothing
End Sub

Sub test()
    ToMau ThisWorkbook.Worksheets("Sheet1").Range("A1:A2"), RGB(0, 0, 255)
End Sub