Tính tổng 1 vài số trong 1 ô

[nonjsc]

Các bạn giúp tôi trong 1 ô 12345678 muốn cộng số 3 đến số 6.Thank you

 

[redeye]

Các bạn giúp tôi trong 1 ô 12345678 muốn cộng số 3 đến số 6.Cảm ơn

Giả sử A1=12345678 thì công thức là:

=SUMPRODUCT(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1)*(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1)*1>=3)*(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1)*1<=6))

 

[befaint]

Các bạn giúp tôi trong 1 ô 12345678 muốn cộng số 3 đến số 6.Cảm ơn

Bắt chước.

=SUMPRODUCT(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1)*(ROW(INDIRECT("1:"&LEN(A1)))>=3)*(ROW(INDIRECT("1:"&LEN(A1)))<=6))

 

[batman1]

Nhiều người không mô tả dữ liệu và chỉ nói nửa câu. Khó mà đoán được trúng ý.
Theo tôi có thể hiểu "muốn cộng số 3 đến số 6" theo 2 cách:
1. Tính tổng các chữ số từ vị trí thứ 3 tới vị trí thứ 6. Có lẽ bạn befaint đã hiểu theo cách này. Nhưng nếu là cách này thì phải phát biểu chính xác là "muốn cộng các chữ số từ vị trí 3 đến vị trí 6"
2. Tính tổng các chữ số 3, ..., 6 có trong chuỗi. Tức mỗi chữ số trong khoảng [3, 6] có thể xuất hiện nhiều lần trong chuỗi, và chúng đều được cộng. Bạn redeye đã hiểu theo cách này.

Nói nửa câu thì người khác khó có thể đoán ý. Và đây là trường hợp điển hình.
------------
Nếu hiểu theo cách 1 thì

=SUM(INDEX(--MID(A1,ROW($A$3:$A$6),1),0))

hoặc

=SUMPRODUCT(--MID(A1,ROW($A$3:$A$6),1))

 

[batman1]

Nếu là cách hiểu 2 thì ngoài cách của redeye cũng còn nhiều cách khác. Ví dụ

=SUMPRODUCT(ISERR(FIND(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1),"127890"))*MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1))

Nếu chuỗi có độ dài không đổi, vd. luôn 10 thì thay vì ROW(INDIRECT("1:"&LEN(A1))) chỉ cần ROW($1:$10)

 

[excel_lv1.5]

Các bạn giúp tôi trong 1 ô 12345678 muốn cộng số 3 đến số 6.Cảm ơn

Cho bạn thêm 1 cách:

=SUMPRODUCT((LEN(A1)-LEN(SUBSTITUTE(A1,ROW($3:$6),"")))*ROW($3:$6))

 

[huuthang_bd]

Nhiều người không mô tả dữ liệu và chỉ nói nửa câu. Khó mà đoán được trúng ý.
Theo tôi có thể hiểu "muốn cộng số 3 đến số 6" theo 2 cách:
1. Tính tổng các chữ số từ vị trí thứ 3 tới vị trí thứ 6. Có lẽ bạn befaint đã hiểu theo cách này. Nhưng nếu là cách này thì phải phát biểu chính xác là "muốn cộng các chữ số từ vị trí 3 đến vị trí 6"
2. Tính tổng các chữ số 3, ..., 6 có trong chuỗi. Tức mỗi chữ số trong khoảng [3, 6] có thể xuất hiện nhiều lần trong chuỗi, và chúng đều được cộng. Bạn redeye đã hiểu theo cách này.

Nói nửa câu thì người khác khó có thể đoán ý. Và đây là trường hợp điển hình.
------------
Nếu hiểu theo cách 1 thì

=SUM(INDEX(--MID(A1,ROW($A$3:$A$6),1),0))

hoặc

=SUMPRODUCT(--MID(A1,ROW($A$3:$A$6),1))

Cũng có thể hiểu là tính tổng các chữ số nằm giữa số 3 và số 6 (bao gồm cả 3 và 6)

 

[HieuCD]

Nếu là cách hiểu 2 thì ngoài cách của redeye cũng còn nhiều cách khác. Ví dụ

=SUMPRODUCT(ISERR(FIND(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1),"127890"))*MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1))

Nếu chuỗi có độ dài không đổi, vd. luôn 10 thì thay vì ROW(INDIRECT("1:"&LEN(A1))) chỉ cần ROW($1:$10)

Cho bạn thêm 1 cách:

=SUMPRODUCT((LEN(A1)-LEN(SUBSTITUTE(A1,ROW($3:$6),"")))*ROW($3:$6))

Nếu chuổi không theo thứ tự như 12347698 thì sao

 

[excel_lv1.5]

Nếu chuổi không theo thứ tự như 12347698 thì sao

Cách này áp dụng cho mọi trường hợp, không theo thứ tự, chuỗi có chữ cái, độ dài không giới hạn!!

 

[Phan Thế Hiệp]

Các bạn giúp tôi trong 1 ô 12345678 muốn cộng số 3 đến số 6.Cảm ơn

Góp thêm một công thức tính bằng mắt như thông lệ:

B1=SUM(--MID(MID(A1,3,4),{1,2,3,4},1))

Chỉ Enter.
Thân.

 

[HieuCD]

Cách này áp dụng cho mọi trường hợp, không theo thứ tự, chuỗi có chữ cái, độ dài không giới hạn!!

Hiểu rồi, tính tổng các số từ 3 đến 6(3,4,5,6)
Cách khác

=SUMPRODUCT((MID(A1,ROW(1:100),1)=COLUMN(C:F)&"")*COLUMN(C:F))

 

[Phan Thế Hiệp]

Cách này áp dụng cho mọi trường hợp, không theo thứ tự, chuỗi có chữ cái, độ dài không giới hạn!!

Tham gia công thức mảng kém cõi hơn chút:

=SUM(IFERROR(MID(A1,ROW(1:10),1)/(MATCH(1*MID(A1,ROW(1:10),1),{3,7})=1),))

Ctrl+Shift+Enter.

Chúc anh em ngày vui.