Những vấn đề về hàm IF (2 người xem)

ndu96081631 · 15/7/08

CHS đã viết:
Theo Mình Không Cần Dùng Hàm "and" Bạn Có Thể Gõ Như Thế Này Cũng Cho Kết Quả Tương Xứng: If(c1>12,"s",if(c1>=8,"m",if(c1<8,"r")))

Tới cuối thì cần gì IF nữa, sao không = "r" luôn cho rồi!
Không > 12 cũng không >= 8 thì đương nhiên nó <8 rồi, cần gì IF

dientrang · 16/7/08

Anh chị trong diễn đàn giúp em cách sử dụng hàm if kết hợp với hàm or và and trong bài tập dưới đây với em không sao mà làm ra được! Cụ thể là:
- Nếu là giám đốc thì phụ cấp là 5000
- Nếu là pgđ hay Tp thì phụ cấp là 4000
- Nếu là pp thì phụ cấp là 3000
- Nếu là Bv và có số ngày công lớn hơn 22 thì phụ cấp là 2000 còn lại là ko có phụ cấp!

huycuongxd · 16/7/08

Bạn xem thế này có đúng ý bạn ko nhé.

BNTT · 16/7/08

dientrang đã viết:
Anh chị trong diễn đàn giúp em cách sử dụng hàm if kết hợp với hàm or và and trong bài tập dưới đây với em không sao mà làm ra được! Cụ thể là:
- Nếu là giám đốc thì phụ cấp là 5000
- Nếu là pgđ hay Tp thì phụ cấp là 4000
- Nếu là pp thì phụ cấp là 3000
- Nếu là Bv và có số ngày công lớn hơn 22 thì phụ cấp là 2000 còn lại là ko có phụ cấp!

Giả sử rằng các chức danh đang năm ở cột C, Số ngày công đang ở cột D
Bạn lập công thức tính như sau (giả sử cho một người ở hàng 1) tại cột tính phụ cấp:

PHP:

= IF(C1="Giám đốc", 5000, IF(OR(C1="pdg", C1="Tp"), 4000, IF(C1="pp", 3000), IF(AND(C1="Bv", D1>22), 2000, 0))))

TKT · 16/7/08

dientrang đã viết:
Anh chị trong diễn đàn giúp em cách sử dụng hàm if kết hợp với hàm or và and trong bài tập dưới đây với em không sao mà làm ra được! Cụ thể là:
- Nếu là giám đốc thì phụ cấp là 5000
- Nếu là pgđ hay Tp thì phụ cấp là 4000
- Nếu là pp thì phụ cấp là 3000
- Nếu là Bv và có số ngày công lớn hơn 22 thì phụ cấp là 2000 còn lại là ko có phụ cấp!

Mã:

 =IF(A1="GĐ";5000;IF(OR(A1="PGĐ";A1="TP");4000;IF(A1="PP";3000;IF(AND(A1="BV";B1>22);2000;0))))

Với ô A1 chứa chức vụ.
.......B1 chứa ngày công.

zozbo · 16/7/08

Hỏi về cách sử dụng hàm IF để tính phí dịch vụ

Các bác giúp em với.
Cơ quan em đang cần tính phí dịch vụ với những yêu cầu sau

Mở file đính kèm)
- nếu số tiền trong cột Số tiền(đi,đến) <=20.000.000 thì Phí(đi,đến) thu là 20.000
- nếu số tiền trong cột Số tiền(đi,đến) <=200.000.000 thì Phí(đi,đến) thu là 100.000
- nếu số tiền trong cột Số tiền(đi,đến) >=20.000.000 và <=200.000.000 thì Phí(đi,đến) thu chính lá Số tiền (đi,đến) nhân với 0.0005.

huycuongxd · 16/7/08

Có vẻ đề bài của bạn không được chuẩn nhưng tớ hiểu ý bạn muốn hỏi. bạn xem file đính kèm nha.

ThuNghi · 16/7/08

zozbo đã viết:
Các bác giúp em với.
Cơ quan em đang cần tính phí dịch vụ với những yêu cầu sauMở file đính kèm)
- nếu số tiền trong cột Số tiền(đi,đến) <=20.000.000 thì Phí(đi,đến) thu là 20.000
- nếu số tiền trong cột Số tiền(đi,đến) <=200.000.000 thì Phí(đi,đến) thu là 100.000
- nếu số tiền trong cột Số tiền(đi,đến) >=20.000.000 và <=200.000.000 thì Phí(đi,đến) thu chính lá Số tiền (đi,đến) nhân với 0.0005.

Tôi nhớ là reply rồi, chắc mất bài.
Số tiền(đi,đến) <=20.000.000
Số tiền(đi,đến) <=200.000.000
Số tiền(đi,đến) >=20.000.000 và <=200.000.000
Đố bạn tìm ra số nào mà >=20 và <=200 và <=20 và ...
Điều kiện sai, nên sửa là (maybe)
- nếu số tiền trong cột Số tiền(đi,đến) <=20.000.000 thì Phí(đi,đến) thu là 20.000
- nếu số tiền trong cột Số tiền(đi,đến) >=200.000.000 thì Phí(đi,đến) thu là 100.000
- nếu số tiền trong cột Số tiền(đi,đến) >20.000.000 và <200.000.000 thì
Lúc đó ct như sau:
If(sotien<=20,20,if(sotien>=200,100,sotien*0.0005))

zozbo · 16/7/08

Hỏi về cách sử dụng hàm IF để tính phí dịch vụ

Cám ơn các Bác.
Em quên không thêm điều kiện: nếu số tiền (đi, đến) là không có thì cũng khoong có phí DV. Sau 1 lúc mày mò Em cũng đã tự làm được rôi

BNTT · 16/7/08

zozbo đã viết:
=IF(C3="","",IF(C3<=20000000,20000,IF(C3>=200000000,100000,C3*0.0005)))

Bạn không nên dùng "" (giá trị text) mà nên dùng 0 (giá trị số), ví dụ:

=IF(OR(C3="", C3=0), 0, IF(C3<=20000000, 20000, IF(C3>=200000000, 100000, C3*0.0005)))

Là để đề phòng có những trường hợp thay vì bỏ trống ô C3, thì người ta lại nhập vào đó là số 0, mà số 0 thì không phải là "".
Bạn thử nhập số 0 vào trong C3 thử xem, nếu dùng công thức của bạn thì Phí của "Đi" sẽ bằng 20000 liền, chứ không phải là "rỗng" đâu.

echo07 · 19/7/08

Hàm IF của em sao phải sử dụng ít nhất hai điều kiện?

Chào các tiền bối. Hôm rồi em cài lại bộ Office. Không hiểu ông IT táy máy thế nào vào mấy mục trong Option của Excel mà hàm chạy sai tè le. Ví dụ em dùng IF thì phải có hai điều kiện mới đúng. tức là nếu để một ĐK thì Đk đó luôn đúng. Vậy phải làm sao nhỉ??? ;;;;;;;;;;;

hoangdanh282vn · 19/7/08

echo07 đã viết:
Chào các tiền bối. Hôm rồi em cài lại bộ Office. Không hiểu ông IT táy máy thế nào vào mấy mục trong Option của Excel mà hàm chạy sai tè le. Ví dụ em dùng IF thì phải có hai điều kiện mới đúng. tức là nếu để một ĐK thì Đk đó luôn đúng. Vậy phải làm sao nhỉ???

