Tách chuỗi ký tự trong excel

[xgame]

Mình đã tìm các bài viết trên diễn đàn nhưng chưa được như ý. Nhờ các bác xem giúp em.

Chuỗi ký tự có dạng: [BGCOLOR=rgb(255, 255, 255)]Ten may, Model abc, Seri: 123abc, Ngay san xuat....[/BGCOLOR]
Kết quả mình cần như sau: [BGCOLOR=rgb(247, 218, 100)]Ten may, Model abc, Seri: 123abc[/BGCOLOR]
Quy luật: chỉ lấy chuỗi ký tự từ dấu phẩy "," thứ 3 trở về đầu.

Cảm ơn các bác.

 

[befaint]

=SUBSTITUTE(TRIM(LEFT(SUBSTITUTE(SUBSTITUTE(A2,",",CHAR(10)&CHAR(160)),CHAR(10),REPT(" ",1000)),3000))," "&CHAR(160),",")

 

[xgame]

=TRIM(LEFT(SUBSTITUTE(A2,",",REPT(" ",1000)),3000))

Như công thức của bác thì kết quả cho ra sẽ là:

Ten may Model abc Seri: 123abc

Ý của mình là muốn kết quả là:
[BGCOLOR=rgb(247, 218, 100)]Ten may, Model abc, Seri: 123abc [/BGCOLOR]
Sẽ bỏ chuỗi: "Ngay san xuat..." đi , chỉ giữ lại phần tô vàng như trên

 

[bebo021999]

Search từ "Ngay san xuat" sau đó dùng LEFT. Vấn đề là tất cả đều có chữ "Ngay san xuat" không?

 

[leonguyenz]

Như công thức của bác thì kết quả cho ra sẽ là:

Ten may Model abc Seri: 123abc

Ý của mình là muốn kết quả là:

[BGCOLOR=rgb(247, 218, 100)]Ten may, Model abc, Seri: 123abc [/BGCOLOR]
Sẽ bỏ chuỗi: "Ngay san xuat..." đi , chỉ giữ lại phần tô vàng như trên

Công thức này đúng khi có 3 dấu phẩy trở lên:

=LEFT(A1,FIND(",",A1,1+FIND(",",A1,1+FIND(",",A1)))-1)

Thêm 1 công thức lấy từ dấu phẩy cuối cùng:

=LEFT(A1,FIND("$",SUBSTITUTE(A1,",","$",LEN(A1)-LEN(SUBSTITUTE(A1,",",""))),1)-1)

Công thức tìm từ "Ngay":

=LEFT(A1,FIND("Ngay",A1)-3)

 

[LamNA]

Mình đã tìm các bài viết trên diễn đàn nhưng chưa được như ý. Nhờ các bác xem giúp em.

Chuỗi ký tự có dạng: [BGCOLOR=rgb(255, 255, 255)]Ten may, Model abc, Seri: 123abc, Ngay san xuat....[/BGCOLOR]
Kết quả mình cần như sau: [BGCOLOR=rgb(247, 218, 100)]Ten may, Model abc, Seri: 123abc[/BGCOLOR]
Quy luật: chỉ lấy chuỗi ký tự từ dấu phẩy "," thứ 3 trở về đầu.

Cảm ơn các bác.

Bạn thử công thức này

=TRIM(LEFT(SUBSTITUTE(A1,",",REPT(" ",LEN(A1))),LEN(A1)*3))

 

[leonguyenz]

Bạn thử công thức này

=TRIM(LEFT(SUBSTITUTE(A1,",",REPT(" ",LEN(A1))),LEN(A1)*3))

Công thức này đã có ở bài #2, xóa hết dấu phẩy rồi

 

[LamNA]

Công thức này đã có ở bài #2, xóa hết dấu phẩy rồi

Em chưa hiểu ý bạn chủ topic muốn thế nào anh nhỉ

 

[HieuCD]

Mình đã tìm các bài viết trên diễn đàn nhưng chưa được như ý. Nhờ các bác xem giúp em.

Chuỗi ký tự có dạng: [BGCOLOR=rgb(255, 255, 255)]Ten may, Model abc, Seri: 123abc, Ngay san xuat....[/BGCOLOR]
Kết quả mình cần như sau: [BGCOLOR=rgb(247, 218, 100)]Ten may, Model abc, Seri: 123abc[/BGCOLOR]
Quy luật: chỉ lấy chuỗi ký tự từ dấu phẩy "," thứ 3 trở về đầu.

Cảm ơn các bác.

Góp vui
=LEFT(A2,FIND("#",SUBSTITUTE(A2,",","#",3))-1)

 

[LamNA]

Công thức này đã có ở bài #2, xóa hết dấu phẩy rồi

À nhìn kỹ thấy rồi muốn lấy luôn dấu ,

 

[leonguyenz]

Em chưa hiểu ý bạn chủ topic muốn thế nào anh nhỉ

Quy luật: chỉ lấy chuỗi ký tự từ dấu phẩy "," thứ 3 trở về đầu.

Nhưng chưa biết là trong file mỗi chuỗi có bao nhiêu dấu phẩy.

 

[Phuocam]

Nhưng chưa biết là trong file mỗi chuỗi có bao nhiêu dấu phẩy.

Xóa file bài 1 rồi, xong xgame!

 

[xgame]

=LEFT(A1,FIND(",",A1,1+FIND(",",A1,1+FIND(",",A1)))-1)

Công thức này đã cho kết quả như ý muốn, cảm ơn bác nhiều lắm.