Tìm công thức để xếp loại có điều kiện

[vanlank18]

Cần giúp đỡ công thức đánh giá chung, sắp xếp theo các tiêu chí được đưa ra, cụ thể mình đã viết trong tập tin.

 

[Phuocam]

Cần giúp đỡ công thức đánh giá chung, sắp xếp theo các tiêu chí được đưa ra, cụ thể mình đã viết trong tập tin.
View attachment 280963

1. Cách chuẩn:

Bạn có thể dùng IF và COUNTIF lần lượt để đánh giá.

- Trường hợp không đạt: IF(COUNTIF(C4:G4,"Không đạt")>0,"Không đạt",

- Trường hợp đạt: IF(COUNTIF(C4:G4,"Đạt")>1,"Đạt")

...

2. Cách gán điểm: Mỗi trường hợp gán một điểm tương ứng và phù hợp.

Dùng SUM tính tổng.

Dùng LOOKUP dò tổng trong mảng tìm kiếm cho ra kết quả tương úng.

.

 

[bebo021999]

Làm đại. Tại ô G4:

=IF(COUNTIF($C4:$F4,"Không đạt"),"Không đạt",IF(COUNTIF($C4:$F4,"Đạt")>1,"Đạt",IF(AND(COUNTIF($C4:$F4,"Khá")=1,COUNTIF($C4:$F4,"Giỏi")=3),"Giỏi","Khá")))

 

[bebo021999]

Phương pháp gán điểm:
Nếu cho điểm: Giỏi = 1, Khá = 10, Đạt = 100, Không Đạt = 1000
Khi tổng 4 tiêu chí lại thì sẽ có quy luật:
Tổng >=1000 (Có 1 tiêu chí Không Đạt) : Không Đạt
Tổng >=200 (Có 2 tiêu chí Đạt trở lên): Đạt
Tổng >13 (có 1 Đạt, hoặc không có Đạt): Khá
Còn lại <=13: Có nhiều nhất 1 khá: Giỏi

=INDEX({"Không đạt","Đạt","Khá","Giỏi"},MATCH(TRUE,SUMPRODUCT(COUNTIF($C4:$F4,{"Giỏi","Khá","Đạt","Không Đạt"})*{1,10,100,1000})>{999,199,13,0},0))

 

[Nhattanktnn]

Làm đại. Tại ô G4:

=IF(COUNTIF($C4:$F4,"Không đạt"),"Không đạt",IF(COUNTIF($C4:$F4,"Đạt")>1,"Đạt",IF(AND(COUNTIF($C4:$F4,"Khá")=1,COUNTIF($C4:$F4,"Giỏi")=3),"Giỏi","Khá")))

Sửa một chút cho trường hợp 4 giỏi trong công thức bác trả về chưa đúng:

=IF(COUNTIF($C4:$F4,"Không đạt"),"Không đạt",IF(COUNTIF($C4:$F4,"Đạt")>1,"Đạt",IF(AND(COUNTIF($C4:$F4,"Đạt")=0,COUNTIF($C4:$F4,"Giỏi")>=3),"Giỏi","Khá")))

 

[VetMini]

Tại đề bài miêu tả lô gic theo kiểu thường tình. Qua phân tích thì cần sủa đổi cách miêu tả tuần tự 1 chút để dễ làm toán:
- Có một không đạt trở lên là không đạt
- Có nhiều hơn một đạt là chỉ đạt
- Có một đạt, hoặc hai khá trở lên thì là khá.
- Còn lại là giỏi

=IF(COUNTIF($C4:$F4, "Không đạt"), "Không đạt", IF(COUNTIF($C4:$F4, "Đạt")>1, "Đạt", IF(OR(COUNTIF($C4:$F4, "Đạt"), COUNTIF($C4:$F4, "Khá") > 1), "Khá", "Giỏi")))

Công thức trông thấy Countif hơi nhiều. Nhưng trên thực tế, hàm IF rất hiệu quả, có khả năng đi đường tắt (khi lô gic thỏa thì nó đi theo chiều đó và không tính các chiều còn lại) cho nên cũng không đến nổi tệ.

 

[anhtuan2939]

Tận dùng công thức bài 5, nhưng dùng hàm IFS thay cho hàm IF.

=IFS(COUNTIF($C4:$F4,"Không đạt"),"Không đạt",COUNTIF($C4:$F4,"Đạt")>1,"Đạt",AND(COUNTIF($C4:$F4,"Đạt")=0,COUNTIF($C4:$F4,"Giỏi")>=3),"Giỏi",TRUE,"Khá")

 

[Phan Thế Hiệp]

Góp thêm công thức theo ý bài #2.

2. Cách gán điểm: Mỗi trường hợp gán một điểm tương ứng và phù hợp.

Dùng SUM tính tổng.

Dùng LOOKUP dò tổng trong mảng tìm kiếm cho ra kết quả tương úng.

G4=LOOKUP(SUMPRODUCT(COUNTIF(C4:F4,$J$1:$J$4)*10^{0;1;2;3}),{0,20,200,1000},$J$1:$J$4)

Enter, fill xuống.

Thân

 

[vanlank18]

Edit một chút cho trường hợp 4 tốt trong công thức trả về không đúng:

 = IF (COUNTIF ($ C4: $ F4, "Không đạt"), "Không đạt", IF (COUNTIF ($ C4: $ F4, "Đạt")> 1, "Đạt", IF (AND ( COUNTIF ($ C4: $ F4, "Đạt") = 0, COUNTIF ($ C4: $ F4, "Giỏi")> = 3), "Giỏi", "Khá"))) [/ CODE]
[/QUOTE]
Cảm ơn bạn đã hỗ trợ. mình đã làm xong