Bạn gửi file lên đi, muốn khám bệnh phải có người chứ, dự đoán nhiều khi trật lất bạn à.

tedaynui · 19/7/08

echo07 đã viết:
Chào các tiền bối. Hôm rồi em cài lại bộ Office. Không hiểu ông IT táy máy thế nào vào mấy mục trong Option của Excel mà hàm chạy sai tè le. Ví dụ em dùng IF thì phải có hai điều kiện mới đúng. tức là nếu để một ĐK thì Đk đó luôn đúng. Vậy phải làm sao nhỉ???

Chắc là do công thức của bạn thôi, chứ trong Option không có chức năng nào có khả năng làm thay đổi cách tính toán của các hàm đâu. Có lẽ, bạn nên đưa công thức lên để anh em kiểm tra lại xem sao.

TDN

huycuongxd · 19/7/08

Bạn nhớ rằng cú pháp của hàm IF() là: IF(logical_test,value_if_true,value_if_false), trong đó:
+logical_test: Địa chỉ của ô cần kiểm tra
+value_if_true: Cho giá trị nếu thỏa mãn điều kiện
+value_if_false: Cho giá trị nếu không thỏa mãn điều kiện
VD: =IF(A1="EM YEU ANH","ANH CUNG YEU EM", "ANH KO YEU EM")

echo07 · 19/7/08

Các bác xem giúp. em không đến nỗi không hiểu mấy cái sơ đẳng đó đâu.

hoangdanh282vn · 19/7/08

echo07 đã viết:
Các bác xem giúp. em không đến nỗi không hiểu mấy cái sơ đẳng đó đâu.

Cột K, trong CF bạn thêm điều kiện <>"" vào hàm if nữa là ok, vì "a"=0 => true
Cột Au bạn tô màu nền mặc định là xanh nên mới thế, chọn nofill là ok

BNTT · 19/7/08

Tôi đã xem file của bạn. Thú thật không hiểu bạn nói nó sai là sai chỗ nào.

Nhưng có cái này, xin góp ý.
Mấy cái công thức trong Conditional Formatting của bạn, không cần thiết phải dùng IF, vì bản thân Conditional Formatting là IF rồi. Nghĩa là, Conditional Formatting chỉ thực hiện định dạng khi điều kiện trả về giá trị TRUE, hay nói cách khác, NẾU điều kiện trả về TRUE thì thực hiện việc định dạng.

Do đó, ví dụ công thức này của bạn: =IF(A=1, TRUE, FALSE) là quá dư, bạn chỉ cần dùng =A=1
Khi A=1 thì biểu thức đó tự động trả về TRUE, còn khi A khác 1 thì biểu thức đó tự động trả về FALSE, và sẽ không thực hiện Conditional Formatting.

Hay là bạn thử sửa hết lại mấy cái công thức trong Conditional Formatting, bỏ hết IF và TRUE, FALSE gì đó đi... Có thể sẽ giải quyết được cái bạn muốn hỏi.

duongdv · 19/7/08

Cái files này của bạn khó hiểu thật. Mình đã thử bỏ tất cả các điều kiện đó đi và thử với một điều kiện đơn giản và duy nhất nhưng nó vẫn bị như vậy?

yeudoi · 19/7/08

Cái này mình cũng thấy lạ đấy anh BNTT xem ở cột AO so với cột K đấy, khi bỏ SW ở cột K thì điều kiện cột AO vẫn hiểu là 1.

hoangdanh282vn · 19/7/08

yeudoi đã viết:
Cái này mình cũng thấy lạ đấy anh BNTT xem ở cột AO so với cột K đấy, khi bỏ SW ở cột K thì điều kiện cột AO vẫn hiểu là 1.

Cái này có gì đâu mà lạ Bác.
ở trên em có nói là "sw"=K10 với K10 trống thì hiển nhiên trả về TRUE, vì khi so sánh chuỗi với ô rỗng (hay =0) thì luôn trả về TRUE, Bác thử thay K10=1 hay a,b...thử xem.

DOSNET · 19/7/08

yeudoi đã viết:
Cái này mình cũng thấy lạ đấy anh BNTT xem ở cột AO so với cột K đấy, khi bỏ SW ở cột K thì điều kiện cột AO vẫn hiểu là 1.

Cái đó bỏ 2 dấu chọn trong Options\Transition là ok

+ Transition formula evaluation
+ Transition formula entry

echo07 · 19/7/08

Thankyou các bác. em tìm ra rồi. Trong mục thẻ Transition của Tool/Options cứ bỏ hết dấu tích trên các lựa chọn là ô văn kê, khốn khổ thân em mò mãi vì cái ông IT nửa mùa hôm qua.

DOSNET · 19/7/08

echo07 đã viết:
Thankyou các bác. em tìm ra rồi. Trong mục thẻ Transition của Tool/Options cứ bỏ hết dấu tích trên các lựa chọn là ô văn kê, khốn khổ thân em mò mãi vì cái ông IT nửa mùa hôm qua.

Đồng ý là tìm ra rồi nhưng nên sửa điều kiện trong CF đi cho nhẹ bảng !
Ví dụ :

=IF(OR($K10="FW",$K10="TW"),TRUE,FALSE)

Sửa thành : =OR($K10="FW",$K10="TW")

=IF($K10="FFW",TRUE,FALSE)

Sửa thành =$K10="FFW"

=IF($BY10=1,TRUE,FALSE)

Sửa thành =$BY10=1

Vitcon hay khoc nhe · 15/8/08

Hỏi về hàm if?

tớ làm bảng kê hàng hóa mà,muốn cuối mỗi tháng có kế hoạch mua hàng.
Do đó muốn căn cứ vào loại hàng đó là cần thiết hay không cần thiết và số lượng tồn là <2 hay >2.Nhưng tớ dùng công thức thế này lại không được
=IF(AND(E=CAN,I<=2),"PHAIMUA",0)
Nhờ các bạn giúp với!

Thanks các bạn rất nhiều! Nhưng ko hiểu sao nếu mình dùng chuột kéo copy công thức xuống các ô bên dưới thì được, còn nếu lập lại công thức thì ngay từ khi nhập: AND(D5=''cần'',H5<2) thì lại cho kết quả Invalid chứ ko phải là True.
Ko hiểu tại sao nữa. Trời ới!

huycuongxd · 15/8/08

Bạn xem file đính kèm nhé!

cadafi · 15/8/08

Vitcon hay khoc nhe đã viết:
tớ làm bảng kê hàng hóa mà,muốn cuối mỗi tháng có kế hoạch mua hàng.
Do đó muốn căn cứ vào loại hàng đó là cần thiết hay không cần thiết và số lượng tồn là <2 hay >2.Nhưng tớ dùng công thức thế này lại không được
=IF(AND(E=CAN,I<=2),"PHAIMUA",0)
Nhờ các bạn giúp với!

Tại ô I4 bạn gõ vào:

I4=IF(AND(D4="cần",H4<2),"Phải mua","")

Sau đó fill công thức xuống.

xnamgl08 · 15/8/08

thừa dấu hai nháy rồi bạn ơi, xóa bớt một cái đi

BNTT · 15/8/08

xnamgl08 đã viết:
thừa dấu hai nháy rồi bạn ơi, xóa bớt một cái đi

Thừa chỗ nào vậy bạn?
Công thức ở I4: =IF(AND(D4="cần",H4<2),"Phải mua","")
Có nghĩa là nếu ở D4 là "cần" và ở H4 nhỏ hơn 2, thì ghi vào ô I4 là "phải mua", còn không thì bỏ trống ô I4
Chả có thừa cái gì cả.

Luu Ly Tim · 16/8/08

Vịt con ơi làm lại bị nhận giá trị True là đúng rồi vì vịt con phải nhần chuột vào D5 chứ không được dùng đánh bằng tay đâu. hi. tờ tìm ra rồi đó.

ndu96081631 · 16/8/08

Cái vụ Invalid này rất có thể do sai dấu phân cách công thức (dấu phẩy hoặc dấu chấm phẩy)
Bạn kiểm tra lại xem
Ngay khi xuất hiên lổi, nếu bạn bấm OK sẽ có 1 thông báo, bạn xem lại thông báo ấy nói gì? Nói cầm bấm Help xem thông tin chi tiết

Vitcon hay khoc nhe · 16/8/08

Thanks rất nhiều! Cả ngày qua và hnay tớ phát hiện ra rồi.
Chỉ là 1 thói quen, tớ gõ dấu nháy ko dùng Shift+'' mà gõ 2 dấu nháy đơn.Hic

haonlh · 17/8/08

Nhầm nháy kép thành 2 dấu nháy đơn là thường có. Sao bạn không gửi file excel ngay từ đầu.
Ngoài ra còn có thể nhầm số không (0) với chữ o hoa (O).
Có người còn nhầm chữ i hoa (I) hay chữ elờ (l) với số một (1) (bạn chọn font Times New Roman mà xem).
Có lần tôi chỉ dẫn: "tại ô I2"...
mà người nghe cứ hiểu là "tại ô 12"...
Cẩn thận nhé

thuyno · 17/8/08

Bài tập tính toán với hàm If?

Em có bài tập như thế này nhưng không bít làm +-+-+-+

.
+ Lương được tăng được tính như sau: Nếu nv được tuyển dụng trước ngày 01/01/88 thì được tăng 0.5% lương chính thức, ngược lại chỉ được tăng 0.3%.
+ Tính tạm ứng: bằng 2/3 lương chính thức nhưng không lớn hơn $3000.
Em đã thử dùng hàm if với công thức là =if(c2<1/1/88,"0,5%","0,3%") thì nó cho kết quả ở tất cả các ô lương được tăng đều là 0,5%. Ai giải đáp giúp em với. &&&%$R

FTC · 17/8/08

+) ở ô ương được tăng, bạn nhập công thức sau:
=IF(C3-DATE(88;1;1)<0;D3*0,5%;D3*0,3%)
+) ô tạm ứng bạn nhập công thức sau:
=IF(D2*2/3>3000;3000;D2*2/3)

cadafi · 18/8/08

thuyno đã viết:
Em có bài tập như thế này nhưng không bít làm.
+ Lương được tăng được tính như sau: Nếu nv được tuyển dụng trước ngày 01/01/88 thì được tăng 0.5% lương chính thức, ngược lại chỉ được tăng 0.3%.
+ Tính tạm ứng: bằng 2/3 lương chính thức nhưng không lớn hơn $3000.
Em đã thử dùng hàm if với công thức là =if(c2<1/1/88,"0,5%","0,3%") thì nó cho kết quả ở tất cả các ô lương được tăng đều là 0,5%. Ai giải đáp giúp em với.

Công thức của bạn đúng ra phải là:
=if(c2<"1/1/88","0,5%","0,3%")
Phải đặt ngày vào trong hai dấu nháy kép.

quanghai69 · 18/8/08

hoặc bạn làm thế này cũng giống nhau thôi
=IF(DATE(88,1,1)-C2>0,D2*5%,D2*3%)

cadafi · 18/8/08

quanghai69 đã viết:
hoặc bạn làm thế này cũng giống nhau thôi
=IF(DATE(88,1,1)-C2>0,D2*5%,D2*3%)

Khác chứ bạn, trong hàm if của bạn, bạn phải làm phép trừ, sao đó so sánh với số 0. Trong khi công thức của thuyno chỉ là mỗi phép so sánh thôi ==> nhanh hơn của bạn.

Bạn ấy chỉ thiếu mỗi cái dấu nháy kép thôi.

BNTT · 18/8/08

Xin góp ý một chút, khi sử dụng hàm DATE(), các bạn không nên dùng số năm chỉ có 2 chữ số (88), mà nên dùng đủ 4 chữ số (1988). Mặc dù với riêng số 88 thì không sai, nhưng đây là vấn đề "thói quen", nếu như các bạn tập cho mình cái thói quen luôn luôn nhập năm với 4 chữ số, ở bất kỳ tình huống nào, thì vẫn tốt hơn, vì các bạn sẽ không bao giờ gặp những tình huống trục trặc so với việc sử dụng năm ở dạng có 2 chữ số.

thanhklktu · 18/8/08

Hỏi cách lồng hàm IF để tính 14 hệ số lương

Kính gửi các anh chị!
Tôi có 1 câu hỏi muốn nhờ các anh chị giải đáp giúp:
Hiện tôi đang làm công tác tổ chức cho Chi cục kiểm lâm Kon Tum, trong đó có công việc phải làm thủ tục nâng lương định kỳ cho cán bộ, công chức và người hợp đồng lao động. Toàn Chi cục có 14 mã ngạch khác nhau, mỗi mã ngạch lại có hệ số tăng thêm khác nhau (Ví dụ: ngạch Kiểm lâm viên (10026), mỗi lần nâng hệ số được 0,33; ngạch kiểm lâm viên trung cấp (10028) mỗi lần nâng được 0,20, v.v…).
Tôi đã thực hiện trên M. Excel và sử dụng hàm IF. Tuy nhiên hàm này chỉ cho phép thực hiện với 8 hệ số lương (tức là 8 lần IF), trong khi tôi muốn 1 hàm sử dụng được cả 14 hệ số.
Xin các anh chị chỉ giúp tôi có cách nào không? Nếu không sử dụng hàm IF thì phải sử dụng hàm gì? hoặc có cách khắc phục nào khác không? Tôi cũng không rành lắm về lập trình.
Hiện tôi đang tìm kiếm trên mạng xem có phần mềm nào chuyên về công tác tổ chức cán bộ cho cơ quan nhà nước, nhưng không có. Vậy xin các anh chị chỉ giúp có chỗ nào có không? Và giá cả như thế nào ?
Rất mong được sự giúp đỡ của các anh chị !.
Xin cảm ơn các anh chị rất nhiều!
Phạm Quang Thành - thanhklktu@yahoo.com

hong gam · 18/8/08

bạn có thể sử dụng vlookup. Tuy nhiên để sử dụng nó bạn phải 1 bảng dữ liệu để tham chiếu tới. Trong bảng dữ liệu này, bạn ghi 1 cột mã ngạch, 1 cột hệ số. sau đó quay sang bảng chính, để sử dụng vlookup để dò tìm nó ra. cách này mình học của bác BNTT đó.

ndu96081631 · 18/8/08

Không biết phần tạm ứng, cái 2/3 là của cái gì nhỉ? Của lương tại cột D hay là lương sau khi tăng?
Và công thức tính tạm ứng tôi nghĩ như vầy:

=MIN(Lương/3*2,3000)

Sẽ gọn gàng hơn

nhatthai · 18/8/08

sẵn đây gợi ý cho bạn luôn này

PhanTuHuong · 18/8/08

Yêu cầu của bác dùng VBA là khoa học nhất.

Còn muốn đặt phần mềm quản lý bác có thể liên lạc với các anh Admin TuanVNUNI hay Mod Hai2hai.

boyxin · 18/8/08

nhatthai đã viết:
sẵn đây gợi ý cho bạn luôn này

Theo như File đính kèm: Để tính cột E
Ngoài cách tính trong File

PHP:

E5 =IF(D5=0,VLOOKUP(C5,$P$6:$Q$19,2,0)*$U$5,(VLOOKUP(C5,$P$6:$Q$19,2,0)+VLOOKUP(D5,$R$6:$S$9,2,0))*$U$5)

Có thêm 1 cách dùng SUMPRODUCT

PHP:

E5 =(SUMPRODUCT((P$6:P$19=C5)*(Q$6:Q$19))+SUMPRODUCT((R$6:R$9=D5)*(S$6:S$9)))*U$5

Rồi copy công thức xuống (kéo fill xuống)

thuyno · 18/8/08

Cảm ơn các bạn đã giúp mình. Mình làm thử thấy dùng công thức này
=IF(Date(1988,1,1)-C2>0,"0.5%","0.3%") ra đúng kết quả. Còn công thức
=IF(C2<"1/1/88","0.5%","0.3%") thì cho kết quả toàn là 0.5 % thui.

Các bạn cho mình hỏi thêm /-*+/

, với những bài tập hàm IF mà căn cứ vào ký tự ví dụ như là : nếu ký tự ở giữa là A thì thế này, kí tự ở đầu là B thì như thế kia... thì lập công thức như thế nào. Trước mình có học Excel ở trường cấp 3 nhưng giờ quên hết rùi, đang tự học ở nhà. Các bạn giúp mình với nha }}}}}

.

BNTT · 18/8/08

thuyno đã viết:
Các bạn cho mình hỏi thêm, với những bài tập hàm IF mà căn cứ vào ký tự ví dụ như là : nếu ký tự ở giữa là A thì thế này, kí tự ở đầu là B thì như thế kia... thì lập công thức như thế nào. Trước mình có học Excel ở trường cấp 3 nhưng giờ quên hết rùi, đang tự học ở nhà. Các bạn giúp mình với nha.

Tìm ký tự ở giữa thì dùng hàm MID()
Tìm ký tự ở đầu thì dùng hàm LEFT()
Tìm ký tự ở cuối thì dùng hàm RIGHT()
Bạn nghiên cứu thêm ở chữ ký của tôi nhé (mục Tra cứu hàm Excel)

cadafi · 18/8/08

thuyno đã viết:
Cảm ơn các bạn đã giúp mình. Mình làm thử thấy dùng công thức này
=IF(Date(1988,1,1)-C2>0,"0.5%","0.3%") ra đúng kết quả. Còn công thức
=IF(C2<"1/1/88","0.5%","0.3%") thì cho kết quả toàn là 0.5 % thui.

Do bạn format ngày không đúng đó thôi.
Hãy thử:
=IF(C2<"01/01/1988","0.5%","0.3%")

hoặc:
=IF(C2<Date(1988,1,1),"0.5%","0.3%")

thuyno · 19/8/08

BNTT đã viết:
Tìm ký tự ở giữa thì dùng hàm MID()
Tìm ký tự ở đầu thì dùng hàm LEFT()
Tìm ký tự ở cuối thì dùng hàm RIGHT()
Bạn nghiên cứu thêm ở chữ ký của tôi nhé (mục Tra cứu hàm Excel)

Mình nhớ là có dùng đến các hàm trên. Nhưng mình chỉ bít dùng các hàm LEFT, RIGHT, MID để trích ký tự ra thui, còn không bít cách kết hợp nó với hàm IF.
Giả sử mình nhập vào ô A1 "MNA" giả sử có đề là nếu kí tự cuối là A thì là "Tốt" thì công thức viết như thế nào hả bạn.
Hình như nó kiểu thế này thì phải: =IF(RIGHT(A1,1)"A","Tốt") nhưng chắc là sai, hay thiếu cái gì đấy, nhưng mình không bít.

hoangminhtien · 19/8/08

thuyno đã viết:
Giả sử mình nhập vào ô A1 "MNA" giả sử có đề là nếu kí tự cuối là A thì là "Tốt" thì công thức viết như thế nào hả bạn.
Hình như nó kiểu thế này thì phải: =IF(RIGHT(A1,1)"A","Tốt") nhưng chắc là sai, hay thiếu cái gì đấy, nhưng mình không bít.

bạn phải sửa lại 1 chút, như thê này

=IF(RIGHT(A1,1)="A","Tốt","").

BNTT · 19/8/08

Bạn chỉ thiếu có dấu bằng thôi.
=IF(RIGHT(A1)="A","Tốt")

Thêm tí, nếu chỉ dò mỗi một chữ cuối cùng, bạn không cần dùng số 1 trong hàm RIGHT().

tucontruc · 21/8/08

thuyno đã viết:
Cảm ơn các bạn đã giúp mình. Mình làm thử thấy dùng công thức này
=IF(Date(1988,1,1)-C2>0,"0.5%","0.3%") ra đúng kết quả. Còn công thức
=IF(C2<"1/1/88","0.5%","0.3%") thì cho kết quả toàn là 0.5 % thui.

Thêm nữa nên chọn Format Cell Number ô ngày tháng, chọn custom tự định dạng dd/mm/yy sẽ chuẩn hơn theo đúng định dạng ngày tháng của Việt Nam, khi bạn tính hàm phức tạp hơn chẳng hạn tính từ mốc 01/01/1998 trở về trước cứ tăng 1 tháng thì được tăng lương 0,1% chẳng hạn sẽ có tác dụng đó.

thanhklktu · 2/9/08

Tôi đã nhận được hồi âm của các anh chị về cách sử dụng Hàm IF và hàm thay thế IF trong việc tính toán nâng lương. Xin cảm ơn các anh chị rất nhiều. Với những công chức như tôi, kiến thức nâng cao về Tin học văn phòng là rất hạn chế (đặc biệt là lập trình), vì vậy sự giúp đỡ của các anh chị thật là quý báu.
Hiện tôi đang thực hiện theo sự hướng dẫn của các anh chị. Chắc chắn sẽ cần sự tư vấn thêm của mọi người, vì vậy hy vọng tiếp tục nhận được sự giúp đỡ của các anh chị.
Một lần nữa xin cảm ơn và trân trọng kính chào!

tigertiger · 2/9/08

Bạn nên sử dụng hàm CHOOSE thay thế là hay hơn cả và gọn:
CHOOSE (num, value1 [, value2, ...])

Bấ vào link ở chữ choose trên để xem cách dùng

SA_DQ · 2/9/08

Bạn nên sử dụng hàm CHOOSE thay thế là hay hơn cả và gọn

Chỉ cần lưu ý một điều, hàm này chỉ đến 30 đối số mà thôi; (e2003)
Nếu muốn vượt bức tường này, lại phải xài hàm SWITCH():

http://www.giaiphapexcel.com/forum/showthread.php?t=498

tigertiger · 2/9/08

SA_DQ đã viết:
Chỉ cần lưu ý một điều, hàm này chỉ đến 30 đối số mà thôi; (e2003)
Nếu muốn vượt bức tường này, lại phải xài hàm SWITCH():

http://www.giaiphapexcel.com/forum/showthread.php?t=498

oh, hàm CHOOSE trong hàm của Excel mà bác ,
ý kiến bác là trong VBA

ndu96081631 · 2/9/08

tigertiger đã viết:
oh, hàm CHOOSE trong hàm của Excel mà bác ,
ý kiến bác là trong VBA

Thì đúng rồi, CHOOSE trong hàm Excel giới hạn "hết ga" là 29 phần tử:
CHOOSE

Uses index_num to return a value from the list of value arguments. Use CHOOSE to select one of up to 29 values based on the index number. For example, if value1 through value7 are the days of the week, CHOOSE returns one of the days when a number between 1 and 7 is used as index_num.

phamduylong · 2/9/08

thanhklktu đã viết:
Kính gửi các anh chị!
Tôi có 1 câu hỏi muốn nhờ các anh chị giải đáp giúp:
Hiện tôi đang làm công tác tổ chức cho Chi cục kiểm lâm Kon Tum, trong đó có công việc phải làm thủ tục nâng lương định kỳ cho cán bộ, công chức và người hợp đồng lao động. Toàn Chi cục có 14 mã ngạch khác nhau, mỗi mã ngạch lại có hệ số tăng thêm khác nhau (Ví dụ: ngạch Kiểm lâm viên (10026), mỗi lần nâng hệ số được 0,33; ngạch kiểm lâm viên trung cấp (10028) mỗi lần nâng được 0,20, v.v…).
Tôi đã thực hiện trên M. Excel và sử dụng hàm IF. Tuy nhiên hàm này chỉ cho phép thực hiện với 8 hệ số lương (tức là 8 lần IF), trong khi tôi muốn 1 hàm sử dụng được cả 14 hệ số.Phạm Quang Thành - thanhklktu@yahoo.com

Tại sao không dùng VLOOKUP nhỉ ? Khai báo 1 vùng các chi tiết về ngạch lương như mã ngạch, tên ngạch, bậc 1, bậc 2, ..., bậc n.
Dùng VLOOKUP, chỉ cần nhập mã ngạch là các thông tin khác nó kéo ra theo.

thanhklktu · 2/9/08

Nhân đây, tôi cũng có 1 câu hỏi muốn nhờ các anh chị giải đáp giúp: Làm thế nào để thay tên cột hoặc dòng trong Excel ? (Dùng để trộn thư trong World cho thuận tiện hơn). Cụ thể là có thể thay tên Cột A, B, C...; dòng 1, 2, 3 thành những tên khác theo ý muốn của mình.
Rất cảm ơn các anh chị.

ndu96081631 · 2/9/08

thanhklktu đã viết:
Nhân đây, tôi cũng có 1 câu hỏi muốn nhờ các anh chị giải đáp giúp: Làm thế nào để thay tên cột hoặc dòng trong Excel ? (Dùng để trộn thư trong World cho thuận tiện hơn). Cụ thể là có thể thay tên Cột A, B, C...; dòng 1, 2, 3 thành những tên khác theo ý muốn của mình.
Rất cảm ơn các anh chị.

Bạn có thể thay tên cột từ A, B, C... thành số 1, 2, 3... và cũng chỉ vậy thôi... theo ý muốn của mình thì... xin miển đi
Tôi vẩn hơi thắc mắc: Giã sử ta làm đựoc vụ thay tên đổi họ này thì nó có liên quan gì đến trộn thư nhỉ (mà bạn lại nói là THUẬN TIỆN HƠN)
???

Tiger62 · 2/9/08

Dùng Vlookup tôi thấy là phù hợp đấy, khi cần chỉnh sửa thêm thắt chẳng có vấn đề gì chỉ có chú ý mã ngạch bậc lương trong vùng tham chiếu cần có thứ tự 1,2,a,b .

win4u · 9/9/08

Nhờ điều chỉnh công thức hàm IF

Yêu cầu thể hiên công thức trên cột H với các yêu cầu:

Mã:

[B]với B[/B]
Nếu B <> 0 và E <> 0 thì =(B/E)*(1-F/100)
Nếu B <> 0 và E ="" thì =B*(1-F/100)

[B]với C[/B]
Nếu C <> 0 và E <> 0 thì =C*E*(1-F/100)
Nếu C <> 0 và E ="" thì =C*(1-F/100)

[B]với D[/B]
Nếu D <> 0 và E <> 0 thì =(D/E)*(1-F/100)
Nếu D <> 0 và E ="" thì báo lỗi vì kg có trường hợp này

Em viết như sau:

Mã:

[FONT=Tahoma]=IF(B5<>0,IF(E5<>0,(B5/E5)*(1-F5/100),B5*(1-F5/100)),IF(C5<>0,IF(E5<>0,(C5*E5)*(1-F5/100),C5*(1-F5/100)),IF(D5<>0,IF(E5<>0,(D5*E5)*(1-F5/100),"Sai rồi"),0)))[/FONT]

á á, nhìn nhiều IF với dấu phẩy quá, mắt em hoa lên roài ạ.

Em cần công thức nhanh, chuẩn và dễ hiểu hơn. Bác nào giúp em với!!!

DOSNET · 9/9/08

- Nghe có vẻ điều kiện chưa rõ ràng lắm, tuy nhiên nếu...thì phải if rồi, làm gọn hơn chút thôi

cadafi · 9/9/08

Bạn đưa vào file excel rồi gửi lên được không? Mọi người chẳng lẽ phải làm giúp bạn cả cái file ví dụ mẫu sao?

win4u · 9/9/08

Em có cột B,C,D,E và F.
B,C,D - chỉ có 1 cột có số
E - có thể có số, có thể kg có số
-----------------------------------
Sau đó em cần làm 1 công thức xem xét xem cột nào trong số B,C,D có số và tùy theo biến E thì làm +, -, *, / khác nhau.

Cái file của em đây ạ.

ndu96081631 · 9/9/08

Cái nào cũng nhân với (1-F/100) sao không đưa nó ra ngoài làm thừa số chung:

=(1-F/100)* IF(..... )

Với điều kiện E<>0 thì lấy nó, bằng ngược lại E = 0 thì cho =1... vậy ta có thể không cần IF chổ này và thay nó thành:

((E=0)+E)

Cuối cùng bạn chỉ cần 3 IF cho các trường hợp B, C và D mà thôi

ndu96081631 · 9/9/08

win4u đã viết:
Em có cột B,C,D,E và F.
B,C,D - chỉ có 1 cột có số
E - có thể có số, có thể kg có số
-----------------------------------
Sau đó em cần làm 1 công thức xem xét xem cột nào trong số B,C,D có số và tùy theo biến E thì làm +, -, *, / khác nhau.

Cái file của em đây ạ.

Tôi rút gọn hơn 1 tí thôi:

Mã:

=IF(AND($D2<>0,$E2=""),"Sai rồi",(1-$F2/100)*1/(($E2=0)+$E2)*IF($B2=0,$C2*(($E2=0)+$E2)^2,MAX($B2:$D2)))

Hoặc đặt name để rút gọn như file đính kèm này

=IF(DK,"Sai rồi",TS1*TS2*IF($B2="",$C2*1/TS2^2,MAX($B2:$D2)))

win4u · 9/9/08

1. Bác xem lại chứ em xóa B,C đi, để lại D,E,F thì công thức của bác báo bằng 0.
2. Nếu dùng Name như thế mà em dùng nhiều sheet thì làm sao ạ ?

Cám ơn bác phát hiện giùm em cái thừa số chung =(1-F/100)* IF(..... )

Đoạn này thì em mù tịt hẳn:
(1-$F2/100)*1/(($E2=0)+$E2)*IF($B2=0,$C2*(($E2=0)+$E2)^2,MAX($B2:$D2)))mấy cái này bác cắt nghĩa cho em với:
1. ($E2=0)+$E2)
2. C2*(($E2=0)+$E2)^2

ndu96081631 · 9/9/08

Có lẽ tôi đã suy luận sai nên đã dùng hàm MAX trong file này! Vậy sửa lại nhé

adboy · 9/9/08

Rút gọn hoặc thay thế công thức "If"

Mình có 1 bảng tính đơn giá dựa theo kích thước của thùng vận chuyển, nếu lập c.thức If thì được rồi, nhưng quá dài và quá rối, nhờ các bạn lập dùm mình 1 công thức ngắn gọn nhe (mình làm hàm if nhưng rối quá)

Mình gởi file đính kèm, và có ghi rõ các yêu cầu .

ptm0412 · 9/9/08

Dùng Index và If cho dễ hiểu:
K8 = INDEX($W$5:$AB$7;IF(G8<=300;1;IF(G8<=400;2;3));IF(E8<=1200;1;2)+IF(F8<=300;0;IF(F8<=400;2;4)))

Đó là tra trong bảng, còn MAX: 12M X 2.4 M X 2.4 M tôi không hiểu?

boyxin · 9/9/08

win4u đã viết:
với D
Nếu D <> 0 và E ="" thì báo lỗi vì kg có trường hợp này

Nếu biết trước không có trường hợp này thì cần gì phải IF để ra thông báo

win4u đã viết:
Em viết như sau:
=IF(B5<>0,IF(E5<>0,(B5/E5)*(1-F5/100),B5*(1-F5/100)),IF(C5<>0,IF(E5<>0,(C5*E5)*(1-F5/100),C5*(1-F5/100)),IF(D5<>0,IF(E5<>0,(D5*E5)*(1-F5/100),"Sai rồi"),0)))

Không đúng như yêu cầu

với D
Nếu D <> 0 và E <> 0 thì =(D/E)*(1-F/100)

Với phân tích như trên thì boyxin đề xuất phương án như sau

PHP:

=IF(B5<>0,B5/IF(E5<>0,E5,1),IF(C5<>0,C5*IF(E5<>0,E5,1),IF(D5<>0,D5/IF(E5<>0,E5,1),0)))*(1-F5/100)

Đã test <=> chỉ khác duy nhất chỗ báo lỗi "Sai rồi" còn lại các kết quả y hệt

Nếu vẫn muốn có thông báo lỗi thì

PHP:

=IF((COUNT(B5:E5)=1)*(D5<>0),"Sai rồi",IF(B5<>0,B5/IF(E5<>0,E5,1),IF(C5<>0,C5*IF(E5<>0,E5,1),IF(D5<>0,D5/IF(E5<>0,E5,1),0)))*(1-F5/100))

binhle · 10/9/08

mình cũng đang bị rối giống như bạn

adboy · 10/9/08

Cám ơn bạn PTM0412 nhe, áp dụng được c.thức của bạn rồi, rất gọn và chính xác.

huuthang_bd · 10/9/08

Mình mới tham gia diễn đàn này nhưng cũng xin góp ý kiến về vấn đề này. Giải pháp của mình như sau:

Mã:

=IF(AND(B5=0,C5=0,D5=0),"sai roi",(1-F5%)/((E5=0)+E5)*IF(B5<>0,B5,IF(C5<>0,C5,D5)))

Xin mọi người cho ý kiến.

boyxin · 10/9/08

huuthang_bd đã viết:
Mình mới tham gia diễn đàn này nhưng cũng xin góp ý kiến về vấn đề này. Giải pháp của mình như sau:

Mã:

=IF(AND(B5=0,C5=0,D5=0),"sai roi",(1-F5%)/((E5=0)+E5)*IF(B5<>0,B5,IF(C5<>0,C5,D5)))

Xin mọi người cho ý kiến.

| A | B | C | D | E | F | G | H -Công thức cũ|Công thức của bạn
1 | |2||5| | | |10|0.4

2| |2|1|5| | | | 10|0.4

3| |2|1|5| | | |10|0.4
4| | |1| | | | |Sai rồi|1

5| | |1| | |100| |Sai rồi|0

huuthang_bd · 10/9/08

Theo như hình bạn post lên diễn đàn thì bạn hiểu sai đề bài rồi. Trong ví dụ của bạn, ở row4 và row5 cột C có số liệu thì không thể ra kết quả "Sai rồi" được.

win4u đã viết:
Em có cột B,C,D,E và F.
B,C,D - chỉ có 1 cột có số
E - có thể có số, có thể kg có số
-----------------------------------
Sau đó em cần làm 1 công thức xem xét xem cột nào trong số B,C,D có số và tùy theo biến E thì làm +, -, *, / khác nhau.

Cái file của em đây ạ.

Đây là file ví dụ của mình.

boyxin · 10/9/08

huuthang_bd đã viết:
Theo như hình bạn post lên diễn đàn thì bạn hiểu sai đề bài rồi. Trong ví dụ của bạn, ở row4 và row5 cột C có số liệu thì không thể ra kết quả "Sai rồi" được.

Đây là file ví dụ của mình.

he he he, để mình nói câu này nhé

Theo bạn rút gọn công thức là gì?
Theo mình: muốn rút gọn kiểu gì cũng được, nhưng kết quả của công thức cũ (chưa gọn) và kết quả của công thức đã rút gọn (công thức mới) là phải như nhau (cùng cho 1 kết quả nếu các điều kiện, dữ liệu đầu vào giống nhau) và lẽ đương nhiên là phải gọn hơn, nhìn vào dễ hiểu hơn ...
Từ file đính kèm của bạn, hãy nhập công thức nguyên thủy của tác giả vào rồi so sánh kết quả sẽ thấy
Công thức nguyên thủy của tác giả đây nè

PHP:

=IF(B5<>0,IF(E5<>0,(B5/E5)*(1-F5/100),B5*(1-F5/100)),IF(C5<>0,IF(E5<>0,(C5*E5)*(1-F5/100),C5*(1-F5/100)),IF(D5<>0,IF(E5<>0,(D5*E5)*(1-F5/100),"Sai rồi"),0)))

huuthang_bd · 11/9/08

Tác giả yêu cầu điều chỉnh công thức chứ ko chỉ là rút gọn. Nếu công thức của tác giả ko đúng với yêu cầu của đề bài liệu ta có nên rút gọn theo công thức đó ko???
Trong trường hợp này nếu vẫn muốn rút gọn theo công thức của tác giả thì phương án của bạn vẫn chưa phải là tối ưu.
1. Nếu dữ liệu ở các ô B5, C5 ko phải là ô trống mà 0 thì hàm Count của bạn hoàn toàn ko có tác dụng và kết quả đương nhiêu là ko đúng với yêu cầu của tác giả. Bạn xem file đính kèm sẽ thấy rõ hơn.
2. Công thức của bạn vẫn còn khá dài.
Nếu muốn rút gọn công thức cũ của tác giả thì mình có phương án này gọn hơn, chuẩn hơn.

Mã:

=IF((SUM(B5:E5)=D5)*(D5<>0),"sai roi",(1-F5%)/((E5=0)+E5)*IF(B5<>0,B5,IF(C5<>0,C5*((E5=0)+E5)^2,D5)))

Thân!

mrphansu · 25/9/08

nói rõ hơn dc không? tôi không hiểu. Thank trước nhá.

huuthang_bd · 25/9/08

nói rõ hơn dc không? tôi không hiểu. Thank trước nhá.

Bạn không hiểu đoạn nào? Đoạn này hả?

Để tổng quát cho trường hợp các giá trị cột C là sp001; sp002; ...; sp1000 ... thì nên dùng =MID($C2;3;10)*1 thay cho Right.

Đoạn này có nghĩa là trong trường hợp MHS là sp1000 nếu dùng hàm Right() thì chuỗi 3 ký tự cuối là 000 lúc đó sp1000 sẽ nhỏ hơn sp001, công thức sẽ sai. Còn nếu dùng hàm Mid thì sẽ lấy từ ký tự thứ tư trở đi, kết quả là chuỗi ký tự 1000, so với 001 của MHS sp001 thì vẫn lớn hơn.

To duongsatdn.
Mình nghĩ người ta đã thiết kế MHS là sp001 tức là người ta đã biết trước không quá 1000 MHS. Nếu biết trước có hơn 1000 MHS thì sẽ đặt MHS là sp0001 hoặc sp1 chứ không đặt là sp001 đâu.

BNTT · 25/9/08

anhtuan1066 đã viết:
Thế thì theo công thức của ThuNghi, nhưng có thể rút gọn 1 chút
Thay VALUE(RIGHT($C2,3))>2 thành RIGHT($C2,3)*1>2
hoặc RIGHT($C2,1)*1>2 nếu số mã phía sau ko lớn hơn 10

Nếu số mã phía sau không lớn hơn 10 thì... ngắn hơn tí nữa:

RIGHT($C2)*1>2

cadafi · 25/9/08

Bạn thử công thức này xem:

=IF(AND($B2>DATE(2007,5,15),--MID($C2,3,LEN($C2)-2))>2) ,$D2*$E2,$D2*$F2)

vncnghia · 25/9/08

Gởi CATHY

Tôi đính kèm file cho bạn thấy rõ hơn nè, tôi lấy ý kiến của các bạn gởi cho bạn trong file này. --=0

kimlan · 4/10/08

Kết hợp 3 hàm if or and

Em có một bài kết hợp 3 hàm mà em giải không ra có ai đó biết chỉ giùm em với nha.
Đó là: nếu cột a là HN hoặc HL và là T thì được 300 còn lại là 0.

cadafi · 4/10/08

kimlan đã viết:
Em có một bài kết hợp 3 hàm mà em giải không ra có ai đó biết chỉ giùm em với nha.
Đó là: nếu cột a là HN hoặc HL và là T thì được 300 còn lại là 0.

Xin lỗi bạn, nhưng tôi không hiểu: Cột A làm sao vừa là HN/HL và là T được. Giống như 2 = 3 vậy??? Bạn có thể nói rõ hơn không?

salam · 4/10/08

kimlan đã viết:
Em có một bài kết hợp 3 hàm mà em giải không ra có ai đó biết chỉ giùm em với nha.
Đó là: nếu cột a là HN hoặc HL và là T thì được 300 còn lại là 0.

Cột A đã là HL thì sao lại là T được nữa nhỉ, Bạn xem lại đề bài xem.
hay là hoặc là HN hoặc là HL hoặc T

Mã:

=IF(OR(A1="HN",A1="HL",A1="T"),300,0)

ptm0412 · 4/10/08

Không và được đâu, trừ khi:
nếu cột a là HN hoặc HL và cột B là T ...
Thi dụ: nếu ai hộ khẩu tại HN hoặc HL, và giới tính nữ là True thì ....

mymichau · 4/10/08

Em cũng bí về cách lồng 3 hàm : If, Search, Or như trong File Ví dụ. Nhờ các Anh chỉ giúp.

ptm0412 · 4/10/08

- Or nằm ngoài, 2 cái search nằm trong.
- Search() phải sửa thành IsError(search())
- đổi ngược lại Z và X

BNTT · 4/10/08

mymichau đã viết:
Em cũng bí về cách lồng 3 hàm : If, Search, Or như trong File Ví dụ. Nhờ các Anh chỉ giúp.

Cụ thể hơn cái lý thuyết của anh Ptm0412:

Cột C =IF(ISERROR(SEARCH(" "&"B"&" ",$B4)),"Z","X")

Cột D =IF(ISERROR(SEARCH(" "&"A"&" ",$B4)),"Z","X")

Cột E: Mặc dù lý thuyết là "Nếu trong cột B có chữ A hoặc chữ B", nhưng khi dùng ISERROR, thì phải hiểu là: "Nếu như có lỗi khi tìm chữ A và chữ B trong cột A", do đó phải dùng AND. Nếu dùng OR thì lúc nào nó cũng sai hết.

=IF(AND(ISERROR(SEARCH(" "&"A"&" ",$B4)),ISERROR(SEARCH(" "&"B"&" ",$B4))),"Z","X")

ptm0412 · 4/10/08

Nếu dùng OR thì lúc nào nó cũng sai hết

Đúng rồi, vì:
Not(A Or B) = Not(A) And Not(B) (viết theo theo luận lý học)
Not(Or(A,B)) = And(Not(A), Not(B)) (viết theo hàm Excel)
Cám ơn BNTT đã nhắc nhở.

viendo · 6/10/08

salam đã viết:
Cột A đã là HL thì sao lại là T được nữa nhỉ, Bạn xem lại đề bài xem.
hay là hoặc là HN hoặc là HL hoặc T

Mã:

=IF(OR(A1="HN",A1="HL",A1="T"),300,0)

Trường hợp này ta có thể bỏ luôn hàm IF được :

=OR((A1="HL"),(A1="T"),(A1="HN"))*300

minhvukhanh · 6/10/08

Em đang làm lại bài tập này mà không hiểu sao không được, rõ ràng trước làm ngon mà. Các bác chỉ giúp em với. Thanks.

Tính cột giá thành=Thành tiền+Thuế+thưởng (dùng hàm if)
Trong đó cột thành tiền và thuế sau khi tính toán đã có đầy đủ số liệu rồi
Cột thưởng thì có người được, có người không (để trống)
Em dùng công thức thế này:

=if(thưởng>0,thành tiền+thuế+thưởng,if(thưởng=" ",thành tiền+thuế+0))

dùng công thức này thì những cột thưởng nào mà có dữ liệu thì cho kết quả đúng, nhưng cột thưởng nào không có dữ liều thì nó báo #VALUE!

Hic, em không tải file lên được, các bác thông cảm nhé.

ptm0412 · 6/10/08

Cột thưởng thì có người được, có người không (để trống)

if(thưởng=" ", . . .

Trống và " " khác nhau bạn à,
- nếu thực sự là trống thí bạn cứ cộng thành tiền+thuế+thưởng không cần if.
- nếu nhìn thì trống, nhưng do công thức mà trống, thì xem lại công thức trả về là 0, hay là "", hay là " " để IF cho đúng.

ngoài ra công thức If của bạn chưa đúng chuẩn: thiếu giá trị trả về nếu đk không thoả. Công thức đúng là:
= If(thưởng>0,thành tiền+thuế+thưởng, thành tiền+thuế)

Khỏi cần cộng zero nha bạn.

BNTT · 6/10/08

minhvukhanh đã viết:
Em đang làm lại bài tập này mà không hiểu sao không được, rõ ràng trước làm ngon mà. Các bác chỉ giúp em với. Thanks.

Tính cột giá thành=Thành tiền+Thuế+thưởng (dùng hàm if)
Trong đó cột thành tiền và thuế sau khi tính toán đã có đầy đủ số liệu rồi
Cột thưởng thì có người được, có người không (để trống)
Em dùng công thức thế này:

=if(thưởng>0,thành tiền+thuế+thưởng,if(thưởng=" ",thành tiền+thuế+0))

dùng công thức này thì những cột thưởng nào mà có dữ liệu thì cho kết quả đúng, nhưng cột thưởng nào không có dữ liều thì nó báo #VALUE!

Hic, em không tải file lên được, các bác thông cảm nhé.

Bạn thử lại như vầy xem sao:

=thành tiền + thuế + IF(OR(thưởng="", thưởng=0), 0, thưởng)

Lưu ý: Dấu "" là liền nhau, không phải là " "

hoangminhtien · 6/10/08

minhvukhanh đã viết:
Em đang làm lại bài tập này mà không hiểu sao không được, rõ ràng trước làm ngon mà. Các bác chỉ giúp em với. Thanks.

Tính cột giá thành=Thành tiền+Thuế+thưởng (dùng hàm if)
Trong đó cột thành tiền và thuế sau khi tính toán đã có đầy đủ số liệu rồi
Cột thưởng thì có người được, có người không (để trống)
Em dùng công thức thế này:

=if(thưởng>0,thành tiền+thuế+thưởng,if(thưởng=" ",thành tiền+thuế+0))

dùng công thức này thì những cột thưởng nào mà có dữ liệu thì cho kết quả đúng, nhưng cột thưởng nào không có dữ liều thì nó báo #VALUE!

Hic, em không tải file lên được, các bác thông cảm nhé.

bài này bạn không cần dùng if cũng được. bạn chỉ cần
=thành tiền+thuế+thưởng

rollover79 · 6/10/08

hoangminhtien đã viết:
bài này bạn không cần dùng if cũng được. bạn chỉ cần
=thành tiền+thuế+thưởng

Công thức này nếu thưởng mà là 1 dấu cách là sẽ có vấn đề, trong trường hợp này nên dùng hàm SUM

Mã:

    =SUM(Thành tiền,Thuế,Thưởng)

Nếu liền nhau thì chọn cả vùng 3 ô luôn cho nhanh

minhvukhanh · 6/10/08

rollover79 đã viết:
Công thức này nếu thưởng mà là 1 dấu cách là sẽ có vấn đề, trong trường hợp này nên dùng hàm SUM

Mã:

=SUM(Thành tiền,Thuế,Thưởng)

Nếu liền nhau thì chọn cả vùng 3 ô luôn cho nhanh

Hàm SUM thì làm được bác ạ. Mỗi tội em nhớ là lần trước làm hàm IF và đề bài cũng yêu cầu dùng hàm IF. Thanks bác $-\\/.$

hoangminhtien đã viết:
bài này bạn không cần dùng if cũng được. bạn chỉ cần
=thành tiền+thuế+thưởng

Thanks bạn nhưng công thức này không được, mình đã thử rồi, chỉ được với ô mà thưởng có dữ liệu thôi

ptm0412 đã viết:
Trống và " " khác nhau bạn à,
- nếu thực sự là trống thí bạn cứ cộng thành tiền+thuế+thưởng không cần if.
- nếu nhìn thì trống, nhưng do công thức mà trống, thì xem lại công thức trả về là 0, hay là "", hay là " " để IF cho đúng.

ngoài ra công thức If của bạn chưa đúng chuẩn: thiếu giá trị trả về nếu đk không thoả. Công thức đúng là:
= If(thưởng>0,thành tiền+thuế+thưởng, thành tiền+thuế)

Khỏi cần cộng zero nha bạn.

Cột thưởng có ô trống không dữ liệu là do công thức mà trống, công thức trả về là " " bạn ạ.

Ui có ai giải thích được hộ tớ tại sao tớ up file lên đều báo là không được mặc dù file chỉ có 21kb thôi không (xlxs), thế để các bạn nhìn cho dễ ý mà.

ptm0412 · 6/10/08

Nếu vậy thì
=thành tiền + thuế + if(thưởng <>" ", thưởng, 0)
hoặc
=thành tiền + thuế + if(isnumber(thưởng), thưởng, 0)

minhvukhanh · 7/10/08

Thanks các bác, cuối cùng theo gợi ý của bác Ptm0412 em đã làm được theo công thức sau:

=if(thưởng<>"",thành tiền+thuế+thưởng,if(thưởng="",thành tiền+thuế))

Cảm ơn các bác rất nhiều

Những vấn đề về hàm IF (2 người xem)

Người dùng đang xem chủ đề này

Huyền thoại GPE

Thành viên mới

Thành viên thường trực

File đính kèm

Bùi Nguyễn Triệu Tường

Thành viên tiêu biểu

File đính kèm

Thành viên mới

File đính kèm

Thành viên thường trực

File đính kèm

Hãy cho rồi sẽ nhận!

Thành viên mới

File đính kèm

Bùi Nguyễn Triệu Tường

Nguyệt Hà

Nguyễn Cảnh Hoàng Danh

(*_*)

Thành viên thường trực

Nguyệt Hà

File đính kèm

Nguyễn Cảnh Hoàng Danh

Bùi Nguyễn Triệu Tường

Thành viên tích cực

Thành viên gắn bó

Nguyễn Cảnh Hoàng Danh

Thành viên gắn bó

Nguyệt Hà

Thành viên gắn bó

Thành viên mới

File đính kèm

Thành viên thường trực

File đính kèm

Hành động từ trái tim

Thành viên mới

Bùi Nguyễn Triệu Tường

Thành viên mới

Huyền thoại GPE

Thành viên mới

Thành viên tích cực

Thành viên mới

File đính kèm

Thành viên mới

Hành động từ trái tim

Thành viên mới

Hành động từ trái tim

Bùi Nguyễn Triệu Tường

Thành viên mới

Thành viên thường trực

Huyền thoại GPE

Thành viên thường trực

File đính kèm

VBA & VB.NET for Excel & AutoCad

Members actively

Thành viên mới

Bùi Nguyễn Triệu Tường

Hành động từ trái tim

Thành viên mới

Thành viên gắn bó

Bùi Nguyễn Triệu Tường

Thành viên mới

File đính kèm

Thành viên mới

Coming back ...

/(hông là gì!

Coming back ...

Huyền thoại GPE

-

Thành viên mới

Huyền thoại GPE

Thành viên hoạt động

Thành viên mới

Thành viên gắn bó

Hành động từ trái tim

Thành viên mới

File đính kèm

Huyền thoại GPE

Huyền thoại GPE

(_)